data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Unregister()
   5 {
   6         if(self.owner && self.owner.lastrocket == self)
   7         {
   8                 self.owner.lastrocket = world;
   9                 // self.owner.rl_release = 1;
  10         }
  11 }
  12
  13 void W_Rocket_Explode (void)
  14 {
  15         W_Rocket_Unregister();
  16
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  19
  20         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  21         {
  22                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  23                 {
  24                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  25                         ATTACK_FINISHED(self.owner) = time;
  26                         self.owner.switchweapon = w_getbestweapon(self.owner);
  27                 }
  28                 if(g_laserguided_missile)
  29                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
  30         }
  31         remove (self);
  32 }
  33
  34 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  35 {
  36         entity head, selected;
  37         vector dir;
  38         float dist, maxdist,// bestdist,
  39                 dot,// bestdot,
  40                 points, bestpoints;
  41         //bestdist = 9999;
  42         //bestdot = -2;
  43         bestpoints = 0;
  44         maxdist = 800;
  45         selected = world;
  46
  47         makevectors(e.angles);
  48
  49         head = find(world, classname, "laser_target");
  50         while(head)
  51         {
  52                 points = 0;
  53                 dir = normalize(head.origin - self.origin);
  54                 dot = dir * v_forward;
  55                 dist = vlen(head.origin - self.origin);
  56                 if(dist > maxdist)
  57                         dist = maxdist;
  58
  59                 // gain points for being in front
  60                 points = points + ((dot+1)*0.5) * 500
  61                         * (1 + crandom()*dot_variance);
  62                 // gain points for being close away
  63                 points = points + (1 - dist/maxdist) * 1000
  64                         * (1 + crandom()*dot_variance);
  65
  66                 traceline(e.origin, head.origin, TRUE, self);
  67                 if(trace_fraction < 1)
  68                 {
  69                         points = 0;
  70                 }
  71
  72                 if(points > bestpoints)//random() > 0.5)//
  73                 {
  74                         bestpoints = points;
  75                         selected = head;
  76                 }
  77
  78                 head = find(head, classname, "laser_target");
  79         }
  80
  81         //bprint(selected.owner.netname);
  82         //bprint("\n");
  83         return selected;
  84 }
  85
  86 void W_Rocket_RemoteExplode()
  87 {
  88         if(self.owner.deadflag == DEAD_NO)
  89         if(self.owner.lastrocket)
  90         {
  91                 if((self.spawnshieldtime >= 0)
  92                         ? (time >= self.spawnshieldtime) // timer
  93                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  94                 )
  95                 {
  96                         other = world;
  97                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  98                         W_Rocket_Explode ();
  99                 }
 100                 else
 101                 {
 102                 }
 103         }
 104 }
 105
 106 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 107 {
 108         if(thisdir * goaldir > maxturn_cos)
 109                 return goaldir;
 110         float f, m2;
 111         vector v;
 112         // solve:
 113         //   g = normalize(thisdir + goaldir * X)
 114         //   thisdir * g = maxturn
 115         //
 116         //   gg = thisdir + goaldir * X
 117         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 118         //
 119         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 120         f = thisdir * goaldir;
 121         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 122         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 123         m2 = maxturn_cos * maxturn_cos;
 124         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 125         return normalize(thisdir + goaldir * v_y); // the larger solution!
 126 }
 127
 128 void W_Rocket_Think (void)
 129 {
 130         entity e;
 131         vector desireddir, olddir, newdir, desiredorigin, goal;
 132         float turnrate, velspeed, f;
 133         self.nextthink = time;
 134         if (time > self.cnt)
 135         {
 136                 other = world;
 137                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 138                 W_Rocket_Explode ();
 139                 return;
 140         }
 141
 142         if(g_laserguided_missile)
 143         {
 144                 // accelerate
 145                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 146                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 147                 if (velspeed > 0)
 148                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 149         }
 150         else
 151         {
 152                 // accelerate
 153                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 154                 velspeed = cvar("g_balance_rocketlauncher_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 155                 if (velspeed > 0)
 156                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * g_weaponspeedfactor * frametime, velspeed);
 157         }
 158
 159         // laser guided, or remote detonation
 160         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 161         {
 162                 if(g_laserguided_missile)
 163                 {
 164                         if(self.rl_detonate_later)
 165                                 W_Rocket_RemoteExplode();
 166
 167                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 168                         {
 169                                 if(self.owner.laser_on)
 170                                 {
 171                                         if(self.attack_finished_single < time)
 172                                         {
 173                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 174                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 175                                         }
 176
 177                                         if(!self.enemy)
 178                                                 self.enemy = self.owner.weaponentity.lasertarget;
 179                                 }
 180                                 else self.enemy = world;
 181                         }
 182                         else // don't allow stealing: always target my owner's laser (if it exists)
 183                                 self.enemy = self.owner.weaponentity.lasertarget;
 184
 185                         if(self.enemy != world)
 186                         {
 187                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 188                                 velspeed = vlen(self.velocity);
 189                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 190                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 191                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 192                                 olddir = normalize(self.velocity);                                      // get my current direction
 193                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 194                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 195                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 196
 197                                 ATTACK_FINISHED(self.owner) = time + 0.2 * W_WeaponRateFactor();
 198                         }
 199                 }
 200                 else
 201                 {
 202                         if(self == self.owner.lastrocket)
 203                         if(!self.owner.rl_release)
 204                         if(cvar("g_balance_rocketlauncher_guiderate"))
 205                         if(time > self.pushltime)
 206                         if(self.owner.deadflag == DEAD_NO)
 207                         {
 208                                 f = min(1, (time - self.pushltime) / cvar("g_balance_rocketlauncher_guideratedelay"));
 209                                 velspeed = vlen(self.velocity);
 210
 211                                 makevectors(self.owner.v_angle);
 212                                 desireddir = v_forward;
 213                                 desiredorigin = self.owner.origin + self.owner.view_ofs;
 214                                 olddir = normalize(self.velocity);
 215
 216                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 217                                 // but we are limiting the rate at which we can turn!
 218                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 219                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * f * frametime * PI / 180));
 220
 221                                 self.velocity = newdir * velspeed;
 222                         }
 223
 224                         if(self.rl_detonate_later)
 225                                 W_Rocket_RemoteExplode();
 226                 }
 227         }
 228
 229         if(self.csqcprojectile_clientanimate == 0)
 230                 UpdateCSQCProjectile(self);
 231 }
 232
 233 void W_Rocket_Touch (void)
 234 {
 235         W_Rocket_Unregister();
 236
 237         PROJECTILE_TOUCH;
 238         W_Rocket_Explode ();
 239 }
 240
 241 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 242 {
 243         if (self.health <= 0)
 244                 return;
 245         self.health = self.health - damage;
 246         self.angles = vectoangles(self.velocity);
 247         if (self.health <= 0)
 248                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 249 }
 250
 251 void W_Rocket_Attack (void)
 252 {
 253         local entity missile;
 254         local entity flash;
 255
 256         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 257                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 258
 259         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", cvar("g_balance_rocketlauncher_damage"));
 260         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 261
 262         missile = spawn ();
 263         missile.owner = self;
 264         self.lastrocket = missile;
 265         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 266                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 267         else
 268                 missile.spawnshieldtime = -1;
 269         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 270         missile.classname = "rocket";
 271         missile.bot_dodge = TRUE;
 272         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 273
 274         missile.takedamage = DAMAGE_YES;
 275         missile.damageforcescale = cvar("g_balance_rocketlauncher_damageforcescale");
 276         missile.health = cvar("g_balance_rocketlauncher_health");
 277         missile.event_damage = W_Rocket_Damage;
 278
 279         missile.movetype = MOVETYPE_FLY;
 280         PROJECTILE_MAKETRIGGER(missile);
 281         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 282         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 283
 284         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 285         if(g_laserguided_missile && self.laser_on)
 286                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart") * g_weaponspeedfactor;
 287         else
 288                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart") * g_weaponspeedfactor;
 289         W_SetupProjectileVelocity(missile);
 290         missile.angles = vectoangles (missile.velocity);
 291
 292         missile.touch = W_Rocket_Touch;
 293         missile.think = W_Rocket_Think;
 294         missile.nextthink = time;
 295         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 296         missile.flags = FL_PROJECTILE;
 297
 298         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 299
 300         // muzzle flash for 1st person view
 301         flash = spawn ();
 302         setmodel (flash, "models/flash.md3"); // precision set below
 303         SUB_SetFade (flash, time, 0.1);
 304         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 305         W_AttachToShotorg(flash, '5 0 0');
 306
 307         // common properties
 308 }
 309
 310 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 311
 312 float w_rlauncher(float req)
 313 {
 314         entity rock;
 315         float rockfound;
 316         if (req == WR_AIM)
 317         {
 318                 // aim and decide to fire if appropriate
 319                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 320                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 321                 {
 322                         // decide whether to detonate rockets
 323                         local entity missile, targetlist, targ;
 324                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 325                         local float selfdamage, teamdamage, enemydamage;
 326                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 327                         coredamage = cvar("g_balance_rocketlauncher_damage");
 328                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 329                         recipricoledgeradius = 1 / edgeradius;
 330                         selfdamage = 0;
 331                         teamdamage = 0;
 332                         enemydamage = 0;
 333                         targetlist = findchainfloat(bot_attack, TRUE);
 334                         missile = find(world, classname, "rocket");
 335                         while (missile)
 336                         {
 337                                 if (missile.owner != self)
 338                                 {
 339                                         missile = find(missile, classname, "rocket");
 340                                         continue;
 341                                 }
 342                                 targ = targetlist;
 343                                 while (targ)
 344                                 {
 345                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 346                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 347                                         // count potential damage according to type of target
 348                                         if (targ == self)
 349                                                 selfdamage = selfdamage + d;
 350                                         else if (targ.team == self.team && teams_matter)
 351                                                 teamdamage = teamdamage + d;
 352                                         else if (bot_shouldattack(targ))
 353                                                 enemydamage = enemydamage + d;
 354                                         targ = targ.chain;
 355                                 }
 356                                 missile = find(missile, classname, "rocket");
 357                         }
 358                         local float desirabledamage;
 359                         desirabledamage = enemydamage;
 360                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 361                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 362                         if (self.team && teamplay != 1)
 363                                 desirabledamage = desirabledamage - teamdamage;
 364
 365                         missile = find(world, classname, "rocket");
 366                         while (missile)
 367                         {
 368                                 if (missile.owner != self)
 369                                 {
 370                                         missile = find(missile, classname, "rocket");
 371                                         continue;
 372                                 }
 373                                 makevectors(missile.v_angle);
 374                                 targ = targetlist;
 375                                 if (skill > 9) // normal players only do this for the target they are tracking
 376                                 {
 377                                         targ = targetlist;
 378                                         while (targ)
 379                                         {
 380                                                 if (
 381                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 382                                                         && desirabledamage > 0.1*coredamage
 383                                                 )self.BUTTON_ATCK2 = TRUE;
 384                                                 targ = targ.chain;
 385                                         }
 386                                 }else{
 387                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 388                                         //As the distance gets larger, a correct detonation gets near imposible
 389                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 390                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 391                                                 if(self.enemy.classname == "player")
 392                                                         if(desirabledamage >= 0.1*coredamage)
 393                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 394                                                                         self.BUTTON_ATCK2 = TRUE;
 395                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 396                                 }
 397
 398                                 missile = find(missile, classname, "rocket");
 399                         }
 400                         // if we would be doing at X percent of the core damage, detonate it
 401                         // but don't fire a new shot at the same time!
 402                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 403                                 self.BUTTON_ATCK2 = TRUE;
 404                         if ((skill > 6.5) && (selfdamage > self.health))
 405                                 self.BUTTON_ATCK2 = FALSE;
 406                         //if(self.BUTTON_ATCK2 == TRUE)
 407                         //      dprint(ftos(desirabledamage),"\n");
 408                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 409                 }
 410         }
 411         else if (req == WR_THINK)
 412         {
 413                 if(g_laserguided_missile)
 414                 {
 415                         if (self.BUTTON_ATCK && self.rl_release)
 416                         {
 417                                 rockfound = 0;
 418                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 419                                 {
 420                                         if(!rock.rl_detonate_later)
 421                                         {
 422                                                 rock.rl_detonate_later = TRUE;
 423                                                 rockfound = 1;
 424                                         }
 425                                 }
 426                                 if(rockfound)
 427                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 428                                 else
 429                                 {
 430                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 431                                         {
 432                                                 W_Rocket_Attack();
 433                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 434                                         }
 435                                 }
 436                                 self.rl_release = 0;
 437                         }
 438                         if (!self.BUTTON_ATCK)
 439                                 self.rl_release = 1;
 440                         if (self.BUTTON_ATCK2)
 441                         if(self.exteriorweaponentity.attack_finished_single < time)
 442                         {
 443                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 444                                 self.laser_on = !self.laser_on;
 445                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 446                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 447                         }
 448                 }
 449                 else
 450                 {
 451                         if (self.BUTTON_ATCK)
 452                         {
 453                                 if(self.rl_release)
 454                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 455                                 {
 456                                         W_Rocket_Attack();
 457                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 458                                         self.rl_release = 0;
 459                                 }
 460                         }
 461                         else
 462                                 self.rl_release = 1;
 463
 464                         if (self.BUTTON_ATCK2)
 465                         {
 466                                 rockfound = 0;
 467                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 468                                 {
 469                                         if(!rock.rl_detonate_later)
 470                                         {
 471                                                 rock.rl_detonate_later = TRUE;
 472                                                 rockfound = 1;
 473                                         }
 474                                 }
 475                                 if(rockfound)
 476                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 477                         }
 478                 }
 479         }
 480         else if (req == WR_PRECACHE)
 481         {
 482                 precache_model ("models/flash.md3");
 483                 precache_model ("models/weapons/g_rl.md3");
 484                 precache_model ("models/weapons/v_rl.md3");
 485                 precache_model ("models/weapons/h_rl.dpm");
 486                 precache_sound ("weapons/rocket_det.wav");
 487                 precache_sound ("weapons/rocket_fire.wav");
 488                 if (g_laserguided_missile)
 489                 {
 490                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 491                         precache_sound ("weapons/rocket_mode.wav");
 492                 }
 493         }
 494         else if (req == WR_SETUP)
 495         {
 496                 weapon_setup(WEP_ROCKET_LAUNCHER);
 497                 self.rl_release = 1;
 498         }
 499         else if (req == WR_CHECKAMMO1)
 500         {
 501                 // don't switch while guiding a missile
 502                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 503                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 504                         return FALSE;
 505         }
 506         else if (req == WR_CHECKAMMO2)
 507                 return FALSE;
 508         else if (req == WR_SUICIDEMESSAGE)
 509                 w_deathtypestring = "exploded";
 510         else if (req == WR_KILLMESSAGE)
 511         {
 512                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 513                         w_deathtypestring = "got too close to #'s rocket";
 514                 else if(w_deathtype & HITTYPE_SPLASH)
 515                         w_deathtypestring = "almost dodged #'s rocket";
 516                 else
 517                         w_deathtypestring = "ate #'s rocket";
 518         }
 519         return TRUE;
 520 };