data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
   8         org2 = findbetterlocation (self.origin, 16);
   9
  10         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
  11
  12         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  13         self.event_damage = SUB_Null;
  14         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  15
  16         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  17         {
  18                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  19                 {
  20                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  21                         ATTACK_FINISHED(self.owner) = time;
  22                         self.owner.switchweapon = w_getbestweapon(self.owner);
  23                 }
  24                 if(g_laserguided_missile)
  25                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  26         }
  27         remove (self);
  28 }
  29
  30 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  31 {
  32         entity head, selected;
  33         vector dir;
  34         float dist, maxdist,// bestdist,
  35                 dot,// bestdot,
  36                 points, bestpoints;
  37         //bestdist = 9999;
  38         //bestdot = -2;
  39         bestpoints = 0;
  40         maxdist = 800;
  41         selected = world;
  42
  43         makevectors(e.angles);
  44
  45         head = find(world, classname, "laser_target");
  46         while(head)
  47         {
  48                 points = 0;
  49                 dir = normalize(head.origin - self.origin);
  50                 dot = dir * v_forward;
  51                 dist = vlen(head.origin - self.origin);
  52                 if(dist > maxdist)
  53                         dist = maxdist;
  54
  55                 // gain points for being in front
  56                 points = points + ((dot+1)*0.5) * 500
  57                         * (1 + crandom()*dot_variance);
  58                 // gain points for being close away
  59                 points = points + (1 - dist/maxdist) * 1000
  60                         * (1 + crandom()*dot_variance);
  61
  62                 traceline(e.origin, head.origin, TRUE, self);
  63                 if(trace_fraction < 1)
  64                 {
  65                         points = 0;
  66                 }
  67
  68                 if(points > bestpoints)//random() > 0.5)//
  69                 {
  70                         bestpoints = points;
  71                         selected = head;
  72                 }
  73
  74                 head = find(head, classname, "laser_target");
  75         }
  76
  77         //bprint(selected.owner.netname);
  78         //bprint("\n");
  79         return selected;
  80 }
  81
  82 void W_Rocket_RemoteExplode()
  83 {
  84         if(self.owner.deadflag == DEAD_NO)
  85         {
  86                 if((self.spawnshieldtime >= 0)
  87                         ? (time >= self.spawnshieldtime) // timer
  88                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  89                 )
  90                 {
  91                         other = world;
  92                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  93                         W_Rocket_Explode ();
  94                 }
  95                 else
  96                 {
  97                 }
  98         }
  99 }
 100
 101 void W_Rocket_Think (void)
 102 {
 103         entity e;
 104         vector desireddir, olddir, newdir;
 105         float turnrate, velspeed;
 106         self.nextthink = time;
 107         if (time > self.cnt)
 108         {
 109                 other = world;
 110                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 111                 W_Rocket_Explode ();
 112                 return;
 113         }
 114
 115         if(g_laserguided_missile)
 116         {
 117                 // accelerate
 118                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 119                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 120                 if (velspeed > 0)
 121                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 122         }
 123         else
 124         {
 125                 // accelerate
 126                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 127                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 128                 if (velspeed > 0)
 129                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 130         }
 131
 132         // laser guided, or remote detonation
 133         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 134         {
 135                 if(g_laserguided_missile)
 136                 {
 137                         if(self.rl_detonate_later)
 138                                 W_Rocket_RemoteExplode();
 139
 140                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 141                         {
 142                                 if(self.owner.laser_on)
 143                                 {
 144                                         if(self.attack_finished_single < time)
 145                                         {
 146                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 147                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 148                                         }
 149
 150                                         if(!self.enemy)
 151                                                 self.enemy = self.owner.weaponentity.lasertarget;
 152                                 }
 153                                 else self.enemy = world;
 154                         }
 155                         else // don't allow stealing: always target my owner's laser (if it exists)
 156                                 self.enemy = self.owner.weaponentity.lasertarget;
 157
 158                         if(self.enemy != world)
 159                         {
 160                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 161                                 velspeed = vlen(self.velocity);
 162                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 163                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 164                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 165                                 olddir = normalize(self.velocity);                                      // get my current direction
 166                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 167                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 168                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 169
 170                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 171                         }
 172                 }
 173                 else
 174                 {
 175                         if(self.rl_detonate_later)
 176                                 W_Rocket_RemoteExplode();
 177                 }
 178         }
 179
 180         if(self.csqcprojectile_clientanimate == 0)
 181                 UpdateCSQCProjectile(self);
 182 }
 183
 184 void W_Rocket_Touch (void)
 185 {
 186         if(self.owner && self.owner.lastrocket == self)
 187                 self.owner.lastrocket = world;
 188         PROJECTILE_TOUCH;
 189         W_Rocket_Explode ();
 190 }
 191
 192 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 193 {
 194         self.health = self.health - damage;
 195         self.angles = vectoangles(self.velocity);
 196         if (self.health <= 0)
 197                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 198 }
 199
 200 void W_Rocket_Attack (void)
 201 {
 202         local entity missile;
 203         local entity flash, flash2;
 204
 205         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 206                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 207
 208         W_SetupShot (self, '25 3 -4', FALSE, 5, "weapons/rocket_fire.wav");
 209         //W_SetupShot (self, '25 8 -8', FALSE, 5, "weapons/rocket_fire.wav"); // TODO: move model to the right a little
 210         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 211
 212         missile = spawn ();
 213         missile.owner = self;
 214         self.lastrocket = missile;
 215         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 216                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 217         else
 218                 missile.spawnshieldtime = -1;
 219         missile.classname = "rocket";
 220         missile.bot_dodge = TRUE;
 221         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 222
 223         missile.takedamage = DAMAGE_YES;
 224         missile.damageforcescale = 4;
 225         missile.health = cvar("g_balance_rocketlauncher_health");
 226         missile.event_damage = W_Rocket_Damage;
 227
 228         missile.movetype = MOVETYPE_FLY;
 229         missile.solid = SOLID_BBOX;
 230         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 231         setmodel (missile, "models/rocket.md3"); // precision set below
 232         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 233
 234         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 235         if(g_laserguided_missile && self.laser_on)
 236                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 237         else
 238                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 239         W_SetupProjectileVelocity(missile);
 240         missile.angles = vectoangles (missile.velocity);
 241
 242         missile.touch = W_Rocket_Touch;
 243         missile.think = W_Rocket_Think;
 244         missile.nextthink = time;
 245         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 246         missile.effects = EF_LOWPRECISION;
 247         //sound (missile, CHAN_PAIN, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 248         missile.flags = FL_PROJECTILE;
 249
 250         CSQCProjectile(missile);
 251
 252         if(cvar("g_balance_rocketlauncher_speedaccel") == 0 && cvar("g_laserguided_missiles") == 0)
 253                 missile.csqcprojectile_clientanimate = 1;
 254         else
 255                 missile.csqcprojectile_clientanimate = 0; // we won't client animate if the missiles may behave weird
 256
 257         missile.gravity = 0;
 258         missile.csqcprojectile_flysound = 2;
 259
 260         // muzzle flash for 1st person view
 261         flash = spawn ();
 262         flash.scale = 1.2;
 263         flash.angles_z = 180;
 264         flash.owner = self;
 265         flash.viewmodelforclient = self;
 266         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 267         setorigin (flash, '35 8 0');
 268         setmodel (flash, "models/flash.md3"); // precision set below
 269         setattachment(flash, self.weaponentity, "bone01");
 270         SUB_SetFade (flash, time, 0.4);
 271
 272         // muzzle flash for 3rd person view
 273         flash2 = spawn ();
 274         flash2.scale = 0.8;
 275         flash2.angles_y = 180;
 276         flash2.angles_z = 90;
 277         setorigin (flash2, '42 0 5');
 278         setmodel (flash2, "models/flash.md3"); // precision set below
 279         setattachment(flash2, self.exteriorweaponentity, "");
 280         SUB_SetFade (flash2, time, 0.4);
 281
 282         // common properties
 283         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 284 }
 285
 286 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 287
 288 float w_rlauncher(float req)
 289 {
 290         entity rock;
 291         float rockfound;
 292         if (req == WR_AIM)
 293         {
 294                 // aim and decide to fire if appropriate
 295                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 296                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 297                 {
 298                         // decide whether to detonate rockets
 299                         local entity missile, targetlist, targ;
 300                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 301                         local float selfdamage, teamdamage, enemydamage;
 302                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 303                         coredamage = cvar("g_balance_rocketlauncher_damage");
 304                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 305                         recipricoledgeradius = 1 / edgeradius;
 306                         selfdamage = 0;
 307                         teamdamage = 0;
 308                         enemydamage = 0;
 309                         targetlist = findchainfloat(bot_attack, TRUE);
 310                         missile = find(world, classname, "rocket");
 311                         while (missile)
 312                         {
 313                                 if (missile.owner != self)
 314                                 {
 315                                         missile = find(missile, classname, "rocket");
 316                                         continue;
 317                                 }
 318                                 targ = targetlist;
 319                                 while (targ)
 320                                 {
 321                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 322                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 323                                         // count potential damage according to type of target
 324                                         if (targ == self)
 325                                                 selfdamage = selfdamage + d;
 326                                         else if (targ.team == self.team && teamplay)
 327                                                 teamdamage = teamdamage + d;
 328                                         else if (bot_shouldattack(targ))
 329                                                 enemydamage = enemydamage + d;
 330                                         targ = targ.chain;
 331                                 }
 332                                 missile = find(missile, classname, "rocket");
 333                         }
 334                         local float desirabledamage;
 335                         desirabledamage = enemydamage;
 336                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 337                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 338                         if (self.team && teamplay == 2)
 339                                 desirabledamage = desirabledamage - teamdamage;
 340
 341                         missile = find(world, classname, "rocket");
 342                         while (missile)
 343                         {
 344                                 if (missile.owner != self)
 345                                 {
 346                                         missile = find(missile, classname, "rocket");
 347                                         continue;
 348                                 }
 349                                 makevectors(missile.v_angle);
 350                                 targ = targetlist;
 351                                 if (skill > 9) // normal players only do this for the target they are tracking
 352                                 {
 353                                         targ = targetlist;
 354                                         while (targ)
 355                                         {
 356                                                 if (
 357                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 358                                                         && desirabledamage > 0.1*coredamage
 359                                                 )self.BUTTON_ATCK2 = TRUE;
 360                                                 targ = targ.chain;
 361                                         }
 362                                 }else{
 363                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 364                                         //As the distance gets larger, a correct detonation gets near imposible
 365                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 366                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 367                                                 if(self.enemy.classname == "player")
 368                                                         if(desirabledamage >= 0.1*coredamage)
 369                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 370                                                                         self.BUTTON_ATCK2 = TRUE;
 371                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 372                                 }
 373
 374                                 missile = find(missile, classname, "rocket");
 375                         }
 376                         // if we would be doing at X percent of the core damage, detonate it
 377                         // but don't fire a new shot at the same time!
 378                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 379                                 self.BUTTON_ATCK2 = TRUE;
 380                         if ((skill > 6.5) && (selfdamage > self.health))
 381                                 self.BUTTON_ATCK2 = FALSE;
 382                         //if(self.BUTTON_ATCK2 == TRUE)
 383                         //      dprint(ftos(desirabledamage),"\n");
 384                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 385                 }
 386         }
 387         else if (req == WR_THINK)
 388         {
 389                 if(g_laserguided_missile)
 390                 {
 391                         if (self.BUTTON_ATCK && self.rl_release)
 392                         {
 393                                 rockfound = 0;
 394                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 395                                 {
 396                                         if(!rock.rl_detonate_later)
 397                                         {
 398                                                 rock.rl_detonate_later = TRUE;
 399                                                 rockfound = 1;
 400                                         }
 401                                 }
 402                                 if(rockfound)
 403                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 404                                 else
 405                                 {
 406                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 407                                         {
 408                                                 W_Rocket_Attack();
 409                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 410                                         }
 411                                 }
 412                                 self.rl_release = 0;
 413                         }
 414                         if (!self.BUTTON_ATCK)
 415                                 self.rl_release = 1;
 416                         if (self.BUTTON_ATCK2)
 417                         if(self.exteriorweaponentity.attack_finished_single < time)
 418                         {
 419                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 420                                 self.laser_on = !self.laser_on;
 421                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 422                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 423                         }
 424                 }
 425                 else
 426                 {
 427                         if (self.BUTTON_ATCK)
 428                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 429                         {
 430                                 W_Rocket_Attack();
 431                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 432                         }
 433                         if (self.BUTTON_ATCK2)
 434                         {
 435                                 rockfound = 0;
 436                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 437                                 {
 438                                         if(!rock.rl_detonate_later)
 439                                         {
 440                                                 rock.rl_detonate_later = TRUE;
 441                                                 rockfound = 1;
 442                                         }
 443                                 }
 444                                 if(rockfound)
 445                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 446                         }
 447                 }
 448         }
 449         else if (req == WR_PRECACHE)
 450         {
 451                 precache_model ("models/flash.md3");
 452                 precache_model ("models/rocket.md3");
 453                 precache_model ("models/weapons/g_rl.md3");
 454                 precache_model ("models/weapons/v_rl.md3");
 455                 precache_model ("models/weapons/w_rl.zym");
 456                 precache_sound ("weapons/rocket_det.wav");
 457                 precache_sound ("weapons/rocket_fire.wav");
 458                 precache_sound ("weapons/rocket_fly.wav");
 459                 precache_sound ("weapons/rocket_impact.wav");
 460                 if (g_laserguided_missile)
 461                 {
 462                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 463                         precache_sound ("weapons/rocket_mode.wav");
 464                 }
 465         }
 466         else if (req == WR_SETUP)
 467         {
 468                 weapon_setup(WEP_ROCKET_LAUNCHER);
 469                 self.rl_release = 1;
 470         }
 471         else if (req == WR_CHECKAMMO1)
 472         {
 473                 // don't switch while guiding a missile
 474                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 475                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 476                         return FALSE;
 477         }
 478         else if (req == WR_CHECKAMMO2)
 479                 return FALSE;
 480         else if (req == WR_SUICIDEMESSAGE)
 481                 w_deathtypestring = "exploded";
 482         else if (req == WR_KILLMESSAGE)
 483         {
 484                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 485                         w_deathtypestring = "got too close to #'s rocket";
 486                 else if(w_deathtype & HITTYPE_SPLASH)
 487                         w_deathtypestring = "almost dodged #'s rocket";
 488                 else
 489                         w_deathtypestring = "ate #'s rocket";
 490         }
 491         return TRUE;
 492 };