data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         self.event_damage = SUB_Null;
   7         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
   8
   9         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  10         {
  11                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  12                 {
  13                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  14                         ATTACK_FINISHED(self.owner) = time;
  15                         self.owner.switchweapon = w_getbestweapon(self.owner);
  16                 }
  17                 if(g_laserguided_missile)
  18                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  19         }
  20         remove (self);
  21 }
  22
  23 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  24 {
  25         entity head, selected;
  26         vector dir;
  27         float dist, maxdist,// bestdist,
  28                 dot,// bestdot,
  29                 points, bestpoints;
  30         //bestdist = 9999;
  31         //bestdot = -2;
  32         bestpoints = 0;
  33         maxdist = 800;
  34         selected = world;
  35
  36         makevectors(e.angles);
  37
  38         head = find(world, classname, "laser_target");
  39         while(head)
  40         {
  41                 points = 0;
  42                 dir = normalize(head.origin - self.origin);
  43                 dot = dir * v_forward;
  44                 dist = vlen(head.origin - self.origin);
  45                 if(dist > maxdist)
  46                         dist = maxdist;
  47
  48                 // gain points for being in front
  49                 points = points + ((dot+1)*0.5) * 500
  50                         * (1 + crandom()*dot_variance);
  51                 // gain points for being close away
  52                 points = points + (1 - dist/maxdist) * 1000
  53                         * (1 + crandom()*dot_variance);
  54
  55                 traceline(e.origin, head.origin, TRUE, self);
  56                 if(trace_fraction < 1)
  57                 {
  58                         points = 0;
  59                 }
  60
  61                 if(points > bestpoints)//random() > 0.5)//
  62                 {
  63                         bestpoints = points;
  64                         selected = head;
  65                 }
  66
  67                 head = find(head, classname, "laser_target");
  68         }
  69
  70         //bprint(selected.owner.netname);
  71         //bprint("\n");
  72         return selected;
  73 }
  74
  75 void W_Rocket_RemoteExplode()
  76 {
  77         if(self.owner.deadflag == DEAD_NO)
  78         {
  79                 if((self.spawnshieldtime >= 0)
  80                         ? (time >= self.spawnshieldtime) // timer
  81                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  82                 )
  83                 {
  84                         other = world;
  85                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  86                         W_Rocket_Explode ();
  87                 }
  88                 else
  89                 {
  90                 }
  91         }
  92 }
  93
  94 void W_Rocket_Think (void)
  95 {
  96         entity e;
  97         vector desireddir, olddir, newdir;
  98         float turnrate, velspeed;
  99         self.nextthink = time;
 100         if (time > self.cnt)
 101         {
 102                 other = world;
 103                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 104                 W_Rocket_Explode ();
 105                 return;
 106         }
 107
 108         if(g_laserguided_missile)
 109         {
 110                 // accelerate
 111                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 112                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 113                 if (velspeed > 0)
 114                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 115         }
 116         else
 117         {
 118                 // accelerate
 119                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 120                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 121                 if (velspeed > 0)
 122                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 123         }
 124
 125         // laser guided, or remote detonation
 126         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 127         {
 128                 if(g_laserguided_missile)
 129                 {
 130                         if(self.rl_detonate_later)
 131                                 W_Rocket_RemoteExplode();
 132
 133                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 134                         {
 135                                 if(self.owner.laser_on)
 136                                 {
 137                                         if(self.attack_finished_single < time)
 138                                         {
 139                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 140                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 141                                         }
 142
 143                                         if(!self.enemy)
 144                                                 self.enemy = self.owner.weaponentity.lasertarget;
 145                                 }
 146                                 else self.enemy = world;
 147                         }
 148                         else // don't allow stealing: always target my owner's laser (if it exists)
 149                                 self.enemy = self.owner.weaponentity.lasertarget;
 150
 151                         if(self.enemy != world)
 152                         {
 153                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 154                                 velspeed = vlen(self.velocity);
 155                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 156                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 157                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 158                                 olddir = normalize(self.velocity);                                      // get my current direction
 159                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 160                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 161                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 162
 163                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 164                         }
 165                 }
 166                 else
 167                 {
 168                         if(self.rl_detonate_later)
 169                                 W_Rocket_RemoteExplode();
 170                 }
 171         }
 172
 173         if(self.csqcprojectile_clientanimate == 0)
 174                 UpdateCSQCProjectile(self);
 175 }
 176
 177 void W_Rocket_Touch (void)
 178 {
 179         if(self.owner && self.owner.lastrocket == self)
 180                 self.owner.lastrocket = world;
 181         PROJECTILE_TOUCH;
 182         W_Rocket_Explode ();
 183 }
 184
 185 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 186 {
 187         self.health = self.health - damage;
 188         self.angles = vectoangles(self.velocity);
 189         if (self.health <= 0)
 190                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 191 }
 192
 193 void W_Rocket_Attack (void)
 194 {
 195         local entity missile;
 196         local entity flash;
 197
 198         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 199                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 200
 201         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav");
 202         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 203
 204         missile = spawn ();
 205         missile.owner = self;
 206         self.lastrocket = missile;
 207         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 208                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 209         else
 210                 missile.spawnshieldtime = -1;
 211         missile.classname = "rocket";
 212         missile.bot_dodge = TRUE;
 213         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 214
 215         missile.takedamage = DAMAGE_YES;
 216         missile.damageforcescale = 4;
 217         missile.health = cvar("g_balance_rocketlauncher_health");
 218         missile.event_damage = W_Rocket_Damage;
 219
 220         missile.movetype = MOVETYPE_FLY;
 221         missile.solid = SOLID_BBOX;
 222         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 223         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 224
 225         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 226         if(g_laserguided_missile && self.laser_on)
 227                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 228         else
 229                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 230         W_SetupProjectileVelocity(missile);
 231         missile.angles = vectoangles (missile.velocity);
 232
 233         missile.touch = W_Rocket_Touch;
 234         missile.think = W_Rocket_Think;
 235         missile.nextthink = time;
 236         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 237         missile.flags = FL_PROJECTILE;
 238
 239         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 240
 241         // muzzle flash for 1st person view
 242         flash = spawn ();
 243         setmodel (flash, "models/flash.md3"); // precision set below
 244         SUB_SetFade (flash, time, 0.1);
 245         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 246         W_AttachToShotorg(flash, '5 0 0');
 247
 248         // common properties
 249 }
 250
 251 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 252
 253 float w_rlauncher(float req)
 254 {
 255         entity rock;
 256         float rockfound;
 257         if (req == WR_AIM)
 258         {
 259                 // aim and decide to fire if appropriate
 260                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 261                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 262                 {
 263                         // decide whether to detonate rockets
 264                         local entity missile, targetlist, targ;
 265                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 266                         local float selfdamage, teamdamage, enemydamage;
 267                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 268                         coredamage = cvar("g_balance_rocketlauncher_damage");
 269                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 270                         recipricoledgeradius = 1 / edgeradius;
 271                         selfdamage = 0;
 272                         teamdamage = 0;
 273                         enemydamage = 0;
 274                         targetlist = findchainfloat(bot_attack, TRUE);
 275                         missile = find(world, classname, "rocket");
 276                         while (missile)
 277                         {
 278                                 if (missile.owner != self)
 279                                 {
 280                                         missile = find(missile, classname, "rocket");
 281                                         continue;
 282                                 }
 283                                 targ = targetlist;
 284                                 while (targ)
 285                                 {
 286                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 287                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 288                                         // count potential damage according to type of target
 289                                         if (targ == self)
 290                                                 selfdamage = selfdamage + d;
 291                                         else if (targ.team == self.team && teams_matter)
 292                                                 teamdamage = teamdamage + d;
 293                                         else if (bot_shouldattack(targ))
 294                                                 enemydamage = enemydamage + d;
 295                                         targ = targ.chain;
 296                                 }
 297                                 missile = find(missile, classname, "rocket");
 298                         }
 299                         local float desirabledamage;
 300                         desirabledamage = enemydamage;
 301                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 302                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 303                         if (self.team && teamplay != 1)
 304                                 desirabledamage = desirabledamage - teamdamage;
 305
 306                         missile = find(world, classname, "rocket");
 307                         while (missile)
 308                         {
 309                                 if (missile.owner != self)
 310                                 {
 311                                         missile = find(missile, classname, "rocket");
 312                                         continue;
 313                                 }
 314                                 makevectors(missile.v_angle);
 315                                 targ = targetlist;
 316                                 if (skill > 9) // normal players only do this for the target they are tracking
 317                                 {
 318                                         targ = targetlist;
 319                                         while (targ)
 320                                         {
 321                                                 if (
 322                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 323                                                         && desirabledamage > 0.1*coredamage
 324                                                 )self.BUTTON_ATCK2 = TRUE;
 325                                                 targ = targ.chain;
 326                                         }
 327                                 }else{
 328                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 329                                         //As the distance gets larger, a correct detonation gets near imposible
 330                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 331                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 332                                                 if(self.enemy.classname == "player")
 333                                                         if(desirabledamage >= 0.1*coredamage)
 334                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 335                                                                         self.BUTTON_ATCK2 = TRUE;
 336                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 337                                 }
 338
 339                                 missile = find(missile, classname, "rocket");
 340                         }
 341                         // if we would be doing at X percent of the core damage, detonate it
 342                         // but don't fire a new shot at the same time!
 343                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 344                                 self.BUTTON_ATCK2 = TRUE;
 345                         if ((skill > 6.5) && (selfdamage > self.health))
 346                                 self.BUTTON_ATCK2 = FALSE;
 347                         //if(self.BUTTON_ATCK2 == TRUE)
 348                         //      dprint(ftos(desirabledamage),"\n");
 349                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 350                 }
 351         }
 352         else if (req == WR_THINK)
 353         {
 354                 if(g_laserguided_missile)
 355                 {
 356                         if (self.BUTTON_ATCK && self.rl_release)
 357                         {
 358                                 rockfound = 0;
 359                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 360                                 {
 361                                         if(!rock.rl_detonate_later)
 362                                         {
 363                                                 rock.rl_detonate_later = TRUE;
 364                                                 rockfound = 1;
 365                                         }
 366                                 }
 367                                 if(rockfound)
 368                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 369                                 else
 370                                 {
 371                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 372                                         {
 373                                                 W_Rocket_Attack();
 374                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 375                                         }
 376                                 }
 377                                 self.rl_release = 0;
 378                         }
 379                         if (!self.BUTTON_ATCK)
 380                                 self.rl_release = 1;
 381                         if (self.BUTTON_ATCK2)
 382                         if(self.exteriorweaponentity.attack_finished_single < time)
 383                         {
 384                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 385                                 self.laser_on = !self.laser_on;
 386                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 387                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 388                         }
 389                 }
 390                 else
 391                 {
 392                         if (self.BUTTON_ATCK)
 393                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 394                         {
 395                                 W_Rocket_Attack();
 396                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 397                         }
 398                         if (self.BUTTON_ATCK2)
 399                         {
 400                                 rockfound = 0;
 401                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 402                                 {
 403                                         if(!rock.rl_detonate_later)
 404                                         {
 405                                                 rock.rl_detonate_later = TRUE;
 406                                                 rockfound = 1;
 407                                         }
 408                                 }
 409                                 if(rockfound)
 410                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 411                         }
 412                 }
 413         }
 414         else if (req == WR_PRECACHE)
 415         {
 416                 precache_model ("models/flash.md3");
 417                 precache_model ("models/weapons/g_rl.md3");
 418                 precache_model ("models/weapons/v_rl.md3");
 419                 precache_model ("models/weapons/h_rl.dpm");
 420                 precache_sound ("weapons/rocket_det.wav");
 421                 precache_sound ("weapons/rocket_fire.wav");
 422                 if (g_laserguided_missile)
 423                 {
 424                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 425                         precache_sound ("weapons/rocket_mode.wav");
 426                 }
 427         }
 428         else if (req == WR_SETUP)
 429         {
 430                 weapon_setup(WEP_ROCKET_LAUNCHER);
 431                 self.rl_release = 1;
 432         }
 433         else if (req == WR_CHECKAMMO1)
 434         {
 435                 // don't switch while guiding a missile
 436                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 437                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 438                         return FALSE;
 439         }
 440         else if (req == WR_CHECKAMMO2)
 441                 return FALSE;
 442         else if (req == WR_SUICIDEMESSAGE)
 443                 w_deathtypestring = "exploded";
 444         else if (req == WR_KILLMESSAGE)
 445         {
 446                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 447                         w_deathtypestring = "got too close to #'s rocket";
 448                 else if(w_deathtype & HITTYPE_SPLASH)
 449                         w_deathtypestring = "almost dodged #'s rocket";
 450                 else
 451                         w_deathtypestring = "ate #'s rocket";
 452         }
 453         return TRUE;
 454 };