data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         self.event_damage = SUB_Null;
   7         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
   8
   9         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  10         {
  11                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  12                 {
  13                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  14                         ATTACK_FINISHED(self.owner) = time;
  15                         self.owner.switchweapon = w_getbestweapon(self.owner);
  16                 }
  17                 if(g_laserguided_missile)
  18                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  19         }
  20         remove (self);
  21 }
  22
  23 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  24 {
  25         entity head, selected;
  26         vector dir;
  27         float dist, maxdist,// bestdist,
  28                 dot,// bestdot,
  29                 points, bestpoints;
  30         //bestdist = 9999;
  31         //bestdot = -2;
  32         bestpoints = 0;
  33         maxdist = 800;
  34         selected = world;
  35
  36         makevectors(e.angles);
  37
  38         head = find(world, classname, "laser_target");
  39         while(head)
  40         {
  41                 points = 0;
  42                 dir = normalize(head.origin - self.origin);
  43                 dot = dir * v_forward;
  44                 dist = vlen(head.origin - self.origin);
  45                 if(dist > maxdist)
  46                         dist = maxdist;
  47
  48                 // gain points for being in front
  49                 points = points + ((dot+1)*0.5) * 500
  50                         * (1 + crandom()*dot_variance);
  51                 // gain points for being close away
  52                 points = points + (1 - dist/maxdist) * 1000
  53                         * (1 + crandom()*dot_variance);
  54
  55                 traceline(e.origin, head.origin, TRUE, self);
  56                 if(trace_fraction < 1)
  57                 {
  58                         points = 0;
  59                 }
  60
  61                 if(points > bestpoints)//random() > 0.5)//
  62                 {
  63                         bestpoints = points;
  64                         selected = head;
  65                 }
  66
  67                 head = find(head, classname, "laser_target");
  68         }
  69
  70         //bprint(selected.owner.netname);
  71         //bprint("\n");
  72         return selected;
  73 }
  74
  75 void W_Rocket_RemoteExplode()
  76 {
  77         if(self.owner.deadflag == DEAD_NO)
  78         {
  79                 if((self.spawnshieldtime >= 0)
  80                         ? (time >= self.spawnshieldtime) // timer
  81                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  82                 )
  83                 {
  84                         other = world;
  85                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  86                         W_Rocket_Explode ();
  87                 }
  88                 else
  89                 {
  90                 }
  91         }
  92 }
  93
  94 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
  95 {
  96         if(thisdir * goaldir > maxturn_cos)
  97                 return goaldir;
  98         float f, m2;
  99         vector v;
 100         // solve:
 101         //   g = normalize(thisdir + goaldir * X)
 102         //   thisdir * g = maxturn
 103         //
 104         //   gg = thisdir + goaldir * X
 105         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 106         //
 107         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 108         f = thisdir * goaldir;
 109         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 110         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 111         m2 = maxturn_cos * maxturn_cos;
 112         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 113         return normalize(thisdir + goaldir * v_y); // the larger solution!
 114 }
 115
 116 void W_Rocket_Think (void)
 117 {
 118         entity e;
 119         vector desireddir, olddir, newdir, desiredorigin, goal;
 120         float turnrate, velspeed;
 121         self.nextthink = time;
 122         if (time > self.cnt)
 123         {
 124                 other = world;
 125                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 126                 W_Rocket_Explode ();
 127                 return;
 128         }
 129
 130         if(g_laserguided_missile)
 131         {
 132                 // accelerate
 133                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 134                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 135                 if (velspeed > 0)
 136                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 137         }
 138         else
 139         {
 140                 // accelerate
 141                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 142                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 143                 if (velspeed > 0)
 144                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 145         }
 146
 147         // laser guided, or remote detonation
 148         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 149         {
 150                 if(g_laserguided_missile)
 151                 {
 152                         if(self.rl_detonate_later)
 153                                 W_Rocket_RemoteExplode();
 154
 155                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 156                         {
 157                                 if(self.owner.laser_on)
 158                                 {
 159                                         if(self.attack_finished_single < time)
 160                                         {
 161                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 162                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 163                                         }
 164
 165                                         if(!self.enemy)
 166                                                 self.enemy = self.owner.weaponentity.lasertarget;
 167                                 }
 168                                 else self.enemy = world;
 169                         }
 170                         else // don't allow stealing: always target my owner's laser (if it exists)
 171                                 self.enemy = self.owner.weaponentity.lasertarget;
 172
 173                         if(self.enemy != world)
 174                         {
 175                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 176                                 velspeed = vlen(self.velocity);
 177                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 178                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 179                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 180                                 olddir = normalize(self.velocity);                                      // get my current direction
 181                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 182                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 183                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 184
 185                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 186                         }
 187                 }
 188                 else
 189                 {
 190                         if(!self.rl_release && !self.owner.rl_release && cvar("g_balance_rocketlauncher_guiderate"))
 191                         {
 192                                 if(time > self.pushltime)
 193                                 {
 194                                         velspeed = vlen(self.velocity);
 195
 196                                         makevectors(self.owner.v_angle);
 197                                         desireddir = v_forward;
 198                                         desiredorigin = self.owner.origin + self.owner.view_ofs;
 199                                         olddir = normalize(self.velocity);
 200
 201                                         // now it gets tricky... we want to move like some curve to approximate the target direction
 202                                         // but we are limiting the rate at which we can turn!
 203                                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 204                                         newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * frametime * PI / 180));
 205
 206                                         self.velocity = newdir * velspeed;
 207                                 }
 208                         }
 209                         else
 210                                 self.rl_release = 1;
 211
 212                         if(self.rl_detonate_later)
 213                                 W_Rocket_RemoteExplode();
 214                 }
 215         }
 216
 217         if(self.csqcprojectile_clientanimate == 0)
 218                 UpdateCSQCProjectile(self);
 219 }
 220
 221 void W_Rocket_Touch (void)
 222 {
 223         if(self.owner && self.owner.lastrocket == self)
 224                 self.owner.lastrocket = world;
 225         PROJECTILE_TOUCH;
 226         W_Rocket_Explode ();
 227 }
 228
 229 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 230 {
 231         self.health = self.health - damage;
 232         self.angles = vectoangles(self.velocity);
 233         if (self.health <= 0)
 234                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 235 }
 236
 237 void W_Rocket_Attack (void)
 238 {
 239         local entity missile;
 240         local entity flash;
 241
 242         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 243                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 244
 245         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav");
 246         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 247
 248         missile = spawn ();
 249         missile.owner = self;
 250         self.lastrocket = missile;
 251         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 252                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 253         else
 254                 missile.spawnshieldtime = -1;
 255         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 256         missile.classname = "rocket";
 257         missile.bot_dodge = TRUE;
 258         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 259
 260         missile.takedamage = DAMAGE_YES;
 261         missile.damageforcescale = 4;
 262         missile.health = cvar("g_balance_rocketlauncher_health");
 263         missile.event_damage = W_Rocket_Damage;
 264
 265         missile.movetype = MOVETYPE_FLY;
 266         missile.solid = SOLID_BBOX;
 267         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 268         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 269
 270         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 271         if(g_laserguided_missile && self.laser_on)
 272                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 273         else
 274                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 275         W_SetupProjectileVelocity(missile);
 276         missile.angles = vectoangles (missile.velocity);
 277
 278         missile.touch = W_Rocket_Touch;
 279         missile.think = W_Rocket_Think;
 280         missile.nextthink = time;
 281         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 282         missile.flags = FL_PROJECTILE;
 283
 284         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 285
 286         // muzzle flash for 1st person view
 287         flash = spawn ();
 288         setmodel (flash, "models/flash.md3"); // precision set below
 289         SUB_SetFade (flash, time, 0.1);
 290         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 291         W_AttachToShotorg(flash, '5 0 0');
 292
 293         // common properties
 294 }
 295
 296 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 297
 298 float w_rlauncher(float req)
 299 {
 300         entity rock;
 301         float rockfound;
 302         if (req == WR_AIM)
 303         {
 304                 // aim and decide to fire if appropriate
 305                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 306                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 307                 {
 308                         // decide whether to detonate rockets
 309                         local entity missile, targetlist, targ;
 310                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 311                         local float selfdamage, teamdamage, enemydamage;
 312                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 313                         coredamage = cvar("g_balance_rocketlauncher_damage");
 314                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 315                         recipricoledgeradius = 1 / edgeradius;
 316                         selfdamage = 0;
 317                         teamdamage = 0;
 318                         enemydamage = 0;
 319                         targetlist = findchainfloat(bot_attack, TRUE);
 320                         missile = find(world, classname, "rocket");
 321                         while (missile)
 322                         {
 323                                 if (missile.owner != self)
 324                                 {
 325                                         missile = find(missile, classname, "rocket");
 326                                         continue;
 327                                 }
 328                                 targ = targetlist;
 329                                 while (targ)
 330                                 {
 331                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 332                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 333                                         // count potential damage according to type of target
 334                                         if (targ == self)
 335                                                 selfdamage = selfdamage + d;
 336                                         else if (targ.team == self.team && teams_matter)
 337                                                 teamdamage = teamdamage + d;
 338                                         else if (bot_shouldattack(targ))
 339                                                 enemydamage = enemydamage + d;
 340                                         targ = targ.chain;
 341                                 }
 342                                 missile = find(missile, classname, "rocket");
 343                         }
 344                         local float desirabledamage;
 345                         desirabledamage = enemydamage;
 346                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 347                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 348                         if (self.team && teamplay != 1)
 349                                 desirabledamage = desirabledamage - teamdamage;
 350
 351                         missile = find(world, classname, "rocket");
 352                         while (missile)
 353                         {
 354                                 if (missile.owner != self)
 355                                 {
 356                                         missile = find(missile, classname, "rocket");
 357                                         continue;
 358                                 }
 359                                 makevectors(missile.v_angle);
 360                                 targ = targetlist;
 361                                 if (skill > 9) // normal players only do this for the target they are tracking
 362                                 {
 363                                         targ = targetlist;
 364                                         while (targ)
 365                                         {
 366                                                 if (
 367                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 368                                                         && desirabledamage > 0.1*coredamage
 369                                                 )self.BUTTON_ATCK2 = TRUE;
 370                                                 targ = targ.chain;
 371                                         }
 372                                 }else{
 373                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 374                                         //As the distance gets larger, a correct detonation gets near imposible
 375                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 376                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 377                                                 if(self.enemy.classname == "player")
 378                                                         if(desirabledamage >= 0.1*coredamage)
 379                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 380                                                                         self.BUTTON_ATCK2 = TRUE;
 381                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 382                                 }
 383
 384                                 missile = find(missile, classname, "rocket");
 385                         }
 386                         // if we would be doing at X percent of the core damage, detonate it
 387                         // but don't fire a new shot at the same time!
 388                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 389                                 self.BUTTON_ATCK2 = TRUE;
 390                         if ((skill > 6.5) && (selfdamage > self.health))
 391                                 self.BUTTON_ATCK2 = FALSE;
 392                         //if(self.BUTTON_ATCK2 == TRUE)
 393                         //      dprint(ftos(desirabledamage),"\n");
 394                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 395                 }
 396         }
 397         else if (req == WR_THINK)
 398         {
 399                 if(g_laserguided_missile)
 400                 {
 401                         if (self.BUTTON_ATCK && self.rl_release)
 402                         {
 403                                 rockfound = 0;
 404                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 405                                 {
 406                                         if(!rock.rl_detonate_later)
 407                                         {
 408                                                 rock.rl_detonate_later = TRUE;
 409                                                 rockfound = 1;
 410                                         }
 411                                 }
 412                                 if(rockfound)
 413                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 414                                 else
 415                                 {
 416                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 417                                         {
 418                                                 W_Rocket_Attack();
 419                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 420                                         }
 421                                 }
 422                                 self.rl_release = 0;
 423                         }
 424                         if (!self.BUTTON_ATCK)
 425                                 self.rl_release = 1;
 426                         if (self.BUTTON_ATCK2)
 427                         if(self.exteriorweaponentity.attack_finished_single < time)
 428                         {
 429                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 430                                 self.laser_on = !self.laser_on;
 431                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 432                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 433                         }
 434                 }
 435                 else
 436                 {
 437                         if (self.BUTTON_ATCK && self.rl_release)
 438                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 439                         {
 440                                 W_Rocket_Attack();
 441                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 442                                 self.rl_release = 0;
 443                         }
 444                         if (!self.BUTTON_ATCK)
 445                                 self.rl_release = 1;
 446                         if (self.BUTTON_ATCK2)
 447                         {
 448                                 rockfound = 0;
 449                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 450                                 {
 451                                         if(!rock.rl_detonate_later)
 452                                         {
 453                                                 rock.rl_detonate_later = TRUE;
 454                                                 rockfound = 1;
 455                                         }
 456                                 }
 457                                 if(rockfound)
 458                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 459                         }
 460                 }
 461         }
 462         else if (req == WR_PRECACHE)
 463         {
 464                 precache_model ("models/flash.md3");
 465                 precache_model ("models/weapons/g_rl.md3");
 466                 precache_model ("models/weapons/v_rl.md3");
 467                 precache_model ("models/weapons/h_rl.dpm");
 468                 precache_sound ("weapons/rocket_det.wav");
 469                 precache_sound ("weapons/rocket_fire.wav");
 470                 if (g_laserguided_missile)
 471                 {
 472                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 473                         precache_sound ("weapons/rocket_mode.wav");
 474                 }
 475         }
 476         else if (req == WR_SETUP)
 477         {
 478                 weapon_setup(WEP_ROCKET_LAUNCHER);
 479                 self.rl_release = 1;
 480         }
 481         else if (req == WR_CHECKAMMO1)
 482         {
 483                 // don't switch while guiding a missile
 484                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 485                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 486                         return FALSE;
 487         }
 488         else if (req == WR_CHECKAMMO2)
 489                 return FALSE;
 490         else if (req == WR_SUICIDEMESSAGE)
 491                 w_deathtypestring = "exploded";
 492         else if (req == WR_KILLMESSAGE)
 493         {
 494                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 495                         w_deathtypestring = "got too close to #'s rocket";
 496                 else if(w_deathtype & HITTYPE_SPLASH)
 497                         w_deathtypestring = "almost dodged #'s rocket";
 498                 else
 499                         w_deathtypestring = "ate #'s rocket";
 500         }
 501         return TRUE;
 502 };