data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Unregister(float complain)
   5 {
   6         if(self.owner && self.owner.lastrocket == self)
   7         {
   8                 self.owner.lastrocket = world;
   9                 // self.owner.rl_release = 1;
  10         }
  11 }
  12
  13 void W_Rocket_Explode (void)
  14 {
  15         W_Rocket_Unregister();
  16
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  19
  20         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  21         {
  22                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  23                 {
  24                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  25                         ATTACK_FINISHED(self.owner) = time;
  26                         self.owner.switchweapon = w_getbestweapon(self.owner);
  27                 }
  28                 if(g_laserguided_missile)
  29                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  30         }
  31         remove (self);
  32 }
  33
  34 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  35 {
  36         entity head, selected;
  37         vector dir;
  38         float dist, maxdist,// bestdist,
  39                 dot,// bestdot,
  40                 points, bestpoints;
  41         //bestdist = 9999;
  42         //bestdot = -2;
  43         bestpoints = 0;
  44         maxdist = 800;
  45         selected = world;
  46
  47         makevectors(e.angles);
  48
  49         head = find(world, classname, "laser_target");
  50         while(head)
  51         {
  52                 points = 0;
  53                 dir = normalize(head.origin - self.origin);
  54                 dot = dir * v_forward;
  55                 dist = vlen(head.origin - self.origin);
  56                 if(dist > maxdist)
  57                         dist = maxdist;
  58
  59                 // gain points for being in front
  60                 points = points + ((dot+1)*0.5) * 500
  61                         * (1 + crandom()*dot_variance);
  62                 // gain points for being close away
  63                 points = points + (1 - dist/maxdist) * 1000
  64                         * (1 + crandom()*dot_variance);
  65
  66                 traceline(e.origin, head.origin, TRUE, self);
  67                 if(trace_fraction < 1)
  68                 {
  69                         points = 0;
  70                 }
  71
  72                 if(points > bestpoints)//random() > 0.5)//
  73                 {
  74                         bestpoints = points;
  75                         selected = head;
  76                 }
  77
  78                 head = find(head, classname, "laser_target");
  79         }
  80
  81         //bprint(selected.owner.netname);
  82         //bprint("\n");
  83         return selected;
  84 }
  85
  86 void W_Rocket_RemoteExplode()
  87 {
  88         if(self.owner.deadflag == DEAD_NO)
  89         {
  90                 if((self.spawnshieldtime >= 0)
  91                         ? (time >= self.spawnshieldtime) // timer
  92                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  93                 )
  94                 {
  95                         other = world;
  96                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  97                         W_Rocket_Explode ();
  98                 }
  99                 else
 100                 {
 101                 }
 102         }
 103 }
 104
 105 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 106 {
 107         if(thisdir * goaldir > maxturn_cos)
 108                 return goaldir;
 109         float f, m2;
 110         vector v;
 111         // solve:
 112         //   g = normalize(thisdir + goaldir * X)
 113         //   thisdir * g = maxturn
 114         //
 115         //   gg = thisdir + goaldir * X
 116         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 117         //
 118         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 119         f = thisdir * goaldir;
 120         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 121         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 122         m2 = maxturn_cos * maxturn_cos;
 123         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 124         return normalize(thisdir + goaldir * v_y); // the larger solution!
 125 }
 126
 127 void W_Rocket_Think (void)
 128 {
 129         entity e;
 130         vector desireddir, olddir, newdir, desiredorigin, goal;
 131         float turnrate, velspeed;
 132         self.nextthink = time;
 133         if (time > self.cnt)
 134         {
 135                 other = world;
 136                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 137                 W_Rocket_Explode ();
 138                 return;
 139         }
 140
 141         if(g_laserguided_missile)
 142         {
 143                 // accelerate
 144                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 145                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 146                 if (velspeed > 0)
 147                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 148         }
 149         else
 150         {
 151                 // accelerate
 152                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 153                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 154                 if (velspeed > 0)
 155                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 156         }
 157
 158         // laser guided, or remote detonation
 159         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 160         {
 161                 if(g_laserguided_missile)
 162                 {
 163                         if(self.rl_detonate_later)
 164                                 W_Rocket_RemoteExplode();
 165
 166                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 167                         {
 168                                 if(self.owner.laser_on)
 169                                 {
 170                                         if(self.attack_finished_single < time)
 171                                         {
 172                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 173                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 174                                         }
 175
 176                                         if(!self.enemy)
 177                                                 self.enemy = self.owner.weaponentity.lasertarget;
 178                                 }
 179                                 else self.enemy = world;
 180                         }
 181                         else // don't allow stealing: always target my owner's laser (if it exists)
 182                                 self.enemy = self.owner.weaponentity.lasertarget;
 183
 184                         if(self.enemy != world)
 185                         {
 186                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 187                                 velspeed = vlen(self.velocity);
 188                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 189                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 190                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 191                                 olddir = normalize(self.velocity);                                      // get my current direction
 192                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 193                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 194                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 195
 196                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 197                         }
 198                 }
 199                 else
 200                 {
 201                         if(self == self.owner.lastrocket)
 202                         if(!self.owner.rl_release)
 203                         if(cvar("g_balance_rocketlauncher_guiderate"))
 204                         if(time > self.pushltime)
 205                         {
 206                                 velspeed = vlen(self.velocity);
 207
 208                                 makevectors(self.owner.v_angle);
 209                                 desireddir = v_forward;
 210                                 desiredorigin = self.owner.origin + self.owner.view_ofs;
 211                                 olddir = normalize(self.velocity);
 212
 213                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 214                                 // but we are limiting the rate at which we can turn!
 215                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 216                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * frametime * PI / 180));
 217
 218                                 self.velocity = newdir * velspeed;
 219                         }
 220
 221                         if(self.rl_detonate_later)
 222                                 W_Rocket_RemoteExplode();
 223                 }
 224         }
 225
 226         if(self.csqcprojectile_clientanimate == 0)
 227                 UpdateCSQCProjectile(self);
 228 }
 229
 230 void W_Rocket_Touch (void)
 231 {
 232         W_Rocket_Unregister();
 233
 234         PROJECTILE_TOUCH;
 235         W_Rocket_Explode ();
 236 }
 237
 238 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 239 {
 240         self.health = self.health - damage;
 241         self.angles = vectoangles(self.velocity);
 242         if (self.health <= 0)
 243                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 244 }
 245
 246 void W_Rocket_Attack (void)
 247 {
 248         local entity missile;
 249         local entity flash;
 250
 251         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 252                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 253
 254         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav");
 255         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 256
 257         missile = spawn ();
 258         missile.owner = self;
 259         self.lastrocket = missile;
 260         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 261                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 262         else
 263                 missile.spawnshieldtime = -1;
 264         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 265         missile.classname = "rocket";
 266         missile.bot_dodge = TRUE;
 267         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 268
 269         missile.takedamage = DAMAGE_YES;
 270         missile.damageforcescale = 4;
 271         missile.health = cvar("g_balance_rocketlauncher_health");
 272         missile.event_damage = W_Rocket_Damage;
 273
 274         missile.movetype = MOVETYPE_FLY;
 275         missile.solid = SOLID_BBOX;
 276         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 277         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 278
 279         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 280         if(g_laserguided_missile && self.laser_on)
 281                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 282         else
 283                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 284         W_SetupProjectileVelocity(missile);
 285         missile.angles = vectoangles (missile.velocity);
 286
 287         missile.touch = W_Rocket_Touch;
 288         missile.think = W_Rocket_Think;
 289         missile.nextthink = time;
 290         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 291         missile.flags = FL_PROJECTILE;
 292
 293         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 294
 295         // muzzle flash for 1st person view
 296         flash = spawn ();
 297         setmodel (flash, "models/flash.md3"); // precision set below
 298         SUB_SetFade (flash, time, 0.1);
 299         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 300         W_AttachToShotorg(flash, '5 0 0');
 301
 302         // common properties
 303 }
 304
 305 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 306
 307 float w_rlauncher(float req)
 308 {
 309         entity rock;
 310         float rockfound;
 311         if (req == WR_AIM)
 312         {
 313                 // aim and decide to fire if appropriate
 314                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 315                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 316                 {
 317                         // decide whether to detonate rockets
 318                         local entity missile, targetlist, targ;
 319                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 320                         local float selfdamage, teamdamage, enemydamage;
 321                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 322                         coredamage = cvar("g_balance_rocketlauncher_damage");
 323                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 324                         recipricoledgeradius = 1 / edgeradius;
 325                         selfdamage = 0;
 326                         teamdamage = 0;
 327                         enemydamage = 0;
 328                         targetlist = findchainfloat(bot_attack, TRUE);
 329                         missile = find(world, classname, "rocket");
 330                         while (missile)
 331                         {
 332                                 if (missile.owner != self)
 333                                 {
 334                                         missile = find(missile, classname, "rocket");
 335                                         continue;
 336                                 }
 337                                 targ = targetlist;
 338                                 while (targ)
 339                                 {
 340                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 341                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 342                                         // count potential damage according to type of target
 343                                         if (targ == self)
 344                                                 selfdamage = selfdamage + d;
 345                                         else if (targ.team == self.team && teams_matter)
 346                                                 teamdamage = teamdamage + d;
 347                                         else if (bot_shouldattack(targ))
 348                                                 enemydamage = enemydamage + d;
 349                                         targ = targ.chain;
 350                                 }
 351                                 missile = find(missile, classname, "rocket");
 352                         }
 353                         local float desirabledamage;
 354                         desirabledamage = enemydamage;
 355                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 356                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 357                         if (self.team && teamplay != 1)
 358                                 desirabledamage = desirabledamage - teamdamage;
 359
 360                         missile = find(world, classname, "rocket");
 361                         while (missile)
 362                         {
 363                                 if (missile.owner != self)
 364                                 {
 365                                         missile = find(missile, classname, "rocket");
 366                                         continue;
 367                                 }
 368                                 makevectors(missile.v_angle);
 369                                 targ = targetlist;
 370                                 if (skill > 9) // normal players only do this for the target they are tracking
 371                                 {
 372                                         targ = targetlist;
 373                                         while (targ)
 374                                         {
 375                                                 if (
 376                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 377                                                         && desirabledamage > 0.1*coredamage
 378                                                 )self.BUTTON_ATCK2 = TRUE;
 379                                                 targ = targ.chain;
 380                                         }
 381                                 }else{
 382                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 383                                         //As the distance gets larger, a correct detonation gets near imposible
 384                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 385                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 386                                                 if(self.enemy.classname == "player")
 387                                                         if(desirabledamage >= 0.1*coredamage)
 388                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 389                                                                         self.BUTTON_ATCK2 = TRUE;
 390                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 391                                 }
 392
 393                                 missile = find(missile, classname, "rocket");
 394                         }
 395                         // if we would be doing at X percent of the core damage, detonate it
 396                         // but don't fire a new shot at the same time!
 397                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 398                                 self.BUTTON_ATCK2 = TRUE;
 399                         if ((skill > 6.5) && (selfdamage > self.health))
 400                                 self.BUTTON_ATCK2 = FALSE;
 401                         //if(self.BUTTON_ATCK2 == TRUE)
 402                         //      dprint(ftos(desirabledamage),"\n");
 403                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 404                 }
 405         }
 406         else if (req == WR_THINK)
 407         {
 408                 if(g_laserguided_missile)
 409                 {
 410                         if (self.BUTTON_ATCK && self.rl_release)
 411                         {
 412                                 rockfound = 0;
 413                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 414                                 {
 415                                         if(!rock.rl_detonate_later)
 416                                         {
 417                                                 rock.rl_detonate_later = TRUE;
 418                                                 rockfound = 1;
 419                                         }
 420                                 }
 421                                 if(rockfound)
 422                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 423                                 else
 424                                 {
 425                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 426                                         {
 427                                                 W_Rocket_Attack();
 428                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 429                                         }
 430                                 }
 431                                 self.rl_release = 0;
 432                         }
 433                         if (!self.BUTTON_ATCK)
 434                                 self.rl_release = 1;
 435                         if (self.BUTTON_ATCK2)
 436                         if(self.exteriorweaponentity.attack_finished_single < time)
 437                         {
 438                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 439                                 self.laser_on = !self.laser_on;
 440                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 441                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 442                         }
 443                 }
 444                 else
 445                 {
 446                         if (self.BUTTON_ATCK)
 447                         {
 448                                 if(self.rl_release)
 449                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 450                                 {
 451                                         W_Rocket_Attack();
 452                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 453                                         self.rl_release = 0;
 454                                 }
 455                         }
 456                         else
 457                                 self.rl_release = 1;
 458
 459                         if (self.BUTTON_ATCK2)
 460                         {
 461                                 rockfound = 0;
 462                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 463                                 {
 464                                         if(!rock.rl_detonate_later)
 465                                         {
 466                                                 rock.rl_detonate_later = TRUE;
 467                                                 rockfound = 1;
 468                                         }
 469                                 }
 470                                 if(rockfound)
 471                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 472                         }
 473                 }
 474         }
 475         else if (req == WR_PRECACHE)
 476         {
 477                 precache_model ("models/flash.md3");
 478                 precache_model ("models/weapons/g_rl.md3");
 479                 precache_model ("models/weapons/v_rl.md3");
 480                 precache_model ("models/weapons/h_rl.dpm");
 481                 precache_sound ("weapons/rocket_det.wav");
 482                 precache_sound ("weapons/rocket_fire.wav");
 483                 if (g_laserguided_missile)
 484                 {
 485                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 486                         precache_sound ("weapons/rocket_mode.wav");
 487                 }
 488         }
 489         else if (req == WR_SETUP)
 490         {
 491                 weapon_setup(WEP_ROCKET_LAUNCHER);
 492                 self.rl_release = 1;
 493         }
 494         else if (req == WR_CHECKAMMO1)
 495         {
 496                 // don't switch while guiding a missile
 497                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 498                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 499                         return FALSE;
 500         }
 501         else if (req == WR_CHECKAMMO2)
 502                 return FALSE;
 503         else if (req == WR_SUICIDEMESSAGE)
 504                 w_deathtypestring = "exploded";
 505         else if (req == WR_KILLMESSAGE)
 506         {
 507                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 508                         w_deathtypestring = "got too close to #'s rocket";
 509                 else if(w_deathtype & HITTYPE_SPLASH)
 510                         w_deathtypestring = "almost dodged #'s rocket";
 511                 else
 512                         w_deathtypestring = "ate #'s rocket";
 513         }
 514         return TRUE;
 515 };