data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         stopsound(self, CHAN_PAIN);
   8         sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
   9         org2 = findbetterlocation (self.origin, 16);
  10
  11         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
  12
  13         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  14         self.event_damage = SUB_Null;
  15         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  16
  17         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  18         {
  19                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  20                 {
  21                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  22                         ATTACK_FINISHED(self.owner) = time;
  23                         self.owner.switchweapon = w_getbestweapon(self.owner);
  24                 }
  25                 if(g_laserguided_missile)
  26                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  27         }
  28         remove (self);
  29 }
  30
  31 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  32 {
  33         entity head, selected;
  34         vector dir;
  35         float dist, maxdist,// bestdist,
  36                 dot,// bestdot,
  37                 points, bestpoints;
  38         //bestdist = 9999;
  39         //bestdot = -2;
  40         bestpoints = 0;
  41         maxdist = 800;
  42         selected = world;
  43
  44         makevectors(e.angles);
  45
  46         head = find(world, classname, "laser_target");
  47         while(head)
  48         {
  49                 points = 0;
  50                 dir = normalize(head.origin - self.origin);
  51                 dot = dir * v_forward;
  52                 dist = vlen(head.origin - self.origin);
  53                 if(dist > maxdist)
  54                         dist = maxdist;
  55
  56                 // gain points for being in front
  57                 points = points + ((dot+1)*0.5) * 500
  58                         * (1 + crandom()*dot_variance);
  59                 // gain points for being close away
  60                 points = points + (1 - dist/maxdist) * 1000
  61                         * (1 + crandom()*dot_variance);
  62
  63                 traceline(e.origin, head.origin, TRUE, self);
  64                 if(trace_fraction < 1)
  65                 {
  66                         points = 0;
  67                 }
  68
  69                 if(points > bestpoints)//random() > 0.5)//
  70                 {
  71                         bestpoints = points;
  72                         selected = head;
  73                 }
  74
  75                 head = find(head, classname, "laser_target");
  76         }
  77
  78         //bprint(selected.owner.netname);
  79         //bprint("\n");
  80         return selected;
  81 }
  82
  83 void W_Rocket_RemoteExplode()
  84 {
  85         if(self.owner.deadflag == DEAD_NO)
  86         {
  87                 if((self.spawnshieldtime >= 0)
  88                         ? (time >= self.spawnshieldtime) // timer
  89                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  90                 )
  91                 {
  92                         other = world;
  93                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  94                         W_Rocket_Explode ();
  95                 }
  96                 else
  97                 {
  98                 }
  99         }
 100 }
 101
 102 void W_Rocket_Think (void)
 103 {
 104         entity e;
 105         vector desireddir, olddir, newdir;
 106         float turnrate, velspeed;
 107         self.nextthink = time;
 108         if (time > self.cnt)
 109         {
 110                 other = world;
 111                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 112                 W_Rocket_Explode ();
 113                 return;
 114         }
 115
 116         if(g_laserguided_missile)
 117         {
 118                 // accelerate
 119                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 120                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 121                 if (velspeed > 0)
 122                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 123         }
 124         else
 125         {
 126                 // accelerate
 127                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 128                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 129                 if (velspeed > 0)
 130                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 131         }
 132
 133         // laser guided, or remote detonation
 134         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 135         {
 136                 if(g_laserguided_missile)
 137                 {
 138                         if(self.rl_detonate_later)
 139                                 W_Rocket_RemoteExplode();
 140
 141                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 142                         {
 143                                 if(self.owner.laser_on)
 144                                 {
 145                                         if(self.attack_finished_single < time)
 146                                         {
 147                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 148                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 149                                         }
 150
 151                                         if(!self.enemy)
 152                                                 self.enemy = self.owner.weaponentity.lasertarget;
 153                                 }
 154                                 else self.enemy = world;
 155                         }
 156                         else // don't allow stealing: always target my owner's laser (if it exists)
 157                                 self.enemy = self.owner.weaponentity.lasertarget;
 158
 159                         if(self.enemy != world)
 160                         {
 161                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 162                                 velspeed = vlen(self.velocity);
 163                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 164                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 165                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 166                                 olddir = normalize(self.velocity);                                      // get my current direction
 167                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 168                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 169                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 170
 171                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 172                         }
 173                 }
 174                 else
 175                 {
 176                         if(self.rl_detonate_later)
 177                                 W_Rocket_RemoteExplode();
 178                 }
 179         }
 180
 181         if(self.csqcprojectile_clientanimate == 0)
 182                 UpdateCSQCProjectile(self);
 183 }
 184
 185 void W_Rocket_Touch (void)
 186 {
 187         if(self.owner && self.owner.lastrocket == self)
 188                 self.owner.lastrocket = world;
 189         PROJECTILE_TOUCH_NOSOUND;
 190         W_Rocket_Explode ();
 191 }
 192
 193 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 194 {
 195         self.health = self.health - damage;
 196         self.angles = vectoangles(self.velocity);
 197         if (self.health <= 0)
 198                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 199 }
 200
 201 void W_Rocket_Attack (void)
 202 {
 203         local entity missile;
 204         local entity flash, flash2;
 205
 206         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 207                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 208
 209         W_SetupShot (self, '25 3 -4', FALSE, 5, "weapons/rocket_fire.wav");
 210         //W_SetupShot (self, '25 8 -8', FALSE, 5, "weapons/rocket_fire.wav"); // TODO: move model to the right a little
 211         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 212
 213         missile = spawn ();
 214         missile.owner = self;
 215         self.lastrocket = missile;
 216         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 217                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 218         else
 219                 missile.spawnshieldtime = -1;
 220         missile.classname = "rocket";
 221         missile.bot_dodge = TRUE;
 222         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 223
 224         missile.takedamage = DAMAGE_YES;
 225         missile.damageforcescale = 4;
 226         missile.health = cvar("g_balance_rocketlauncher_health");
 227         missile.event_damage = W_Rocket_Damage;
 228
 229         missile.movetype = MOVETYPE_FLY;
 230         missile.solid = SOLID_BBOX;
 231         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 232         setmodel (missile, "models/rocket.md3"); // precision set below
 233         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 234
 235         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 236         if(g_laserguided_missile && self.laser_on)
 237                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 238         else
 239                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 240         W_SetupProjectileVelocity(missile);
 241         missile.angles = vectoangles (missile.velocity);
 242
 243         missile.touch = W_Rocket_Touch;
 244         missile.think = W_Rocket_Think;
 245         missile.nextthink = time;
 246         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 247         missile.effects = EF_LOWPRECISION;
 248         //sound (missile, CHAN_PAIN, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 249         missile.flags = FL_PROJECTILE;
 250
 251         CSQCProjectile(missile);
 252         if(cvar("g_balance_rocketlauncher_speedaccel") == 0 && cvar("g_laserguided_missiles") == 0)
 253                 missile.csqcprojectile_clientanimate = 1;
 254         else
 255                 missile.csqcprojectile_clientanimate = 0; // we won't client animate if the missiles may behave weird
 256         missile.gravity = 0;
 257         missile.csqcprojectile_flysound = 2;
 258
 259         // muzzle flash for 1st person view
 260         flash = spawn ();
 261         flash.scale = 1.2;
 262         flash.angles_z = 180;
 263         flash.owner = self;
 264         flash.viewmodelforclient = self;
 265         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 266         setorigin (flash, '35 8 0');
 267         setmodel (flash, "models/flash.md3"); // precision set below
 268         setattachment(flash, self.weaponentity, "bone01");
 269         SUB_SetFade (flash, time, 0.4);
 270
 271         // muzzle flash for 3rd person view
 272         flash2 = spawn ();
 273         flash2.scale = 0.8;
 274         flash2.angles_y = 180;
 275         flash2.angles_z = 90;
 276         setorigin (flash2, '42 0 5');
 277         setmodel (flash2, "models/flash.md3"); // precision set below
 278         setattachment(flash2, self.exteriorweaponentity, "");
 279         SUB_SetFade (flash2, time, 0.4);
 280
 281         // common properties
 282         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 283 }
 284
 285 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 286
 287 float w_rlauncher(float req)
 288 {
 289         entity rock;
 290         float rockfound;
 291         if (req == WR_AIM)
 292         {
 293                 // aim and decide to fire if appropriate
 294                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 295                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 296                 {
 297                         // decide whether to detonate rockets
 298                         local entity missile, targetlist, targ;
 299                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 300                         local float selfdamage, teamdamage, enemydamage;
 301                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 302                         coredamage = cvar("g_balance_rocketlauncher_damage");
 303                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 304                         recipricoledgeradius = 1 / edgeradius;
 305                         selfdamage = 0;
 306                         teamdamage = 0;
 307                         enemydamage = 0;
 308                         targetlist = findchainfloat(bot_attack, TRUE);
 309                         missile = find(world, classname, "rocket");
 310                         while (missile)
 311                         {
 312                                 if (missile.owner != self)
 313                                 {
 314                                         missile = find(missile, classname, "rocket");
 315                                         continue;
 316                                 }
 317                                 targ = targetlist;
 318                                 while (targ)
 319                                 {
 320                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 321                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 322                                         // count potential damage according to type of target
 323                                         if (targ == self)
 324                                                 selfdamage = selfdamage + d;
 325                                         else if (targ.team == self.team && teamplay)
 326                                                 teamdamage = teamdamage + d;
 327                                         else if (bot_shouldattack(targ))
 328                                                 enemydamage = enemydamage + d;
 329                                         targ = targ.chain;
 330                                 }
 331                                 missile = find(missile, classname, "rocket");
 332                         }
 333                         local float desirabledamage;
 334                         desirabledamage = enemydamage;
 335                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 336                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 337                         if (self.team && teamplay == 2)
 338                                 desirabledamage = desirabledamage - teamdamage;
 339
 340                         missile = find(world, classname, "rocket");
 341                         while (missile)
 342                         {
 343                                 if (missile.owner != self)
 344                                 {
 345                                         missile = find(missile, classname, "rocket");
 346                                         continue;
 347                                 }
 348                                 makevectors(missile.v_angle);
 349                                 targ = targetlist;
 350                                 if (skill > 9) // normal players only do this for the target they are tracking
 351                                 {
 352                                         targ = targetlist;
 353                                         while (targ)
 354                                         {
 355                                                 if (
 356                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 357                                                         && desirabledamage > 0.1*coredamage
 358                                                 )self.BUTTON_ATCK2 = TRUE;
 359                                                 targ = targ.chain;
 360                                         }
 361                                 }else{
 362                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 363                                         //As the distance gets larger, a correct detonation gets near imposible
 364                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 365                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 366                                                 if(self.enemy.classname == "player")
 367                                                         if(desirabledamage >= 0.1*coredamage)
 368                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 369                                                                         self.BUTTON_ATCK2 = TRUE;
 370                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 371                                 }
 372
 373                                 missile = find(missile, classname, "rocket");
 374                         }
 375                         // if we would be doing at X percent of the core damage, detonate it
 376                         // but don't fire a new shot at the same time!
 377                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 378                                 self.BUTTON_ATCK2 = TRUE;
 379                         if ((skill > 6.5) && (selfdamage > self.health))
 380                                 self.BUTTON_ATCK2 = FALSE;
 381                         //if(self.BUTTON_ATCK2 == TRUE)
 382                         //      dprint(ftos(desirabledamage),"\n");
 383                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 384                 }
 385         }
 386         else if (req == WR_THINK)
 387         {
 388                 if(g_laserguided_missile)
 389                 {
 390                         if (self.BUTTON_ATCK && self.rl_release)
 391                         {
 392                                 rockfound = 0;
 393                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 394                                 {
 395                                         if(!rock.rl_detonate_later)
 396                                         {
 397                                                 rock.rl_detonate_later = TRUE;
 398                                                 rockfound = 1;
 399                                         }
 400                                 }
 401                                 if(rockfound)
 402                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 403                                 else
 404                                 {
 405                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 406                                         {
 407                                                 W_Rocket_Attack();
 408                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 409                                         }
 410                                 }
 411                                 self.rl_release = 0;
 412                         }
 413                         if (!self.BUTTON_ATCK)
 414                                 self.rl_release = 1;
 415                         if (self.BUTTON_ATCK2)
 416                         if(self.exteriorweaponentity.attack_finished_single < time)
 417                         {
 418                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 419                                 self.laser_on = !self.laser_on;
 420                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 421                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 422                         }
 423                 }
 424                 else
 425                 {
 426                         if (self.BUTTON_ATCK)
 427                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 428                         {
 429                                 W_Rocket_Attack();
 430                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 431                         }
 432                         if (self.BUTTON_ATCK2)
 433                         {
 434                                 rockfound = 0;
 435                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 436                                 {
 437                                         if(!rock.rl_detonate_later)
 438                                         {
 439                                                 rock.rl_detonate_later = TRUE;
 440                                                 rockfound = 1;
 441                                         }
 442                                 }
 443                                 if(rockfound)
 444                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 445                         }
 446                 }
 447         }
 448         else if (req == WR_PRECACHE)
 449         {
 450                 precache_model ("models/flash.md3");
 451                 precache_model ("models/rocket.md3");
 452                 precache_model ("models/weapons/g_rl.md3");
 453                 precache_model ("models/weapons/v_rl.md3");
 454                 precache_model ("models/weapons/w_rl.zym");
 455                 precache_sound ("weapons/rocket_det.wav");
 456                 precache_sound ("weapons/rocket_fire.wav");
 457                 precache_sound ("weapons/rocket_fly.wav");
 458                 precache_sound ("weapons/rocket_impact.wav");
 459                 if (g_laserguided_missile)
 460                 {
 461                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 462                         precache_sound ("weapons/rocket_mode.wav");
 463                 }
 464         }
 465         else if (req == WR_SETUP)
 466         {
 467                 weapon_setup(WEP_ROCKET_LAUNCHER);
 468                 self.rl_release = 1;
 469         }
 470         else if (req == WR_CHECKAMMO1)
 471         {
 472                 // don't switch while guiding a missile
 473                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 474                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 475                         return FALSE;
 476         }
 477         else if (req == WR_CHECKAMMO2)
 478                 return FALSE;
 479         else if (req == WR_SUICIDEMESSAGE)
 480                 w_deathtypestring = "exploded";
 481         else if (req == WR_KILLMESSAGE)
 482         {
 483                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 484                         w_deathtypestring = "got too close to #'s rocket";
 485                 else if(w_deathtype & HITTYPE_SPLASH)
 486                         w_deathtypestring = "almost dodged #'s rocket";
 487                 else
 488                         w_deathtypestring = "ate #'s rocket";
 489         }
 490         return TRUE;
 491 };