data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         stopsound(self, CHAN_PAIN);
   8         sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
   9         org2 = findbetterlocation (self.origin, 16);
  10
  11         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
  12
  13         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  14         self.event_damage = SUB_Null;
  15         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  16
  17         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  18         {
  19                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  20                 {
  21                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  22                         ATTACK_FINISHED(self.owner) = time;
  23                         self.owner.switchweapon = w_getbestweapon(self.owner);
  24                 }
  25                 if(g_laserguided_missile)
  26                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  27         }
  28         remove (self);
  29 }
  30
  31 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  32 {
  33         entity head, selected;
  34         vector dir;
  35         float dist, maxdist,// bestdist,
  36                 dot,// bestdot,
  37                 points, bestpoints;
  38         //bestdist = 9999;
  39         //bestdot = -2;
  40         bestpoints = 0;
  41         maxdist = 800;
  42         selected = world;
  43
  44         makevectors(e.angles);
  45
  46         head = find(world, classname, "laser_target");
  47         while(head)
  48         {
  49                 points = 0;
  50                 dir = normalize(head.origin - self.origin);
  51                 dot = dir * v_forward;
  52                 dist = vlen(head.origin - self.origin);
  53                 if(dist > maxdist)
  54                         dist = maxdist;
  55
  56                 // gain points for being in front
  57                 points = points + ((dot+1)*0.5) * 500
  58                         * (1 + crandom()*dot_variance);
  59                 // gain points for being close away
  60                 points = points + (1 - dist/maxdist) * 1000
  61                         * (1 + crandom()*dot_variance);
  62
  63                 traceline(e.origin, head.origin, TRUE, self);
  64                 if(trace_fraction < 1)
  65                 {
  66                         points = 0;
  67                 }
  68
  69                 if(points > bestpoints)//random() > 0.5)//
  70                 {
  71                         bestpoints = points;
  72                         selected = head;
  73                 }
  74
  75                 head = find(head, classname, "laser_target");
  76         }
  77
  78         //bprint(selected.owner.netname);
  79         //bprint("\n");
  80         return selected;
  81 }
  82
  83 void W_Rocket_RemoteExplode()
  84 {
  85         if(self.owner.deadflag == DEAD_NO)
  86         {
  87                 if((self.spawnshieldtime >= 0)
  88                         ? (time >= self.spawnshieldtime) // timer
  89                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  90                 )
  91                 {
  92                         other = world;
  93                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  94                         W_Rocket_Explode ();
  95                 }
  96                 else
  97                 {
  98                 }
  99         }
 100 }
 101
 102 void W_Rocket_Think (void)
 103 {
 104         entity e;
 105         vector desireddir, olddir, newdir;
 106         float turnrate, velspeed;
 107         self.nextthink = time;
 108         if (time > self.cnt)
 109         {
 110                 other = world;
 111                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 112                 W_Rocket_Explode ();
 113                 return;
 114         }
 115
 116         if(g_laserguided_missile)
 117         {
 118                 // accelerate
 119                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 120                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 121                 if (velspeed > 0)
 122                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 123         }
 124         else
 125         {
 126                 // accelerate
 127                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 128                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 129                 if (velspeed > 0)
 130                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 131         }
 132
 133         // laser guided, or remote detonation
 134         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 135         {
 136                 if(g_laserguided_missile)
 137                 {
 138                         if(self.rl_detonate_later)
 139                                 W_Rocket_RemoteExplode();
 140
 141                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 142                         {
 143                                 if(self.owner.laser_on)
 144                                 {
 145                                         if(self.attack_finished_single < time)
 146                                         {
 147                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 148                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 149                                         }
 150
 151                                         if(!self.enemy)
 152                                                 self.enemy = self.owner.weaponentity.lasertarget;
 153                                 }
 154                                 else self.enemy = world;
 155                         }
 156                         else // don't allow stealing: always target my owner's laser (if it exists)
 157                                 self.enemy = self.owner.weaponentity.lasertarget;
 158
 159                         if(self.enemy != world)
 160                         {
 161                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 162                                 velspeed = vlen(self.velocity);
 163                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 164                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 165                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 166                                 olddir = normalize(self.velocity);                                      // get my current direction
 167                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 168                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 169                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 170
 171                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 172                         }
 173                 }
 174                 else
 175                 {
 176                         if(self.rl_detonate_later)
 177                                 W_Rocket_RemoteExplode();
 178                 }
 179         }
 180 }
 181
 182 void W_Rocket_Touch (void)
 183 {
 184         if(self.owner && self.owner.lastrocket == self)
 185                 self.owner.lastrocket = world;
 186         PROJECTILE_TOUCH_NOSOUND;
 187         W_Rocket_Explode ();
 188 }
 189
 190 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 191 {
 192         self.health = self.health - damage;
 193         self.angles = vectoangles(self.velocity);
 194         if (self.health <= 0)
 195                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 196 }
 197
 198 void W_Rocket_Attack (void)
 199 {
 200         local entity missile;
 201         local entity flash, flash2;
 202
 203         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 204                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 205
 206         W_SetupShot (self, '25 3 -4', FALSE, 5, "weapons/rocket_fire.wav");
 207         //W_SetupShot (self, '25 8 -8', FALSE, 5, "weapons/rocket_fire.wav"); // TODO: move model to the right a little
 208         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 209
 210         missile = spawn ();
 211         missile.owner = self;
 212         self.lastrocket = missile;
 213         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 214                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 215         else
 216                 missile.spawnshieldtime = -1;
 217         missile.classname = "rocket";
 218         missile.bot_dodge = TRUE;
 219         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 220
 221         missile.takedamage = DAMAGE_YES;
 222         missile.damageforcescale = 4;
 223         missile.health = cvar("g_balance_rocketlauncher_health");
 224         missile.event_damage = W_Rocket_Damage;
 225
 226         missile.movetype = MOVETYPE_FLY;
 227         missile.solid = SOLID_BBOX;
 228         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 229         setmodel (missile, "models/rocket.md3"); // precision set below
 230         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 231
 232         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 233         if(g_laserguided_missile && self.laser_on)
 234                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 235         else
 236                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 237         W_SetupProjectileVelocity(missile);
 238         missile.angles = vectoangles (missile.velocity);
 239
 240         missile.touch = W_Rocket_Touch;
 241         missile.think = W_Rocket_Think;
 242         missile.nextthink = time;
 243         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 244         missile.effects = EF_LOWPRECISION;
 245         sound (missile, CHAN_PAIN, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 246         missile.flags = FL_PROJECTILE;
 247
 248         // muzzle flash for 1st person view
 249         flash = spawn ();
 250         flash.scale = 1.2;
 251         flash.angles_z = 180;
 252         flash.owner = self;
 253         flash.viewmodelforclient = self;
 254         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 255         setorigin (flash, '35 8 0');
 256         setmodel (flash, "models/flash.md3"); // precision set below
 257         setattachment(flash, self.weaponentity, "bone01");
 258         SUB_SetFade (flash, time, 0.4);
 259
 260         // muzzle flash for 3rd person view
 261         flash2 = spawn ();
 262         flash2.scale = 0.8;
 263         flash2.angles_y = 180;
 264         flash2.angles_z = 90;
 265         setorigin (flash2, '42 0 5');
 266         setmodel (flash2, "models/flash.md3"); // precision set below
 267         setattachment(flash2, self.exteriorweaponentity, "");
 268         SUB_SetFade (flash2, time, 0.4);
 269
 270         // common properties
 271         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 272 }
 273
 274 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 275
 276 float w_rlauncher(float req)
 277 {
 278         entity rock;
 279         float rockfound;
 280         if (req == WR_AIM)
 281         {
 282                 // aim and decide to fire if appropriate
 283                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 284                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 285                 {
 286                         // decide whether to detonate rockets
 287                         local entity missile, targetlist, targ;
 288                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 289                         local float selfdamage, teamdamage, enemydamage;
 290                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 291                         coredamage = cvar("g_balance_rocketlauncher_damage");
 292                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 293                         recipricoledgeradius = 1 / edgeradius;
 294                         selfdamage = 0;
 295                         teamdamage = 0;
 296                         enemydamage = 0;
 297                         targetlist = findchainfloat(bot_attack, TRUE);
 298                         missile = find(world, classname, "rocket");
 299                         while (missile)
 300                         {
 301                                 if (missile.owner != self)
 302                                 {
 303                                         missile = find(missile, classname, "rocket");
 304                                         continue;
 305                                 }
 306                                 targ = targetlist;
 307                                 while (targ)
 308                                 {
 309                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 310                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 311                                         // count potential damage according to type of target
 312                                         if (targ == self)
 313                                                 selfdamage = selfdamage + d;
 314                                         else if (targ.team == self.team && teamplay)
 315                                                 teamdamage = teamdamage + d;
 316                                         else if (bot_shouldattack(targ))
 317                                                 enemydamage = enemydamage + d;
 318                                         targ = targ.chain;
 319                                 }
 320                                 missile = find(missile, classname, "rocket");
 321                         }
 322                         local float desirabledamage;
 323                         desirabledamage = enemydamage;
 324                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 325                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 326                         if (self.team && teamplay == 2)
 327                                 desirabledamage = desirabledamage - teamdamage;
 328
 329                         missile = find(world, classname, "rocket");
 330                         while (missile)
 331                         {
 332                                 if (missile.owner != self)
 333                                 {
 334                                         missile = find(missile, classname, "rocket");
 335                                         continue;
 336                                 }
 337                                 makevectors(missile.v_angle);
 338                                 targ = targetlist;
 339                                 if (skill > 9) // normal players only do this for the target they are tracking
 340                                 {
 341                                         targ = targetlist;
 342                                         while (targ)
 343                                         {
 344                                                 if (
 345                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 346                                                         && desirabledamage > 0.1*coredamage
 347                                                 )self.BUTTON_ATCK2 = TRUE;
 348                                                 targ = targ.chain;
 349                                         }
 350                                 }else{
 351                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 352                                         //As the distance gets larger, a correct detonation gets near imposible
 353                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 354                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 355                                                 if(self.enemy.classname == "player")
 356                                                         if(desirabledamage >= 0.1*coredamage)
 357                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 358                                                                         self.BUTTON_ATCK2 = TRUE;
 359                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 360                                 }
 361
 362                                 missile = find(missile, classname, "rocket");
 363                         }
 364                         // if we would be doing at X percent of the core damage, detonate it
 365                         // but don't fire a new shot at the same time!
 366                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 367                                 self.BUTTON_ATCK2 = TRUE;
 368                         if ((skill > 6.5) && (selfdamage > self.health))
 369                                 self.BUTTON_ATCK2 = FALSE;
 370                         //if(self.BUTTON_ATCK2 == TRUE)
 371                         //      dprint(ftos(desirabledamage),"\n");
 372                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 373                 }
 374         }
 375         else if (req == WR_THINK)
 376         {
 377                 if(g_laserguided_missile)
 378                 {
 379                         if (self.BUTTON_ATCK && self.rl_release)
 380                         {
 381                                 rockfound = 0;
 382                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 383                                 {
 384                                         if(!rock.rl_detonate_later)
 385                                         {
 386                                                 rock.rl_detonate_later = TRUE;
 387                                                 rockfound = 1;
 388                                         }
 389                                 }
 390                                 if(rockfound)
 391                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 392                                 else
 393                                 {
 394                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 395                                         {
 396                                                 W_Rocket_Attack();
 397                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 398                                         }
 399                                 }
 400                                 self.rl_release = 0;
 401                         }
 402                         if (!self.BUTTON_ATCK)
 403                                 self.rl_release = 1;
 404                         if (self.BUTTON_ATCK2)
 405                         if(self.exteriorweaponentity.attack_finished_single < time)
 406                         {
 407                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 408                                 self.laser_on = !self.laser_on;
 409                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 410                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 411                         }
 412                 }
 413                 else
 414                 {
 415                         if (self.BUTTON_ATCK)
 416                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 417                         {
 418                                 W_Rocket_Attack();
 419                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 420                         }
 421                         if (self.BUTTON_ATCK2)
 422                         {
 423                                 rockfound = 0;
 424                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 425                                 {
 426                                         if(!rock.rl_detonate_later)
 427                                         {
 428                                                 rock.rl_detonate_later = TRUE;
 429                                                 rockfound = 1;
 430                                         }
 431                                 }
 432                                 if(rockfound)
 433                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 434                         }
 435                 }
 436         }
 437         else if (req == WR_PRECACHE)
 438         {
 439                 precache_model ("models/flash.md3");
 440                 precache_model ("models/rocket.md3");
 441                 precache_model ("models/weapons/g_rl.md3");
 442                 precache_model ("models/weapons/v_rl.md3");
 443                 precache_model ("models/weapons/w_rl.zym");
 444                 precache_sound ("weapons/rocket_det.wav");
 445                 precache_sound ("weapons/rocket_fire.wav");
 446                 precache_sound ("weapons/rocket_fly.wav");
 447                 precache_sound ("weapons/rocket_impact.wav");
 448                 if (g_laserguided_missile)
 449                 {
 450                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 451                         precache_sound ("weapons/rocket_mode.wav");
 452                 }
 453         }
 454         else if (req == WR_SETUP)
 455         {
 456                 weapon_setup(WEP_ROCKET_LAUNCHER);
 457                 self.rl_release = 1;
 458         }
 459         else if (req == WR_CHECKAMMO1)
 460         {
 461                 // don't switch while guiding a missile
 462                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 463                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 464                         return FALSE;
 465         }
 466         else if (req == WR_CHECKAMMO2)
 467                 return FALSE;
 468         else if (req == WR_SUICIDEMESSAGE)
 469                 w_deathtypestring = "exploded";
 470         else if (req == WR_KILLMESSAGE)
 471         {
 472                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 473                         w_deathtypestring = "got too close to #'s rocket";
 474                 else if(w_deathtype & HITTYPE_SPLASH)
 475                         w_deathtypestring = "almost dodged #'s rocket";
 476                 else
 477                         w_deathtypestring = "ate #'s rocket";
 478         }
 479         return TRUE;
 480 };