data/qcsrc/server/w_porto.qc

   1 .entity porto_current;
   2 .vector porto_v_angle; // holds "held" view angles
   3 .float porto_v_angle_held;
   4 .vector right_vector;
   5
   6 void W_Porto_Success (void)
   7 {
   8         if(self.owner == world)
   9         {
  10                 objerror("Cannot succeed successfully: no owner\n");
  11                 return;
  12         }
  13
  14         self.owner.porto_current = world;
  15         remove(self);
  16 }
  17
  18 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  19 void W_Porto_Fail (float failhard)
  20 {
  21         if(self.owner == world)
  22         {
  23                 objerror("Cannot fail successfully: no owner\n");
  24                 return;
  25         }
  26
  27         // no portals here!
  28         Portal_ClearWithID(self.owner, self.portal_id);
  29         self.owner.porto_current = world;
  30
  31         if(!failhard && !(self.owner.weapons & WEPBIT_PORTO))
  32         {
  33                 setsize (self, '-16 -16 0', '16 16 32');
  34                 setorigin(self, self.origin + trace_plane_normal);
  35                 if(move_out_of_solid(self))
  36                 {
  37                         self.flags = FL_ITEM;
  38                         self.velocity = trigger_push_calculatevelocity(self.origin, self.owner, 128);
  39                         tracetoss(self, self);
  40                         if(vlen(trace_endpos - self.owner.origin) < 128)
  41                         {
  42                                 W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, self.velocity);
  43                                 centerprint(self.owner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  44                         }
  45                 }
  46         }
  47         remove(self);
  48 }
  49
  50 void W_Porto_Think (void)
  51 {
  52         trace_plane_normal = '0 0 0';
  53         if(self.owner.playerid != self.playerid)
  54                 remove(self);
  55         else
  56                 W_Porto_Fail(0);
  57 }
  58
  59 void W_Porto_Touch (void)
  60 {
  61         vector norm;
  62
  63         if(other.classname == "portal")
  64                 return; // handled by the portal
  65
  66         norm = trace_plane_normal;
  67         if(trace_ent.movetype == MOVETYPE_WALK)
  68         {
  69                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN_z, MOVE_NORMAL, self);
  70                 if(trace_fraction >= 1)
  71                         return;
  72                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  73                         return;
  74                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  75                         return;
  76         }
  77
  78         if(self.owner.playerid != self.playerid)
  79         {
  80                 sound(self, CHAN_PROJECTILE, "porto/unsupported.ogg", VOL_BASE, ATTN_NORM);
  81                 remove(self);
  82         }
  83         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  84         {
  85                 sound(self, CHAN_PROJECTILE, "porto/bounce.ogg", VOL_BASE, ATTN_NORM);
  86                 // just reflect
  87                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  88                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  89         }
  90         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  91         {
  92                 sound(self, CHAN_PROJECTILE, "porto/unsupported.ogg", VOL_BASE, ATTN_NORM);
  93                 W_Porto_Fail(0);
  94         }
  95         else if(self.effects & EF_RED)
  96         {
  97                 self.effects += EF_BLUE - EF_RED;
  98                 if(Portal_SpawnInPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  99                 {
 100                         sound(self, CHAN_PROJECTILE, "porto/create.ogg", VOL_BASE, ATTN_NORM);
 101                         trace_plane_normal = norm;
 102                         centerprint(self.owner, "^1In^7-portal created.\n");
 103                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 104                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 105                 }
 106                 else
 107                 {
 108                         sound(self, CHAN_PROJECTILE, "porto/unsupported.ogg", VOL_BASE, ATTN_NORM);
 109                         trace_plane_normal = norm;
 110                         W_Porto_Fail(0);
 111                 }
 112         }
 113         else
 114         {
 115                 if(self.owner.portal_in.portal_id == self.portal_id)
 116                 {
 117                         if(Portal_SpawnOutPortalAtTrace(self.owner, self.right_vector, self.portal_id))
 118                         {
 119                                 sound(self, CHAN_PROJECTILE, "porto/create.ogg", VOL_BASE, ATTN_NORM);
 120                                 trace_plane_normal = norm;
 121                                 centerprint(self.owner, "^4Out^7-portal created.\n");
 122                                 W_Porto_Success();
 123                         }
 124                         else
 125                         {
 126                                 sound(self, CHAN_PROJECTILE, "porto/unsupported.ogg", VOL_BASE, ATTN_NORM);
 127                                 W_Porto_Fail(0);
 128                         }
 129                 }
 130                 else
 131                 {
 132                         sound(self, CHAN_PROJECTILE, "porto/unsupported.ogg", VOL_BASE, ATTN_NORM);
 133                         W_Porto_Fail(0);
 134                 }
 135         }
 136
 137 }
 138
 139 void W_Porto_Attack (void)
 140 {
 141         local entity gren;
 142
 143         if not(self.items & IT_UNLIMITED_AMMO)
 144                 self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
 145         W_SetupShot (self, '0 0 0', FALSE, 4, "porto/fire.ogg");
 146
 147         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 148
 149         gren = spawn ();
 150         gren.owner = self;
 151         gren.classname = "porto";
 152         gren.bot_dodge = TRUE;
 153         gren.bot_dodgerating = 200;
 154         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 155         gren.solid = SOLID_BBOX;
 156         gren.effects = EF_LOWPRECISION | EF_RED | EF_ADDITIVE;
 157         gren.scale = 4;
 158         gren.modelflags = MF_GRENADE;
 159         setmodel(gren, "models/grenademodel.md3"); // precision set above
 160         setsize(gren, '0 0 0', '0 0 0');
 161         setorigin(gren, w_shotorg);
 162
 163         gren.nextthink = time + cvar("g_balance_porto_primary_lifetime");
 164         gren.think = W_Porto_Think;
 165         gren.touch = W_Porto_Touch;
 166         gren.velocity = w_shotdir * cvar("g_balance_porto_primary_speed");
 167         if(self.items & IT_STRENGTH)
 168                 gren.velocity = gren.velocity * cvar("g_balance_powerup_strength_force");
 169         W_SetupProjectileVelocity(gren);
 170
 171         gren.angles = vectoangles (gren.velocity);
 172         gren.flags = FL_PROJECTILE;
 173
 174         gren.portal_id = time;
 175         self.porto_current = gren;
 176         gren.playerid = self.playerid;
 177         fixedmakevectors(vectoangles(gren.velocity));
 178         gren.right_vector = v_right;
 179
 180         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 181 }
 182
 183 void spawnfunc_weapon_porto (void)
 184 {
 185         weapon_defaultspawnfunc(WEP_PORTO);
 186 }
 187
 188 float w_porto(float req)
 189 {
 190         vector v_angle_save;
 191
 192         if (req == WR_AIM)
 193         {
 194                 self.BUTTON_ATCK = FALSE;
 195                 self.BUTTON_ATCK2 = FALSE;
 196                 if(bot_aim(cvar("g_balance_porto_primary_speed"), 0, cvar("g_balance_grenadelauncher_primary_lifetime"), FALSE))
 197                         self.BUTTON_ATCK = TRUE;
 198         }
 199         else if (req == WR_THINK)
 200         {
 201                 if(self.porto_v_angle_held)
 202                 {
 203                         if(!self.BUTTON_ATCK2)
 204                         {
 205                                 msg_entity = self;
 206                                 WRITESPECTATABLE_MSG_ONE_VARNAME(dummy1, {
 207                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 208                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 209                                         WriteByte(MSG_ONE, WEP_PORTO);
 210                                         WriteByte(MSG_ONE, 0);
 211                                 });
 212                                 self.porto_v_angle_held = 0;
 213                         }
 214                 }
 215                 else
 216                 {
 217                         if(self.BUTTON_ATCK2)
 218                         {
 219                                 self.porto_v_angle = self.v_angle;
 220                                 msg_entity = self;
 221                                 WRITESPECTATABLE_MSG_ONE_VARNAME(dummy2, {
 222                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 223                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 224                                         WriteByte(MSG_ONE, WEP_PORTO);
 225                                         WriteByte(MSG_ONE, 1);
 226                                         WriteCoord(MSG_ONE, self.v_angle_x);
 227                                         WriteCoord(MSG_ONE, self.v_angle_y);
 228                                 });
 229                                 self.porto_v_angle_held = 1;
 230                         }
 231                 }
 232                 v_angle_save = self.v_angle;
 233                 if(self.porto_v_angle_held)
 234                         makevectors(self.porto_v_angle); // override the previously set angles
 235
 236                 if (self.BUTTON_ATCK)
 237                 if (!self.porto_current)
 238                 if (!self.porto_forbidden)
 239                 if (weapon_prepareattack(0, cvar("g_balance_porto_primary_refire")))
 240                 {
 241                         W_Porto_Attack();
 242                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_porto_primary_animtime"), w_ready);
 243                 }
 244         }
 245         else if (req == WR_PRECACHE)
 246         {
 247                 precache_model ("models/grenademodel.md3");
 248                 precache_model ("models/weapons/g_porto.md3");
 249                 precache_model ("models/weapons/v_porto.md3");
 250                 precache_model ("models/weapons/w_porto.zym");
 251                 precache_model ("models/portal.md3");
 252                 precache_sound ("porto/bounce.ogg");
 253                 precache_sound ("porto/create.ogg");
 254                 precache_sound ("porto/expire.ogg");
 255                 precache_sound ("porto/explode.ogg");
 256                 precache_sound ("porto/fire.ogg");
 257                 precache_sound ("porto/unsupported.ogg");
 258         }
 259         else if (req == WR_SETUP)
 260                 weapon_setup(WEP_PORTO);
 261         else if (req == WR_SUICIDEMESSAGE)
 262                 w_deathtypestring = "did the impossible";
 263         else if (req == WR_KILLMESSAGE)
 264                 w_deathtypestring = "felt # doing the impossible";
 265         return TRUE;
 266 };