data/qcsrc/server/w_porto.qc

   1 .float portal_id;
   2 .entity porto_current;
   3 .vector porto_v_angle; // holds "held" view angles
   4 .float porto_v_angle_held;
   5 .vector right_vector;
   6
   7 void W_Porto_Success (void)
   8 {
   9         if(self.owner == world)
  10         {
  11                 objerror("Cannot succeed successfully: no owner\n");
  12                 return;
  13         }
  14
  15         self.owner.porto_current = world;
  16         remove(self);
  17 }
  18
  19 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  20 void W_Porto_Fail (float failhard)
  21 {
  22         if(self.owner == world)
  23         {
  24                 objerror("Cannot fail successfully: no owner\n");
  25                 return;
  26         }
  27
  28         // no portals here!
  29         Portal_ClearWithID(self.owner, self.portal_id);
  30         self.owner.porto_current = world;
  31
  32         if(!failhard && !(self.owner.weapons & WEPBIT_PORTO))
  33         {
  34                 centerprint(self.owner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  35                 setsize (self, '-16 -16 0', '16 16 32');
  36                 setorigin(self, self.origin + trace_plane_normal);
  37                 if(move_out_of_solid(self))
  38                 {
  39                         self.flags = FL_ITEM;
  40                         self.velocity = trigger_push_calculatevelocity(self.origin, self.owner, 128);
  41                         tracetoss(self, self);
  42                         if(vlen(trace_endpos - self.owner.origin) > 128)
  43                                 self.velocity = '0 0 0';
  44                         W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, self.velocity);
  45                 }
  46                 else
  47                 {
  48                         W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, '0 0 0');
  49                 }
  50         }
  51         remove(self);
  52 }
  53
  54 void W_Porto_Think (void)
  55 {
  56         trace_plane_normal = '0 0 0';
  57         if(self.owner.playerid != self.playerid)
  58                 remove(self);
  59         else
  60                 W_Porto_Fail(0);
  61 }
  62
  63 void W_Porto_Touch (void)
  64 {
  65         vector norm;
  66
  67         if(other.classname == "portal")
  68                 return; // handled by the portal
  69
  70         norm = trace_plane_normal;
  71         if(self.owner.playerid != self.playerid)
  72         {
  73                 remove(self);
  74         }
  75         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
  76         {
  77                 // just reflect
  78                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  79                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  80         }
  81         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  82         {
  83                 W_Porto_Fail(0);
  84         }
  85         else if(self.effects & EF_RED)
  86         {
  87                 self.effects += EF_BLUE - EF_RED;
  88                 if(Portal_SpawnInPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  89                 {
  90                         sound(self, CHAN_PROJECTILE, "misc/invshot.wav", VOL_BASE, ATTN_NORM);
  91                         centerprint(self.owner, "^1In^7-portal created.\n");
  92                         trace_plane_normal = norm;
  93                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  94                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  95                 }
  96                 else
  97                 {
  98                         trace_plane_normal = norm;
  99                         W_Porto_Fail(0);
 100                 }
 101         }
 102         else
 103         {
 104                 if(Portal_SpawnOutPortalAtTrace(self.owner, self.right_vector, self.portal_id))
 105                 {
 106                         sound(self, CHAN_PROJECTILE, "misc/invshot.wav", VOL_BASE, ATTN_NORM);
 107                         centerprint(self.owner, "^4Out^7-portal created.\n");
 108                         W_Porto_Success();
 109                 }
 110                 else
 111                 {
 112                         trace_plane_normal = norm;
 113                         W_Porto_Fail(0);
 114                 }
 115         }
 116
 117 }
 118
 119 void W_Porto_Attack (void)
 120 {
 121         local entity gren;
 122
 123         if not(self.items & IT_UNLIMITED_AMMO)
 124                 self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
 125         W_SetupShot (self, '0 0 0', FALSE, 4, "weapons/grenade_fire.wav");
 126
 127         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 128
 129         gren = spawn ();
 130         gren.owner = self;
 131         gren.classname = "porto";
 132         gren.bot_dodge = TRUE;
 133         gren.bot_dodgerating = 200;
 134         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 135         gren.solid = SOLID_BBOX;
 136         gren.effects = EF_LOWPRECISION | EF_RED;
 137         gren.scale = 4;
 138         gren.modelflags = MF_GRENADE;
 139         setmodel(gren, "models/grenademodel.md3"); // precision set above
 140         setsize(gren, '0 0 0', '0 0 0');
 141         setorigin(gren, w_shotorg);
 142
 143         gren.nextthink = time + cvar("g_balance_porto_primary_lifetime");
 144         gren.think = W_Porto_Think;
 145         gren.touch = W_Porto_Touch;
 146         gren.velocity = w_shotdir * cvar("g_balance_porto_primary_speed");
 147         if(self.items & IT_STRENGTH)
 148                 gren.velocity = gren.velocity * cvar("g_balance_powerup_strength_force");
 149         W_SetupProjectileVelocity(gren);
 150
 151         gren.angles = vectoangles (gren.velocity);
 152         gren.flags = FL_PROJECTILE;
 153
 154         gren.portal_id = time;
 155         self.porto_current = gren;
 156         gren.playerid = self.playerid;
 157         fixedmakevectors(vectoangles(gren.velocity));
 158         gren.right_vector = v_right;
 159
 160         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 161 }
 162
 163 void spawnfunc_weapon_porto (void)
 164 {
 165         weapon_defaultspawnfunc(WEP_PORTO);
 166 }
 167
 168 float w_porto(float req)
 169 {
 170         vector v_angle_save;
 171
 172         if (req == WR_AIM)
 173         {
 174                 self.BUTTON_ATCK = FALSE;
 175                 self.BUTTON_ATCK2 = FALSE;
 176                 if(bot_aim(cvar("g_balance_porto_primary_speed"), 0, cvar("g_balance_grenadelauncher_primary_lifetime"), FALSE))
 177                         self.BUTTON_ATCK = TRUE;
 178         }
 179         else if (req == WR_THINK)
 180         {
 181                 if(self.porto_v_angle_held)
 182                 {
 183                         if(!self.BUTTON_ATCK2)
 184                         {
 185                                 msg_entity = self;
 186                                 WRITESPECTATABLE_MSG_ONE({
 187                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 188                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 189                                         WriteByte(MSG_ONE, WEP_PORTO);
 190                                         WriteByte(MSG_ONE, 0);
 191                                 });
 192                                 self.porto_v_angle_held = 0;
 193                         }
 194                 }
 195                 else
 196                 {
 197                         if(self.BUTTON_ATCK2)
 198                         {
 199                                 self.porto_v_angle = self.v_angle;
 200                                 msg_entity = self;
 201                                 WRITESPECTATABLE_MSG_ONE({
 202                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 203                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 204                                         WriteByte(MSG_ONE, WEP_PORTO);
 205                                         WriteByte(MSG_ONE, 1);
 206                                         WriteCoord(MSG_ONE, self.v_angle_x);
 207                                         WriteCoord(MSG_ONE, self.v_angle_y);
 208                                 });
 209                                 self.porto_v_angle_held = 1;
 210                         }
 211                 }
 212                 v_angle_save = self.v_angle;
 213                 if(self.porto_v_angle_held)
 214                         makevectors(self.porto_v_angle); // override the previously set angles
 215
 216                 if (self.BUTTON_ATCK)
 217                 if (!self.porto_current)
 218                 if (weapon_prepareattack(0, cvar("g_balance_porto_primary_refire")))
 219                 {
 220                         W_Porto_Attack();
 221                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_porto_primary_animtime"), w_ready);
 222                 }
 223         }
 224         else if (req == WR_PRECACHE)
 225         {
 226                 precache_model ("models/grenademodel.md3");
 227                 precache_model ("models/weapons/g_porto.md3");
 228                 precache_model ("models/weapons/v_porto.md3");
 229                 precache_model ("models/weapons/w_porto.zym");
 230                 precache_sound ("weapons/grenade_fire.wav");
 231                 precache_model ("models/portal.md3");
 232         }
 233         else if (req == WR_SETUP)
 234                 weapon_setup(WEP_PORTO);
 235         else if (req == WR_SUICIDEMESSAGE)
 236                 w_deathtypestring = "did the impossible";
 237         else if (req == WR_KILLMESSAGE)
 238                 w_deathtypestring = "felt # doing the impossible";
 239         return TRUE;
 240 };