data/qcsrc/server/w_porto.qc

   1 .float porto_grenade_id;
   2 .vector porto_v_angle; // holds "held" view angles
   3 .float porto_v_angle_held;
   4 .vector right_vector;
   5
   6 void W_Porto_Success (void)
   7 {
   8         self.owner.porto_grenade_id = 0;
   9         remove(self);
  10 }
  11
  12 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  13 void W_Porto_Fail (void)
  14 {
  15         centerprint(self.owner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  16         self.owner.porto_grenade_id = 0;
  17         // TODO maybe instead throw the portal gun there?
  18         // self.owner.weapons = self.owner.weapons | WEPBIT_PORTO;
  19         setsize (self, '-16 -16 0', '16 16 32');
  20         setorigin(self, self.origin + trace_plane_normal);
  21         if(move_out_of_solid(self))
  22         {
  23                 self.flags = FL_ITEM;
  24                 self.velocity = trigger_push_calculatevelocity(self.origin, self.owner, 128);
  25                 tracetoss(self, self);
  26                 if(vlen(trace_endpos - self.owner.origin) > 128)
  27                         self.velocity = '0 0 0';
  28                 W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, self.velocity);
  29         }
  30         else
  31         {
  32                 W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, '0 0 0');
  33         }
  34         remove(self);
  35 }
  36
  37 void W_Porto_Think (void)
  38 {
  39         trace_plane_normal = '0 0 0';
  40         if(self.owner.playerid != self.playerid)
  41                 remove(self);
  42         else
  43                 W_Porto_Fail();
  44 }
  45
  46 void W_Porto_Touch (void)
  47 {
  48         vector norm;
  49         norm = trace_plane_normal;
  50         if(self.owner.playerid != self.playerid)
  51         {
  52                 remove(self);
  53         }
  54         else if(self.cnt == 0)
  55         {
  56                 self.cnt = 1;
  57                 if(!Portal_SpawnInPortalAtTrace(self.owner, self.right_vector, self.porto_grenade_id))
  58                 {
  59                         trace_plane_normal = norm;
  60                         W_Porto_Fail();
  61                         return;
  62                 }
  63                 trace_plane_normal = norm;
  64                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  65         }
  66         else
  67         {
  68                 if(!Portal_SpawnOutPortalAtTrace(self.owner, self.right_vector, self.porto_grenade_id))
  69                 {
  70                         trace_plane_normal = norm;
  71                         W_Porto_Fail();
  72                 }
  73                 else
  74                         W_Porto_Success();
  75         }
  76
  77 }
  78
  79 void W_Porto_Attack (void)
  80 {
  81         local entity gren;
  82
  83         if (cvar("g_use_ammunition"))
  84                 self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
  85         W_SetupShot (self, '0 0 0', FALSE, 4, "weapons/grenade_fire.wav");
  86
  87         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  88
  89         gren = spawn ();
  90         gren.owner = self;
  91         gren.classname = "porto";
  92         gren.bot_dodge = TRUE;
  93         gren.bot_dodgerating = 200;
  94         gren.movetype = MOVETYPE_BOUNCEMISSILE;
  95         gren.solid = SOLID_BBOX;
  96         gren.effects = EF_LOWPRECISION;
  97         gren.modelflags = MF_GRENADE;
  98         setmodel(gren, "models/grenademodel.md3"); // precision set above
  99         setsize(gren, '0 0 0', '0 0 0');
 100         setorigin(gren, w_shotorg);
 101
 102         gren.nextthink = time + cvar("g_balance_porto_primary_lifetime");
 103         gren.think = W_Porto_Think;
 104         gren.touch = W_Porto_Touch;
 105         gren.velocity = w_shotdir * cvar("g_balance_porto_primary_speed");
 106         W_SetupProjectileVelocity(gren);
 107
 108         gren.angles = vectoangles (gren.velocity);
 109         gren.flags = FL_PROJECTILE;
 110
 111         self.porto_grenade_id = gren.porto_grenade_id = time;
 112         gren.playerid = self.playerid;
 113         fixedmakevectors(vectoangles(gren.velocity));
 114         gren.right_vector = v_right;
 115
 116         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 117 }
 118
 119 void spawnfunc_weapon_porto (void)
 120 {
 121         weapon_defaultspawnfunc(WEP_PORTO);
 122 }
 123
 124 float w_porto(float req)
 125 {
 126         vector v_angle_save;
 127
 128         if (req == WR_AIM)
 129         {
 130                 self.BUTTON_ATCK = FALSE;
 131                 self.BUTTON_ATCK2 = FALSE;
 132                 if(bot_aim(cvar("g_balance_porto_primary_speed"), 0, cvar("g_balance_grenadelauncher_primary_lifetime"), FALSE))
 133                         self.BUTTON_ATCK = TRUE;
 134         }
 135         else if (req == WR_THINK)
 136         {
 137                 if(self.porto_v_angle_held)
 138                 {
 139                         if(!self.BUTTON_ATCK2)
 140                         {
 141                                 msg_entity = self;
 142                                 WRITESPECTATABLE_MSG_ONE({
 143                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 144                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 145                                         WriteByte(MSG_ONE, WEP_PORTO);
 146                                         WriteByte(MSG_ONE, 0);
 147                                 });
 148                                 self.porto_v_angle_held = 0;
 149                         }
 150                 }
 151                 else
 152                 {
 153                         if(self.BUTTON_ATCK2)
 154                         {
 155                                 self.porto_v_angle = self.v_angle;
 156                                 msg_entity = self;
 157                                 WRITESPECTATABLE_MSG_ONE({
 158                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 159                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 160                                         WriteByte(MSG_ONE, WEP_PORTO);
 161                                         WriteByte(MSG_ONE, 1);
 162                                         WriteCoord(MSG_ONE, self.v_angle_x);
 163                                         WriteCoord(MSG_ONE, self.v_angle_y);
 164                                 });
 165                                 self.porto_v_angle_held = 1;
 166                         }
 167                 }
 168                 v_angle_save = self.v_angle;
 169                 if(self.porto_v_angle_held)
 170                         makevectors(self.porto_v_angle); // override the previously set angles
 171
 172                 if (self.BUTTON_ATCK)
 173                 if (!self.porto_grenade_id)
 174                 if (weapon_prepareattack(0, cvar("g_balance_porto_primary_refire")))
 175                 {
 176                         W_Porto_Attack();
 177                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_porto_primary_animtime"), w_ready);
 178                 }
 179         }
 180         else if (req == WR_PRECACHE)
 181         {
 182                 precache_model ("models/grenademodel.md3");
 183                 precache_model ("models/weapons/g_porto.md3");
 184                 precache_model ("models/weapons/v_porto.md3");
 185                 precache_model ("models/weapons/w_porto.zym");
 186                 precache_sound ("weapons/grenade_fire.wav");
 187                 precache_model ("models/portal.md3");
 188         }
 189         else if (req == WR_SETUP)
 190                 weapon_setup(WEP_PORTO);
 191         else if (req == WR_SUICIDEMESSAGE)
 192                 w_deathtypestring = "did the impossible";
 193         else if (req == WR_KILLMESSAGE)
 194                 w_deathtypestring = "felt # doing the impossible";
 195         return TRUE;
 196 };