data/qcsrc/server/w_hook.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_radius;
   4 .float dmg_force;
   5 .float dmg_power;
   6 .float dmg_duration;
   7 .float dmg_last;
   8 .float hook_refire;
   9 .float hook_time_hooked;
  10 .float hook_time_fueldecrease;
  11
  12 void W_Hook_ExplodeThink (void)
  13 {
  14         float dt, dmg_remaining_next, f;
  15
  16         dt = time - self.teleport_time;
  17         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  18
  19         f = self.dmg_last - dmg_remaining_next;
  20         self.dmg_last = dmg_remaining_next;
  21
  22         RadiusDamage (self, self.owner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.owner, self.dmg_force * f, self.projectiledeathtype, world);
  23         self.projectiledeathtype |= HITTYPE_BOUNCE;
  24         //RadiusDamage (self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, self.dmg_force * f, self.projectiledeathtype, world);
  25
  26         if(dt < self.dmg_duration)
  27                 self.nextthink = time + 0.05; // soon
  28         else
  29                 remove(self);
  30 }
  31
  32 void W_Hook_Explode2 (void)
  33 {
  34         self.event_damage = SUB_Null;
  35         self.touch = SUB_Null;
  36         self.effects |= EF_NODRAW;
  37
  38         self.think = W_Hook_ExplodeThink;
  39         self.nextthink = time;
  40         self.dmg = cvar("g_balance_hook_secondary_damage");
  41         self.dmg_edge = cvar("g_balance_hook_secondary_edgedamage");
  42         self.dmg_radius = cvar("g_balance_hook_secondary_radius");
  43         self.dmg_force = cvar("g_balance_hook_secondary_force");
  44         self.dmg_power = cvar("g_balance_hook_secondary_power");
  45         self.dmg_duration = cvar("g_balance_hook_secondary_duration");
  46         self.teleport_time = time;
  47         self.dmg_last = 1;
  48         self.movetype = MOVETYPE_NONE;
  49 }
  50
  51 void W_Hook_Touch2 (void)
  52 {
  53         PROJECTILE_TOUCH;
  54         self.use();
  55 }
  56
  57 void W_Hook_Attack2()
  58 {
  59         local entity gren;
  60
  61         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  62                 self.ammo_cells = self.ammo_cells - cvar("g_balance_hook_secondary_ammo");
  63         W_SetupShot (self, FALSE, 4, "weapons/hookbomb_fire.wav");
  64
  65         gren = spawn ();
  66         gren.owner = self;
  67         gren.classname = "hookbomb";
  68         gren.bot_dodge = TRUE;
  69         gren.bot_dodgerating = cvar("g_balance_hook_secondary_damage");
  70         gren.movetype = MOVETYPE_TOSS;
  71         gren.solid = SOLID_BBOX;
  72         gren.projectiledeathtype = WEP_HOOK | HITTYPE_SECONDARY;
  73         setorigin(gren, w_shotorg);
  74
  75         gren.nextthink = time + cvar("g_balance_hook_secondary_lifetime");
  76         gren.think = adaptor_think2use;
  77         gren.use = W_Hook_Explode2;
  78         gren.touch = W_Hook_Touch2;
  79
  80         gren.velocity = '0 0 1' * cvar("g_balance_hook_secondary_speed");
  81         if(cvar("g_projectiles_newton_style"))
  82                 gren.velocity = gren.velocity + self.velocity;
  83
  84         gren.gravity = cvar("g_balance_hook_secondary_gravity");
  85         //W_SetupProjectileVelocity(gren); // just falling down!
  86
  87         gren.angles = '0 0 0';
  88         gren.flags = FL_PROJECTILE;
  89
  90         CSQCProjectile(gren, TRUE, PROJECTILE_HOOKBOMB, TRUE);
  91 }
  92
  93 void spawnfunc_weapon_hook (void)
  94 {
  95         if(g_grappling_hook) // offhand hook
  96         {
  97                 startitem_failed = TRUE;
  98                 remove(self);
  99                 return;
 100         }
 101         weapon_defaultspawnfunc(WEP_HOOK);
 102 }
 103
 104 float w_hook(float req)
 105 {
 106         float hooked_time_max, hooked_fuel;
 107
 108         if (req == WR_AIM)
 109         {
 110                 // ... sorry ...
 111         }
 112         else if (req == WR_THINK)
 113         {
 114                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 115                 {
 116                         if(!self.hook)
 117                         if not(self.hook_state & HOOK_WAITING_FOR_RELEASE)
 118                         if not(self.hook_state & HOOK_FIRING)
 119                         if (time > self.hook_refire)
 120                         if (weapon_prepareattack(0, -1))
 121                         {
 122                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 123                                         self.ammo_fuel = self.ammo_fuel - cvar("g_balance_hook_primary_fuel");
 124                                 self.hook_state |= HOOK_FIRING;
 125                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hook_primary_animtime"), w_ready);
 126                         }
 127                 }
 128
 129                 if (self.BUTTON_ATCK2)
 130                 {
 131                         if (weapon_prepareattack(1, cvar("g_balance_hook_secondary_refire")))
 132                         {
 133                                 W_Hook_Attack2();
 134                                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_hook_secondary_animtime"), w_ready);
 135                         }
 136                 }
 137
 138                 if(self.hook)
 139                 {
 140                         // if hooked, no bombs, and increase the timer
 141                         self.hook_refire = max(self.hook_refire, time + cvar("g_balance_hook_primary_refire"));
 142
 143                         // hook also inhibits health regeneration, but only for 1 second
 144                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 145                                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
 146                 }
 147
 148                 if(self.hook && self.hook.state == 1)
 149                 {
 150                         hooked_time_max = cvar("g_balance_hook_primary_hooked_time_max");
 151                         if (hooked_time_max > 0)
 152                         {
 153                                 if ( time > self.hook_time_hooked + hooked_time_max )
 154                                         self.hook_state |= HOOK_REMOVING;
 155                         }
 156
 157                         hooked_fuel = cvar("g_balance_hook_primary_hooked_fuel");
 158                         if (hooked_fuel > 0)
 159                         {
 160                                 if ( time > self.hook_time_fueldecrease )
 161                                 {
 162                                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 163                                         {
 164                                                 if ( self.ammo_fuel >= (time - self.hook_time_fueldecrease) * hooked_fuel )
 165                                                 {
 166                                                         self.ammo_fuel -= (time - self.hook_time_fueldecrease) * hooked_fuel;
 167                                                         self.hook_time_fueldecrease = time;
 168                                                         // decrease next frame again
 169                                                 }
 170                                                 else
 171                                                 {
 172                                                         self.ammo_fuel = 0;
 173                                                         self.hook_state |= HOOK_REMOVING;
 174                                                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 175                                                 }
 176                                         }
 177                                 }
 178                         }
 179                 }
 180                 else
 181                 {
 182                         self.hook_time_hooked = time;
 183                         self.hook_time_fueldecrease = time + cvar("g_balance_hook_primary_hooked_time_free");
 184                 }
 185
 186                 if (self.BUTTON_CROUCH)
 187                 {
 188                         self.hook_state &~= HOOK_PULLING;
 189                         if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 190                                 self.hook_state &~= HOOK_RELEASING;
 191                         else
 192                                 self.hook_state |= HOOK_RELEASING;
 193                 }
 194                 else
 195                 {
 196                         self.hook_state |= HOOK_PULLING;
 197                         self.hook_state &~= HOOK_RELEASING;
 198
 199                         if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 200                         {
 201                                 // already fired
 202                                 if(self.hook)
 203                                         self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 204                         }
 205                         else
 206                         {
 207                                 self.hook_state |= HOOK_REMOVING;
 208                                 self.hook_state &~= HOOK_WAITING_FOR_RELEASE;
 209                         }
 210                 }
 211         }
 212         else if (req == WR_PRECACHE)
 213         {
 214                 precache_model ("models/weapons/g_hookgun.md3");
 215                 precache_model ("models/weapons/v_hookgun.md3");
 216                 precache_model ("models/weapons/h_hookgun.dpm");
 217                 precache_sound ("weapons/hook_impact.wav"); // done by g_hook.qc
 218                 precache_sound ("weapons/hook_fire.wav");
 219                 precache_sound ("weapons/hookbomb_fire.wav");
 220         }
 221         else if (req == WR_SETUP)
 222         {
 223                 weapon_setup(WEP_HOOK);
 224                 self.hook_state &~= HOOK_WAITING_FOR_RELEASE;
 225         }
 226         else if (req == WR_CHECKAMMO1)
 227         {
 228                 if(self.hook)
 229                         return self.ammo_fuel > 0;
 230                 else
 231                         return self.ammo_fuel >= cvar("g_balance_hook_primary_fuel");
 232         }
 233         else if (req == WR_CHECKAMMO2)
 234         {
 235                 return self.ammo_cells >= cvar("g_balance_hook_secondary_ammo");
 236         }
 237         else if (req == WR_SUICIDEMESSAGE)
 238                 w_deathtypestring = "did the impossible";
 239         else if (req == WR_KILLMESSAGE)
 240                 w_deathtypestring = "has run into #'s gravity bomb";
 241         return TRUE;
 242 };