data/qcsrc/server/w_hook.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_radius;
   4 .float dmg_force;
   5 .float dmg_power;
   6 .float dmg_duration;
   7 .float dmg_last;
   8
   9 void W_Hook_ExplodeThink (void)
  10 {
  11         float dt, dmg_remaining, dmg_remaining_next, f;
  12
  13         dt = time - self.teleport_time;
  14         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  15
  16         f = self.dmg_last - dmg_remaining_next;
  17         self.dmg_last = dmg_remaining_next;
  18
  19         RadiusDamage (self, self.owner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.owner, self.dmg_force * f, self.projectiledeathtype, world);
  20
  21         if(dt < self.dmg_duration)
  22                 self.nextthink = time + 0.05; // soon
  23         else
  24                 remove(self);
  25 }
  26
  27 void W_Hook_Explode2 (void)
  28 {
  29         vector org2;
  30
  31         org2 = findbetterlocation (self.origin, 12);
  32         pointparticles(particleeffectnum("hookbomb_explode"), org2, '0 0 0', 1);
  33         sound (self, CHAN_PROJECTILE, "weapons/hookbomb_impact.wav", VOL_BASE, ATTN_NORM);
  34
  35         self.event_damage = SUB_Null;
  36         self.touch = SUB_Null;
  37
  38         self.think = W_Hook_ExplodeThink;
  39         self.nextthink = time;
  40         self.dmg = cvar("g_balance_hook_secondary_damage");
  41         self.dmg_edge = cvar("g_balance_hook_secondary_edgedamage");
  42         self.dmg_radius = cvar("g_balance_hook_secondary_radius");
  43         self.dmg_force = cvar("g_balance_hook_secondary_force");
  44         self.dmg_power = cvar("g_balance_hook_secondary_power");
  45         self.dmg_duration = cvar("g_balance_hook_secondary_duration");
  46         self.teleport_time = time;
  47         self.dmg_last = 1;
  48 }
  49
  50 void W_Hook_Touch2 (void)
  51 {
  52         PROJECTILE_TOUCH;
  53         self.use();
  54 }
  55
  56 void W_Hook_Attack2()
  57 {
  58         local entity gren;
  59
  60         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  61                 self.ammo_cells = self.ammo_cells - cvar("g_balance_hook_secondary_ammo");
  62         W_SetupShot (self, '25 6 -8', FALSE, 4, "weapons/hookbomb_fire.wav");
  63
  64         gren = spawn ();
  65         gren.owner = self;
  66         gren.classname = "hookbomb";
  67         gren.bot_dodge = TRUE;
  68         gren.bot_dodgerating = cvar("g_balance_hook_secondary_damage");
  69         gren.movetype = MOVETYPE_TOSS;
  70         gren.solid = SOLID_BBOX;
  71         gren.effects = EF_LOWPRECISION;
  72         gren.modelflags = MF_TRACER2;
  73         gren.projectiledeathtype = WEP_HOOK | HITTYPE_SECONDARY;
  74         setmodel(gren, "models/grenademodel.md3"); // precision set above // FIXME replace
  75         setsize(gren, '0 0 0', '0 0 0');
  76         setorigin(gren, w_shotorg);
  77
  78         gren.nextthink = time + cvar("g_balance_hook_secondary_lifetime");
  79         gren.think = adaptor_think2use;
  80         gren.use = W_Hook_Explode2;
  81         gren.touch = W_Hook_Touch2;
  82         gren.velocity = '0 0 1' * cvar("g_balance_hook_secondary_speed");
  83         gren.gravity = cvar("g_balance_hook_secondary_gravity");
  84         //W_SetupProjectileVelocity(gren); // just falling down!
  85
  86         gren.angles = '0 0 0';
  87         gren.flags = FL_PROJECTILE;
  88 }
  89
  90 void spawnfunc_weapon_hook (void)
  91 {
  92         if(g_grappling_hook) // offhand hook
  93         {
  94                 startitem_failed = TRUE;
  95                 remove(self);
  96                 return;
  97         }
  98         weapon_defaultspawnfunc(WEP_HOOK);
  99 }
 100
 101 float w_hook(float req)
 102 {
 103         if (req == WR_AIM)
 104         {
 105                 // ... sorry ...
 106         }
 107         else if (req == WR_THINK)
 108         {
 109                 if (self.BUTTON_ATCK || self.BUTTON_HOOK)
 110                 {
 111                         if(!self.hook)
 112                         if not(self.hook_state & HOOK_WAITING_FOR_RELEASE)
 113                         if (weapon_prepareattack(0, cvar("g_balance_hook_primary_refire")))
 114                         {
 115                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 116                                         self.ammo_cells = self.ammo_cells - cvar("g_balance_hook_primary_ammo");
 117                                 self.hook_state |= HOOK_FIRING;
 118                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hook_primary_animtime"), w_ready);
 119                         }
 120                 }
 121
 122                 if (self.BUTTON_ATCK2)
 123                 {
 124                         if (weapon_prepareattack(1, cvar("g_balance_hook_secondary_refire")))
 125                         {
 126                                 W_Hook_Attack2();
 127                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hook_secondary_animtime"), w_ready);
 128                         }
 129                 }
 130
 131                 if (self.BUTTON_CROUCH)
 132                 {
 133                         self.hook_state (-) HOOK_PULLING;
 134                         if (self.BUTTON_ATCK || self.BUTTON_HOOK)
 135                                 self.hook_state (-) HOOK_RELEASING;
 136                         else
 137                                 self.hook_state |= HOOK_RELEASING;
 138                 }
 139                 else
 140                 {
 141                         self.hook_state |= HOOK_PULLING;
 142                         self.hook_state (-) HOOK_RELEASING;
 143
 144                         if (self.BUTTON_ATCK || self.BUTTON_HOOK)
 145                         {
 146                                 // already fired
 147                                 if(self.hook)
 148                                         self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 149                         }
 150                         else
 151                         {
 152                                 self.hook_state |= HOOK_REMOVING;
 153                                 self.hook_state (-) HOOK_WAITING_FOR_RELEASE;
 154                         }
 155                 }
 156         }
 157         else if (req == WR_PRECACHE)
 158         {
 159                 precache_model ("models/weapons/g_hookgun.md3");
 160                 precache_model ("models/weapons/v_hookgun.md3");
 161                 precache_model ("models/weapons/w_hookgun.zym");
 162                 precache_sound ("weapons/hook_fire.wav");
 163                 precache_sound ("weapons/hook_impact.wav");
 164                 precache_sound ("weapons/hookbomb_fire.wav");
 165                 precache_sound ("weapons/hookbomb_impact.wav");
 166         }
 167         else if (req == WR_SETUP)
 168         {
 169                 weapon_setup(WEP_HOOK);
 170         }
 171         else if (req == WR_CHECKAMMO1)
 172         {
 173                 return self.ammo_cells >= cvar("g_balance_hook_primary_ammo");
 174         }
 175         else if (req == WR_CHECKAMMO2)
 176         {
 177                 return self.ammo_cells >= cvar("g_balance_hook_secondary_ammo");
 178         }
 179         else if (req == WR_SUICIDEMESSAGE)
 180                 w_deathtypestring = "did the impossible";
 181         else if (req == WR_KILLMESSAGE)
 182                 w_deathtypestring = "has run into #'s gravity bomb";
 183         return TRUE;
 184 };