data/qcsrc/server/w_grenadelauncher.qc

   1 void W_Grenade_Explode (void)
   2 {
   3         if(other.takedamage == DAMAGE_AIM)
   4                 if(other.classname == "player")
   5                         if(IsDifferentTeam(self.owner, other))
   6                                 if(IsFlying(other))
   7                                         announce(self.owner, "announcer/male/airshot.wav");
   8
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Grenade_Explode2 (void)
  16 {
  17         if(other.takedamage == DAMAGE_AIM)
  18                 if(other.classname == "player")
  19                         if(IsDifferentTeam(self.owner, other))
  20                                 if(IsFlying(other))
  21                                         announce(self.owner, "announcer/male/airshot.wav");
  22
  23         self.event_damage = SUB_Null;
  24         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), self.projectiledeathtype, other);
  25
  26         remove (self);
  27 }
  28
  29 void W_Grenade_Touch1 (void)
  30 {
  31         PROJECTILE_TOUCH;
  32         W_Grenade_Explode ();
  33 }
  34
  35 void W_Grenade_Touch2 (void)
  36 {
  37         PROJECTILE_TOUCH;
  38         if (other.takedamage == DAMAGE_AIM)
  39         {
  40                 self.use ();
  41         }
  42         else
  43         {
  44                 float r;
  45                 r = random() * 6;
  46                 if(r < 1)
  47                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
  48                 else if(r < 2)
  49                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
  50                 else if(r < 3)
  51                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
  52                 else if(r < 4)
  53                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
  54                 else if(r < 5)
  55                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
  56                 else
  57                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
  58                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  59         }
  60 }
  61
  62 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  63 {
  64         self.health = self.health - damage;
  65         if (self.health <= 0)
  66         {
  67                 W_PrepareExplosionByDamage(attacker, self.think);
  68         }
  69 }
  70
  71 void W_Grenade_Attack (void)
  72 {
  73         local entity gren;
  74
  75         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  76                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
  77         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 4, "weapons/grenade_fire.wav");
  78         w_shotdir = v_forward; // no TrueAim for grenades please
  79
  80         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  81
  82         gren = spawn ();
  83         gren.owner = self;
  84         gren.classname = "grenade";
  85         gren.bot_dodge = TRUE;
  86         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_primary_damage");
  87         gren.movetype = MOVETYPE_BOUNCE;
  88         gren.solid = SOLID_BBOX;
  89         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
  90         setorigin(gren, w_shotorg);
  91         setsize(gren, '0 0 -3', '0 0 -3');
  92
  93         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
  94         gren.think = adaptor_think2use;
  95         gren.use = W_Grenade_Explode;
  96         gren.touch = W_Grenade_Touch1;
  97         gren.velocity = w_shotdir * cvar("g_balance_grenadelauncher_primary_speed") + v_up * cvar("g_balance_grenadelauncher_primary_speed_up");
  98         W_SetupProjectileVelocity(gren);
  99
 100         gren.angles = vectoangles (gren.velocity);
 101         gren.flags = FL_PROJECTILE;
 102
 103         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 104 }
 105
 106 void W_Grenade_Attack2 (void)
 107 {
 108         local entity gren;
 109
 110         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 111                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 112         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 4, "weapons/grenade_fire.wav");
 113         w_shotdir = v_forward; // no TrueAim for grenades please
 114
 115         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 116
 117         gren = spawn ();
 118         gren.owner = self;
 119         gren.classname = "grenade";
 120         gren.bot_dodge = TRUE;
 121         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_secondary_damage");
 122         gren.movetype = MOVETYPE_BOUNCE;
 123         gren.solid = SOLID_BBOX;
 124         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 125         setsize(gren, '0 0 -3', '0 0 -3');
 126         setorigin(gren, w_shotorg);
 127
 128         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 129         gren.think = adaptor_think2use;
 130         gren.use = W_Grenade_Explode2;
 131         gren.touch = W_Grenade_Touch2;
 132         gren.takedamage = DAMAGE_YES;
 133         gren.health = cvar("g_balance_grenadelauncher_secondary_health");
 134         gren.damageforcescale = 4;
 135         gren.event_damage = W_Grenade_Damage;
 136         gren.velocity = w_shotdir * cvar("g_balance_grenadelauncher_secondary_speed") + v_up * cvar("g_balance_grenadelauncher_secondary_speed_up");
 137         W_SetupProjectileVelocity(gren);
 138
 139         gren.angles = vectoangles (gren.velocity);
 140         gren.flags = FL_PROJECTILE;
 141
 142         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 143 }
 144
 145 void spawnfunc_weapon_grenadelauncher (void)
 146 {
 147         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 148 }
 149
 150 .float bot_secondary_grenademooth;
 151 float w_glauncher(float req)
 152 {
 153         if (req == WR_AIM)
 154         {
 155                 self.BUTTON_ATCK = FALSE;
 156                 self.BUTTON_ATCK2 = FALSE;
 157                 if (self.bot_secondary_grenademooth == 0)
 158                 {
 159                         if(bot_aim(cvar("g_balance_grenadelauncher_primary_speed"), cvar("g_balance_grenadelauncher_primary_speed_up"), cvar("g_balance_grenadelauncher_primary_lifetime"), TRUE))
 160                         {
 161                                 self.BUTTON_ATCK = TRUE;
 162                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 163                         }
 164                 }
 165                 else
 166                 {
 167                         if(bot_aim(cvar("g_balance_grenadelauncher_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_grenadelauncher_secondary_lifetime"), TRUE))
 168                         {
 169                                 self.BUTTON_ATCK2 = TRUE;
 170                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 171                         }
 172                 }
 173         }
 174         else if (req == WR_THINK)
 175         {
 176                 if (self.BUTTON_ATCK)
 177                 if (weapon_prepareattack(0, cvar("g_balance_grenadelauncher_primary_refire")))
 178                 {
 179                         W_Grenade_Attack();
 180                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), w_ready);
 181                 }
 182                 if (self.BUTTON_ATCK2)
 183                 if (weapon_prepareattack(1, cvar("g_balance_grenadelauncher_secondary_refire")))
 184                 {
 185                         W_Grenade_Attack2();
 186                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), w_ready);
 187                 }
 188         }
 189         else if (req == WR_PRECACHE)
 190         {
 191                 precache_model ("models/weapons/g_gl.md3");
 192                 precache_model ("models/weapons/v_gl.md3");
 193                 precache_model ("models/weapons/h_gl.dpm");
 194                 precache_sound ("weapons/grenade_bounce1.wav");
 195                 precache_sound ("weapons/grenade_bounce2.wav");
 196                 precache_sound ("weapons/grenade_bounce3.wav");
 197                 precache_sound ("weapons/grenade_bounce4.wav");
 198                 precache_sound ("weapons/grenade_bounce5.wav");
 199                 precache_sound ("weapons/grenade_bounce6.wav");
 200                 precache_sound ("weapons/grenade_fire.wav");
 201         }
 202         else if (req == WR_SETUP)
 203                 weapon_setup(WEP_GRENADE_LAUNCHER);
 204         else if (req == WR_CHECKAMMO1)
 205                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo");
 206         else if (req == WR_CHECKAMMO2)
 207                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo");
 208         else if (req == WR_SUICIDEMESSAGE)
 209         {
 210                 if(w_deathtype & HITTYPE_SECONDARY)
 211                         w_deathtypestring = "tried out his own grenade";
 212                 else
 213                         w_deathtypestring = "detonated";
 214         }
 215         else if (req == WR_KILLMESSAGE)
 216         {
 217                 if(w_deathtype & HITTYPE_SPLASH)
 218                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 219                                 w_deathtypestring = "didn't see #'s grenade";
 220                         else // unchecked: SECONDARY
 221                                 w_deathtypestring = "almost dodged #'s grenade";
 222                 else // unchecked: SECONDARY, BOUNCE
 223                         w_deathtypestring = "ate #'s grenade";
 224         }
 225         return TRUE;
 226 };