data/qcsrc/server/w_crylink.qc

   1 .float gravity;
   2
   3 .entity realowner;
   4
   5 void W_Crylink_Touch (void)
   6 {
   7         float finalhit;
   8         float f;
   9         PROJECTILE_TOUCH;
  10         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
  11         if(finalhit)
  12                 f = 1;
  13         else
  14                 f = cvar("g_balance_crylink_primary_bouncedamagefactor");
  15         if(self.alpha)
  16                 f *= self.alpha;
  17         RadiusDamage (self, self.realowner, cvar("g_balance_crylink_primary_damage") * f, cvar("g_balance_crylink_primary_edgedamage") * f, cvar("g_balance_crylink_primary_radius"), world, cvar("g_balance_crylink_primary_force") * f, self.projectiledeathtype, other);
  18         if (finalhit)
  19         {
  20                 remove (self);
  21                 return;
  22         }
  23         self.cnt = self.cnt - 1;
  24         self.angles = vectoangles(self.velocity);
  25         self.owner = world;
  26         self.projectiledeathtype |= HITTYPE_BOUNCE;
  27         //self.scale = 1 + self.cnt;
  28
  29         UpdateCSQCProjectile(self);
  30 }
  31
  32 void W_Crylink_Touch2 (void)
  33 {
  34         float finalhit;
  35         float f;
  36         PROJECTILE_TOUCH;
  37         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
  38         if(finalhit)
  39                 f = 1;
  40         else
  41                 f = cvar("g_balance_crylink_secondary_bouncedamagefactor");
  42         if(self.alpha)
  43                 f *= self.alpha;
  44         RadiusDamage (self, self.realowner, cvar("g_balance_crylink_secondary_damage") * f, cvar("g_balance_crylink_secondary_edgedamage") * f, cvar("g_balance_crylink_secondary_radius"), world, cvar("g_balance_crylink_secondary_force") * f, self.projectiledeathtype, other);
  45         if (finalhit)
  46         {
  47                 remove (self);
  48                 return;
  49         }
  50         self.cnt = self.cnt - 1;
  51         self.angles = vectoangles(self.velocity);
  52         self.owner = world;
  53         self.projectiledeathtype |= HITTYPE_BOUNCE;
  54 //      self.scale = 1 + 1 * self.cnt;
  55
  56         UpdateCSQCProjectile(self);
  57 }
  58
  59 void W_Crylink_Attack (void)
  60 {
  61         local float counter, shots;
  62         local entity proj;
  63         local vector s;
  64         vector forward, right, up;
  65
  66         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  67                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_primary_ammo");
  68
  69         W_SetupShot (self, '25 8 -8', FALSE, 2, "weapons/crylink_fire.wav");
  70         forward = v_forward;
  71         right = v_right;
  72         up = v_up;
  73
  74         shots = cvar("g_balance_crylink_primary_shots");
  75         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
  76         while (counter < shots)
  77         {
  78                 proj = spawn ();
  79                 proj.realowner = proj.owner = self;
  80                 proj.classname = "spike";
  81                 proj.bot_dodge = TRUE;
  82                 proj.bot_dodgerating = cvar("g_balance_crylink_primary_damage");
  83
  84                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
  85                 proj.solid = SOLID_BBOX;
  86                 proj.projectiledeathtype = WEP_CRYLINK;
  87                 //proj.gravity = 0.001;
  88
  89                 setmodel (proj, "models/plasmatrail.mdl"); // precision set below
  90                 setsize (proj, '0 0 0', '0 0 0');
  91                 setorigin (proj, w_shotorg);
  92
  93
  94                 s = '0 0 0';
  95                 if (counter == 0)
  96                         s = '0 0 0';
  97                 else
  98                 {
  99                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 100                         s_y = v_forward_x;
 101                         s_z = v_forward_y;
 102                 }
 103                 s = s * cvar("g_balance_crylink_primary_spread");
 104                 proj.velocity = (w_shotdir + right * s_y + up * s_z) * cvar("g_balance_crylink_primary_speed");
 105 //              proj.velocity = (w_shotdir + randomvec() * cvar("g_balance_crylink_primary_spread")) * cvar("g_balance_crylink_primary_speed");
 106                 W_SetupProjectileVelocity(proj);
 107                 proj.touch = W_Crylink_Touch;
 108                 if(counter == 0)
 109                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_middle_lifetime"), cvar("g_balance_crylink_primary_middle_fadetime"));
 110                 else if(counter <= 3)
 111                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_star_lifetime"), cvar("g_balance_crylink_primary_star_fadetime"));
 112                 else
 113                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_other_lifetime"), cvar("g_balance_crylink_primary_other_fadetime"));
 114                 proj.cnt = cvar("g_balance_crylink_primary_bounces");
 115                 //proj.scale = 1 + 1 * proj.cnt;
 116
 117                 proj.angles = vectoangles (proj.velocity);
 118
 119                 //proj.glow_size = 20;
 120
 121                 proj.effects = EF_LOWPRECISION;
 122                 proj.flags = FL_PROJECTILE;
 123
 124                 CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK);
 125
 126                 counter = counter + 1;
 127         }
 128 }
 129
 130 void W_Crylink_Attack2 (void)
 131 {
 132         local float counter, shots;
 133         local entity proj;
 134
 135         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 136                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_secondary_ammo");
 137
 138         W_SetupShot (self, '25 8 -8', FALSE, 2, "weapons/crylink_fire2.wav");
 139
 140         shots = cvar("g_balance_crylink_secondary_shots");
 141         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
 142         while (counter < shots)
 143         {
 144                 proj = spawn ();
 145                 proj.realowner = proj.owner = self;
 146                 proj.classname = "spike";
 147                 proj.bot_dodge = TRUE;
 148                 proj.bot_dodgerating = cvar("g_balance_crylink_secondary_damage");
 149
 150                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
 151                 proj.solid = SOLID_BBOX;
 152                 proj.projectiledeathtype = WEP_CRYLINK | HITTYPE_SECONDARY;
 153                 //proj.gravity = 0.001;
 154
 155                 setmodel (proj, "models/plasmatrail.mdl"); // precision set below
 156                 setsize (proj, '0 0 0', '0 0 0');
 157                 setorigin (proj, w_shotorg);
 158
 159                 proj.velocity = (w_shotdir + (((counter + 0.5) / shots) * 2 - 1) * v_right * cvar("g_balance_crylink_secondary_spread")) * cvar("g_balance_crylink_secondary_speed");
 160                 W_SetupProjectileVelocity(proj);
 161                 proj.touch = W_Crylink_Touch2;
 162                 if(counter == (shots - 1) / 2)
 163                         SUB_SetFade(proj, time + cvar("g_balance_crylink_secondary_middle_lifetime"), cvar("g_balance_crylink_secondary_middle_fadetime"));
 164                 else
 165                         SUB_SetFade(proj, time + cvar("g_balance_crylink_secondary_line_lifetime"), cvar("g_balance_crylink_secondary_line_fadetime"));
 166                 proj.cnt = cvar("g_balance_crylink_secondary_bounces");
 167                 //proj.scale = 1 + 1 * proj.cnt;
 168
 169                 proj.angles = vectoangles (proj.velocity);
 170
 171                 //proj.glow_size = 20;
 172
 173                 proj.effects = EF_LOWPRECISION;
 174                 proj.flags = FL_PROJECTILE;
 175
 176                 CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK);
 177
 178                 counter = counter + 1;
 179         }
 180 }
 181
 182
 183 /*
 184 // experimental lightning gun
 185 void W_Crylink_Attack3 (void)
 186 {
 187         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 188                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_primary_ammo");
 189         W_SetupShot (self, '25 8 -8', TRUE, 0, "weapons/crylink_fire.wav");
 190
 191         traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * 1000, FALSE, self, self.ping * 0.001);
 192
 193         pointparticles(particleeffectnum("lightning_muzzleflash", w_shotorg, w_shotdir * 1000, 1);
 194         pointparticles(particleeffectnum("lightning_impact", trace_endpos, trace_plane_normal * 1000, 1);
 195         trailparticles(world, particleeffectnum("lightning_beam", w_shotorg, trace_endpos);
 196
 197         if (trace_fraction < 1)
 198                 Damage(trace_ent, self, self, cvar("g_balance_crylink_primary_damage"), WEP_CRYLINK | HITTYPE_SECONDARY, trace_endpos, '0 0 0');
 199 }
 200 */
 201
 202 void spawnfunc_weapon_crylink (void)
 203 {
 204         weapon_defaultspawnfunc(WEP_CRYLINK);
 205 }
 206
 207 float w_crylink(float req)
 208 {
 209         if (req == WR_AIM)
 210         {
 211                 if (random() > 0.15)
 212                         self.BUTTON_ATCK = bot_aim(cvar("g_balance_crylink_primary_speed"), 0, cvar("g_balance_crylink_primary_middle_lifetime"), FALSE);
 213                 else
 214                         self.BUTTON_ATCK2 = bot_aim(cvar("g_balance_crylink_secondary_speed"), 0, cvar("g_balance_crylink_secondary_middle_lifetime"), FALSE);
 215         }
 216         else if (req == WR_THINK)
 217         {
 218                 if (self.BUTTON_ATCK)
 219                 if (weapon_prepareattack(0, cvar("g_balance_crylink_primary_refire")))
 220                 {
 221                         W_Crylink_Attack();
 222                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_crylink_primary_animtime"), w_ready);
 223                 }
 224                 if (self.BUTTON_ATCK2)
 225                 if (weapon_prepareattack(1, cvar("g_balance_crylink_secondary_refire")))
 226                 {
 227                         W_Crylink_Attack2();
 228                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_crylink_secondary_animtime"), w_ready);
 229                 }
 230         }
 231         else if (req == WR_PRECACHE)
 232         {
 233                 precache_model ("models/plasma.mdl");
 234                 precache_model ("models/plasmatrail.mdl");
 235                 precache_model ("models/weapons/g_crylink.md3");
 236                 precache_model ("models/weapons/v_crylink.md3");
 237                 precache_model ("models/weapons/w_crylink.zym");
 238                 precache_sound ("weapons/crylink_fire.wav");
 239                 precache_sound ("weapons/crylink_fire2.wav");
 240                 precache_sound ("weapons/crylink_impact.wav");
 241                 precache_sound ("weapons/crylink_impact2.wav");
 242         }
 243         else if (req == WR_SETUP)
 244                 weapon_setup(WEP_CRYLINK);
 245         else if (req == WR_CHECKAMMO1)
 246                 return self.ammo_cells >= cvar("g_balance_crylink_primary_ammo");
 247         else if (req == WR_CHECKAMMO2)
 248                 return self.ammo_cells >= cvar("g_balance_crylink_secondary_ammo");
 249         else if (req == WR_SUICIDEMESSAGE)
 250         {
 251                 w_deathtypestring = "succeeded at self-destructing himself with the Crylink";
 252         }
 253         else if (req == WR_KILLMESSAGE)
 254         {
 255                 if(w_deathtype & HITTYPE_BOUNCE)
 256                         w_deathtypestring = "could not hide from #'s Crylink"; // unchecked: SPLASH (SECONDARY can't be)
 257                 else if(w_deathtype & HITTYPE_SPLASH)
 258                         w_deathtypestring = "was too close to #'s Crylink"; // unchecked: SECONDARY
 259                 else
 260                         w_deathtypestring = "took a close look at #'s Crylink"; // unchecked: SECONDARY
 261         }
 262         return TRUE;
 263 };