data/qcsrc/server/w_crylink.qc

   1 .float gravity;
   2 const vector proj_color = '1 1 1';
   3
   4 .entity realowner;
   5
   6 void W_Crylink_Touch (void)
   7 {
   8         float finalhit;
   9         float f;
  10         PROJECTILE_TOUCH;
  11         pointparticles(particleeffectnum("crylink_impactbig"), self.origin, '0 0 0', 1);
  12         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
  13         if(finalhit)
  14                 f = 1;
  15         else
  16                 f = cvar("g_balance_crylink_primary_bouncedamagefactor");
  17         if(self.alpha)
  18                 f *= self.alpha;
  19         RadiusDamage (self, self.realowner, cvar("g_balance_crylink_primary_damage") * f, cvar("g_balance_crylink_primary_edgedamage") * f, cvar("g_balance_crylink_primary_radius"), world, cvar("g_balance_crylink_primary_force") * f, self.projectiledeathtype, other);
  20         if (finalhit)
  21         {
  22                 remove (self);
  23                 return;
  24         }
  25         self.cnt = self.cnt - 1;
  26         self.angles = vectoangles(self.velocity);
  27         self.owner = world;
  28         self.projectiledeathtype |= HITTYPE_BOUNCE;
  29         //self.scale = 1 + self.cnt;
  30 }
  31
  32 void W_Crylink_Touch2 (void)
  33 {
  34         float finalhit;
  35         float f;
  36         PROJECTILE_TOUCH;
  37         pointparticles(particleeffectnum("crylink_impact"), self.origin, '0 0 0', 1);
  38         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
  39         if(finalhit)
  40                 f = 1;
  41         else
  42                 f = cvar("g_balance_crylink_secondary_bouncedamagefactor");
  43         if(self.alpha)
  44                 f *= self.alpha;
  45         RadiusDamage (self, self.realowner, cvar("g_balance_crylink_secondary_damage") * f, cvar("g_balance_crylink_secondary_edgedamage") * f, cvar("g_balance_crylink_secondary_radius"), world, cvar("g_balance_crylink_secondary_force") * f, self.projectiledeathtype, other);
  46         if (finalhit)
  47         {
  48                 remove (self);
  49                 return;
  50         }
  51         self.cnt = self.cnt - 1;
  52         self.angles = vectoangles(self.velocity);
  53         self.owner = world;
  54         self.projectiledeathtype |= HITTYPE_BOUNCE;
  55 //      self.scale = 1 + 1 * self.cnt;
  56 }
  57
  58 void W_Crylink_Attack (void)
  59 {
  60         local float counter, shots;
  61         local entity proj;
  62         local vector s;
  63
  64         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  65                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_primary_ammo");
  66
  67         W_SetupShot (self, '25 8 -8', FALSE, 2, "weapons/crylink_fire.wav");
  68
  69         shots = cvar("g_balance_crylink_primary_shots");
  70         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
  71         while (counter < shots)
  72         {
  73                 proj = spawn ();
  74                 proj.realowner = proj.owner = self;
  75                 proj.classname = "spike";
  76                 proj.bot_dodge = TRUE;
  77                 proj.bot_dodgerating = cvar("g_balance_crylink_primary_damage");
  78
  79                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
  80                 proj.solid = SOLID_BBOX;
  81                 proj.projectiledeathtype = WEP_CRYLINK;
  82                 //proj.gravity = 0.001;
  83
  84                 setmodel (proj, "models/plasmatrail.mdl"); // precision set below
  85                 setsize (proj, '0 0 0', '0 0 0');
  86                 setorigin (proj, w_shotorg);
  87
  88                 s = '0 0 0';
  89                 if (counter == 0)
  90                         s = '0 0 0';
  91                 else if (counter == 1)
  92                         s = '0 0 1';
  93                 else if (counter == 2)
  94                         s = '0 -0.71 -0.71';
  95                 else if (counter == 3)
  96                         s = '0 0.71 -0.71';
  97                 else
  98                         s = randomvec();
  99                 s = s * cvar("g_balance_crylink_primary_spread");
 100                 proj.velocity = (w_shotdir + v_right * s_y + v_up * s_z) * cvar("g_balance_crylink_primary_speed");
 101 //              proj.velocity = (w_shotdir + randomvec() * cvar("g_balance_crylink_primary_spread")) * cvar("g_balance_crylink_primary_speed");
 102                 W_SetupProjectileVelocity(proj);
 103                 proj.touch = W_Crylink_Touch;
 104                 if(counter == 0)
 105                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_middle_lifetime"), cvar("g_balance_crylink_primary_middle_fadetime"));
 106                 else if(counter <= 3)
 107                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_star_lifetime"), cvar("g_balance_crylink_primary_star_fadetime"));
 108                 else
 109                         SUB_SetFade(proj, time + cvar("g_balance_crylink_primary_other_lifetime"), cvar("g_balance_crylink_primary_other_fadetime"));
 110                 proj.cnt = cvar("g_balance_crylink_primary_bounces");
 111                 proj.scale = 1 + 1 * proj.cnt;
 112
 113                 proj.angles = vectoangles (proj.velocity);
 114
 115                 //proj.glow_size = 20;
 116
 117                 proj.effects = EF_LOWPRECISION;
 118                 proj.flags = FL_PROJECTILE;
 119                 proj.colormod = proj_color;
 120                 counter = counter + 1;
 121         }
 122 }
 123
 124 void W_Crylink_Attack2 (void)
 125 {
 126         local float counter, shots;
 127         local entity proj;
 128
 129         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 130                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_secondary_ammo");
 131
 132         W_SetupShot (self, '25 8 -8', FALSE, 2, "weapons/crylink_fire.wav");
 133
 134         shots = cvar("g_balance_crylink_secondary_shots");
 135         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
 136         while (counter < shots)
 137         {
 138                 proj = spawn ();
 139                 proj.realowner = proj.owner = self;
 140                 proj.classname = "spike";
 141                 proj.bot_dodge = TRUE;
 142                 proj.bot_dodgerating = cvar("g_balance_crylink_secondary_damage");
 143
 144                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
 145                 proj.solid = SOLID_BBOX;
 146                 proj.projectiledeathtype = WEP_CRYLINK | HITTYPE_SECONDARY;
 147                 //proj.gravity = 0.001;
 148
 149                 setmodel (proj, "models/plasmatrail.mdl"); // precision set below
 150                 setsize (proj, '0 0 0', '0 0 0');
 151                 setorigin (proj, w_shotorg);
 152
 153                 proj.velocity = (w_shotdir + (((counter + 0.5) / shots) * 2 - 1) * v_right * cvar("g_balance_crylink_secondary_spread")) * cvar("g_balance_crylink_secondary_speed");
 154                 W_SetupProjectileVelocity(proj);
 155                 proj.touch = W_Crylink_Touch2;
 156                 if(counter == (shots - 1) / 2)
 157                         SUB_SetFade(proj, time + cvar("g_balance_crylink_secondary_middle_lifetime"), cvar("g_balance_crylink_secondary_middle_fadetime"));
 158                 else
 159                         SUB_SetFade(proj, time + cvar("g_balance_crylink_secondary_line_lifetime"), cvar("g_balance_crylink_secondary_line_fadetime"));
 160                 proj.cnt = cvar("g_balance_crylink_secondary_bounces");
 161                 proj.scale = 1 + 1 * proj.cnt;
 162
 163                 proj.angles = vectoangles (proj.velocity);
 164
 165                 //proj.glow_size = 20;
 166
 167                 proj.effects = EF_LOWPRECISION;
 168                 proj.flags = FL_PROJECTILE;
 169                 proj.colormod = proj_color;
 170                 counter = counter + 1;
 171         }
 172 }
 173
 174
 175 /*
 176 // experimental lightning gun
 177 void W_Crylink_Attack3 (void)
 178 {
 179         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 180                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_primary_ammo");
 181         W_SetupShot (self, '25 8 -8', TRUE, 0, "weapons/crylink_fire.wav");
 182
 183         traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * 1000, FALSE, self, self.ping * 0.001);
 184
 185         pointparticles(particleeffectnum("lightning_muzzleflash", w_shotorg, w_shotdir * 1000, 1);
 186         pointparticles(particleeffectnum("lightning_impact", trace_endpos, trace_plane_normal * 1000, 1);
 187         trailparticles(world, particleeffectnum("lightning_beam", w_shotorg, trace_endpos);
 188
 189         if (trace_fraction < 1)
 190                 Damage(trace_ent, self, self, cvar("g_balance_crylink_primary_damage"), WEP_CRYLINK | HITTYPE_SECONDARY, trace_endpos, '0 0 0');
 191 }
 192 */
 193
 194 void spawnfunc_weapon_crylink (void)
 195 {
 196         weapon_defaultspawnfunc(WEP_CRYLINK);
 197 }
 198
 199 float w_crylink(float req)
 200 {
 201         if (req == WR_AIM)
 202         {
 203                 if (random() > 0.15)
 204                         self.BUTTON_ATCK = bot_aim(cvar("g_balance_crylink_primary_speed"), 0, cvar("g_balance_crylink_primary_middle_lifetime"), FALSE);
 205                 else
 206                         self.BUTTON_ATCK2 = bot_aim(cvar("g_balance_crylink_secondary_speed"), 0, cvar("g_balance_crylink_secondary_middle_lifetime"), FALSE);
 207         }
 208         else if (req == WR_THINK)
 209         {
 210                 if (self.BUTTON_ATCK)
 211                 if (weapon_prepareattack(0, cvar("g_balance_crylink_primary_refire")))
 212                 {
 213                         W_Crylink_Attack();
 214                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_crylink_primary_animtime"), w_ready);
 215                 }
 216                 if (self.BUTTON_ATCK2)
 217                 if (weapon_prepareattack(1, cvar("g_balance_crylink_secondary_refire")))
 218                 {
 219                         W_Crylink_Attack2();
 220                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_crylink_secondary_animtime"), w_ready);
 221                 }
 222         }
 223         else if (req == WR_PRECACHE)
 224         {
 225                 precache_model ("models/plasma.mdl");
 226                 precache_model ("models/plasmatrail.mdl");
 227                 precache_model ("models/weapons/g_crylink.md3");
 228                 precache_model ("models/weapons/v_crylink.md3");
 229                 precache_model ("models/weapons/w_crylink.zym");
 230                 precache_sound ("weapons/crylink_fire.wav");
 231         }
 232         else if (req == WR_SETUP)
 233                 weapon_setup(WEP_CRYLINK);
 234         else if (req == WR_CHECKAMMO1)
 235                 return self.ammo_cells >= cvar("g_balance_crylink_primary_ammo");
 236         else if (req == WR_CHECKAMMO2)
 237                 return self.ammo_cells >= cvar("g_balance_crylink_secondary_ammo");
 238         else if (req == WR_SUICIDEMESSAGE)
 239         {
 240                 w_deathtypestring = "succeeded at self-destructing himself with the Crylink";
 241         }
 242         else if (req == WR_KILLMESSAGE)
 243         {
 244                 if(w_deathtype & HITTYPE_BOUNCE)
 245                         w_deathtypestring = "could not hide from #'s Crylink"; // unchecked: SPLASH (SECONDARY can't be)
 246                 else if(w_deathtype & HITTYPE_SPLASH)
 247                         w_deathtypestring = "was too close to #'s Crylink"; // unchecked: SECONDARY
 248                 else
 249                         w_deathtypestring = "took a close look at #'s Crylink"; // unchecked: SECONDARY
 250         }
 251         return TRUE;
 252 };