data/qcsrc/server/w_common.qc

   1 .float bullets_hit[WEP_COUNT];          //for hitscan bullets hit
   2 .float bullets_fired[WEP_COUNT];        //for hitscan bullets fired
   3
   4 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(bullets_hit);
   5 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(bullets_fired);
   6
   7 void W_GiveWeapon (entity e, float wep, string name)
   8 {
   9         entity oldself;
  10
  11         if (!wep)
  12                 return;
  13
  14         e.weapons = e.weapons | W_WeaponBit(wep);
  15
  16         oldself = self;
  17         self = e;
  18
  19         if not(g_minstagib)
  20         if (other.classname == "player")
  21         {
  22                 sprint (other, "You got the ^2");
  23                 sprint (other, name);
  24                 sprint (other, "\n");
  25         }
  26
  27
  28         self = oldself;
  29 }
  30
  31 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float deathtype)
  32 {
  33         local vector hitloc, force, endpoint, dir;
  34         local entity ent, endent;
  35         local float endq3surfaceflags;
  36         //local entity explosion;
  37         float did_hit;
  38         float length;
  39         vector beampos;
  40         string snd;
  41         entity pseudoprojectile;
  42         float f;
  43
  44         did_hit = 0;
  45
  46         railgun_start = start;
  47         railgun_end = end;
  48
  49         dir = normalize(end - start);
  50         length = vlen(end - start);
  51         force = dir * bforce;
  52
  53         // go a little bit into the wall because we need to hit this wall later
  54         end = end + dir;
  55
  56         // trace multiple times until we hit a wall, each obstacle will be made
  57         // non-solid so we can hit the next, while doing this we spawn effects and
  58         // note down which entities were hit so we can damage them later
  59         while (1)
  60         {
  61                 if(self.antilag_debug)
  62                         traceline_antilag (self, start, end, FALSE, self, self.antilag_debug);
  63                 else
  64                         traceline_antilag (self, start, end, FALSE, self, ANTILAG_LATENCY(self));
  65
  66                 // if it is world we can't hurt it so stop now
  67                 if (trace_ent == world || trace_fraction == 1)
  68                         break;
  69
  70                 // make the entity non-solid so we can hit the next one
  71                 trace_ent.railgunhit = TRUE;
  72                 trace_ent.railgunhitloc = end;
  73                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
  74
  75                 // stop if this is a wall
  76                 if (trace_ent.solid == SOLID_BSP)
  77                         break;
  78
  79                 // make the entity non-solid
  80                 trace_ent.solid = SOLID_NOT;
  81         }
  82
  83         endpoint = trace_endpos;
  84         endent = trace_ent;
  85         endq3surfaceflags = trace_dphitq3surfaceflags;
  86
  87         // find all the entities the railgun hit and restore their solid state
  88         ent = findfloat(world, railgunhit, TRUE);
  89         while (ent)
  90         {
  91                 // restore their solid type
  92                 ent.solid = ent.railgunhitsolidbackup;
  93                 ent = findfloat(ent, railgunhit, TRUE);
  94         }
  95
  96         // spawn a temporary explosion entity for RadiusDamage calls
  97         //explosion = spawn();
  98
  99         // Find all non-hit players the beam passed close by
 100         if(deathtype == WEP_MINSTANEX || deathtype == WEP_NEX)
 101         {
 102                 FOR_EACH_REALCLIENT(msg_entity) if(msg_entity != self) if(!msg_entity.railgunhit) // we use realclient, so spectators can hear the whoosh too
 103                 {
 104                         // nearest point on the beam
 105                         beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 106
 107                         f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 108                         if(f <= 0)
 109                                 continue;
 110
 111                         snd = strcat("weapons/nexwhoosh", ftos(floor(random() * 3) + 1), ".wav");
 112
 113                         if(!pseudoprojectile)
 114                                 pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 115                         soundtoat(MSG_ONE, pseudoprojectile, beampos, CHAN_PROJECTILE, snd, VOL_BASE * f, ATTN_NONE);
 116                 }
 117
 118                 if(pseudoprojectile)
 119                         remove(pseudoprojectile);
 120         }
 121
 122         // find all the entities the railgun hit and hurt them
 123         ent = findfloat(world, railgunhit, TRUE);
 124         while (ent)
 125         {
 126                 // get the details we need to call the damage function
 127                 hitloc = ent.railgunhitloc;
 128                 ent.railgunhitloc = '0 0 0';
 129                 ent.railgunhitsolidbackup = SOLID_NOT;
 130                 ent.railgunhit = FALSE;
 131
 132                 //for stats so that team hit will count as a miss
 133                 if(ent.flags & FL_CLIENT)
 134                 if(ent.deadflag == DEAD_NO)
 135                         did_hit = 1;
 136
 137                 if(teams_matter)
 138                 if(ent.team == self.team)
 139                         did_hit = 0;
 140
 141                 // apply the damage
 142                 if (ent.takedamage || ent.classname == "case")
 143                         Damage (ent, self, self, bdamage, deathtype, hitloc, force);
 144
 145                 // create a small explosion to throw gibs around (if applicable)
 146                 //setorigin (explosion, hitloc);
 147                 //RadiusDamage (explosion, self, 10, 0, 50, world, 300, deathtype);
 148
 149                 // advance to the next entity
 150                 ent = findfloat(ent, railgunhit, TRUE);
 151         }
 152
 153         //calculate hits and fired shots for hitscan
 154         if not(inWarmupStage)
 155         if not(self.isbot)
 156         {
 157                 self.bullets_fired[self.weapon] += 1;
 158
 159                 if(did_hit)
 160                         self.bullets_hit[self.weapon] += 1;
 161
 162                 // update the client and store in addstat() in g_world
 163                 self.damage_hits = self.weapon + 64 * rint(self.bullets_hit[self.weapon]);
 164                 self.maxdamage_fired = self.weapon + 64 * rint(self.bullets_fired[self.weapon]);
 165         }
 166
 167         // we're done with the explosion entity, remove it
 168         //remove(explosion);
 169
 170         trace_endpos = endpoint;
 171         trace_ent = endent;
 172         trace_dphitq3surfaceflags = endq3surfaceflags;
 173 }
 174
 175 .float dmg_edge;
 176 .float dmg_force;
 177 .float dmg_radius;
 178 void W_BallisticBullet_Hit (void)
 179 {
 180         float f;
 181
 182         float hit;
 183         hit = 0;
 184
 185         f = pow(bound(0, vlen(self.velocity) / vlen(self.oldvelocity), 1), 2); // energy multiplier
 186
 187         if(other.solid == SOLID_BSP)
 188                 Damage_DamageInfo(self.origin, self.dmg * f, 0, 0, self.dmg_force * normalize(self.velocity) * f, self.projectiledeathtype, self);
 189
 190         if(other && other != self.enemy)
 191         {
 192                 headshot = 0;
 193                 yoda = 0;
 194                 damage_headshotbonus = self.dmg_edge;
 195                 railgun_start = self.origin - 2 * frametime * self.velocity;
 196                 railgun_end = self.origin + 2 * frametime * self.velocity;
 197
 198                 if(other.flags & FL_CLIENT)
 199                 if(other.deadflag == DEAD_NO)
 200                         hit = 1;
 201
 202                 if(teamplay)
 203                 if(other.team == self.owner.team)
 204                         hit = 0;
 205
 206                 Damage(other, self, self.owner, self.dmg * f, self.projectiledeathtype, self.origin, self.dmg_force * normalize(self.velocity) * f);
 207                 damage_headshotbonus = 0;
 208
 209                 if(self.dmg_edge != 0)
 210                 {
 211                         if(headshot)
 212                                 announce(self.owner, "announcer/male/headshot.wav");
 213                         if(yoda)
 214                                 announce(self.owner, "announcer/male/awesome.wav");
 215                 }
 216
 217                 //calculate hits for ballistic weapons
 218                 if not(self.owner.isbot)
 219                 {
 220                         if(hit)
 221                                 self.owner.bullets_hit[self.owner.weapon] += 1;
 222                         // update the client
 223                         self.owner.damage_hits = self.owner.weapon + 64 * rint(self.owner.bullets_hit[self.owner.weapon]);
 224                 }
 225
 226                 //sound (self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 227         }
 228
 229         self.enemy = other; // don't hit the same player twice with the same bullet
 230 }
 231
 232 .void(void) W_BallisticBullet_LeaveSolid_think_save;
 233 .float W_BallisticBullet_LeaveSolid_nextthink_save;
 234 .vector W_BallisticBullet_LeaveSolid_origin;
 235 .vector W_BallisticBullet_LeaveSolid_velocity;
 236
 237 void W_BallisticBullet_LeaveSolid_think()
 238 {
 239         setorigin(self, self.W_BallisticBullet_LeaveSolid_origin);
 240         self.velocity = self.W_BallisticBullet_LeaveSolid_velocity;
 241
 242         self.think = self.W_BallisticBullet_LeaveSolid_think_save;
 243         self.nextthink = max(time, self.W_BallisticBullet_LeaveSolid_nextthink_save);
 244         self.W_BallisticBullet_LeaveSolid_think_save = SUB_Null;
 245
 246         self.flags &~= FL_ONGROUND;
 247
 248         if(self.enemy.solid == SOLID_BSP)
 249         {
 250                 float f;
 251                 f = pow(bound(0, vlen(self.velocity) / vlen(self.oldvelocity), 1), 2); // energy multiplier
 252                 Damage_DamageInfo(self.origin, 0, 0, 0, self.dmg_force * normalize(self.velocity) * -f, self.projectiledeathtype, self);
 253         }
 254
 255         UpdateCSQCProjectile(self);
 256 }
 257
 258 // a fake logarithm function
 259 float log(float x)
 260 {
 261         if(x < 0.0001)
 262                 return 0;
 263         if(x > 0.9 && x < 1.1)
 264                 return x - 1;
 265         return 2 * log(sqrt(x));
 266 }
 267
 268 float W_BallisticBullet_LeaveSolid(entity e, vector vel, float constant)
 269 {
 270         // move the entity along its velocity until it's out of solid, then let it resume
 271
 272         float dt, dst, velfactor, v0, vs;
 273         float maxdist;
 274         float E0_m, Es_m;
 275
 276         // outside the world? forget it
 277         if(self.origin_x > world.maxs_x || self.origin_y > world.maxs_y || self.origin_z > world.maxs_z || self.origin_x < world.mins_x || self.origin_y < world.mins_y || self.origin_z < world.mins_z)
 278                 return 0;
 279
 280         // E(s) = E0 - constant * s, constant = area of bullet circle * material constant / mass
 281         v0 = vlen(vel);
 282
 283         E0_m = 0.5 * v0 * v0;
 284         maxdist = E0_m / constant;
 285         // maxdist = 0.5 * v0 * v0 / constant
 286         // dprint("max dist = ", ftos(maxdist), "\n");
 287
 288         if(maxdist <= 0.5)
 289                 return 0;
 290
 291         traceline_inverted (self.origin, self.origin + normalize(vel) * maxdist, MOVE_NORMAL, self);
 292
 293         if(trace_fraction == 1) // 1: we never got out of solid
 294                 return 0;
 295
 296         self.W_BallisticBullet_LeaveSolid_origin = trace_endpos;
 297
 298         dst = vlen(trace_endpos - self.origin);
 299         // E(s) = E0 - constant * s, constant = area of bullet circle * material constant / mass
 300         Es_m = E0_m - constant * dst;
 301         if(Es_m <= 0)
 302         {
 303                 // roundoff errors got us
 304                 return 0;
 305         }
 306         vs = sqrt(2 * Es_m);
 307         velfactor = vs / v0;
 308
 309         dt = dst / (0.5 * (v0 + vs));
 310         // this is not correct, but the differential equations have no analytic
 311         // solution - and these times are very small anyway
 312         //print("dt = ", ftos(dt), "\n");
 313
 314         self.W_BallisticBullet_LeaveSolid_think_save = self.think;
 315         self.W_BallisticBullet_LeaveSolid_nextthink_save = self.nextthink;
 316         self.think = W_BallisticBullet_LeaveSolid_think;
 317         self.nextthink = time + dt;
 318
 319         vel = vel * velfactor;
 320
 321         self.velocity = '0 0 0';
 322         self.flags |= FL_ONGROUND; // prevent moving
 323         self.W_BallisticBullet_LeaveSolid_velocity = vel;
 324
 325         return 1;
 326 }
 327
 328 void W_BallisticBullet_Touch (void)
 329 {
 330         if(self.think == W_BallisticBullet_LeaveSolid_think) // skip this!
 331                 return;
 332
 333         PROJECTILE_TOUCH;
 334         W_BallisticBullet_Hit ();
 335
 336         // go through solid!
 337         if(!W_BallisticBullet_LeaveSolid(self, self.velocity, self.dmg_radius))
 338         {
 339                 remove(self);
 340                 return;
 341         }
 342
 343         self.projectiledeathtype |= HITTYPE_BOUNCE;
 344 }
 345
 346 void fireBallisticBullet(vector start, vector dir, float spread, float pSpeed, float lifetime, float damage, float headshotbonus, float force, float dtype, float tracereffects, float gravityfactor, float bulletconstant)
 347 {
 348         float lag, dt, savetime;
 349         entity pl, oldself;
 350
 351         entity proj;
 352         proj = spawn();
 353         proj.classname = "bullet";
 354         proj.owner = self;
 355         PROJECTILE_MAKETRIGGER(proj);
 356         if(gravityfactor > 0)
 357         {
 358                 proj.movetype = MOVETYPE_TOSS;
 359                 proj.gravity = gravityfactor;
 360         }
 361         else
 362                 proj.movetype = MOVETYPE_FLY;
 363         proj.think = SUB_Remove;
 364         proj.nextthink = time + lifetime; // min(pLifetime, vlen(world.maxs - world.mins) / pSpeed);
 365         proj.velocity = (dir + randomvec() * spread) * pSpeed;
 366         W_SetupProjectileVelocity(proj);
 367         proj.angles = vectoangles(proj.velocity);
 368         proj.dmg_radius = cvar("g_ballistics_materialconstant") / bulletconstant;
 369         // so: bulletconstant = bullet mass / area of bullet circle
 370         setorigin(proj, start);
 371         proj.flags = FL_PROJECTILE;
 372
 373         proj.touch = W_BallisticBullet_Touch;
 374         proj.dmg = damage;
 375         proj.dmg_edge = headshotbonus;
 376         proj.dmg_force = force;
 377         proj.projectiledeathtype = dtype;
 378
 379         proj.oldvelocity = proj.velocity;
 380
 381         //calculate fired bullets for ballistics
 382         if not(self.isbot)
 383         {
 384                 self.bullets_fired[self.weapon] += 1;
 385                 self.maxdamage_fired = self.weapon + 64 * rint(self.bullets_fired[self.weapon]);
 386         }
 387
 388         if(cvar("g_antilag_bullets"))
 389         if(pSpeed >= cvar("g_antilag_bullets"))
 390         {
 391                 // NOTE: this may severely throw off weapon balance
 392                 lag = ANTILAG_LATENCY(self);
 393                 if(lag < 0.001)
 394                         lag = 0;
 395                 if(clienttype(self) != CLIENTTYPE_REAL)
 396                         lag = 0;
 397                 if(cvar("g_antilag") == 0)
 398                         lag = 0; // only do hitscan, but no antilag
 399
 400                 if(lag)
 401                         FOR_EACH_PLAYER(pl)
 402                                 antilag_takeback(pl, time - lag);
 403
 404                 oldself = self;
 405                 self = proj;
 406
 407                 savetime = frametime;
 408                 frametime = 0.05;
 409
 410                 for(;;)
 411                 {
 412                         // DP tracetoss is stupid and always traces in 0.05s
 413                         // ticks. This makes it trace in 0.05*0.125s ticks
 414                         // instead.
 415                         vector v0;
 416                         float g0;
 417                         v0 = self.velocity;
 418                         g0 = self.gravity;
 419                         self.velocity = self.velocity * 0.125;
 420                         self.gravity *= 0.125 * 0.125;
 421                         trace_fraction = 0;
 422                         tracetoss(self, oldself);
 423                         self.velocity = v0;
 424                         self.gravity = g0;
 425
 426                         if not(self.isbot)
 427                         {
 428                                 self.bullets_fired[self.weapon] += 1;
 429                                 self.maxdamage_fired = self.weapon + 64 * rint(self.bullets_fired[self.weapon]);
 430                         }
 431
 432                         if(vlen(trace_endpos - self.origin) > 32)
 433                                 zcurveparticles_from_tracetoss(particleeffectnum("tr_bullet"), self.origin, trace_endpos, self.velocity);
 434                         if(trace_fraction == 1)
 435                                 break;
 436                                 // won't hit anything anytime soon (DP's
 437                                 // tracetoss does 200 tics of, here,
 438                                 // 0.05*0.125s, that is, 1.25 seconds
 439
 440                         other = trace_ent;
 441                         dt = vlen(trace_endpos - self.origin) / vlen(self.velocity); // this is only approximate!
 442                         setorigin(self, trace_endpos);
 443                         self.velocity_z -= sv_gravity * dt;
 444
 445                         if(!SUB_OwnerCheck())
 446                         {
 447                                 if(SUB_NoImpactCheck())
 448                                         break;
 449
 450                                 // hit the player
 451                                 W_BallisticBullet_Hit ();
 452                         }
 453
 454                         // go through solid!
 455                         if(!W_BallisticBullet_LeaveSolid(self, self.velocity, self.dmg_radius))
 456                                 break;
 457
 458                         W_BallisticBullet_LeaveSolid_think();
 459                 }
 460                 frametime = savetime;
 461                 self = oldself;
 462
 463                 if(lag)
 464                         FOR_EACH_PLAYER(pl)
 465                                 antilag_restore(pl);
 466
 467                 remove(proj);
 468
 469                 return;
 470         }
 471
 472         if(tracereffects & EF_RED)
 473                 CSQCProjectile(proj, TRUE, PROJECTILE_BULLET_GLOWING, TRUE);
 474         else
 475                 CSQCProjectile(proj, TRUE, PROJECTILE_BULLET, TRUE);
 476 }
 477
 478
 479 void fireBullet (vector start, vector dir, float spread, float damage, float force, float dtype, float tracer)
 480 {
 481         vector  end;
 482         //local entity e;
 483
 484         dir = normalize(dir + randomvec() * spread);
 485         end = start + dir * MAX_SHOT_DISTANCE;
 486         if(self.antilag_debug)
 487                 traceline_antilag (self, start, end, FALSE, self, self.antilag_debug);
 488         else
 489                 traceline_antilag (self, start, end, FALSE, self, ANTILAG_LATENCY(self));
 490
 491     end = trace_endpos;
 492
 493         if ((trace_fraction != 1.0) && (pointcontents (trace_endpos) != CONTENT_SKY))
 494         {
 495                 pointparticles(particleeffectnum("TE_KNIGHTSPIKE"),end,trace_plane_normal * 2500,1);
 496                 if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 497                         Damage_DamageInfo(trace_endpos, damage, 0, 0, dir * force, dtype, self);
 498                 Damage (trace_ent, self, self, damage, dtype, trace_endpos, dir * force);
 499                 //void(float effectnum, vector org, vector vel, float howmany) pointparticles = #337; // same as in CSQC
 500         }
 501         trace_endpos = end;
 502 }
 503
 504
 505 void W_PrepareExplosionByDamage(entity attacker, void() explode)
 506 {
 507         self.takedamage = DAMAGE_NO;
 508         self.event_damage = SUB_Null;
 509         self.owner = attacker;
 510
 511         // do not explode NOW but in the NEXT FRAME!
 512         // because recursive calls to RadiusDamage are not allowed
 513         self.nextthink = time;
 514         self.think = explode;
 515 }