data/qcsrc/server/t_teleporters.qc

   1 void trigger_teleport_use()
   2 {
   3         if(teams_matter)
   4                 self.team = activator.team;
   5 }
   6
   7 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
   8 {
   9         entity head;
  10         vector deathmin;
  11         vector deathmax;
  12         float deathradius;
  13         deathmin = player.absmin;
  14         deathmax = player.absmax;
  15         if(telefragmin != telefragmax)
  16         {
  17                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  18                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  19                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  20                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  21                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  22                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  23         }
  24         deathradius = max(vlen(deathmin), vlen(deathmax));
  25         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  26                 if(head != player)
  27                         if(head.takedamage)
  28                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  29                                 {
  30                                         if ((player.classname == "player") && (player.health >= 1))
  31                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  32                                         else if (telefragger.health < 1) // corpses gib
  33                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  34                                         else // dead bodies and monsters gib themselves instead of telefragging
  35                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  36                                 }
  37 }
  38
  39 void spawn_tdeath(vector v0, entity e, vector v)
  40 {
  41         tdeath(e, e, e, '0 0 0', '0 0 0');
  42 }
  43
  44 .entity pusher;
  45 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
  46 {
  47         entity oldself;
  48         entity telefragger;
  49         vector from;
  50
  51         if(teleporter.owner)
  52                 telefragger = teleporter.owner;
  53         else
  54                 telefragger = player;
  55
  56         makevectors (to_angles);
  57
  58         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  59         {
  60                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  61                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  62                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  63                 self.pushltime = time + 0.2;
  64         }
  65
  66         // Relocate the player
  67         // assuming to allows PL_MIN to PL_MAX box and some more
  68         from = player.origin;
  69         setorigin (player, to);
  70         player.angles = to_angles;
  71         player.fixangle = TRUE;
  72         player.velocity = to_velocity;
  73         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
  74
  75         UpdateCSQCProjectile(player);
  76
  77         if(player.classname == "player")
  78         {
  79                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  80                         tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
  81
  82                 // player no longer is on ground
  83                 player.flags &~= FL_ONGROUND;
  84
  85                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  86                 player.oldvelocity = player.velocity;
  87
  88                 // reset tracking of who pushed you into a hazard (for kill credit)
  89                 if(teleporter.owner)
  90                 {
  91                         player.pusher = teleporter.owner;
  92                         player.pushltime = time + cvar("g_maxpushtime");
  93                 }
  94                 else
  95                 {
  96                         player.pushltime = 0;
  97                 }
  98
  99                 if(player.isbot)
 100                         player.lastteleporttime = time;
 101
 102                 // stop player name display
 103                 {
 104                         oldself = self;
 105                         self = player;
 106                         ClearSelectedPlayer();
 107                         self = oldself;
 108                 }
 109         }
 110 }
 111
 112 void Teleport_Touch (void)
 113 {
 114         entity oldself, e;
 115
 116         if (other.health < 1)
 117                 return;
 118         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 119                 return;
 120
 121         if(self.team)
 122                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 123                         return;
 124
 125         EXACTTRIGGER_TOUCH;
 126
 127         makevectors(self.enemy.mangle);
 128
 129         if(other.classname == "player")
 130                 RemoveGrapplingHook(other);
 131
 132         if(self.enemy)
 133         {
 134                 e = self.enemy;
 135         }
 136         else
 137         {
 138                 RandomSelection_Init();
 139                 for(e = world; (e = find(e, targetname, self.target)); )
 140                 {
 141                         if(e.cnt)
 142                                 RandomSelection_Add(e, 0, string_null, e.cnt, 0);
 143                         else
 144                                 RandomSelection_Add(e, 0, string_null, 1, 0);
 145                 }
 146                 e = RandomSelection_chosen_ent;
 147         }
 148
 149         if(!e)
 150         {
 151                 sprint(other, "Teleport destination vanished. Sorry... please complain to the mapper.\n");
 152         }
 153
 154         TeleportPlayer(self, other, e.origin + '0 0 1' * (1 - other.mins_z - 24), e.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 155
 156         if(e.target)
 157         {
 158                 oldself = self;
 159                 activator = other;
 160                 self = e;
 161                 SUB_UseTargets();
 162                 self = oldself;
 163         }
 164 }
 165
 166 void spawnfunc_info_teleport_destination (void)
 167 {
 168         self.classname = "info_teleport_destination";
 169
 170         self.mangle = self.angles;
 171         self.angles = '0 0 0';
 172
 173         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 174         setorigin (self, self.origin);
 175
 176         IFTARGETED
 177         {
 178         }
 179         else
 180                 objerror ("^3Teleport destination without a targetname");
 181 }
 182
 183 void spawnfunc_misc_teleporter_dest (void)
 184 {
 185         spawnfunc_info_teleport_destination();
 186 }
 187
 188 void spawnfunc_target_teleporter (void)
 189 {
 190         spawnfunc_info_teleport_destination();
 191 }
 192
 193 void teleport_findtarget (void)
 194 {
 195         entity e;
 196         float n;
 197
 198         n = 0;
 199         for(e = world; (e = find(e, targetname, self.target)); )
 200         {
 201                 ++n;
 202                 if(e.movetype == MOVETYPE_NONE)
 203                         waypoint_spawnforteleporter(self, e.origin, 0);
 204                 if(e.classname != "info_teleport_destination")
 205                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 206         }
 207
 208         if(n == 0)
 209         {
 210                 // no dest!
 211                 objerror ("Teleporter with nonexistant target");
 212                 return;
 213         }
 214         else if(n == 1)
 215         {
 216                 // exactly one dest - bots love that
 217                 self.enemy = find(e, targetname, self.target);
 218                 self.dest = self.enemy.origin;
 219         }
 220         else
 221         {
 222                 // have to use random selection every single time
 223                 self.enemy = world;
 224         }
 225
 226         // now enable touch
 227         self.touch = Teleport_Touch;
 228 }
 229
 230 void spawnfunc_trigger_teleport (void)
 231 {
 232         self.angles = '0 0 0';
 233
 234         EXACTTRIGGER_INIT;
 235
 236         self.use = trigger_teleport_use;
 237
 238         // this must be called to spawn the teleport waypoints for bots
 239         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 240
 241         if (!self.target)
 242         {
 243                 objerror ("Teleporter with no target");
 244                 return;
 245         }
 246 }