data/qcsrc/server/t_teleporters.qc

   1 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
   2 {
   3         entity head;
   4         vector deathmin;
   5         vector deathmax;
   6         float deathradius;
   7         deathmin = player.absmin;
   8         deathmax = player.absmax;
   9         if(telefragmin != telefragmax)
  10         {
  11                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  12                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  13                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  14                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  15                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  16                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  17         }
  18         deathradius = max(vlen(deathmin), vlen(deathmax));
  19         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  20                 if(head != player)
  21                         if(head.takedamage)
  22                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  23                                 {
  24                                         if ((player.classname == "player") && (player.health >= 1))
  25                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  26                                         else if (telefragger.health < 1) // corpses gib
  27                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  28                                         else // dead bodies and monsters gib themselves instead of telefragging
  29                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  30                                 }
  31 }
  32
  33 void spawn_tdeath(vector v0, entity e, vector v)
  34 {
  35         tdeath(e, e, e, '0 0 0', '0 0 0');
  36 }
  37
  38 .entity pusher;
  39 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
  40 {
  41         entity oldself;
  42         entity telefragger;
  43         vector from;
  44
  45         if(teleporter.owner)
  46                 telefragger = teleporter.owner;
  47         else
  48                 telefragger = player;
  49
  50         makevectors (to_angles);
  51
  52         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  53         {
  54                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  55                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  56                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  57                 self.pushltime = time + 0.2;
  58         }
  59
  60         // Relocate the player
  61         // assuming to allows PL_MIN to PL_MAX box and some more
  62         from = player.origin;
  63         setorigin (player, to);
  64         player.angles = to_angles;
  65         player.fixangle = TRUE;
  66         player.velocity = to_velocity;
  67
  68         UpdateCSQCProjectile(player);
  69
  70         if(player.classname == "player")
  71         {
  72                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  73                         tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
  74
  75                 // hide myself a tic
  76                 player.effects = player.effects | EF_NODRAW;
  77                 if (player.weaponentity) // misuse FL_FLY to avoid EF_NODRAW on viewmodel
  78                         player.weaponentity.flags = player.weaponentity.flags | FL_FLY;
  79                 player.teleport_time = time + cvar("sys_ticrate");
  80
  81                 // player no longer is on ground
  82                 player.flags = player.flags - (player.flags & FL_ONGROUND);
  83
  84                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  85                 player.oldvelocity = player.velocity;
  86
  87                 // reset tracking of who pushed you into a hazard (for kill credit)
  88                 if(teleporter.owner)
  89                 {
  90                         player.pusher = teleporter.owner;
  91                         player.pushltime = time + cvar("g_maxpushtime");
  92                 }
  93                 else
  94                 {
  95                         player.pushltime = 0;
  96                 }
  97
  98                 // stop player name display
  99                 {
 100                         oldself = self;
 101                         self = player;
 102                         ClearSelectedPlayer();
 103                         self = oldself;
 104                 }
 105         }
 106 }
 107
 108 void Teleport_Touch (void)
 109 {
 110         entity oldself, e;
 111
 112         if (other.health < 1)
 113                 return;
 114         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 115                 return;
 116
 117         EXACTTRIGGER_TOUCH;
 118
 119         makevectors(self.enemy.mangle);
 120
 121         if(other.classname == "player")
 122                 RemoveGrapplingHook(other);
 123
 124         if(self.enemy)
 125         {
 126                 e = self.enemy;
 127         }
 128         else
 129         {
 130                 RandomSelection_Init();
 131                 for(e = world; (e = find(e, targetname, self.target)); )
 132                 {
 133                         if(e.cnt)
 134                                 RandomSelection_Add(e, 0, e.cnt, 0);
 135                         else
 136                                 RandomSelection_Add(e, 0, 1, 0);
 137                 }
 138                 e = RandomSelection_chosen_ent;
 139         }
 140
 141         if(!e)
 142         {
 143                 sprint(other, "Teleport destination vanished. Sorry... please complain to the mapper.\n");
 144         }
 145
 146         TeleportPlayer(self, other, e.origin + '0 0 1' * (1 - other.mins_z - 24), e.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 147
 148         if(e.target)
 149         {
 150                 oldself = self;
 151                 activator = other;
 152                 self = e;
 153                 SUB_UseTargets();
 154                 self = oldself;
 155         }
 156 }
 157
 158 void spawnfunc_info_teleport_destination (void)
 159 {
 160         self.classname = "info_teleport_destination";
 161
 162         self.mangle = self.angles;
 163         self.angles = '0 0 0';
 164
 165         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 166         setorigin (self, self.origin);
 167
 168         IFTARGETED
 169         {
 170         }
 171         else
 172                 objerror ("^3Teleport destination without a targetname");
 173 }
 174
 175 void spawnfunc_misc_teleporter_dest (void)
 176 {
 177         spawnfunc_info_teleport_destination();
 178 }
 179
 180 void spawnfunc_target_teleporter (void)
 181 {
 182         spawnfunc_info_teleport_destination();
 183 }
 184
 185 void teleport_findtarget (void)
 186 {
 187         entity e;
 188         float n;
 189
 190         n = 0;
 191         for(e = world; (e = find(e, targetname, self.target)); )
 192         {
 193                 ++n;
 194                 if(e.movetype == MOVETYPE_NONE)
 195                         waypoint_spawnforteleporter(self, e.origin, 0);
 196                 if(e.classname != "info_teleport_destination")
 197                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 198         }
 199
 200         if(n == 0)
 201         {
 202                 // no dest!
 203                 objerror ("Teleporter with nonexistant target");
 204                 return;
 205         }
 206         else if(n == 1)
 207         {
 208                 // exactly one dest - bots love that
 209                 self.enemy = find(e, targetname, self.target);
 210                 self.dest = self.enemy.origin;
 211         }
 212         else
 213         {
 214                 // have to use random selection every single time
 215                 self.enemy = world;
 216         }
 217
 218         // now enable touch
 219         self.touch = Teleport_Touch;
 220 }
 221
 222 void spawnfunc_trigger_teleport (void)
 223 {
 224         self.angles = '0 0 0';
 225
 226         EXACTTRIGGER_INIT;
 227
 228         // this must be called to spawn the teleport waypoints for bots
 229         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 230
 231         if (!self.target)
 232         {
 233                 objerror ("Teleporter with no target");
 234                 return;
 235         }
 236 }