data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43
  44 void Item_Respawn (void)
  45 {
  46         self.model = self.mdl;          // restore original model
  47         self.solid = SOLID_TRIGGER;     // allow it to be touched again
  48         if(!g_minstagib && self.items == IT_STRENGTH)
  49                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
  50         else if(!g_minstagib && self.items == IT_INVINCIBLE)
  51                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
  52         else
  53                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
  54         setorigin (self, self.origin);
  55
  56         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
  57         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
  58 }
  59
  60 void Item_RespawnCountdown (void)
  61 {
  62         if(self.count >= ITEM_RESPAWN_TICKS)
  63         {
  64                 if(self.waypointsprite_attached)
  65                         WaypointSprite_Kill(self.waypointsprite_attached);
  66                 Item_Respawn();
  67         }
  68         else
  69         {
  70                 self.nextthink = time + 1;
  71                 self.count += 1;
  72                 if(self.count == 1)
  73                 {
  74                         string name;
  75                         vector rgb;
  76                         name = string_null;
  77                         if(g_minstagib)
  78                         {
  79                                 switch(self.items)
  80                                 {
  81                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
  82                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
  83                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
  84                                 }
  85                         }
  86                         else
  87                         {
  88                                 switch(self.items)
  89                                 {
  90                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
  91                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
  92                                 }
  93                         }
  94                         switch(self.items)
  95                         {
  96                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
  97                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
  98                         }
  99                         if(name)
 100                         {
 101                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 102                                 if(self.waypointsprite_attached)
 103                                 {
 104                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 105                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 106                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 107                                 }
 108                         }
 109                 }
 110                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 111                 if(self.waypointsprite_attached)
 112                 {
 113                         WaypointSprite_Ping(self.waypointsprite_attached);
 114                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 115                 }
 116         }
 117 }
 118
 119 void Item_ScheduleRespawnIn(entity e, float t)
 120 {
 121         if(e.flags & FL_POWERUP)
 122         {
 123                 e.think = Item_RespawnCountdown;
 124                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 125                 e.count = 0;
 126         }
 127         else
 128         {
 129                 e.think = Item_Respawn;
 130                 e.nextthink = time + t;
 131         }
 132 }
 133
 134 void Item_ScheduleRespawn(entity e)
 135 {
 136         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 137 }
 138
 139 void Item_ScheduleInitialRespawn(entity e)
 140 {
 141         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 142 }
 143
 144 float Item_GiveTo(entity item, entity player)
 145 {
 146         float _switchweapon;
 147         float pickedup;
 148         float it;
 149         float i;
 150         entity e;
 151
 152         // if nothing happens to player, just return without taking the item
 153         pickedup = FALSE;
 154         _switchweapon = FALSE;
 155
 156         if (g_minstagib)
 157         {
 158                 if (item.ammo_fuel)
 159                 if (player.ammo_fuel < g_pickup_fuel_max)
 160                 {
 161                         pickedup = TRUE;
 162                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 163                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 164                 }
 165                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 166                 {
 167                         pickedup = TRUE;
 168                         player.items |= it;
 169                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 170                 }
 171
 172                 _switchweapon = TRUE;
 173                 if (item.ammo_cells)
 174                 {
 175                         pickedup = TRUE;
 176                         // play some cool sounds ;)
 177                         centerprint(player, "\n");
 178                         if (clienttype(player) == CLIENTTYPE_REAL)
 179                         {
 180                                 if(player.health <= 5)
 181                                         play2(player, "announcer/robotic/lastsecond.wav");
 182                                 else if(player.health < 50)
 183                                         play2(player, "announcer/robotic/narrowly.wav");
 184                         }
 185                         // sound not available
 186                         // else if(item.items == IT_CELLS)
 187                         //      play2(player, "announce/robotic/ammo.wav");
 188
 189                         if (item.weapons & WEPBIT_MINSTANEX)
 190                                 W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 191                         if (item.ammo_cells)
 192                                 player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 193                         player.health = 100;
 194                 }
 195
 196                 // extralife powerup
 197                 if (item.max_health)
 198                 {
 199                         pickedup = TRUE;
 200                         // sound not available
 201                         // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.wav");
 202                         player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 203                         sprint(player, "^3You picked up some extra lives\n");
 204                 }
 205
 206                 // invis powerup
 207                 if (item.strength_finished)
 208                 {
 209                         pickedup = TRUE;
 210                         // sound not available
 211                         // play2(player, "announce/robotic/invisible.wav");
 212                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 213                 }
 214
 215                 // speed powerup
 216                 if (item.invincible_finished)
 217                 {
 218                         pickedup = TRUE;
 219                         // sound not available
 220                         // play2(player, "announce/robotic/speed.wav");
 221                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 222                 }
 223
 224                 if (item.ammo_fuel)
 225                 if (player.ammo_fuel < g_pickup_fuel_max)
 226                 {
 227                         pickedup = TRUE;
 228                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 229                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 230                 }
 231
 232         }
 233         else
 234         {
 235                 if (g_weapon_stay == 1)
 236                 if not(item.flags & FL_NO_WEAPON_STAY)
 237                 if (item.flags & FL_WEAPON)
 238                 {
 239                         if(item.classname == "droppedweapon")
 240                         {
 241                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 242                                         goto skip;
 243                         }
 244                         else
 245                         {
 246                                 if (player.weapons & item.weapons)
 247                                         goto skip;
 248                         }
 249                 }
 250
 251                 // in case the player has autoswitch enabled do the following:
 252                 // if the player is using their best weapon before items are given, they
 253                 // probably want to switch to an even better weapon after items are given
 254                 if (player.autoswitch)
 255                 if (player.switchweapon == w_getbestweapon(player))
 256                         _switchweapon = TRUE;
 257
 258                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 259                         _switchweapon = TRUE;
 260
 261                 if (item.ammo_shells)
 262                 if (player.ammo_shells < g_pickup_shells_max)
 263                 {
 264                         pickedup = TRUE;
 265                         player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 266                 }
 267                 if (item.ammo_nails)
 268                 if (player.ammo_nails < g_pickup_nails_max)
 269                 {
 270                         pickedup = TRUE;
 271                         player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 272                 }
 273                 if (item.ammo_rockets)
 274                 if (player.ammo_rockets < g_pickup_rockets_max)
 275                 {
 276                         pickedup = TRUE;
 277                         player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 278                 }
 279                 if (item.ammo_cells)
 280                 if (player.ammo_cells < g_pickup_cells_max)
 281                 {
 282                         pickedup = TRUE;
 283                         player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 284                 }
 285                 if (item.ammo_fuel)
 286                 if (player.ammo_fuel < g_pickup_fuel_max)
 287                 {
 288                         pickedup = TRUE;
 289                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 290                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 291                 }
 292
 293                 if (item.flags & FL_WEAPON)
 294                 if ((it = item.weapons - (item.weapons & player.weapons)))
 295                 {
 296                         pickedup = TRUE;
 297                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 298                         {
 299                                 e = get_weaponinfo(i);
 300                                 if(it & e.weapons)
 301                                         W_GiveWeapon (player, e.weapon, item.netname);
 302                         }
 303                 }
 304
 305                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 306                 {
 307                         pickedup = TRUE;
 308                         player.items |= it;
 309                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 310                 }
 311
 312                 if (item.strength_finished)
 313                 {
 314                         pickedup = TRUE;
 315                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 316                 }
 317                 if (item.invincible_finished)
 318                 {
 319                         pickedup = TRUE;
 320                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 321                 }
 322                 //if (item.speed_finished)
 323                 //{
 324                 //      pickedup = TRUE;
 325                 //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 326                 //}
 327                 //if (item.slowmo_finished)
 328                 //{
 329                 //      pickedup = TRUE;
 330                 //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 331                 //}
 332
 333                 if (item.health)
 334                 if (player.health < item.max_health)
 335                 {
 336                         pickedup = TRUE;
 337                         player.health = min(player.health + item.health, item.max_health);
 338                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 339                 }
 340                 if (item.armorvalue)
 341                 if (player.armorvalue < item.max_armorvalue)
 342                 {
 343                         pickedup = TRUE;
 344                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 345                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 346                 }
 347         }
 348
 349 :skip
 350         // always eat teamed entities
 351         if(item.team)
 352                 pickedup = TRUE;
 353
 354         if (!pickedup)
 355                 return 0;
 356
 357         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 358         if (_switchweapon)
 359                 if (player.switchweapon != w_getbestweapon(player))
 360                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 361
 362         return 1;
 363 }
 364
 365 void Item_Touch (void)
 366 {
 367         entity e, head;
 368
 369         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 370         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 371         {
 372                 remove(self);
 373                 return;
 374         }
 375         if (other.classname != "player")
 376                 return;
 377         if (other.deadflag)
 378                 return;
 379         if (self.solid != SOLID_TRIGGER)
 380                 return;
 381         if (self.owner == other)
 382                 return;
 383
 384         if(!Item_GiveTo(self, other))
 385                 return;
 386
 387         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 388
 389         if (self.classname == "droppedweapon")
 390                 remove (self);
 391         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 392                 return;
 393         else
 394         {
 395                 self.solid = SOLID_NOT;
 396                 self.model = string_null;
 397                 if(self.team)
 398                 {
 399                         RandomSelection_Init();
 400                         for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 401                                 RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 402                         e = RandomSelection_chosen_ent;
 403                 }
 404                 else
 405                         e = self;
 406                 Item_ScheduleRespawn(e);
 407         }
 408 }
 409
 410 void Item_FindTeam()
 411 {
 412         entity head, e;
 413
 414         if(self.effects & EF_NODRAW)
 415         {
 416                 // marker for item team search
 417                 dprint("Initializing item team ", ftos(self.team), "\n");
 418                 RandomSelection_Init();
 419                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 420                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 421                 e = RandomSelection_chosen_ent;
 422                 e.state = 0;
 423
 424                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 425                 {
 426                         if(head != e)
 427                         {
 428                                 // make it a non-spawned item
 429                                 head.solid = SOLID_NOT;
 430                                 head.model = string_null;
 431                                 head.state = 1; // state 1 = initially hidden item
 432                         }
 433                         head.effects &~= EF_NODRAW;
 434                 }
 435
 436                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 437                 {
 438                         e.solid = SOLID_NOT;
 439                         e.model = string_null;
 440                         Item_ScheduleInitialRespawn(e);
 441                 }
 442         }
 443 }
 444
 445 void Item_Reset()
 446 {
 447         if(self.state == 1)
 448         {
 449                 self.model = string_null;
 450                 self.solid = SOLID_NOT;
 451         }
 452         else
 453         {
 454                 self.model = self.mdl;
 455                 self.solid = SOLID_TRIGGER;
 456         }
 457         setorigin (self, self.origin);
 458         self.think = SUB_Null;
 459         self.nextthink = 0;
 460
 461         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 462         {
 463                 self.solid = SOLID_NOT;
 464                 self.model = string_null;
 465                 Item_ScheduleInitialRespawn(self);
 466         }
 467 }
 468
 469 // Savage: used for item garbage-collection
 470 // TODO: perhaps nice special effect?
 471 void RemoveItem(void)
 472 {
 473         remove(self);
 474 }
 475
 476 // pickup evaluation functions
 477 // these functions decide how desirable an item is to the bots
 478
 479 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 480
 481 float weapon_pickupevalfunc(entity player, entity item)
 482 {
 483         float c, i, j, position;
 484
 485         // See if I have it already
 486         if(player.weapons & item.weapons == item.weapons)
 487         {
 488                 // If I can pick it up
 489                 if(g_weapon_stay)
 490                         c = 0;
 491                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 492                 {
 493                         // Skilled bots will grab more
 494                         c = bound(0, skill / 10, 1) * 0.5;
 495                 }
 496                 else
 497                         c = 0;
 498         }
 499         else
 500                 c = 1;
 501
 502         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 503         if( bot_custom_weapon && c )
 504         {
 505                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 506                 {
 507                         // Find weapon
 508                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 509                                 continue;
 510
 511                         // Find the highest position on any range
 512                         position = -1;
 513                         for(j = 0; j < WEP_LAST ; ++j){
 514                                 if(
 515                                                 bot_weapons_far[j] == i ||
 516                                                 bot_weapons_mid[j] == i ||
 517                                                 bot_weapons_close[j] == i
 518                                   )
 519                                 {
 520                                         position = j;
 521                                         break;
 522                                 }
 523                         }
 524
 525                         // Rate it
 526                         if (position >= 0 )
 527                         {
 528                                 position = WEP_LAST - position;
 529                                 // item.bot_pickupbasevalue is overwritten here
 530                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 531                         }
 532                 }
 533         }
 534
 535         return item.bot_pickupbasevalue * c;
 536 };
 537
 538 float commodity_pickupevalfunc(entity player, entity item)
 539 {
 540         float c, i, need_shells, need_nails, need_rockets, need_cells;
 541         entity wi;
 542         c = 0;
 543
 544         // Detect needed ammo
 545         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 546         {
 547                 wi = get_weaponinfo(i);
 548
 549                 if not(wi.weapons & player.weapons)
 550                         continue;
 551
 552                 if(wi.items & IT_SHELLS)
 553                         need_shells = TRUE;
 554                 else if(wi.items & IT_NAILS)
 555                         need_nails = TRUE;
 556                 else if(wi.items & IT_ROCKETS)
 557                         need_rockets = TRUE;
 558                 else if(wi.items & IT_CELLS)
 559                         need_cells = TRUE;
 560         }
 561
 562         // TODO: figure out if the player even has the weapon this ammo is for?
 563         // may not affect strategy much though...
 564         // find out how much more ammo/armor/health the player can hold
 565         if (need_shells)
 566         if (item.ammo_shells)
 567         if (player.ammo_shells < g_pickup_shells_max)
 568                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 569         if (need_nails)
 570         if (item.ammo_nails)
 571         if (player.ammo_nails < g_pickup_nails_max)
 572                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 573         if (need_rockets)
 574         if (item.ammo_rockets)
 575         if (player.ammo_rockets < g_pickup_rockets_max)
 576                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 577         if (need_cells)
 578         if (item.ammo_cells)
 579         if (player.ammo_cells < g_pickup_cells_max)
 580                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 581         if (item.armorvalue)
 582         if (player.armorvalue < item.max_armorvalue*0.5)
 583                 c = c + max(0, 1 - player.armorvalue / (item.max_armorvalue*0.5));
 584         if (item.health)
 585         if (player.health < item.max_health*0.5)
 586                 c = c + max(0, 1 - player.health / (item.max_health*0.5));
 587
 588         return item.bot_pickupbasevalue * c;
 589 };
 590
 591
 592 .float is_item;
 593 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 594 {
 595         startitem_failed = FALSE;
 596
 597         // is it a dropped weapon?
 598         if (self.classname == "droppedweapon")
 599         {
 600                 self.reset = SUB_Remove;
 601                 // it's a dropped weapon
 602                 self.movetype = MOVETYPE_TOSS;
 603                 self.solid = SOLID_TRIGGER;
 604                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 605                 self.think = RemoveItem;
 606                 self.nextthink = time + 60;
 607                 // don't drop if in a NODROP zone (such as lava)
 608                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 609                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 610                 {
 611                         startitem_failed = TRUE;
 612                         remove(self);
 613                         return;
 614                 }
 615         }
 616         else
 617         {
 618                 self.reset = Item_Reset;
 619                 // it's a level item
 620                 if(self.spawnflags & 1)
 621                         self.noalign = 1;
 622                 if (self.noalign)
 623                         self.movetype = MOVETYPE_NONE;
 624                 else
 625                         self.movetype = MOVETYPE_TOSS;
 626                 self.solid = SOLID_TRIGGER;
 627                 // do item filtering according to game mode and other things
 628                 if (!self.noalign)
 629                 {
 630                         // first nudge it off the floor a little bit to avoid math errors
 631                         setorigin(self, self.origin + '0 0 1');
 632                         // set item size before we spawn a spawnfunc_waypoint
 633                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 634                                 setsize (self, '-16 -16 0', '16 16 48');
 635                         else
 636                                 setsize (self, '-16 -16 0', '16 16 32');
 637                         // note droptofloor returns FALSE if stuck/or would fall too far
 638                         droptofloor();
 639                         waypoint_spawnforitem(self);
 640                 }
 641
 642                 if(teams_matter)
 643                 {
 644                         if(self.notteam)
 645                         {
 646                                 print("removed non-teamplay ", self.classname, "\n");
 647                                 startitem_failed = TRUE;
 648                                 remove (self);
 649                                 return;
 650                         }
 651                 }
 652                 else
 653                 {
 654                         if(self.notfree)
 655                         {
 656                                 print("removed non-FFA ", self.classname, "\n");
 657                                 startitem_failed = TRUE;
 658                                 remove (self);
 659                                 return;
 660                         }
 661                 }
 662
 663                 if(self.notq3a)
 664                 {
 665                         // We aren't TA or something like that, so we keep the Q3A entities
 666                         print("removed non-Q3A ", self.classname, "\n");
 667                         startitem_failed = TRUE;
 668                         remove (self);
 669                         return;
 670                 }
 671
 672                 /*
 673                  * can't do it that way, as it would break maps
 674                  * TODO make a target_give like entity another way, that perhaps has
 675                  * the weapon name in a key
 676                 if(self.targetname)
 677                 {
 678                         // target_give not yet supported; maybe later
 679                         print("removed targeted ", self.classname, "\n");
 680                         startitem_failed = TRUE;
 681                         remove (self);
 682                         return;
 683                 }
 684                 */
 685
 686                 if(cvar("spawn_debug") >= 2)
 687                 {
 688                         entity otheritem;
 689                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 690                         {
 691                                 if(otheritem.is_item)
 692                                 {
 693                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 694                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 695                                         error("Mapper sucks.");
 696                                 }
 697                         }
 698                         self.is_item = TRUE;
 699                 }
 700
 701                 weaponsInMap |= weaponid;
 702
 703                 if(g_lms)
 704                 {
 705                         startitem_failed = TRUE;
 706                         remove(self);
 707                         return;
 708                 }
 709                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 710                 {
 711                         startitem_failed = TRUE;
 712                         remove(self);
 713                         return;
 714                 }
 715                 else if (g_minstagib)
 716                 {
 717                         // don't remove dropped items and powerups
 718                         if (self.classname != "minstagib")
 719                         {
 720                                 startitem_failed = TRUE;
 721                                 remove (self);
 722                                 return;
 723                         }
 724                 }
 725                 else if (g_nixnex)
 726                 {
 727                         local float rm;
 728
 729                         rm = 1;
 730                         switch (itemid)
 731                         {
 732                                 case IT_HEALTH:
 733                                 case IT_5HP:
 734                                 case IT_25HP:
 735                                 case IT_ARMOR:
 736                                 case IT_ARMOR_SHARD:
 737                                         if (cvar("g_nixnex_with_healtharmor"))
 738                                                 rm = 0;
 739                                         break;
 740                                 case IT_STRENGTH:
 741                                 case IT_INVINCIBLE:
 742                                         if (cvar("g_nixnex_with_powerups"))
 743                                                 rm = 0;
 744                                         break;
 745                         }
 746
 747                         if(rm)
 748                         {
 749                                 startitem_failed = TRUE;
 750                                 remove (self);
 751                                 return;
 752                         }
 753                 }
 754                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 755                 {
 756                         startitem_failed = TRUE;
 757                         remove (self);
 758                         return;
 759                 }
 760
 761                 precache_model (itemmodel);
 762                 precache_sound (pickupsound);
 763                 precache_sound ("misc/itemrespawn.wav");
 764                 precache_sound ("misc/itemrespawncountdown.wav");
 765
 766                 if(itemid == IT_STRENGTH)
 767                         precache_sound ("misc/strength_respawn.wav");
 768                 if(itemid == IT_INVINCIBLE)
 769                         precache_sound ("misc/shield_respawn.wav");
 770
 771                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 772                         self.target = "###item###"; // for finding the nearest item using find()
 773         }
 774
 775         self.bot_pickup = TRUE;
 776         self.bot_pickupevalfunc = pickupevalfunc;
 777         self.bot_pickupbasevalue = pickupbasevalue;
 778         self.mdl = itemmodel;
 779         self.item_pickupsound = pickupsound;
 780         // let mappers override respawntime
 781         if(!self.respawntime) // both set
 782         {
 783                 self.respawntime = defaultrespawntime;
 784                 self.respawntimejitter = defaultrespawntimejitter;
 785         }
 786         self.netname = itemname;
 787         self.items = itemid;
 788         self.weapons = weaponid;
 789         self.flags = FL_ITEM | itemflags;
 790         self.touch = Item_Touch;
 791         setmodel (self, self.mdl); // precision set below
 792         self.effects |= EF_LOWPRECISION;
 793         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 794                 setsize (self, '-16 -16 0', '16 16 48');
 795         else
 796                 setsize (self, '-16 -16 0', '16 16 32');
 797         if(itemflags & FL_WEAPON)
 798                 self.modelflags |= MF_ROTATE;
 799
 800         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 801         if (itemflags & FL_WEAPON)
 802         {
 803                 // neutral team color for pickup weapons
 804                 self.colormap = 1024; // color shirt=0 pants=0 grey
 805         }
 806
 807         if (cvar("g_fullbrightitems"))
 808                 self.effects = self.effects | EF_FULLBRIGHT;
 809
 810         self.state = 0;
 811         if(self.team)
 812         {
 813                 if(!self.cnt)
 814                         self.cnt = 1; // item probability weight
 815                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 816                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 817         }
 818         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 819         {
 820                 self.solid = SOLID_NOT;
 821                 self.model = string_null;
 822                 Item_ScheduleInitialRespawn(self);
 823         }
 824 }
 825
 826 /* replace items in minstagib
 827  * IT_STRENGTH   = invisibility
 828  * IT_NAILS      = extra lives
 829  * IT_INVINCIBLE = speed
 830  */
 831 void minstagib_items (float itemid)
 832 {
 833         // we don't want to replace dropped weapons ;)
 834         if (self.classname == "droppedweapon")
 835         {
 836                 self.ammo_cells = 25;
 837                 StartItem ("models/weapons/g_nex.md3",
 838                         "weapons/weaponpickup.wav", 15, 0,
 839                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 840                 return;
 841         }
 842
 843         local float rnd;
 844         self.classname = "minstagib";
 845
 846         // replace rocket launchers and nex guns with ammo cells
 847         if (itemid == IT_CELLS)
 848         {
 849                 self.ammo_cells = 1;
 850                 StartItem ("models/items/a_cells.md3",
 851                         "misc/itempickup.wav", 45, 0,
 852                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 853                 return;
 854         }
 855
 856         // randomize
 857         rnd = random() * 3;
 858         if (rnd <= 1)
 859                 itemid = IT_STRENGTH;
 860         else if (rnd <= 2)
 861                 itemid = IT_NAILS;
 862         else
 863                 itemid = IT_INVINCIBLE;
 864
 865         // replace with invis
 866         if (itemid == IT_STRENGTH)
 867         {
 868                 self.effects = EF_ADDITIVE;
 869                 self.strength_finished = 30;
 870                 StartItem ("models/items/g_strength.md3",
 871                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 872                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 873         }
 874         // replace with extra lives
 875         if (itemid == IT_NAILS)
 876         {
 877                 self.max_health = 1;
 878                 StartItem ("models/items/g_h100.md3",
 879                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 880                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 881
 882         }
 883         // replace with speed
 884         if (itemid == IT_INVINCIBLE)
 885         {
 886                 self.effects = EF_ADDITIVE;
 887                 self.invincible_finished = 30;
 888                 StartItem ("models/items/g_invincible.md3",
 889                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 890                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 891         }
 892
 893 }
 894
 895 float minst_no_auto_cells;
 896 void minst_remove_item (void) {
 897         if(minst_no_auto_cells)
 898                 remove(self);
 899 }
 900
 901 float weaponswapping;
 902 float internalteam;
 903
 904 void weapon_defaultspawnfunc(float wpn)
 905 {
 906         entity e;
 907         float t;
 908         var .float ammofield;
 909         string s;
 910         entity oldself;
 911         float i, j;
 912
 913         // set the respawntime in advance (so replaced weapons can copy it)
 914
 915         if(!self.respawntime)
 916         {
 917                 e = get_weaponinfo(wpn);
 918                 if(e.items == IT_SUPERWEAPON)
 919                 {
 920                         self.respawntime = g_pickup_respawntime_powerup;
 921                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 922                 }
 923                 else
 924                 {
 925                         self.respawntime = g_pickup_respawntime_weapon;
 926                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 927                 }
 928         }
 929
 930         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 931         {
 932                 e = get_weaponinfo(wpn);
 933                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 934                 if(s == "0")
 935                 {
 936                         remove(self);
 937                         startitem_failed = TRUE;
 938                         return;
 939                 }
 940                 t = tokenize_console(s);
 941                 if(t >= 2)
 942                 {
 943                         self.team = --internalteam;
 944                         oldself = self;
 945                         for(i = 1; i < t; ++i)
 946                         {
 947                                 s = argv(i);
 948                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 949                                 {
 950                                         e = get_weaponinfo(j);
 951                                         if(e.netname == s)
 952                                         {
 953                                                 self = spawn();
 954                                                 copyentity(oldself, self);
 955                                                 self.classname = "replacedweapon";
 956                                                 weapon_defaultspawnfunc(j);
 957                                                 break;
 958                                         }
 959                                 }
 960                                 if(j > WEP_LAST)
 961                                 {
 962                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 963                                 }
 964                         }
 965                         self = oldself;
 966                 }
 967                 if(t >= 1)
 968                 {
 969                         s = argv(0);
 970                         wpn = 0;
 971                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 972                         {
 973                                 e = get_weaponinfo(j);
 974                                 if(e.netname == s)
 975                                 {
 976                                         wpn = j;
 977                                         break;
 978                                 }
 979                         }
 980                         if(j > WEP_LAST)
 981                         {
 982                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 983                         }
 984                 }
 985                 if(wpn == 0)
 986                 {
 987                         remove(self);
 988                         startitem_failed = TRUE;
 989                         return;
 990                 }
 991         }
 992
 993         e = get_weaponinfo(wpn);
 994
 995         if(e.items && e.items != IT_SUPERWEAPON)
 996         {
 997                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
 998                 {
 999                         if(e.items & j)
1000                         {
1001                                 ammofield = Item_CounterField(j);
1002                                 if(!self.ammofield)
1003                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1004                         }
1005                 }
1006         }
1007         else
1008         {
1009                 self.flags |= FL_NO_WEAPON_STAY;
1010         }
1011
1012         // weapon stay isn't supported for teamed weapons
1013         if(self.team)
1014                 self.flags |= FL_NO_WEAPON_STAY;
1015
1016         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1017         {
1018                 self.ammo_shells = 0;
1019                 self.ammo_nails = 0;
1020                 self.ammo_cells = 0;
1021                 self.ammo_rockets = 0;
1022                 // weapon stay 2: don't use ammo on weapon pickups; instead
1023                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1024         }
1025
1026         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1027         if (self.modelindex) // don't precache if self was removed
1028                 weapon_action(e.weapon, WR_PRECACHE);
1029 }
1030
1031 void spawnfunc_weapon_shotgun (void);
1032 void spawnfunc_weapon_uzi (void) {
1033         if(q3acompat_machineshotgunswap)
1034         if(self.classname != "droppedweapon")
1035         {
1036                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1037                 return;
1038         }
1039         weapon_defaultspawnfunc(WEP_UZI);
1040 }
1041
1042 void spawnfunc_weapon_shotgun (void) {
1043         if(q3acompat_machineshotgunswap)
1044         if(self.classname != "droppedweapon")
1045         {
1046                 weapon_defaultspawnfunc(WEP_UZI);
1047                 return;
1048         }
1049         weapon_defaultspawnfunc(WEP_SHOTGUN);
1050 }
1051
1052 void spawnfunc_weapon_nex (void)
1053 {
1054         if (g_minstagib)
1055         {
1056                 minstagib_items(IT_CELLS);
1057                 self.think = minst_remove_item;
1058                 self.nextthink = time;
1059                 return;
1060         }
1061         weapon_defaultspawnfunc(WEP_NEX);
1062 }
1063
1064 void spawnfunc_weapon_minstanex (void)
1065 {
1066         if (g_minstagib)
1067         {
1068                 minstagib_items(IT_CELLS);
1069                 self.think = minst_remove_item;
1070                 self.nextthink = time;
1071                 return;
1072         }
1073         weapon_defaultspawnfunc(WEP_MINSTANEX);
1074 }
1075
1076 void spawnfunc_weapon_rocketlauncher (void)
1077 {
1078         if (g_minstagib)
1079         {
1080                 minstagib_items(IT_CELLS);
1081                 self.think = minst_remove_item;
1082                 self.nextthink = time;
1083                 return;
1084         }
1085         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1086 }
1087
1088 void spawnfunc_item_rockets (void) {
1089         if(!self.ammo_rockets)
1090                 self.ammo_rockets = g_pickup_rockets;
1091         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1092 }
1093
1094 void spawnfunc_item_shells (void);
1095 void spawnfunc_item_bullets (void) {
1096         if(!weaponswapping)
1097         if(q3acompat_machineshotgunswap)
1098         if(self.classname != "droppedweapon")
1099         {
1100                 weaponswapping = TRUE;
1101                 spawnfunc_item_shells();
1102                 weaponswapping = FALSE;
1103                 return;
1104         }
1105
1106         if(!self.ammo_nails)
1107                 self.ammo_nails = g_pickup_nails;
1108         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1109 }
1110
1111 void spawnfunc_item_cells (void) {
1112         if(!self.ammo_cells)
1113                 self.ammo_cells = g_pickup_cells;
1114         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1115 }
1116
1117 void spawnfunc_item_shells (void) {
1118         if(!weaponswapping)
1119         if(q3acompat_machineshotgunswap)
1120         if(self.classname != "droppedweapon")
1121         {
1122                 weaponswapping = TRUE;
1123                 spawnfunc_item_bullets();
1124                 weaponswapping = FALSE;
1125                 return;
1126         }
1127
1128         if(!self.ammo_shells)
1129                 self.ammo_shells = g_pickup_shells;
1130         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1131 }
1132
1133 void spawnfunc_item_armor_small (void) {
1134         if(!self.armorvalue)
1135                 self.armorvalue = g_pickup_armorsmall;
1136         if(!self.max_armorvalue)
1137                 self.max_armorvalue = g_pickup_armorsmall_max;
1138         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1139 }
1140
1141 void spawnfunc_item_armor_medium (void) {
1142         if(!self.armorvalue)
1143                 self.armorvalue = g_pickup_armormedium;
1144         if(!self.max_armorvalue)
1145                 self.max_armorvalue = g_pickup_armormedium_max;
1146         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1147 }
1148
1149 void spawnfunc_item_armor_big (void) {
1150         if(!self.armorvalue)
1151                 self.armorvalue = g_pickup_armorbig;
1152         if(!self.max_armorvalue)
1153                 self.max_armorvalue = g_pickup_armorbig_max;
1154         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1155 }
1156
1157 void spawnfunc_item_armor_large (void) {
1158         if(!self.armorvalue)
1159                 self.armorvalue = g_pickup_armorlarge;
1160         if(!self.max_armorvalue)
1161                 self.max_armorvalue = g_pickup_armorlarge_max;
1162         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1163 }
1164
1165 void spawnfunc_item_health_small (void) {
1166         if(!self.max_health)
1167                 self.max_health = g_pickup_healthsmall_max;
1168         if(!self.health)
1169                 self.health = g_pickup_healthsmall;
1170         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1171 }
1172
1173 void spawnfunc_item_health_medium (void) {
1174         if(!self.max_health)
1175                 self.max_health = g_pickup_healthmedium_max;
1176         if(!self.health)
1177                 self.health = g_pickup_healthmedium;
1178         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1179 }
1180
1181 void spawnfunc_item_health_large (void) {
1182         if(!self.max_health)
1183                 self.max_health = g_pickup_healthlarge_max;
1184         if(!self.health)
1185                 self.health = g_pickup_healthlarge;
1186         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1187 }
1188
1189 void spawnfunc_item_health_mega (void) {
1190         if(!cvar("g_powerup_superhealth"))
1191                 return;
1192
1193         if(g_arena && !cvar("g_arena_powerups"))
1194                 return;
1195
1196         if(g_minstagib) {
1197                 minstagib_items(IT_NAILS);
1198         } else {
1199                 if(!self.max_health)
1200                         self.max_health = g_pickup_healthmega_max;
1201                 if(!self.health)
1202                         self.health = g_pickup_healthmega;
1203                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1204         }
1205 }
1206
1207 // support old misnamed entities
1208 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1209 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1210 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1211 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1212 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1213
1214 void spawnfunc_item_strength (void) {
1215         if(!cvar("g_powerup_strength"))
1216                 return;
1217
1218         if(g_arena && !cvar("g_arena_powerups"))
1219                 return;
1220
1221         if(g_minstagib) {
1222                 minstagib_items(IT_STRENGTH);
1223         } else {
1224                 precache_sound("weapons/strength_fire.wav");
1225                 self.strength_finished = 30;
1226                 self.effects = EF_ADDITIVE;
1227                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1228         }
1229 }
1230
1231 void spawnfunc_item_invincible (void) {
1232         if(!cvar("g_powerup_shield"))
1233                 return;
1234
1235         if(g_arena && !cvar("g_arena_powerups"))
1236                 return;
1237
1238         if(g_minstagib) {
1239                 minstagib_items(IT_INVINCIBLE);
1240         } else {
1241                 self.invincible_finished = 30;
1242                 self.effects = EF_ADDITIVE;
1243                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1244         }
1245 }
1246
1247 void spawnfunc_item_minst_cells (void) {
1248         if (g_minstagib)
1249         {
1250                 minst_no_auto_cells = 1;
1251                 minstagib_items(IT_CELLS);
1252         }
1253         else
1254                 remove(self);
1255 }
1256
1257 // compatibility:
1258 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1259
1260 float target_item_func_set(float a, float b)
1261 {
1262         if(b == 0)
1263                 return a;
1264         else if(b < 0)
1265                 return 0;
1266         else
1267                 return b;
1268 }
1269
1270 float target_item_func_min(float a, float b)
1271 {
1272         if(b == 0)
1273                 return a;
1274         else if(b < 0)
1275                 return 0;
1276         else
1277                 return min(a, b);
1278 }
1279
1280 float target_item_func_max(float a, float b)
1281 {
1282         return max(a, b);
1283 }
1284
1285 float target_item_func_bitset(float a, float b)
1286 {
1287         return b;
1288 }
1289
1290 float target_item_func_and(float a, float b)
1291 {
1292         return a & b;
1293 }
1294
1295 float target_item_func_itembitset(float a, float b)
1296 {
1297         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | b;
1298 }
1299
1300 float target_item_func_itemand(float a, float b)
1301 {
1302         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
1303 }
1304
1305 float target_item_func_or(float a, float b)
1306 {
1307         return a | b;
1308 }
1309
1310 float target_item_func_andnot(float a, float b)
1311 {
1312         return a - (a & b);
1313 }
1314
1315 float target_item_changed;
1316 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
1317 {
1318         float n, d;
1319         n = func(activator.field, self.field);
1320
1321         if(binary)
1322         {
1323                 d = n & activator.field;
1324                 if(d != n) // bits added?
1325                         d = +1;
1326                 else if(d != activator.field) // bits removed?
1327                         d = -1;
1328                 else
1329                         d = 0;
1330         }
1331         else
1332                 d = n - activator.field;
1333
1334         if(d < 0)
1335         {
1336                 if(sound_decrease != "")
1337                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
1338                 target_item_changed = 1;
1339         }
1340         else if(d > 0)
1341         {
1342                 if(sound_increase != "")
1343                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
1344                 target_item_changed = 1;
1345         }
1346         activator.field = n;
1347 }
1348
1349 void target_items_use (void)
1350 {
1351         float h0, a0, f0;
1352
1353         if(activator.classname == "droppedweapon")
1354         {
1355                 EXACTTRIGGER_TOUCH;
1356                 remove(activator);
1357                 return;
1358         }
1359
1360         if(activator.classname != "player")
1361                 return;
1362         if(activator.deadflag != DEAD_NO)
1363                 return;
1364         EXACTTRIGGER_TOUCH;
1365
1366         entity e;
1367         for(e = world; (e = find(e, classname, "droppedweapon")); )
1368                 if(e.enemy == activator)
1369                         remove(e);
1370
1371         float _switchweapon;
1372         _switchweapon = FALSE;
1373         if (activator.autoswitch)
1374                 if (activator.switchweapon == w_getbestweapon(activator))
1375                         _switchweapon = TRUE;
1376
1377         a0 = activator.armorvalue;
1378         h0 = activator.health;
1379         f0 = activator.ammo_fuel;
1380         target_item_changed = 0;
1381
1382         if(self.spawnflags == 0) // SET
1383         {
1384                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1385                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1386                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1387                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1388                 target_item_change(0, ammo_fuel, target_item_func_set, "misc/itempickup.wav", "");
1389                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1390                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1391                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "misc/poweroff.wav");
1392                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1393
1394                 if((self.items & activator.items) & IT_STRENGTH)
1395                         activator.strength_finished = time + self.strength_finished;
1396                 if((self.items & activator.items) & IT_INVINCIBLE)
1397                         activator.invincible_finished = time + self.invincible_finished;
1398         }
1399         else if(self.spawnflags == 1) // AND/MIN
1400         {
1401                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1402                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1403                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1404                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1405                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1406                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1407                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1408                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "misc/poweroff.wav");
1409                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1410
1411                 if((self.items & activator.items) & IT_STRENGTH)
1412                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1413                 if((self.items & activator.items) & IT_INVINCIBLE)
1414                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1415         }
1416         else if(self.spawnflags == 2) // OR/MAX
1417         {
1418                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1419                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1420                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1421                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1422                 target_item_change(0, ammo_fuel, target_item_func_max, "misc/itempickup.wav", "");
1423                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1424                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1425                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "misc/poweroff.wav");
1426                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1427
1428                 if((self.items & activator.items) & IT_STRENGTH)
1429                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1430                 if((self.items & activator.items) & IT_INVINCIBLE)
1431                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1432         }
1433         else if(self.spawnflags == 4) // ANDNOT/MIN
1434         {
1435                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1436                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1437                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1438                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1439                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1440                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1441                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1442                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "misc/poweroff.wav");
1443                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1444
1445                 if((self.items & activator.items) & IT_STRENGTH)
1446                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1447                 if((self.items & activator.items) & IT_INVINCIBLE)
1448                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1449         }
1450
1451         if not(activator.items & IT_STRENGTH)
1452                 activator.strength_finished = 0;
1453         if not(activator.items & IT_INVINCIBLE)
1454                 activator.invincible_finished = 0;
1455
1456         if(activator.health > h0)
1457                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1458         else if(activator.health < h0)
1459                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1460
1461         if(activator.ammo_fuel > f0)
1462                 activator.pauserotfuel_finished = max(activator.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
1463         else if(activator.ammo_fuel < f0)
1464                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1465
1466         if(activator.armorvalue > a0)
1467                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1468
1469         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1470                 _switchweapon = TRUE;
1471         if(_switchweapon)
1472                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1473
1474         if(target_item_changed)
1475                 centerprint(activator, self.message);
1476 }
1477
1478 void spawnfunc_target_items (void)
1479 {
1480         float n, i, j;
1481         entity e;
1482
1483         if(g_nixnex)
1484         {
1485                 // items triggers cannot work in nixnex (as they change weapons/ammo)
1486                 remove(self);
1487                 return;
1488         }
1489
1490         self.use = target_items_use;
1491         if(!self.strength_finished)
1492                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1493         if(!self.invincible_finished)
1494                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1495
1496         precache_sound("misc/itempickup.wav");
1497         precache_sound("misc/itempickup.wav");
1498         precache_sound("misc/itempickup.wav");
1499         precache_sound("misc/itempickup.wav");
1500         precache_sound("misc/megahealth.wav");
1501         precache_sound("misc/armor25.wav");
1502         precache_sound("misc/powerup.wav");
1503         precache_sound("misc/poweroff.wav");
1504         precache_sound("weapons/weaponpickup.wav");
1505
1506         n = tokenize_console(self.netname);
1507         for(i = 0; i < n; ++i)
1508         {
1509                 if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1510                 else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1511                 else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1512                 else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1513                 else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1514                 else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1515                 else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1516                 else
1517                 {
1518                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1519                         {
1520                                 e = get_weaponinfo(j);
1521                                 if(argv(i) == e.netname)
1522                                 {
1523                                         self.weapons |= e.weapons;
1524                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1525                                                 weapon_action(e.weapon, WR_PRECACHE);
1526                                         break;
1527                                 }
1528                         }
1529                         if(j > WEP_LAST)
1530                                 print("target_items: invalid item ", argv(i), "\n");
1531                 }
1532         }
1533 }
1534
1535 void spawnfunc_item_fuel(void)
1536 {
1537         if(!self.ammo_fuel)
1538                 self.ammo_fuel = g_pickup_fuel;
1539         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1540 }
1541
1542 void spawnfunc_item_fuel_regen(void)
1543 {
1544         if(start_items & IT_FUEL_REGEN)
1545         {
1546                 spawnfunc_item_fuel();
1547                 return;
1548         }
1549         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1550 }
1551
1552 void spawnfunc_item_jetpack(void)
1553 {
1554         if(g_grappling_hook)
1555                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1556         if(!self.ammo_fuel)
1557                 self.ammo_fuel = g_pickup_fuel_jetpack;
1558         if(start_items & IT_JETPACK)
1559         {
1560                 spawnfunc_item_fuel();
1561                 return;
1562         }
1563         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1564 }
1565
1566 // we no longer have the seeker
1567 void spawnfunc_weapon_seeker()
1568 {
1569         spawnfunc_weapon_rocketlauncher();
1570 }