data/qcsrc/server/t_items.qc

   1 //void Item_ClearRespawnEffect (void) {
   2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
   3 //}
   4
   5 .float max_armorvalue;
   6
   7 void Item_Respawn (void)
   8 {
   9         self.model = self.mdl;          // restore original model
  10         self.solid = SOLID_TRIGGER;     // allow it to be touched again
  11         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  12         setorigin (self, self.origin);
  13
  14         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
  15         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
  16         //// Savage: Add simple Respawn effect and make sure it gets removed
  17         //self.effects = self.effects | EF_STARDUST;
  18         //self.think = Item_ClearRespawnEffect;
  19         //self.nextthink = time + 0.1;
  20 }
  21
  22 void Item_Touch (void)
  23 {
  24         local entity oldself;
  25         local float _switchweapon;
  26         local float pickedup;
  27         local float it;
  28
  29         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  30         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  31         {
  32                 remove(self);
  33                 return;
  34         }
  35         if (other.classname != "player")
  36                 return;
  37         if (other.deadflag)
  38                 return;
  39         if (self.solid != SOLID_TRIGGER)
  40                 return;
  41         if (self.owner == other)
  42                 return;
  43
  44         // if nothing happens to other, just return without taking the item
  45         pickedup = FALSE;
  46         _switchweapon = FALSE;
  47
  48         if (cvar("g_minstagib"))
  49         {
  50                 _switchweapon = TRUE;
  51                 if (self.ammo_cells)
  52                 {
  53                         pickedup = TRUE;
  54                         // play some cool sounds ;)
  55                         centerprint(other, "\n");
  56                         if(other.health <= 5)
  57                                 play2(other, "announcer/robotic/lastsecond.ogg");
  58                         else if(other.health < 50)
  59                                 play2(other, "announcer/robotic/narrowly.ogg");
  60                         // sound not available
  61                         // else if(self.items == IT_CELLS)
  62                         //      play2(other, "announce/robotic/ammo.ogg");
  63
  64                         if (self.items & IT_NEX)
  65                                 W_GiveWeapon (other, IT_NEX, "Nex");
  66                         if (self.ammo_cells)
  67                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  68                         other.health = 100;
  69                 }
  70
  71                 // extralife powerup
  72                 if (self.max_health)
  73                 {
  74                         pickedup = TRUE;
  75                         // sound not available
  76                         // play2(other, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg");
  77                         other.armorvalue = other.armorvalue + cvar("g_minstagib_extralives");
  78                         sprint(other, "^3You picked up some extra lives\n");
  79                 }
  80
  81                 // invis powerup
  82                 if (self.strength_finished)
  83                 {
  84                         pickedup = TRUE;
  85                         // sound not available
  86                         // play2(other, "announce/robotic/invisible.ogg");
  87                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  88                 }
  89
  90                 // speed powerup
  91                 if (self.invincible_finished)
  92                 {
  93                         pickedup = TRUE;
  94                         // sound not available
  95                         // play2(other, "announce/robotic/speed.ogg");
  96                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  97                 }
  98         }
  99         else
 100         {
 101                 if (cvar("deathmatch") == 2 || cvar("g_weapon_stay"))
 102                 {
 103                         if (self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
 104                                 return;
 105                         if (other.items & self.items && self.flags & FL_TOSSED) // don't let players stack ammo by tossing weapons
 106                                 return;
 107                 }
 108
 109                 // in case the player has autoswitch enabled do the following:
 110                 // if the player is using their best weapon before items are given, they
 111                 // probably want to switch to an even better weapon after items are given
 112                 if (other.autoswitch)
 113                 if (other.switchweapon == w_getbestweapon(other))
 114                         _switchweapon = TRUE;
 115
 116                 if (self.ammo_shells)
 117                 if (other.ammo_shells < g_pickup_shells_max)
 118                 {
 119                         pickedup = TRUE;
 120                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, g_pickup_shells_max);
 121                 }
 122                 if (self.ammo_nails)
 123                 if (other.ammo_nails < g_pickup_nails_max)
 124                 {
 125                         pickedup = TRUE;
 126                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, g_pickup_nails_max);
 127                 }
 128                 if (self.ammo_rockets)
 129                 if (other.ammo_rockets < g_pickup_rockets_max)
 130                 {
 131                         pickedup = TRUE;
 132                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, g_pickup_rockets_max);
 133                 }
 134                 if (self.ammo_cells)
 135                 if (other.ammo_cells < g_pickup_cells_max)
 136                 {
 137                         pickedup = TRUE;
 138                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, g_pickup_cells_max);
 139                 }
 140
 141                 if (self.flags & FL_WEAPON)
 142                 if ((it = self.items - (self.items & other.items)))
 143                 {
 144                         pickedup = TRUE;
 145                         if (it & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 146                         if (it & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 147                         if (it & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 148                         if (it & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 149                         if (it & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 150                         if (it & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 151                         if (it & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 152                         if (it & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 153                 }
 154
 155                 if (self.strength_finished)
 156                 {
 157                         pickedup = TRUE;
 158                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 159                 }
 160                 if (self.invincible_finished)
 161                 {
 162                         pickedup = TRUE;
 163                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 164                 }
 165                 //if (self.speed_finished)
 166                 //{
 167                 //      pickedup = TRUE;
 168                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 169                 //}
 170                 //if (self.slowmo_finished)
 171                 //{
 172                 //      pickedup = TRUE;
 173                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 174                 //}
 175
 176                 if (self.health)
 177                 if (other.health < self.max_health)
 178                 {
 179                         pickedup = TRUE;
 180                         other.health = min(other.health + self.health, self.max_health);
 181                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 182                 }
 183                 if (self.armorvalue)
 184                 if (other.armorvalue < self.max_armorvalue)
 185                 {
 186                         pickedup = TRUE;
 187                         other.armorvalue = min(other.armorvalue + self.armorvalue, self.max_armorvalue);
 188                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 189                 }
 190         }
 191
 192         if (!pickedup)
 193                 return;
 194
 195         // Savage: Remove the respawn effect if still present
 196         self.effects = self.effects - (self.effects & EF_STARDUST);
 197
 198         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
 199         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 200
 201         oldself = self;
 202         self = other;
 203
 204         if (_switchweapon)
 205                 self.switchweapon = w_getbestweapon(self);
 206         if (self.switchweapon != self.weapon)
 207                 self.cnt = self.weapon;
 208
 209         self = oldself;
 210
 211         if (self.classname == "droppedweapon")
 212                 remove (self);
 213         else if(self.flags & FL_WEAPON && (cvar("deathmatch") == 2 || cvar("g_weapon_stay")))
 214                 return;
 215         else
 216         {
 217                 self.solid = SOLID_NOT;
 218                 self.model = string_null;
 219                 self.nextthink = time + self.respawntime;
 220                 self.think = Item_Respawn;
 221                 setorigin (self, self.origin);
 222         }
 223 }
 224
 225 // Savage: used for item garbage-collection
 226 // TODO: perhaps nice special effect?
 227 void RemoveItem(void) = {
 228         remove(self);
 229 }
 230
 231 // pickup evaluation functions
 232 // these functions decide how desirable an item is to the bots
 233
 234 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
 235
 236 float(entity player, entity item) weapon_pickupevalfunc =
 237 {
 238         // if we already have the weapon, rate it 1/5th normal value
 239         if ((player.items & item.items) == item.items)
 240                 return item.bot_pickupbasevalue * 0.2;
 241         return item.bot_pickupbasevalue;
 242 };
 243
 244 float(entity player, entity item) commodity_pickupevalfunc =
 245 {
 246         float c;
 247         c = 0;
 248         // TODO: figure out if the player even has the weapon this ammo is for?
 249         // may not affect strategy much though...
 250         // find out how much more ammo/armor/health the player can hold
 251         if (item.ammo_shells)
 252         if (player.ammo_shells < g_pickup_shells_max)
 253                 c = c + 1 - min(player.ammo_shells / g_pickup_shells_max, 1);
 254         if (item.ammo_nails)
 255         if (player.ammo_nails < g_pickup_nails_max)
 256                 c = c + 1 - min(player.ammo_nails / g_pickup_nails_max, 1);
 257         if (item.ammo_rockets)
 258         if (player.ammo_rockets < g_pickup_rockets_max)
 259                 c = c + 1 - min(player.ammo_rockets / g_pickup_rockets_max, 1);
 260         if (item.ammo_cells)
 261         if (player.ammo_cells < g_pickup_cells_max)
 262                 c = c + 1 - min(player.ammo_cells / g_pickup_cells_max, 1);
 263         if (item.armorvalue)
 264         if (player.armorvalue < item.max_armorvalue)
 265                 c = c + 1 - min(player.armorvalue / item.max_armorvalue, 1);
 266         if (item.health)
 267         if (player.health < item.max_health)
 268                 c = c + 1 - min(player.health / item.max_health, 1);
 269
 270         if (cvar("deathmatch") == 2) // weapon stay is on, so weapons the player already has are of no interest
 271         if (item.flags & FL_WEAPON)
 272         if (self.items & item.items)
 273         if (item.classname != "droppedweapon")
 274                 c = 0;
 275
 276         return item.bot_pickupbasevalue * c;
 277 };
 278
 279
 280 .float is_item;
 281 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 282 {
 283         startitem_failed = FALSE;
 284
 285         if (self.classname != "droppedweapon")
 286         {
 287                 if(cvar("spawn_debug") >= 2)
 288                 {
 289                         entity otheritem;
 290                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 291                         {
 292                                 if(otheritem.is_item)
 293                                 {
 294                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 295                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 296                                         error("Mapper sucks.");
 297                                 }
 298                         }
 299                         self.is_item = TRUE;
 300                 }
 301
 302                 waypoint_spawnforitem(self);
 303         }
 304
 305         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 306                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 307         {
 308                 startitem_failed = TRUE;
 309                 remove (self);
 310                 return;
 311         }
 312
 313         if (cvar("g_minstagib"))
 314         {
 315                 // don't remove dropped items and powerups
 316                 if (self.classname != "droppedweapon" &&
 317                     self.classname != "minstagib")
 318                 {
 319                         startitem_failed = TRUE;
 320                         remove (self);
 321                         return;
 322                 }
 323         }
 324
 325         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 326         {
 327                 startitem_failed = TRUE;
 328                 remove(self);
 329                 return;
 330         }
 331
 332         if(cvar("g_instagib") || cvar("g_rocketarena"))
 333         {
 334                 startitem_failed = TRUE;
 335                 remove(self);
 336                 return;
 337         }
 338
 339         if (self.classname == "droppedweapon")
 340         {
 341                 // don't drop if in a NODROP zone (such as lava)
 342                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 343                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 344                 {
 345                         startitem_failed = TRUE;
 346                         remove(self);
 347                         return;
 348                 }
 349         }
 350
 351         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 352                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 353                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
 354         {
 355                 self.target = "###item###"; // for finding the nearest item using find()
 356         }
 357         self.bot_pickup = TRUE;
 358         self.bot_pickupevalfunc = pickupevalfunc;
 359         self.bot_pickupbasevalue = pickupbasevalue;
 360         self.mdl = itemmodel;
 361         //self.noise = pickupsound;
 362         self.item_pickupsound = pickupsound;
 363         // let mappers override respawntime
 364         if (!self.respawntime)
 365                 self.respawntime = defaultrespawntime;
 366         self.netname = itemname;
 367         self.items = itemid;
 368         self.flags = FL_ITEM | itemflags;
 369         if(self.spawnflags & 1)
 370                 self.noalign = 1;
 371         if (self.noalign)
 372                 self.movetype = MOVETYPE_NONE;
 373         else
 374                 self.movetype = MOVETYPE_TOSS;
 375         self.solid = SOLID_TRIGGER;
 376         self.touch = Item_Touch;
 377         setmodel (self, self.mdl); // precision set below
 378         self.effects |= EF_LOWPRECISION;
 379         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 380                 setsize (self, '-16 -16 0', '16 16 48');
 381         else
 382                 setsize (self, '-16 -16 0', '16 16 32');
 383         if (itemflags & FL_WEAPON)
 384         {
 385                 // neutral team color for pickup weapons
 386                 self.colormap = 160 * 1024 + 160;
 387         }
 388
 389         // Savage: remove thrown items after a certain period of time ("garbage collection")
 390         if (self.classname == "droppedweapon")
 391         {
 392                 self.think = RemoveItem;
 393                 self.nextthink = time + 60;
 394         }
 395         else if (!self.noalign)
 396         {
 397                 // first nudge it off the floor a little bit to avoid math errors
 398                 setorigin(self, self.origin + '0 0 1');
 399                 // note droptofloor returns FALSE if stuck/or would fall too far
 400                 droptofloor();
 401         }
 402
 403         if (cvar("g_fullbrightitems"))
 404                 self.effects = self.effects | EF_FULLBRIGHT;
 405 }
 406
 407 /* replace items in minstagib
 408  * IT_STRENGTH   = invisibility
 409  * IT_NAILS      = extra lives
 410  * IT_INVINCIBLE = speed
 411  */
 412 void minstagib_items (float itemid)
 413 {
 414         // we don't want to replace dropped weapons ;)
 415         if (self.classname == "droppedweapon")
 416         {
 417                 self.ammo_cells = 25;
 418                 StartItem ("models/weapons/g_nex.md3",
 419                         "weapons/weaponpickup.ogg", 15,
 420                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 421                 return;
 422         }
 423
 424         local float rnd;
 425         self.classname = "minstagib";
 426
 427         // replace rocket launchers and nex guns with ammo cells
 428         if (itemid == IT_CELLS)
 429         {
 430                 self.ammo_cells = 1;
 431                 StartItem ("models/items/a_cells.md3",
 432                         "misc/itempickup.ogg", 45,
 433                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
 434                 return;
 435         }
 436
 437         // randomize
 438         rnd = random() * 3;
 439         if (rnd <= 1)
 440                 itemid = IT_STRENGTH;
 441         else if (rnd <= 2)
 442                 itemid = IT_NAILS;
 443         else
 444                 itemid = IT_INVINCIBLE;
 445
 446         // replace with invis
 447         if (itemid == IT_STRENGTH)
 448         {
 449                 self.effects = EF_ADDITIVE;
 450                 self.strength_finished = 30;
 451                 StartItem ("models/items/g_strength.md3",
 452                         "misc/powerup.ogg", 120,
 453                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
 454         }
 455         // replace with extra lives
 456         if (itemid == IT_NAILS)
 457         {
 458                 self.max_health = 1;
 459                 StartItem ("models/items/g_h100.md3",
 460                         "misc/megahealth.ogg", 120,
 461                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
 462
 463         }
 464         // replace with speed
 465         if (itemid == IT_INVINCIBLE)
 466         {
 467                 self.effects = EF_ADDITIVE;
 468                 self.invincible_finished = 30;
 469                 StartItem ("models/items/g_invincible.md3",
 470                         "misc/powerup_shield.ogg", 120,
 471                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
 472         }
 473
 474 }
 475
 476 void weapon_uzi (void) {
 477         if(!self.ammo_nails)
 478                 self.ammo_nails = cvar("g_pickup_nails");
 479         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 1000);
 480 }
 481
 482 void weapon_shotgun (void) {
 483         if(!self.ammo_shells)
 484                 self.ammo_shells = cvar("g_pickup_shells");
 485         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 1000);
 486 }
 487
 488 void weapon_grenadelauncher (void) {
 489         if(!self.ammo_rockets)
 490                 self.ammo_rockets = cvar("g_pickup_rockets");
 491         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 492 }
 493
 494 void weapon_electro (void) {
 495         if(!self.ammo_cells)
 496                 self.ammo_cells = cvar("g_pickup_cells");
 497         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 1000);
 498 }
 499
 500 void weapon_crylink (void) {
 501         if(!self.ammo_cells)
 502                 self.ammo_cells = cvar("g_pickup_cells");
 503         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 1000);
 504 }
 505
 506 void weapon_nex (void) {
 507         if (cvar("g_minstagib")) {
 508                 minstagib_items(IT_CELLS);
 509         } else {
 510                 float nextime;
 511                 if(!self.ammo_cells)
 512                         self.ammo_cells = cvar("g_pickup_cells");
 513                 nextime = cvar("g_balance_nex_respawntime_modifier");
 514                 if(nextime)
 515                         nextime = 15 * nextime;
 516                 else
 517                         nextime = 15;
 518                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", nextime, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 1000);
 519         }
 520 }
 521
 522 void weapon_hagar (void) {
 523         if(!self.ammo_rockets)
 524                 self.ammo_rockets = cvar("g_pickup_rockets");
 525         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 1000);
 526 }
 527
 528 void weapon_rocketlauncher (void) {
 529         if (cvar("g_minstagib")) {
 530                 minstagib_items(IT_CELLS);
 531         } else {
 532                 if(!self.ammo_rockets)
 533                         self.ammo_rockets = g_pickup_rockets;
 534                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 535         }
 536 }
 537
 538 void item_rockets (void) {
 539         if(!self.ammo_rockets)
 540                 self.ammo_rockets = g_pickup_rockets;
 541         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 100);
 542 }
 543
 544 void item_bullets (void) {
 545         if(!self.ammo_nails)
 546                 self.ammo_nails = g_pickup_nails;
 547         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 100);
 548 }
 549
 550 void item_cells (void) {
 551         if(!self.ammo_cells)
 552                 self.ammo_cells = g_pickup_cells;
 553         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 100);
 554 }
 555
 556 void item_shells (void) {
 557         if(!self.ammo_shells)
 558                 self.ammo_shells = g_pickup_shells;
 559         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 100);
 560 }
 561
 562 void item_armor1 (void) {
 563         if(!self.armorvalue)
 564                 self.armorvalue = g_pickup_armorshard;
 565         if(!self.max_armorvalue)
 566                 self.max_armorvalue = g_pickup_armorshard_max;
 567         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 100);
 568 }
 569
 570 void item_armor25 (void) {
 571         if(!self.armorvalue)
 572                 self.armorvalue = g_pickup_armor;
 573         if(!self.max_armorvalue)
 574                 self.max_armorvalue = g_pickup_armor_max;
 575         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 2000);
 576 }
 577
 578 void item_health1 (void) {
 579         if(!self.max_health)
 580                 self.max_health = g_pickup_healthshard_max;
 581         if(!self.health)
 582                 self.health = g_pickup_healthshard;
 583         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 100);
 584 }
 585
 586 void item_health25 (void) {
 587         if(!self.max_health)
 588                 self.max_health = g_pickup_health_max;
 589         if(!self.health)
 590                 self.health = g_pickup_health;
 591         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 500);
 592 }
 593
 594 void item_health100 (void) {
 595         if(!cvar("g_powerup_superhealth"))
 596                 return;
 597
 598         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 599                 return;
 600
 601         if(cvar("g_minstagib")) {
 602                 minstagib_items(IT_NAILS);
 603         } else {
 604                 if(!self.max_health)
 605                         self.max_health = g_pickup_healthmega_max;
 606                 if(!self.health)
 607                         self.health = g_pickup_healthmega;
 608                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 2000);
 609         }
 610 }
 611
 612 void item_strength (void) {
 613         if(!cvar("g_powerup_strength"))
 614                 return;
 615
 616         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 617                 return;
 618
 619         if(cvar("g_minstagib")) {
 620                 minstagib_items(IT_STRENGTH);
 621         } else {
 622                 self.strength_finished = 30;
 623                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 10000);
 624         }
 625 }
 626
 627 void item_invincible (void) {
 628         if(!cvar("g_powerup_shield"))
 629                 return;
 630
 631         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 632                 return;
 633
 634         if(cvar("g_minstagib")) {
 635                 minstagib_items(IT_INVINCIBLE);
 636         } else {
 637                 self.invincible_finished = 30;
 638                 self.effects = EF_ADDITIVE;
 639                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 10000);
 640         }
 641 }
 642 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
 643 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
 644
 645 // compatibility:
 646 void item_quad (void) {self.classname = "item_strength";item_strength();}
 647
 648 void misc_models (void)
 649 {
 650         precache_model (self.model);
 651         setmodel (self, self.model); // precision set by mapper
 652         setsize (self, self.mins, self.maxs);
 653 }
 654
 655
 656
 657
 658
 659 floatfield Item_CounterField(float it)
 660 {
 661         switch(it)
 662         {
 663                 case IT_SHELLS:      return ammo_shells;
 664                 case IT_NAILS:       return ammo_nails;
 665                 case IT_ROCKETS:     return ammo_rockets;
 666                 case IT_CELLS:       return ammo_cells;
 667                 case IT_5HP:         return health;
 668                 case IT_25HP:        return health;
 669                 case IT_HEALTH:      return health;
 670                 case IT_ARMOR_SHARD: return armorvalue;
 671                 case IT_ARMOR:       return armorvalue;
 672                 // add more things here (health, armor)
 673                 default:             error("requested item has no counter field");
 674         }
 675 }
 676
 677 float Item_WeaponCode(float it)
 678 {
 679         switch(it)
 680         {
 681                 case IT_LASER:            return WEP_LASER;
 682                 case IT_SHOTGUN:          return WEP_SHOTGUN;
 683                 case IT_UZI:              return WEP_UZI;
 684                 case IT_GRENADE_LAUNCHER: return WEP_GRENADE_LAUNCHER;
 685                 case IT_ELECTRO:          return WEP_ELECTRO;
 686                 case IT_CRYLINK:          return WEP_CRYLINK;
 687                 case IT_NEX:              return WEP_NEX;
 688                 case IT_HAGAR:            return WEP_HAGAR;
 689                 case IT_ROCKET_LAUNCHER:  return WEP_ROCKET_LAUNCHER;
 690                 default:                  return 0;
 691         }
 692 }
 693
 694 void Item_SpawnByItemCode(float it)
 695 {
 696         switch(it)
 697         {
 698                 case IT_SHOTGUN:          weapon_shotgun(); break;
 699                 case IT_UZI:              weapon_uzi(); break;
 700                 case IT_GRENADE_LAUNCHER: weapon_grenadelauncher(); break;
 701                 case IT_ELECTRO:          weapon_electro(); break;
 702                 case IT_CRYLINK:          weapon_crylink(); break;
 703                 case IT_NEX:              weapon_nex(); break;
 704                 case IT_HAGAR:            weapon_hagar(); break;
 705                 case IT_ROCKET_LAUNCHER:  weapon_rocketlauncher(); break;
 706                 // add all other item spawn functions here
 707                 default:
 708                         error("requested item can't be spawned");
 709         }
 710 }