data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43
  44 void Item_Respawn (void)
  45 {
  46         self.model = self.mdl;          // restore original model
  47         self.solid = SOLID_TRIGGER;     // allow it to be touched again
  48         if(!g_minstagib && self.items == IT_STRENGTH)
  49                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
  50         else if(!g_minstagib && self.items == IT_INVINCIBLE)
  51                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
  52         else
  53                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
  54         setorigin (self, self.origin);
  55
  56         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
  57         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
  58 }
  59
  60 void Item_RespawnCountdown (void)
  61 {
  62         if(self.count >= ITEM_RESPAWN_TICKS)
  63         {
  64                 if(self.waypointsprite_attached)
  65                         WaypointSprite_Kill(self.waypointsprite_attached);
  66                 Item_Respawn();
  67         }
  68         else
  69         {
  70                 self.nextthink = time + 1;
  71                 self.count += 1;
  72                 if(self.count == 1)
  73                 {
  74                         string name;
  75                         vector rgb;
  76                         name = string_null;
  77                         if(g_minstagib)
  78                         {
  79                                 switch(self.items)
  80                                 {
  81                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
  82                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
  83                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
  84                                 }
  85                         }
  86                         else
  87                         {
  88                                 switch(self.items)
  89                                 {
  90                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
  91                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
  92                                 }
  93                         }
  94                         switch(self.items)
  95                         {
  96                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
  97                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
  98                         }
  99                         if(name)
 100                         {
 101                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, FALSE);
 102                                 if(self.waypointsprite_attached)
 103                                 {
 104                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 105                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 106                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 107                                 }
 108                         }
 109                 }
 110                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 111                 if(self.waypointsprite_attached)
 112                 {
 113                         WaypointSprite_Ping(self.waypointsprite_attached);
 114                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 115                 }
 116         }
 117 }
 118
 119 void Item_ScheduleRespawnIn(entity e, float t)
 120 {
 121         if(e.flags & FL_POWERUP)
 122         {
 123                 e.think = Item_RespawnCountdown;
 124                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 125                 e.count = 0;
 126         }
 127         else
 128         {
 129                 e.think = Item_Respawn;
 130                 e.nextthink = time + t;
 131         }
 132 }
 133
 134 void Item_ScheduleRespawn(entity e)
 135 {
 136         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 137 }
 138
 139 void Item_ScheduleInitialRespawn(entity e)
 140 {
 141         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 142 }
 143
 144 float Item_GiveTo(entity item, entity player)
 145 {
 146         float _switchweapon;
 147         float pickedup;
 148         float it;
 149         float i;
 150         entity e;
 151
 152         // if nothing happens to player, just return without taking the item
 153         pickedup = FALSE;
 154         _switchweapon = FALSE;
 155
 156         if (g_minstagib)
 157         {
 158                 if (item.ammo_fuel)
 159                 if (player.ammo_fuel < g_pickup_fuel_max)
 160                 {
 161                         pickedup = TRUE;
 162                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 163                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 164                 }
 165                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 166                 {
 167                         pickedup = TRUE;
 168                         player.items |= it;
 169                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 170                 }
 171
 172                 _switchweapon = TRUE;
 173                 if (item.ammo_cells)
 174                 {
 175                         pickedup = TRUE;
 176                         // play some cool sounds ;)
 177                         centerprint(player, "\n");
 178                         if(player.health <= 5)
 179                                 announce(player, "announcer/robotic/lastsecond.wav");
 180                         else if(player.health < 50)
 181                                 announce(player, "announcer/robotic/narrowly.wav");
 182                         // sound not available
 183                         // else if(item.items == IT_CELLS)
 184                         //      play2(player, "announce/robotic/ammo.wav");
 185
 186                         if (item.weapons & WEPBIT_MINSTANEX)
 187                                 W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 188                         if (item.ammo_cells)
 189                                 player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 190                         player.health = 100;
 191                 }
 192
 193                 // extralife powerup
 194                 if (item.max_health)
 195                 {
 196                         pickedup = TRUE;
 197                         // sound not available
 198                         // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.wav");
 199                         player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 200                         sprint(player, "^3You picked up some extra lives\n");
 201                 }
 202
 203                 // invis powerup
 204                 if (item.strength_finished)
 205                 {
 206                         pickedup = TRUE;
 207                         // sound not available
 208                         // play2(player, "announce/robotic/invisible.wav");
 209                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 210                 }
 211
 212                 // speed powerup
 213                 if (item.invincible_finished)
 214                 {
 215                         pickedup = TRUE;
 216                         // sound not available
 217                         // play2(player, "announce/robotic/speed.wav");
 218                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 219                 }
 220
 221                 if (item.ammo_fuel)
 222                 if (player.ammo_fuel < g_pickup_fuel_max)
 223                 {
 224                         pickedup = TRUE;
 225                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 226                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 227                 }
 228
 229         }
 230         else
 231         {
 232                 if (g_weapon_stay == 1)
 233                 if not(item.flags & FL_NO_WEAPON_STAY)
 234                 if (item.flags & FL_WEAPON)
 235                 {
 236                         if(item.classname == "droppedweapon")
 237                         {
 238                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 239                                         goto skip;
 240                         }
 241                         else
 242                         {
 243                                 if (player.weapons & item.weapons)
 244                                         goto skip;
 245                         }
 246                 }
 247
 248                 // in case the player has autoswitch enabled do the following:
 249                 // if the player is using their best weapon before items are given, they
 250                 // probably want to switch to an even better weapon after items are given
 251                 if (player.autoswitch)
 252                 if (player.switchweapon == w_getbestweapon(player))
 253                         _switchweapon = TRUE;
 254
 255                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 256                         _switchweapon = TRUE;
 257
 258                 if (item.ammo_shells)
 259                 if (player.ammo_shells < g_pickup_shells_max)
 260                 {
 261                         pickedup = TRUE;
 262                         player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 263                 }
 264                 if (item.ammo_nails)
 265                 if (player.ammo_nails < g_pickup_nails_max)
 266                 {
 267                         pickedup = TRUE;
 268                         player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 269                 }
 270                 if (item.ammo_rockets)
 271                 if (player.ammo_rockets < g_pickup_rockets_max)
 272                 {
 273                         pickedup = TRUE;
 274                         player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 275                 }
 276                 if (item.ammo_cells)
 277                 if (player.ammo_cells < g_pickup_cells_max)
 278                 {
 279                         pickedup = TRUE;
 280                         player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 281                 }
 282                 if (item.ammo_fuel)
 283                 if (player.ammo_fuel < g_pickup_fuel_max)
 284                 {
 285                         pickedup = TRUE;
 286                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 287                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 288                 }
 289
 290                 if (item.flags & FL_WEAPON)
 291                 if ((it = item.weapons - (item.weapons & player.weapons)))
 292                 {
 293                         pickedup = TRUE;
 294                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 295                         {
 296                                 e = get_weaponinfo(i);
 297                                 if(it & e.weapons)
 298                                         W_GiveWeapon (player, e.weapon, item.netname);
 299                         }
 300                 }
 301
 302                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 303                 {
 304                         pickedup = TRUE;
 305                         player.items |= it;
 306                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 307                 }
 308
 309                 if (item.strength_finished)
 310                 {
 311                         pickedup = TRUE;
 312                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 313                 }
 314                 if (item.invincible_finished)
 315                 {
 316                         pickedup = TRUE;
 317                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 318                 }
 319                 //if (item.speed_finished)
 320                 //{
 321                 //      pickedup = TRUE;
 322                 //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 323                 //}
 324                 //if (item.slowmo_finished)
 325                 //{
 326                 //      pickedup = TRUE;
 327                 //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 328                 //}
 329
 330                 if (item.health)
 331                 if (player.health < item.max_health)
 332                 {
 333                         pickedup = TRUE;
 334                         player.health = min(player.health + item.health, item.max_health);
 335                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 336                 }
 337                 if (item.armorvalue)
 338                 if (player.armorvalue < item.max_armorvalue)
 339                 {
 340                         pickedup = TRUE;
 341                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 342                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 343                 }
 344         }
 345
 346 :skip
 347         // always eat teamed entities
 348         if(item.team)
 349                 pickedup = TRUE;
 350
 351         if (!pickedup)
 352                 return 0;
 353
 354         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 355         if (_switchweapon)
 356                 if (player.switchweapon != w_getbestweapon(player))
 357                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 358
 359         return 1;
 360 }
 361
 362 void Item_Touch (void)
 363 {
 364         entity e, head;
 365
 366         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 367         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 368         {
 369                 remove(self);
 370                 return;
 371         }
 372         if (other.classname != "player")
 373                 return;
 374         if (other.deadflag)
 375                 return;
 376         if (self.solid != SOLID_TRIGGER)
 377                 return;
 378         if (self.owner == other)
 379                 return;
 380
 381         if(!Item_GiveTo(self, other))
 382                 return;
 383
 384         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 385
 386         if (self.classname == "droppedweapon")
 387                 remove (self);
 388         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 389                 return;
 390         else
 391         {
 392                 self.solid = SOLID_NOT;
 393                 self.model = string_null;
 394                 if(self.team)
 395                 {
 396                         RandomSelection_Init();
 397                         for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 398                                 RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 399                         e = RandomSelection_chosen_ent;
 400                 }
 401                 else
 402                         e = self;
 403                 Item_ScheduleRespawn(e);
 404         }
 405 }
 406
 407 void Item_FindTeam()
 408 {
 409         entity head, e;
 410
 411         if(self.effects & EF_NODRAW)
 412         {
 413                 // marker for item team search
 414                 dprint("Initializing item team ", ftos(self.team), "\n");
 415                 RandomSelection_Init();
 416                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 417                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 418                 e = RandomSelection_chosen_ent;
 419                 e.state = 0;
 420
 421                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 422                 {
 423                         if(head != e)
 424                         {
 425                                 // make it a non-spawned item
 426                                 head.solid = SOLID_NOT;
 427                                 head.model = string_null;
 428                                 head.state = 1; // state 1 = initially hidden item
 429                         }
 430                         head.effects &~= EF_NODRAW;
 431                 }
 432
 433                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 434                 {
 435                         e.solid = SOLID_NOT;
 436                         e.model = string_null;
 437                         Item_ScheduleInitialRespawn(e);
 438                 }
 439         }
 440 }
 441
 442 void Item_Reset()
 443 {
 444         if(self.state == 1)
 445         {
 446                 self.model = string_null;
 447                 self.solid = SOLID_NOT;
 448         }
 449         else
 450         {
 451                 self.model = self.mdl;
 452                 self.solid = SOLID_TRIGGER;
 453         }
 454         setorigin (self, self.origin);
 455         self.think = SUB_Null;
 456         self.nextthink = 0;
 457
 458         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 459         {
 460                 self.solid = SOLID_NOT;
 461                 self.model = string_null;
 462                 Item_ScheduleInitialRespawn(self);
 463         }
 464 }
 465
 466 // Savage: used for item garbage-collection
 467 // TODO: perhaps nice special effect?
 468 void RemoveItem(void)
 469 {
 470         remove(self);
 471 }
 472
 473 // pickup evaluation functions
 474 // these functions decide how desirable an item is to the bots
 475
 476 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 477
 478 float weapon_pickupevalfunc(entity player, entity item)
 479 {
 480         float c, i, j, position;
 481
 482         // See if I have it already
 483         if(player.weapons & item.weapons == item.weapons)
 484         {
 485                 // If I can pick it up
 486                 if(g_weapon_stay == 1)
 487                         c = 0;
 488                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 489                 {
 490                         // Skilled bots will grab more
 491                         c = bound(0, skill / 10, 1) * 0.5;
 492                 }
 493                 else
 494                         c = 0;
 495         }
 496         else
 497                 c = 1;
 498
 499         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 500         if( bot_custom_weapon && c )
 501         {
 502                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 503                 {
 504                         // Find weapon
 505                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 506                                 continue;
 507
 508                         // Find the highest position on any range
 509                         position = -1;
 510                         for(j = 0; j < WEP_LAST ; ++j){
 511                                 if(
 512                                                 bot_weapons_far[j] == i ||
 513                                                 bot_weapons_mid[j] == i ||
 514                                                 bot_weapons_close[j] == i
 515                                   )
 516                                 {
 517                                         position = j;
 518                                         break;
 519                                 }
 520                         }
 521
 522                         // Rate it
 523                         if (position >= 0 )
 524                         {
 525                                 position = WEP_LAST - position;
 526                                 // item.bot_pickupbasevalue is overwritten here
 527                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 528                                 break;
 529                         }
 530                 }
 531         }
 532
 533         return item.bot_pickupbasevalue * c;
 534 };
 535
 536 float commodity_pickupevalfunc(entity player, entity item)
 537 {
 538         float c, i, need_shells, need_nails, need_rockets, need_cells;
 539         entity wi;
 540         c = 0;
 541
 542         // Detect needed ammo
 543         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 544         {
 545                 wi = get_weaponinfo(i);
 546
 547                 if not(wi.weapons & player.weapons)
 548                         continue;
 549
 550                 if(wi.items & IT_SHELLS)
 551                         need_shells = TRUE;
 552                 else if(wi.items & IT_NAILS)
 553                         need_nails = TRUE;
 554                 else if(wi.items & IT_ROCKETS)
 555                         need_rockets = TRUE;
 556                 else if(wi.items & IT_CELLS)
 557                         need_cells = TRUE;
 558         }
 559
 560         // TODO: figure out if the player even has the weapon this ammo is for?
 561         // may not affect strategy much though...
 562         // find out how much more ammo/armor/health the player can hold
 563         if (need_shells)
 564         if (item.ammo_shells)
 565         if (player.ammo_shells < g_pickup_shells_max)
 566                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 567         if (need_nails)
 568         if (item.ammo_nails)
 569         if (player.ammo_nails < g_pickup_nails_max)
 570                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 571         if (need_rockets)
 572         if (item.ammo_rockets)
 573         if (player.ammo_rockets < g_pickup_rockets_max)
 574                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 575         if (need_cells)
 576         if (item.ammo_cells)
 577         if (player.ammo_cells < g_pickup_cells_max)
 578                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 579         if (item.armorvalue)
 580         if (player.armorvalue < item.max_armorvalue*0.5)
 581                 c = c + max(0, 1 - player.armorvalue / (item.max_armorvalue*0.5));
 582         if (item.health)
 583         if (player.health < item.max_health*0.5)
 584                 c = c + max(0, 1 - player.health / (item.max_health*0.5));
 585
 586         return item.bot_pickupbasevalue * c;
 587 };
 588
 589
 590 .float is_item;
 591 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 592 {
 593         startitem_failed = FALSE;
 594
 595         // is it a dropped weapon?
 596         if (self.classname == "droppedweapon")
 597         {
 598                 self.reset = SUB_Remove;
 599                 // it's a dropped weapon
 600                 self.movetype = MOVETYPE_TOSS;
 601                 self.solid = SOLID_TRIGGER;
 602                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 603                 self.think = RemoveItem;
 604                 self.nextthink = time + 60;
 605                 // don't drop if in a NODROP zone (such as lava)
 606                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 607                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 608                 {
 609                         startitem_failed = TRUE;
 610                         remove(self);
 611                         return;
 612                 }
 613         }
 614         else
 615         {
 616                 self.reset = Item_Reset;
 617                 // it's a level item
 618                 if(self.spawnflags & 1)
 619                         self.noalign = 1;
 620                 if (self.noalign)
 621                         self.movetype = MOVETYPE_NONE;
 622                 else
 623                         self.movetype = MOVETYPE_TOSS;
 624                 self.solid = SOLID_TRIGGER;
 625                 // do item filtering according to game mode and other things
 626                 if (!self.noalign)
 627                 {
 628                         // first nudge it off the floor a little bit to avoid math errors
 629                         setorigin(self, self.origin + '0 0 1');
 630                         // set item size before we spawn a spawnfunc_waypoint
 631                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 632                                 setsize (self, '-16 -16 0', '16 16 48');
 633                         else
 634                                 setsize (self, '-16 -16 0', '16 16 32');
 635                         // note droptofloor returns FALSE if stuck/or would fall too far
 636                         droptofloor();
 637                         waypoint_spawnforitem(self);
 638                 }
 639
 640                 if(teams_matter)
 641                 {
 642                         if(self.notteam)
 643                         {
 644                                 print("removed non-teamplay ", self.classname, "\n");
 645                                 startitem_failed = TRUE;
 646                                 remove (self);
 647                                 return;
 648                         }
 649                 }
 650                 else
 651                 {
 652                         if(self.notfree)
 653                         {
 654                                 print("removed non-FFA ", self.classname, "\n");
 655                                 startitem_failed = TRUE;
 656                                 remove (self);
 657                                 return;
 658                         }
 659                 }
 660
 661                 if(self.notq3a)
 662                 {
 663                         // We aren't TA or something like that, so we keep the Q3A entities
 664                         print("removed non-Q3A ", self.classname, "\n");
 665                         startitem_failed = TRUE;
 666                         remove (self);
 667                         return;
 668                 }
 669
 670                 /*
 671                  * can't do it that way, as it would break maps
 672                  * TODO make a target_give like entity another way, that perhaps has
 673                  * the weapon name in a key
 674                 if(self.targetname)
 675                 {
 676                         // target_give not yet supported; maybe later
 677                         print("removed targeted ", self.classname, "\n");
 678                         startitem_failed = TRUE;
 679                         remove (self);
 680                         return;
 681                 }
 682                 */
 683
 684                 if(cvar("spawn_debug") >= 2)
 685                 {
 686                         entity otheritem;
 687                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 688                         {
 689                                 if(otheritem.is_item)
 690                                 {
 691                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 692                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 693                                         error("Mapper sucks.");
 694                                 }
 695                         }
 696                         self.is_item = TRUE;
 697                 }
 698
 699                 weaponsInMap |= weaponid;
 700
 701                 if(g_lms)
 702                 {
 703                         startitem_failed = TRUE;
 704                         remove(self);
 705                         return;
 706                 }
 707                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 708                 {
 709                         startitem_failed = TRUE;
 710                         remove(self);
 711                         return;
 712                 }
 713                 else if (g_minstagib)
 714                 {
 715                         // don't remove dropped items and powerups
 716                         if (self.classname != "minstagib")
 717                         {
 718                                 startitem_failed = TRUE;
 719                                 remove (self);
 720                                 return;
 721                         }
 722                 }
 723                 else if (g_nixnex)
 724                 {
 725                         local float rm;
 726
 727                         rm = 1;
 728                         switch (itemid)
 729                         {
 730                                 case IT_HEALTH:
 731                                 case IT_5HP:
 732                                 case IT_25HP:
 733                                 case IT_ARMOR:
 734                                 case IT_ARMOR_SHARD:
 735                                         if (cvar("g_nixnex_with_healtharmor"))
 736                                                 rm = 0;
 737                                         break;
 738                                 case IT_STRENGTH:
 739                                 case IT_INVINCIBLE:
 740                                         if (cvar("g_nixnex_with_powerups"))
 741                                                 rm = 0;
 742                                         break;
 743                         }
 744
 745                         if(rm)
 746                         {
 747                                 startitem_failed = TRUE;
 748                                 remove (self);
 749                                 return;
 750                         }
 751                 }
 752                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 753                 {
 754                         startitem_failed = TRUE;
 755                         remove (self);
 756                         return;
 757                 }
 758
 759                 precache_model (itemmodel);
 760                 precache_sound (pickupsound);
 761                 precache_sound ("misc/itemrespawn.wav");
 762                 precache_sound ("misc/itemrespawncountdown.wav");
 763
 764                 if(itemid == IT_STRENGTH)
 765                         precache_sound ("misc/strength_respawn.wav");
 766                 if(itemid == IT_INVINCIBLE)
 767                         precache_sound ("misc/shield_respawn.wav");
 768
 769                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 770                         self.target = "###item###"; // for finding the nearest item using find()
 771         }
 772
 773         self.bot_pickup = TRUE;
 774         self.bot_pickupevalfunc = pickupevalfunc;
 775         self.bot_pickupbasevalue = pickupbasevalue;
 776         self.mdl = itemmodel;
 777         self.item_pickupsound = pickupsound;
 778         // let mappers override respawntime
 779         if(!self.respawntime) // both set
 780         {
 781                 self.respawntime = defaultrespawntime;
 782                 self.respawntimejitter = defaultrespawntimejitter;
 783         }
 784         self.netname = itemname;
 785         self.items = itemid;
 786         self.weapons = weaponid;
 787         self.flags = FL_ITEM | itemflags;
 788         self.touch = Item_Touch;
 789         setmodel (self, self.mdl); // precision set below
 790         self.effects |= EF_LOWPRECISION;
 791         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 792                 setsize (self, '-16 -16 0', '16 16 48');
 793         else
 794                 setsize (self, '-16 -16 0', '16 16 32');
 795         if(itemflags & FL_WEAPON)
 796                 self.modelflags |= MF_ROTATE;
 797
 798         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 799         if (itemflags & FL_WEAPON)
 800         {
 801                 // neutral team color for pickup weapons
 802                 self.colormap = 1024; // color shirt=0 pants=0 grey
 803         }
 804
 805         if (cvar("g_fullbrightitems"))
 806                 self.effects = self.effects | EF_FULLBRIGHT;
 807
 808         self.state = 0;
 809         if(self.team)
 810         {
 811                 if(!self.cnt)
 812                         self.cnt = 1; // item probability weight
 813                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 814                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 815         }
 816         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 817         {
 818                 self.solid = SOLID_NOT;
 819                 self.model = string_null;
 820                 Item_ScheduleInitialRespawn(self);
 821         }
 822 }
 823
 824 /* replace items in minstagib
 825  * IT_STRENGTH   = invisibility
 826  * IT_NAILS      = extra lives
 827  * IT_INVINCIBLE = speed
 828  */
 829 void minstagib_items (float itemid)
 830 {
 831         // we don't want to replace dropped weapons ;)
 832         if (self.classname == "droppedweapon")
 833         {
 834                 self.ammo_cells = 25;
 835                 StartItem ("models/weapons/g_nex.md3",
 836                         "weapons/weaponpickup.wav", 15, 0,
 837                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 838                 return;
 839         }
 840
 841         local float rnd;
 842         self.classname = "minstagib";
 843
 844         // replace rocket launchers and nex guns with ammo cells
 845         if (itemid == IT_CELLS)
 846         {
 847                 self.ammo_cells = 1;
 848                 StartItem ("models/items/a_cells.md3",
 849                         "misc/itempickup.wav", 45, 0,
 850                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 851                 return;
 852         }
 853
 854         // randomize
 855         rnd = random() * 3;
 856         if (rnd <= 1)
 857                 itemid = IT_STRENGTH;
 858         else if (rnd <= 2)
 859                 itemid = IT_NAILS;
 860         else
 861                 itemid = IT_INVINCIBLE;
 862
 863         // replace with invis
 864         if (itemid == IT_STRENGTH)
 865         {
 866                 self.effects = EF_ADDITIVE;
 867                 self.strength_finished = 30;
 868                 StartItem ("models/items/g_strength.md3",
 869                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 870                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 871         }
 872         // replace with extra lives
 873         if (itemid == IT_NAILS)
 874         {
 875                 self.max_health = 1;
 876                 StartItem ("models/items/g_h100.md3",
 877                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 878                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 879
 880         }
 881         // replace with speed
 882         if (itemid == IT_INVINCIBLE)
 883         {
 884                 self.effects = EF_ADDITIVE;
 885                 self.invincible_finished = 30;
 886                 StartItem ("models/items/g_invincible.md3",
 887                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 888                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 889         }
 890
 891 }
 892
 893 float minst_no_auto_cells;
 894 void minst_remove_item (void) {
 895         if(minst_no_auto_cells)
 896                 remove(self);
 897 }
 898
 899 float weaponswapping;
 900 float internalteam;
 901
 902 void weapon_defaultspawnfunc(float wpn)
 903 {
 904         entity e;
 905         float t;
 906         var .float ammofield;
 907         string s;
 908         entity oldself;
 909         float i, j;
 910
 911         // set the respawntime in advance (so replaced weapons can copy it)
 912
 913         if(!self.respawntime)
 914         {
 915                 e = get_weaponinfo(wpn);
 916                 if(e.items == IT_SUPERWEAPON)
 917                 {
 918                         self.respawntime = g_pickup_respawntime_powerup;
 919                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 920                 }
 921                 else
 922                 {
 923                         self.respawntime = g_pickup_respawntime_weapon;
 924                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 925                 }
 926         }
 927
 928         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 929         {
 930                 e = get_weaponinfo(wpn);
 931                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 932                 if(s == "0")
 933                 {
 934                         remove(self);
 935                         startitem_failed = TRUE;
 936                         return;
 937                 }
 938                 t = tokenize_console(s);
 939                 if(t >= 2)
 940                 {
 941                         self.team = --internalteam;
 942                         oldself = self;
 943                         for(i = 1; i < t; ++i)
 944                         {
 945                                 s = argv(i);
 946                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 947                                 {
 948                                         e = get_weaponinfo(j);
 949                                         if(e.netname == s)
 950                                         {
 951                                                 self = spawn();
 952                                                 copyentity(oldself, self);
 953                                                 self.classname = "replacedweapon";
 954                                                 weapon_defaultspawnfunc(j);
 955                                                 break;
 956                                         }
 957                                 }
 958                                 if(j > WEP_LAST)
 959                                 {
 960                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 961                                 }
 962                         }
 963                         self = oldself;
 964                 }
 965                 if(t >= 1)
 966                 {
 967                         s = argv(0);
 968                         wpn = 0;
 969                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 970                         {
 971                                 e = get_weaponinfo(j);
 972                                 if(e.netname == s)
 973                                 {
 974                                         wpn = j;
 975                                         break;
 976                                 }
 977                         }
 978                         if(j > WEP_LAST)
 979                         {
 980                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 981                         }
 982                 }
 983                 if(wpn == 0)
 984                 {
 985                         remove(self);
 986                         startitem_failed = TRUE;
 987                         return;
 988                 }
 989         }
 990
 991         e = get_weaponinfo(wpn);
 992
 993         if(e.items && e.items != IT_SUPERWEAPON)
 994         {
 995                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
 996                 {
 997                         if(e.items & j)
 998                         {
 999                                 ammofield = Item_CounterField(j);
1000                                 if(!self.ammofield)
1001                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1002                         }
1003                 }
1004         }
1005         else
1006         {
1007                 self.flags |= FL_NO_WEAPON_STAY;
1008         }
1009
1010         // weapon stay isn't supported for teamed weapons
1011         if(self.team)
1012                 self.flags |= FL_NO_WEAPON_STAY;
1013
1014         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1015         {
1016                 self.ammo_shells = 0;
1017                 self.ammo_nails = 0;
1018                 self.ammo_cells = 0;
1019                 self.ammo_rockets = 0;
1020                 // weapon stay 2: don't use ammo on weapon pickups; instead
1021                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1022         }
1023
1024         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1025         if (self.modelindex) // don't precache if self was removed
1026                 weapon_action(e.weapon, WR_PRECACHE);
1027 }
1028
1029 void spawnfunc_weapon_shotgun (void);
1030 void spawnfunc_weapon_uzi (void) {
1031         if(q3acompat_machineshotgunswap)
1032         if(self.classname != "droppedweapon")
1033         {
1034                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1035                 return;
1036         }
1037         weapon_defaultspawnfunc(WEP_UZI);
1038 }
1039
1040 void spawnfunc_weapon_shotgun (void) {
1041         if(q3acompat_machineshotgunswap)
1042         if(self.classname != "droppedweapon")
1043         {
1044                 weapon_defaultspawnfunc(WEP_UZI);
1045                 return;
1046         }
1047         weapon_defaultspawnfunc(WEP_SHOTGUN);
1048 }
1049
1050 void spawnfunc_weapon_nex (void)
1051 {
1052         if (g_minstagib)
1053         {
1054                 minstagib_items(IT_CELLS);
1055                 self.think = minst_remove_item;
1056                 self.nextthink = time;
1057                 return;
1058         }
1059         weapon_defaultspawnfunc(WEP_NEX);
1060 }
1061
1062 void spawnfunc_weapon_minstanex (void)
1063 {
1064         if (g_minstagib)
1065         {
1066                 minstagib_items(IT_CELLS);
1067                 self.think = minst_remove_item;
1068                 self.nextthink = time;
1069                 return;
1070         }
1071         weapon_defaultspawnfunc(WEP_MINSTANEX);
1072 }
1073
1074 void spawnfunc_weapon_rocketlauncher (void)
1075 {
1076         if (g_minstagib)
1077         {
1078                 minstagib_items(IT_CELLS);
1079                 self.think = minst_remove_item;
1080                 self.nextthink = time;
1081                 return;
1082         }
1083         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1084 }
1085
1086 void spawnfunc_item_rockets (void) {
1087         if(!self.ammo_rockets)
1088                 self.ammo_rockets = g_pickup_rockets;
1089         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1090 }
1091
1092 void spawnfunc_item_shells (void);
1093 void spawnfunc_item_bullets (void) {
1094         if(!weaponswapping)
1095         if(q3acompat_machineshotgunswap)
1096         if(self.classname != "droppedweapon")
1097         {
1098                 weaponswapping = TRUE;
1099                 spawnfunc_item_shells();
1100                 weaponswapping = FALSE;
1101                 return;
1102         }
1103
1104         if(!self.ammo_nails)
1105                 self.ammo_nails = g_pickup_nails;
1106         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1107 }
1108
1109 void spawnfunc_item_cells (void) {
1110         if(!self.ammo_cells)
1111                 self.ammo_cells = g_pickup_cells;
1112         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1113 }
1114
1115 void spawnfunc_item_shells (void) {
1116         if(!weaponswapping)
1117         if(q3acompat_machineshotgunswap)
1118         if(self.classname != "droppedweapon")
1119         {
1120                 weaponswapping = TRUE;
1121                 spawnfunc_item_bullets();
1122                 weaponswapping = FALSE;
1123                 return;
1124         }
1125
1126         if(!self.ammo_shells)
1127                 self.ammo_shells = g_pickup_shells;
1128         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1129 }
1130
1131 void spawnfunc_item_armor_small (void) {
1132         if(!self.armorvalue)
1133                 self.armorvalue = g_pickup_armorsmall;
1134         if(!self.max_armorvalue)
1135                 self.max_armorvalue = g_pickup_armorsmall_max;
1136         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1137 }
1138
1139 void spawnfunc_item_armor_medium (void) {
1140         if(!self.armorvalue)
1141                 self.armorvalue = g_pickup_armormedium;
1142         if(!self.max_armorvalue)
1143                 self.max_armorvalue = g_pickup_armormedium_max;
1144         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1145 }
1146
1147 void spawnfunc_item_armor_big (void) {
1148         if(!self.armorvalue)
1149                 self.armorvalue = g_pickup_armorbig;
1150         if(!self.max_armorvalue)
1151                 self.max_armorvalue = g_pickup_armorbig_max;
1152         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1153 }
1154
1155 void spawnfunc_item_armor_large (void) {
1156         if(!self.armorvalue)
1157                 self.armorvalue = g_pickup_armorlarge;
1158         if(!self.max_armorvalue)
1159                 self.max_armorvalue = g_pickup_armorlarge_max;
1160         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1161 }
1162
1163 void spawnfunc_item_health_small (void) {
1164         if(!self.max_health)
1165                 self.max_health = g_pickup_healthsmall_max;
1166         if(!self.health)
1167                 self.health = g_pickup_healthsmall;
1168         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1169 }
1170
1171 void spawnfunc_item_health_medium (void) {
1172         if(!self.max_health)
1173                 self.max_health = g_pickup_healthmedium_max;
1174         if(!self.health)
1175                 self.health = g_pickup_healthmedium;
1176         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1177 }
1178
1179 void spawnfunc_item_health_large (void) {
1180         if(!self.max_health)
1181                 self.max_health = g_pickup_healthlarge_max;
1182         if(!self.health)
1183                 self.health = g_pickup_healthlarge;
1184         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1185 }
1186
1187 void spawnfunc_item_health_mega (void) {
1188         if(!cvar("g_powerup_superhealth"))
1189                 return;
1190
1191         if(g_arena && !cvar("g_arena_powerups"))
1192                 return;
1193
1194         if(g_minstagib) {
1195                 minstagib_items(IT_NAILS);
1196         } else {
1197                 if(!self.max_health)
1198                         self.max_health = g_pickup_healthmega_max;
1199                 if(!self.health)
1200                         self.health = g_pickup_healthmega;
1201                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1202         }
1203 }
1204
1205 // support old misnamed entities
1206 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1207 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1208 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1209 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1210 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1211
1212 void spawnfunc_item_strength (void) {
1213         if(!cvar("g_powerup_strength"))
1214                 return;
1215
1216         if(g_arena && !cvar("g_arena_powerups"))
1217                 return;
1218
1219         if(g_minstagib) {
1220                 minstagib_items(IT_STRENGTH);
1221         } else {
1222                 precache_sound("weapons/strength_fire.wav");
1223                 self.strength_finished = 30;
1224                 self.effects = EF_ADDITIVE;
1225                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1226         }
1227 }
1228
1229 void spawnfunc_item_invincible (void) {
1230         if(!cvar("g_powerup_shield"))
1231                 return;
1232
1233         if(g_arena && !cvar("g_arena_powerups"))
1234                 return;
1235
1236         if(g_minstagib) {
1237                 minstagib_items(IT_INVINCIBLE);
1238         } else {
1239                 self.invincible_finished = 30;
1240                 self.effects = EF_ADDITIVE;
1241                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1242         }
1243 }
1244
1245 void spawnfunc_item_minst_cells (void) {
1246         if (g_minstagib)
1247         {
1248                 minst_no_auto_cells = 1;
1249                 minstagib_items(IT_CELLS);
1250         }
1251         else
1252                 remove(self);
1253 }
1254
1255 // compatibility:
1256 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1257
1258 float target_item_func_set(float a, float b)
1259 {
1260         if(b == 0)
1261                 return a;
1262         else if(b < 0)
1263                 return 0;
1264         else
1265                 return b;
1266 }
1267
1268 float target_item_func_min(float a, float b)
1269 {
1270         if(b == 0)
1271                 return a;
1272         else if(b < 0)
1273                 return 0;
1274         else
1275                 return min(a, b);
1276 }
1277
1278 float target_item_func_max(float a, float b)
1279 {
1280         return max(a, b);
1281 }
1282
1283 float target_item_func_bitset(float a, float b)
1284 {
1285         return b;
1286 }
1287
1288 float target_item_func_and(float a, float b)
1289 {
1290         return a & b;
1291 }
1292
1293 float target_item_func_itembitset(float a, float b)
1294 {
1295         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | b;
1296 }
1297
1298 float target_item_func_itemand(float a, float b)
1299 {
1300         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
1301 }
1302
1303 float target_item_func_or(float a, float b)
1304 {
1305         return a | b;
1306 }
1307
1308 float target_item_func_andnot(float a, float b)
1309 {
1310         return a - (a & b);
1311 }
1312
1313 float target_item_changed;
1314 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
1315 {
1316         float n, d;
1317         n = func(activator.field, self.field);
1318
1319         if(binary)
1320         {
1321                 d = n & activator.field;
1322                 if(d != n) // bits added?
1323                         d = +1;
1324                 else if(d != activator.field) // bits removed?
1325                         d = -1;
1326                 else
1327                         d = 0;
1328         }
1329         else
1330                 d = n - activator.field;
1331
1332         if(d < 0)
1333         {
1334                 if(sound_decrease != "")
1335                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
1336                 target_item_changed = 1;
1337         }
1338         else if(d > 0)
1339         {
1340                 if(sound_increase != "")
1341                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
1342                 target_item_changed = 1;
1343         }
1344         activator.field = n;
1345 }
1346
1347 void target_items_use (void)
1348 {
1349         float h0, a0, f0;
1350
1351         if(activator.classname == "droppedweapon")
1352         {
1353                 EXACTTRIGGER_TOUCH;
1354                 remove(activator);
1355                 return;
1356         }
1357
1358         if(activator.classname != "player")
1359                 return;
1360         if(activator.deadflag != DEAD_NO)
1361                 return;
1362         EXACTTRIGGER_TOUCH;
1363
1364         entity e;
1365         for(e = world; (e = find(e, classname, "droppedweapon")); )
1366                 if(e.enemy == activator)
1367                         remove(e);
1368
1369         float _switchweapon;
1370         _switchweapon = FALSE;
1371         if (activator.autoswitch)
1372                 if (activator.switchweapon == w_getbestweapon(activator))
1373                         _switchweapon = TRUE;
1374
1375         a0 = activator.armorvalue;
1376         h0 = activator.health;
1377         f0 = activator.ammo_fuel;
1378         target_item_changed = 0;
1379
1380         if(self.spawnflags == 0) // SET
1381         {
1382                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1383                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1384                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1385                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1386                 target_item_change(0, ammo_fuel, target_item_func_set, "misc/itempickup.wav", "");
1387                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1388                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1389                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "misc/poweroff.wav");
1390                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1391
1392                 if((self.items & activator.items) & IT_STRENGTH)
1393                         activator.strength_finished = time + self.strength_finished;
1394                 if((self.items & activator.items) & IT_INVINCIBLE)
1395                         activator.invincible_finished = time + self.invincible_finished;
1396         }
1397         else if(self.spawnflags == 1) // AND/MIN
1398         {
1399                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1400                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1401                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1402                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1403                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1404                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1405                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1406                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "misc/poweroff.wav");
1407                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1408
1409                 if((self.items & activator.items) & IT_STRENGTH)
1410                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1411                 if((self.items & activator.items) & IT_INVINCIBLE)
1412                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1413         }
1414         else if(self.spawnflags == 2) // OR/MAX
1415         {
1416                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1417                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1418                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1419                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1420                 target_item_change(0, ammo_fuel, target_item_func_max, "misc/itempickup.wav", "");
1421                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1422                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1423                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "misc/poweroff.wav");
1424                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1425
1426                 if((self.items & activator.items) & IT_STRENGTH)
1427                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1428                 if((self.items & activator.items) & IT_INVINCIBLE)
1429                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1430         }
1431         else if(self.spawnflags == 4) // ANDNOT/MIN
1432         {
1433                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1434                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1435                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1436                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1437                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1438                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1439                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1440                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "misc/poweroff.wav");
1441                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1442
1443                 if((self.items & activator.items) & IT_STRENGTH)
1444                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1445                 if((self.items & activator.items) & IT_INVINCIBLE)
1446                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1447         }
1448
1449         if not(activator.items & IT_STRENGTH)
1450                 activator.strength_finished = 0;
1451         if not(activator.items & IT_INVINCIBLE)
1452                 activator.invincible_finished = 0;
1453
1454         if(activator.health > h0)
1455                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1456         else if(activator.health < h0)
1457                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1458
1459         if(activator.ammo_fuel > f0)
1460                 activator.pauserotfuel_finished = max(activator.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
1461         else if(activator.ammo_fuel < f0)
1462                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1463
1464         if(activator.armorvalue > a0)
1465                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1466
1467         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1468                 _switchweapon = TRUE;
1469         if(_switchweapon)
1470                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1471
1472         if(target_item_changed)
1473                 centerprint(activator, self.message);
1474 }
1475
1476 void spawnfunc_target_items (void)
1477 {
1478         float n, i, j;
1479         entity e;
1480         self.use = target_items_use;
1481         if(!self.strength_finished)
1482                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1483         if(!self.invincible_finished)
1484                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1485
1486         precache_sound("misc/itempickup.wav");
1487         precache_sound("misc/itempickup.wav");
1488         precache_sound("misc/itempickup.wav");
1489         precache_sound("misc/itempickup.wav");
1490         precache_sound("misc/megahealth.wav");
1491         precache_sound("misc/armor25.wav");
1492         precache_sound("misc/powerup.wav");
1493         precache_sound("misc/poweroff.wav");
1494         precache_sound("weapons/weaponpickup.wav");
1495
1496         n = tokenize_console(self.netname);
1497         for(i = 0; i < n; ++i)
1498         {
1499                 if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1500                 else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1501                 else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1502                 else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1503                 else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1504                 else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1505                 else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1506                 else
1507                 {
1508                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1509                         {
1510                                 e = get_weaponinfo(j);
1511                                 if(argv(i) == e.netname)
1512                                 {
1513                                         self.weapons |= e.weapons;
1514                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1515                                                 weapon_action(e.weapon, WR_PRECACHE);
1516                                         break;
1517                                 }
1518                         }
1519                         if(j > WEP_LAST)
1520                                 print("target_items: invalid item ", argv(i), "\n");
1521                 }
1522         }
1523 }
1524
1525 void spawnfunc_item_fuel(void)
1526 {
1527         if(!self.ammo_fuel)
1528                 self.ammo_fuel = g_pickup_fuel;
1529         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1530 }
1531
1532 void spawnfunc_item_fuel_regen(void)
1533 {
1534         if(start_items & IT_FUEL_REGEN)
1535         {
1536                 spawnfunc_item_fuel();
1537                 return;
1538         }
1539         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1540 }
1541
1542 void spawnfunc_item_jetpack(void)
1543 {
1544         if(g_grappling_hook)
1545                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1546         if(!self.ammo_fuel)
1547                 self.ammo_fuel = g_pickup_fuel_jetpack;
1548         if(start_items & IT_JETPACK)
1549         {
1550                 spawnfunc_item_fuel();
1551                 return;
1552         }
1553         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1554 }