data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   2         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   3 #define ITEM_RESPAWNTIME_INITIAL(i) (10 + random() * ((i).respawntime + (i).respawntimejitter - 10))
   4         // range: 10 .. respawntime + respawntimejitter
   5
   6 floatfield Item_CounterField(float it)
   7 {
   8         switch(it)
   9         {
  10                 case IT_SHELLS:      return ammo_shells;
  11                 case IT_NAILS:       return ammo_nails;
  12                 case IT_ROCKETS:     return ammo_rockets;
  13                 case IT_CELLS:       return ammo_cells;
  14                 case IT_FUEL:        return ammo_fuel;
  15                 case IT_5HP:         return health;
  16                 case IT_25HP:        return health;
  17                 case IT_HEALTH:      return health;
  18                 case IT_ARMOR_SHARD: return armorvalue;
  19                 case IT_ARMOR:       return armorvalue;
  20                 // add more things here (health, armor)
  21                 default:             error("requested item has no counter field");
  22         }
  23 }
  24
  25 string Item_CounterFieldName(float it)
  26 {
  27         switch(it)
  28         {
  29                 case IT_SHELLS:      return "shells";
  30                 case IT_NAILS:       return "nails";
  31                 case IT_ROCKETS:     return "rockets";
  32                 case IT_CELLS:       return "cells";
  33                 case IT_FUEL:        return "fuel";
  34
  35                 // add more things here (health, armor)
  36                 default:             error("requested item has no counter field name");
  37         }
  38 }
  39
  40 .float max_armorvalue;
  41
  42 void Item_Respawn (void)
  43 {
  44         self.model = self.mdl;          // restore original model
  45         self.solid = SOLID_TRIGGER;     // allow it to be touched again
  46         sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
  47         setorigin (self, self.origin);
  48
  49         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
  50         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
  51 }
  52
  53 void Item_RespawnCountdown (void)
  54 {
  55         if(self.count >= 5)
  56         {
  57                 if(self.waypointsprite_attached)
  58                         WaypointSprite_Kill(self.waypointsprite_attached);
  59                 Item_Respawn();
  60         }
  61         else
  62         {
  63                 self.nextthink = time + 1;
  64                 self.count += 1;
  65                 if(self.count == 1)
  66                 {
  67                         string name;
  68                         vector rgb;
  69                         name = string_null;
  70                         if(g_minstagib)
  71                         {
  72                                 switch(self.items)
  73                                 {
  74                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
  75                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
  76                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
  77                                 }
  78                         }
  79                         else
  80                         {
  81                                 switch(self.items)
  82                                 {
  83                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
  84                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
  85                                 }
  86                         }
  87                         switch(self.items)
  88                         {
  89                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
  90                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
  91                         }
  92                         if(name)
  93                         {
  94                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, FALSE);
  95                                 if(self.waypointsprite_attached)
  96                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
  97                         }
  98                 }
  99                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 100                 if(self.waypointsprite_attached)
 101                         WaypointSprite_Ping(self.waypointsprite_attached);
 102         }
 103 }
 104
 105 void Item_ScheduleRespawnIn(entity e, float t)
 106 {
 107         if(e.flags & FL_POWERUP)
 108         {
 109                 e.think = Item_RespawnCountdown;
 110                 e.nextthink = time + max(0, t - 5);
 111                 e.count = 0;
 112         }
 113         else
 114         {
 115                 e.think = Item_Respawn;
 116                 e.nextthink = time + t;
 117         }
 118 }
 119
 120 void Item_ScheduleRespawn(entity e)
 121 {
 122         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 123 }
 124
 125 void Item_ScheduleInitialRespawn(entity e)
 126 {
 127         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME_INITIAL(e));
 128 }
 129
 130 float Item_GiveTo(entity item, entity player)
 131 {
 132         float _switchweapon;
 133         float pickedup;
 134         float it;
 135         float i;
 136         entity e;
 137
 138         // if nothing happens to player, just return without taking the item
 139         pickedup = FALSE;
 140         _switchweapon = FALSE;
 141
 142         if (g_minstagib)
 143         {
 144                 _switchweapon = TRUE;
 145                 if (item.ammo_cells)
 146                 {
 147                         pickedup = TRUE;
 148                         // play some cool sounds ;)
 149                         centerprint(player, "\n");
 150                         if(player.health <= 5)
 151                                 announce(player, "announcer/robotic/lastsecond.wav");
 152                         else if(player.health < 50)
 153                                 announce(player, "announcer/robotic/narrowly.wav");
 154                         // sound not available
 155                         // else if(item.items == IT_CELLS)
 156                         //      play2(player, "announce/robotic/ammo.wav");
 157
 158                         if (item.weapons & WEPBIT_MINSTANEX)
 159                                 W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 160                         if (item.ammo_cells)
 161                                 player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 162                         player.health = 100;
 163                 }
 164
 165                 // extralife powerup
 166                 if (item.max_health)
 167                 {
 168                         pickedup = TRUE;
 169                         // sound not available
 170                         // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.wav");
 171                         player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 172                         sprint(player, "^3You picked up some extra lives\n");
 173                 }
 174
 175                 // invis powerup
 176                 if (item.strength_finished)
 177                 {
 178                         pickedup = TRUE;
 179                         // sound not available
 180                         // play2(player, "announce/robotic/invisible.wav");
 181                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 182                 }
 183
 184                 // speed powerup
 185                 if (item.invincible_finished)
 186                 {
 187                         pickedup = TRUE;
 188                         // sound not available
 189                         // play2(player, "announce/robotic/speed.wav");
 190                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 191                 }
 192         }
 193         else
 194         {
 195                 if (g_weapon_stay == 1)
 196                 if not(item.flags & FL_NO_WEAPON_STAY)
 197                 if (item.flags & FL_WEAPON)
 198                 {
 199                         if(item.classname == "droppedweapon")
 200                         {
 201                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 202                                         goto skip;
 203                         }
 204                         else
 205                         {
 206                                 if (player.weapons & item.weapons)
 207                                         goto skip;
 208                         }
 209                 }
 210
 211                 // in case the player has autoswitch enabled do the following:
 212                 // if the player is using their best weapon before items are given, they
 213                 // probably want to switch to an even better weapon after items are given
 214                 if (player.autoswitch)
 215                 if (player.switchweapon == w_getbestweapon(player))
 216                         _switchweapon = TRUE;
 217
 218                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 219                         _switchweapon = TRUE;
 220
 221                 if (item.ammo_shells)
 222                 if (player.ammo_shells < g_pickup_shells_max)
 223                 {
 224                         pickedup = TRUE;
 225                         player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 226                 }
 227                 if (item.ammo_nails)
 228                 if (player.ammo_nails < g_pickup_nails_max)
 229                 {
 230                         pickedup = TRUE;
 231                         player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 232                 }
 233                 if (item.ammo_rockets)
 234                 if (player.ammo_rockets < g_pickup_rockets_max)
 235                 {
 236                         pickedup = TRUE;
 237                         player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 238                 }
 239                 if (item.ammo_cells)
 240                 if (player.ammo_cells < g_pickup_cells_max)
 241                 {
 242                         pickedup = TRUE;
 243                         player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 244                 }
 245                 if (item.ammo_fuel)
 246                 if (player.ammo_fuel < g_pickup_fuel_max)
 247                 {
 248                         pickedup = TRUE;
 249                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 250                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 251                 }
 252
 253                 if (item.flags & FL_WEAPON)
 254                 if ((it = item.weapons - (item.weapons & player.weapons)))
 255                 {
 256                         pickedup = TRUE;
 257                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 258                         {
 259                                 e = get_weaponinfo(i);
 260                                 if(it & e.weapons)
 261                                         W_GiveWeapon (player, e.weapon, item.netname);
 262                         }
 263                 }
 264
 265                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 266                 {
 267                         pickedup = TRUE;
 268                         player.items |= it;
 269                 }
 270
 271                 if (item.strength_finished)
 272                 {
 273                         pickedup = TRUE;
 274                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 275                 }
 276                 if (item.invincible_finished)
 277                 {
 278                         pickedup = TRUE;
 279                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 280                 }
 281                 //if (item.speed_finished)
 282                 //{
 283                 //      pickedup = TRUE;
 284                 //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 285                 //}
 286                 //if (item.slowmo_finished)
 287                 //{
 288                 //      pickedup = TRUE;
 289                 //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 290                 //}
 291
 292                 if (item.health)
 293                 if (player.health < item.max_health)
 294                 {
 295                         pickedup = TRUE;
 296                         player.health = min(player.health + item.health, item.max_health);
 297                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 298                 }
 299                 if (item.armorvalue)
 300                 if (player.armorvalue < item.max_armorvalue)
 301                 {
 302                         pickedup = TRUE;
 303                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 304                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 305                 }
 306         }
 307
 308 :skip
 309         // always eat teamed entities
 310         if(item.team)
 311                 pickedup = TRUE;
 312
 313         if (!pickedup)
 314                 return 0;
 315
 316         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 317         if (_switchweapon)
 318                 if (player.switchweapon != w_getbestweapon(player))
 319                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 320
 321         return 1;
 322 }
 323
 324 void Item_Touch (void)
 325 {
 326         entity e, head;
 327
 328         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 329         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 330         {
 331                 remove(self);
 332                 return;
 333         }
 334         if (other.classname != "player")
 335                 return;
 336         if (other.deadflag)
 337                 return;
 338         if (self.solid != SOLID_TRIGGER)
 339                 return;
 340         if (self.owner == other)
 341                 return;
 342
 343         if(!Item_GiveTo(self, other))
 344                 return;
 345
 346         if (self.classname == "droppedweapon")
 347                 remove (self);
 348         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 349                 return;
 350         else
 351         {
 352                 self.solid = SOLID_NOT;
 353                 self.model = string_null;
 354                 if(self.team)
 355                 {
 356                         RandomSelection_Init();
 357                         for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 358                                 RandomSelection_Add(head, 0, head.cnt, 0);
 359                         e = RandomSelection_chosen_ent;
 360                 }
 361                 else
 362                         e = self;
 363                 Item_ScheduleRespawn(e);
 364         }
 365 }
 366
 367 void Item_FindTeam()
 368 {
 369         entity head, e;
 370
 371         if(self.effects & EF_NODRAW)
 372         {
 373                 // marker for item team search
 374                 dprint("Initializing item team ", ftos(self.team), "\n");
 375                 RandomSelection_Init();
 376                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 377                         RandomSelection_Add(head, 0, head.cnt, 0);
 378                 e = RandomSelection_chosen_ent;
 379                 e.state = 0;
 380
 381                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 382                 {
 383                         if(head != e)
 384                         {
 385                                 // make it a non-spawned item
 386                                 head.solid = SOLID_NOT;
 387                                 head.model = string_null;
 388                                 head.state = 1; // state 1 = initially hidden item
 389                         }
 390                         head.effects &~= EF_NODRAW;
 391                 }
 392
 393                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 394                 {
 395                         e.solid = SOLID_NOT;
 396                         e.model = string_null;
 397                         Item_ScheduleInitialRespawn(e);
 398                 }
 399         }
 400 }
 401
 402 void Item_Reset()
 403 {
 404         if(self.state == 1)
 405         {
 406                 self.model = string_null;
 407                 self.solid = SOLID_NOT;
 408         }
 409         else
 410         {
 411                 self.model = self.mdl;
 412                 self.solid = SOLID_TRIGGER;
 413         }
 414         setorigin (self, self.origin);
 415         self.think = SUB_Null;
 416         self.nextthink = 0;
 417
 418         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 419         {
 420                 self.solid = SOLID_NOT;
 421                 self.model = string_null;
 422                 Item_ScheduleInitialRespawn(self);
 423         }
 424 }
 425
 426 // Savage: used for item garbage-collection
 427 // TODO: perhaps nice special effect?
 428 void RemoveItem(void)
 429 {
 430         remove(self);
 431 }
 432
 433 // pickup evaluation functions
 434 // these functions decide how desirable an item is to the bots
 435
 436 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 437
 438 float weapon_pickupevalfunc(entity player, entity item)
 439 {
 440         // if we already have the weapon, rate it 1/5th normal value
 441         if ((player.weapons & item.weapons) == item.weapons)
 442                 return item.bot_pickupbasevalue * 0.2;
 443         return item.bot_pickupbasevalue;
 444 };
 445
 446 float commodity_pickupevalfunc(entity player, entity item)
 447 {
 448         float c;
 449         c = 0;
 450         // TODO: figure out if the player even has the weapon this ammo is for?
 451         // may not affect strategy much though...
 452         // find out how much more ammo/armor/health the player can hold
 453         if (item.ammo_shells)
 454         if (player.ammo_shells < g_pickup_shells_max)
 455                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 456         if (item.ammo_nails)
 457         if (player.ammo_nails < g_pickup_nails_max)
 458                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 459         if (item.ammo_rockets)
 460         if (player.ammo_rockets < g_pickup_rockets_max)
 461                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 462         if (item.ammo_cells)
 463         if (player.ammo_cells < g_pickup_cells_max)
 464                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 465         if (item.armorvalue)
 466         if (player.armorvalue < item.max_armorvalue)
 467                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 468         if (item.health)
 469         if (player.health < item.max_health)
 470                 c = c + max(0, 1 - player.health / item.max_health);
 471
 472         return item.bot_pickupbasevalue * c;
 473 };
 474
 475
 476 .float is_item;
 477 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 478 {
 479         startitem_failed = FALSE;
 480
 481         // is it a dropped weapon?
 482         if (self.classname == "droppedweapon")
 483         {
 484                 self.reset = SUB_Remove;
 485                 // it's a dropped weapon
 486                 self.movetype = MOVETYPE_TOSS;
 487                 self.solid = SOLID_TRIGGER;
 488                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 489                 self.think = RemoveItem;
 490                 self.nextthink = time + 60;
 491                 // don't drop if in a NODROP zone (such as lava)
 492                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 493                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 494                 {
 495                         startitem_failed = TRUE;
 496                         remove(self);
 497                         return;
 498                 }
 499         }
 500         else
 501         {
 502                 self.reset = Item_Reset;
 503                 // it's a level item
 504                 if(self.spawnflags & 1)
 505                         self.noalign = 1;
 506                 if (self.noalign)
 507                         self.movetype = MOVETYPE_NONE;
 508                 else
 509                         self.movetype = MOVETYPE_TOSS;
 510                 self.solid = SOLID_TRIGGER;
 511                 // do item filtering according to game mode and other things
 512                 if (!self.noalign)
 513                 {
 514                         // first nudge it off the floor a little bit to avoid math errors
 515                         setorigin(self, self.origin + '0 0 1');
 516                         // set item size before we spawn a spawnfunc_waypoint
 517                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 518                                 setsize (self, '-16 -16 0', '16 16 48');
 519                         else
 520                                 setsize (self, '-16 -16 0', '16 16 32');
 521                         // note droptofloor returns FALSE if stuck/or would fall too far
 522                         droptofloor();
 523                         waypoint_spawnforitem(self);
 524                 }
 525
 526                 if(teams_matter)
 527                 {
 528                         if(self.notteam)
 529                         {
 530                                 print("removed non-teamplay ", self.classname, "\n");
 531                                 startitem_failed = TRUE;
 532                                 remove (self);
 533                                 return;
 534                         }
 535                 }
 536                 else
 537                 {
 538                         if(self.notfree)
 539                         {
 540                                 print("removed non-FFA ", self.classname, "\n");
 541                                 startitem_failed = TRUE;
 542                                 remove (self);
 543                                 return;
 544                         }
 545                 }
 546
 547                 if(self.notq3a)
 548                 {
 549                         // We aren't TA or something like that, so we keep the Q3A entities
 550                         print("removed non-Q3A ", self.classname, "\n");
 551                         startitem_failed = TRUE;
 552                         remove (self);
 553                         return;
 554                 }
 555
 556                 /*
 557                  * can't do it that way, as it would break maps
 558                  * TODO make a target_give like entity another way, that perhaps has
 559                  * the weapon name in a key
 560                 if(self.targetname)
 561                 {
 562                         // target_give not yet supported; maybe later
 563                         print("removed targeted ", self.classname, "\n");
 564                         startitem_failed = TRUE;
 565                         remove (self);
 566                         return;
 567                 }
 568                 */
 569
 570                 if(cvar("spawn_debug") >= 2)
 571                 {
 572                         entity otheritem;
 573                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 574                         {
 575                                 if(otheritem.is_item)
 576                                 {
 577                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 578                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 579                                         error("Mapper sucks.");
 580                                 }
 581                         }
 582                         self.is_item = TRUE;
 583                 }
 584
 585                 weaponsInMap |= weaponid;
 586
 587                 if(g_lms)
 588                 {
 589                         startitem_failed = TRUE;
 590                         remove(self);
 591                         return;
 592                 }
 593                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 594                 {
 595                         startitem_failed = TRUE;
 596                         remove(self);
 597                         return;
 598                 }
 599                 else if (g_minstagib)
 600                 {
 601                         // don't remove dropped items and powerups
 602                         if (self.classname != "minstagib")
 603                         {
 604                                 startitem_failed = TRUE;
 605                                 remove (self);
 606                                 return;
 607                         }
 608                 }
 609                 else if ((!cvar("g_pickup_items") || g_nixnex) && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 610                 {
 611                         startitem_failed = TRUE;
 612                         remove (self);
 613                         return;
 614                 }
 615
 616                 precache_model (itemmodel);
 617                 precache_sound (pickupsound);
 618                 precache_sound ("misc/itemrespawn.wav");
 619                 precache_sound ("misc/itemrespawncountdown.wav");
 620
 621                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 622                         self.target = "###item###"; // for finding the nearest item using find()
 623         }
 624
 625         self.bot_pickup = TRUE;
 626         self.bot_pickupevalfunc = pickupevalfunc;
 627         self.bot_pickupbasevalue = pickupbasevalue;
 628         self.mdl = itemmodel;
 629         self.item_pickupsound = pickupsound;
 630         // let mappers override respawntime
 631         if(!self.respawntime) // both set
 632         {
 633                 self.respawntime = defaultrespawntime;
 634                 self.respawntimejitter = defaultrespawntimejitter;
 635         }
 636         self.netname = itemname;
 637         self.items = itemid;
 638         self.weapons = weaponid;
 639         self.flags = FL_ITEM | itemflags;
 640         self.touch = Item_Touch;
 641         setmodel (self, self.mdl); // precision set below
 642         self.effects |= EF_LOWPRECISION;
 643         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 644                 setsize (self, '-16 -16 0', '16 16 48');
 645         else
 646                 setsize (self, '-16 -16 0', '16 16 32');
 647         if(itemflags & FL_WEAPON)
 648                 self.modelflags |= MF_ROTATE;
 649
 650         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 651         if (itemflags & FL_WEAPON)
 652         {
 653                 // neutral team color for pickup weapons
 654                 self.colormap = 1024; // color shirt=0 pants=0 grey
 655         }
 656
 657         if (cvar("g_fullbrightitems"))
 658                 self.effects = self.effects | EF_FULLBRIGHT;
 659
 660         self.state = 0;
 661         if(self.team)
 662         {
 663                 if(!self.cnt)
 664                         self.cnt = 1; // item probability weight
 665                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 666                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 667         }
 668         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 669         {
 670                 self.solid = SOLID_NOT;
 671                 self.model = string_null;
 672                 Item_ScheduleInitialRespawn(self);
 673         }
 674 }
 675
 676 /* replace items in minstagib
 677  * IT_STRENGTH   = invisibility
 678  * IT_NAILS      = extra lives
 679  * IT_INVINCIBLE = speed
 680  */
 681 void minstagib_items (float itemid)
 682 {
 683         // we don't want to replace dropped weapons ;)
 684         if (self.classname == "droppedweapon")
 685         {
 686                 self.ammo_cells = 25;
 687                 StartItem ("models/weapons/g_nex.md3",
 688                         "weapons/weaponpickup.wav", 15, 0,
 689                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 690                 return;
 691         }
 692
 693         local float rnd;
 694         self.classname = "minstagib";
 695
 696         // replace rocket launchers and nex guns with ammo cells
 697         if (itemid == IT_CELLS)
 698         {
 699                 self.ammo_cells = 1;
 700                 StartItem ("models/items/a_cells.md3",
 701                         "misc/itempickup.wav", 45, 0,
 702                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 703                 return;
 704         }
 705
 706         // randomize
 707         rnd = random() * 3;
 708         if (rnd <= 1)
 709                 itemid = IT_STRENGTH;
 710         else if (rnd <= 2)
 711                 itemid = IT_NAILS;
 712         else
 713                 itemid = IT_INVINCIBLE;
 714
 715         // replace with invis
 716         if (itemid == IT_STRENGTH)
 717         {
 718                 self.effects = EF_ADDITIVE;
 719                 self.strength_finished = 30;
 720                 StartItem ("models/items/g_strength.md3",
 721                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 722                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 723         }
 724         // replace with extra lives
 725         if (itemid == IT_NAILS)
 726         {
 727                 self.max_health = 1;
 728                 StartItem ("models/items/g_h100.md3",
 729                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 730                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 731
 732         }
 733         // replace with speed
 734         if (itemid == IT_INVINCIBLE)
 735         {
 736                 self.effects = EF_ADDITIVE;
 737                 self.invincible_finished = 30;
 738                 StartItem ("models/items/g_invincible.md3",
 739                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 740                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 741         }
 742
 743 }
 744
 745 float minst_no_auto_cells;
 746 void minst_remove_item (void) {
 747         if(minst_no_auto_cells)
 748                 remove(self);
 749 }
 750
 751 float weaponswapping;
 752 float internalteam;
 753
 754 void weapon_defaultspawnfunc(float wpn)
 755 {
 756         entity e;
 757         float t;
 758         var .float ammofield;
 759         string s;
 760         entity oldself;
 761         float i, j;
 762
 763         // set the respawntime in advance (so replaced weapons can copy it)
 764
 765         if(!self.respawntime)
 766         {
 767                 e = get_weaponinfo(wpn);
 768                 if(e.items == IT_SUPERWEAPON)
 769                 {
 770                         self.respawntime = g_pickup_respawntime_powerup;
 771                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 772                 }
 773                 else
 774                 {
 775                         self.respawntime = g_pickup_respawntime_weapon;
 776                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 777                 }
 778         }
 779
 780         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 781         {
 782                 e = get_weaponinfo(wpn);
 783                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 784                 if(s == "0")
 785                 {
 786                         remove(self);
 787                         startitem_failed = TRUE;
 788                         return;
 789                 }
 790                 t = tokenize_console(s);
 791                 if(t >= 2)
 792                 {
 793                         self.team = --internalteam;
 794                         oldself = self;
 795                         for(i = 1; i < t; ++i)
 796                         {
 797                                 s = argv(i);
 798                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 799                                 {
 800                                         e = get_weaponinfo(j);
 801                                         if(e.netname == s)
 802                                         {
 803                                                 self = spawn();
 804                                                 copyentity(oldself, self);
 805                                                 self.classname = "replacedweapon";
 806                                                 weapon_defaultspawnfunc(j);
 807                                                 break;
 808                                         }
 809                                 }
 810                                 if(j > WEP_LAST)
 811                                 {
 812                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 813                                 }
 814                         }
 815                         self = oldself;
 816                 }
 817                 if(t >= 1)
 818                 {
 819                         s = argv(0);
 820                         wpn = 0;
 821                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 822                         {
 823                                 e = get_weaponinfo(j);
 824                                 if(e.netname == s)
 825                                 {
 826                                         wpn = j;
 827                                         break;
 828                                 }
 829                         }
 830                         if(j > WEP_LAST)
 831                         {
 832                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 833                         }
 834                 }
 835                 if(wpn == 0)
 836                 {
 837                         remove(self);
 838                         startitem_failed = TRUE;
 839                         return;
 840                 }
 841         }
 842
 843         e = get_weaponinfo(wpn);
 844
 845         if(e.items && e.items != IT_SUPERWEAPON)
 846         {
 847                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
 848                 {
 849                         if(e.items & j)
 850                         {
 851                                 ammofield = Item_CounterField(j);
 852                                 if(!self.ammofield)
 853                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
 854                         }
 855                 }
 856         }
 857         else
 858         {
 859                 self.flags |= FL_NO_WEAPON_STAY;
 860         }
 861
 862         // weapon stay isn't supported for teamed weapons
 863         if(self.team)
 864                 self.flags |= FL_NO_WEAPON_STAY;
 865
 866         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
 867         {
 868                 self.ammo_shells = 0;
 869                 self.ammo_nails = 0;
 870                 self.ammo_cells = 0;
 871                 self.ammo_rockets = 0;
 872                 // weapon stay 2: don't use ammo on weapon pickups; instead
 873                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
 874         }
 875
 876         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
 877         if (self.modelindex) // don't precache if self was removed
 878                 weapon_action(e.weapon, WR_PRECACHE);
 879 }
 880
 881 void spawnfunc_weapon_shotgun (void);
 882 void spawnfunc_weapon_uzi (void) {
 883         if(q3acompat_machineshotgunswap)
 884         if(self.classname != "droppedweapon")
 885         {
 886                 weapon_defaultspawnfunc(WEP_SHOTGUN);
 887                 return;
 888         }
 889         weapon_defaultspawnfunc(WEP_UZI);
 890 }
 891
 892 void spawnfunc_weapon_shotgun (void) {
 893         if(q3acompat_machineshotgunswap)
 894         if(self.classname != "droppedweapon")
 895         {
 896                 weapon_defaultspawnfunc(WEP_UZI);
 897                 return;
 898         }
 899         weapon_defaultspawnfunc(WEP_SHOTGUN);
 900 }
 901
 902 void spawnfunc_weapon_nex (void)
 903 {
 904         if (g_minstagib)
 905         {
 906                 minstagib_items(IT_CELLS);
 907                 self.think = minst_remove_item;
 908                 self.nextthink = time;
 909                 return;
 910         }
 911         weapon_defaultspawnfunc(WEP_NEX);
 912 }
 913
 914 void spawnfunc_weapon_minstanex (void)
 915 {
 916         if (g_minstagib)
 917         {
 918                 minstagib_items(IT_CELLS);
 919                 self.think = minst_remove_item;
 920                 self.nextthink = time;
 921                 return;
 922         }
 923         weapon_defaultspawnfunc(WEP_MINSTANEX);
 924 }
 925
 926 void spawnfunc_weapon_rocketlauncher (void)
 927 {
 928         if (g_minstagib)
 929         {
 930                 minstagib_items(IT_CELLS);
 931                 self.think = minst_remove_item;
 932                 self.nextthink = time;
 933                 return;
 934         }
 935         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
 936 }
 937
 938 void spawnfunc_item_rockets (void) {
 939         if(!self.ammo_rockets)
 940                 self.ammo_rockets = g_pickup_rockets;
 941         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
 942 }
 943
 944 void spawnfunc_item_shells (void);
 945 void spawnfunc_item_bullets (void) {
 946         if(!weaponswapping)
 947         if(q3acompat_machineshotgunswap)
 948         if(self.classname != "droppedweapon")
 949         {
 950                 weaponswapping = TRUE;
 951                 spawnfunc_item_shells();
 952                 weaponswapping = FALSE;
 953                 return;
 954         }
 955
 956         if(!self.ammo_nails)
 957                 self.ammo_nails = g_pickup_nails;
 958         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
 959 }
 960
 961 void spawnfunc_item_cells (void) {
 962         if(!self.ammo_cells)
 963                 self.ammo_cells = g_pickup_cells;
 964         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
 965 }
 966
 967 void spawnfunc_item_shells (void) {
 968         if(!weaponswapping)
 969         if(q3acompat_machineshotgunswap)
 970         if(self.classname != "droppedweapon")
 971         {
 972                 weaponswapping = TRUE;
 973                 spawnfunc_item_bullets();
 974                 weaponswapping = FALSE;
 975                 return;
 976         }
 977
 978         if(!self.ammo_shells)
 979                 self.ammo_shells = g_pickup_shells;
 980         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
 981 }
 982
 983 void spawnfunc_item_armor_small (void) {
 984         if(!self.armorvalue)
 985                 self.armorvalue = g_pickup_armorsmall;
 986         if(!self.max_armorvalue)
 987                 self.max_armorvalue = g_pickup_armorsmall_max;
 988         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
 989 }
 990
 991 void spawnfunc_item_armor_medium (void) {
 992         if(!self.armorvalue)
 993                 self.armorvalue = g_pickup_armormedium;
 994         if(!self.max_armorvalue)
 995                 self.max_armorvalue = g_pickup_armormedium_max;
 996         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
 997 }
 998
 999 void spawnfunc_item_armor_big (void) {
1000         if(!self.armorvalue)
1001                 self.armorvalue = g_pickup_armorbig;
1002         if(!self.max_armorvalue)
1003                 self.max_armorvalue = g_pickup_armorbig_max;
1004         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1005 }
1006
1007 void spawnfunc_item_armor_large (void) {
1008         if(!self.armorvalue)
1009                 self.armorvalue = g_pickup_armorlarge;
1010         if(!self.max_armorvalue)
1011                 self.max_armorvalue = g_pickup_armorlarge_max;
1012         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1013 }
1014
1015 void spawnfunc_item_health_small (void) {
1016         if(!self.max_health)
1017                 self.max_health = g_pickup_healthsmall_max;
1018         if(!self.health)
1019                 self.health = g_pickup_healthsmall;
1020         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1021 }
1022
1023 void spawnfunc_item_health_medium (void) {
1024         if(!self.max_health)
1025                 self.max_health = g_pickup_healthmedium_max;
1026         if(!self.health)
1027                 self.health = g_pickup_healthmedium;
1028         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1029 }
1030
1031 void spawnfunc_item_health_large (void) {
1032         if(!self.max_health)
1033                 self.max_health = g_pickup_healthlarge_max;
1034         if(!self.health)
1035                 self.health = g_pickup_healthlarge;
1036         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1037 }
1038
1039 void spawnfunc_item_health_mega (void) {
1040         if(!cvar("g_powerup_superhealth"))
1041                 return;
1042
1043         if(g_arena && !cvar("g_arena_powerups"))
1044                 return;
1045
1046         if(g_minstagib) {
1047                 minstagib_items(IT_NAILS);
1048         } else {
1049                 if(!self.max_health)
1050                         self.max_health = g_pickup_healthmega_max;
1051                 if(!self.health)
1052                         self.health = g_pickup_healthmega;
1053                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1054         }
1055 }
1056
1057 // support old misnamed entities
1058 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1059 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1060 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1061 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1062 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1063
1064 void spawnfunc_item_strength (void) {
1065         if(!cvar("g_powerup_strength"))
1066                 return;
1067
1068         if(g_arena && !cvar("g_arena_powerups"))
1069                 return;
1070
1071         if(g_minstagib) {
1072                 minstagib_items(IT_STRENGTH);
1073         } else {
1074                 precache_sound("weapons/strength_fire.wav");
1075                 self.strength_finished = 30;
1076                 self.effects = EF_ADDITIVE;
1077                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1078         }
1079 }
1080
1081 void spawnfunc_item_invincible (void) {
1082         if(!cvar("g_powerup_shield"))
1083                 return;
1084
1085         if(g_arena && !cvar("g_arena_powerups"))
1086                 return;
1087
1088         if(g_minstagib) {
1089                 minstagib_items(IT_INVINCIBLE);
1090         } else {
1091                 self.invincible_finished = 30;
1092                 self.effects = EF_ADDITIVE;
1093                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1094         }
1095 }
1096
1097 void spawnfunc_item_minst_cells (void) {
1098         if (g_minstagib)
1099         {
1100                 minst_no_auto_cells = 1;
1101                 minstagib_items(IT_CELLS);
1102         }
1103         else
1104                 remove(self);
1105 }
1106
1107 // compatibility:
1108 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1109
1110 float target_item_func_set(float a, float b)
1111 {
1112         if(b == 0)
1113                 return a;
1114         else if(b < 0)
1115                 return 0;
1116         else
1117                 return b;
1118 }
1119
1120 float target_item_func_min(float a, float b)
1121 {
1122         if(b == 0)
1123                 return a;
1124         else if(b < 0)
1125                 return 0;
1126         else
1127                 return min(a, b);
1128 }
1129
1130 float target_item_func_max(float a, float b)
1131 {
1132         return max(a, b);
1133 }
1134
1135 float target_item_func_bitset(float a, float b)
1136 {
1137         return b;
1138 }
1139
1140 float target_item_func_and(float a, float b)
1141 {
1142         return a & b;
1143 }
1144
1145 float target_item_func_itembitset(float a, float b)
1146 {
1147         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | b;
1148 }
1149
1150 float target_item_func_itemand(float a, float b)
1151 {
1152         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
1153 }
1154
1155 float target_item_func_or(float a, float b)
1156 {
1157         return a | b;
1158 }
1159
1160 float target_item_func_andnot(float a, float b)
1161 {
1162         return a - (a & b);
1163 }
1164
1165 float target_item_changed;
1166 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
1167 {
1168         float n, d;
1169         n = func(activator.field, self.field);
1170
1171         if(binary)
1172         {
1173                 d = n & activator.field;
1174                 if(d != n) // bits added?
1175                         d = +1;
1176                 else if(d != activator.field) // bits removed?
1177                         d = -1;
1178                 else
1179                         d = 0;
1180         }
1181         else
1182                 d = n - activator.field;
1183
1184         if(d < 0)
1185         {
1186                 if(sound_decrease != "")
1187                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
1188                 target_item_changed = 1;
1189         }
1190         else if(d > 0)
1191         {
1192                 if(sound_increase != "")
1193                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
1194                 target_item_changed = 1;
1195         }
1196         activator.field = n;
1197 }
1198
1199 void target_items_use (void)
1200 {
1201         float h0, a0;
1202
1203         if(activator.classname == "droppedweapon")
1204         {
1205                 EXACTTRIGGER_TOUCH;
1206                 remove(activator);
1207                 return;
1208         }
1209
1210         if(activator.classname != "player")
1211                 return;
1212         if(activator.deadflag != DEAD_NO)
1213                 return;
1214         EXACTTRIGGER_TOUCH;
1215
1216         entity e;
1217         for(e = world; (e = find(e, classname, "droppedweapon")); )
1218                 if(e.enemy == activator)
1219                         remove(e);
1220
1221         float _switchweapon;
1222         _switchweapon = FALSE;
1223         if (activator.autoswitch)
1224                 if (activator.switchweapon == w_getbestweapon(activator))
1225                         _switchweapon = TRUE;
1226
1227         a0 = activator.armorvalue;
1228         h0 = activator.health;
1229         target_item_changed = 0;
1230
1231         if(self.spawnflags == 0) // SET
1232         {
1233                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1234                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1235                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1236                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1237                 target_item_change(0, ammo_fuel, target_item_func_set, "misc/itempickup.wav", "");
1238                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1239                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1240                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "misc/poweroff.wav");
1241                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1242
1243                 if((self.items & activator.items) & IT_STRENGTH)
1244                         activator.strength_finished = time + self.strength_finished;
1245                 if((self.items & activator.items) & IT_INVINCIBLE)
1246                         activator.invincible_finished = time + self.invincible_finished;
1247         }
1248         else if(self.spawnflags == 1) // AND/MIN
1249         {
1250                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1251                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1252                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1253                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1254                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1255                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1256                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1257                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "misc/poweroff.wav");
1258                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1259
1260                 if((self.items & activator.items) & IT_STRENGTH)
1261                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1262                 if((self.items & activator.items) & IT_INVINCIBLE)
1263                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1264         }
1265         else if(self.spawnflags == 2) // OR/MAX
1266         {
1267                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1268                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1269                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1270                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1271                 target_item_change(0, ammo_fuel, target_item_func_max, "misc/itempickup.wav", "");
1272                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1273                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1274                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "misc/poweroff.wav");
1275                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1276
1277                 if((self.items & activator.items) & IT_STRENGTH)
1278                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1279                 if((self.items & activator.items) & IT_INVINCIBLE)
1280                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1281         }
1282         else if(self.spawnflags == 4) // ANDNOT/MIN
1283         {
1284                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1285                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1286                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1287                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1288                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1289                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1290                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1291                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "misc/poweroff.wav");
1292                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1293
1294                 if((self.items & activator.items) & IT_STRENGTH)
1295                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1296                 if((self.items & activator.items) & IT_INVINCIBLE)
1297                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1298         }
1299
1300         if not(activator.items & IT_STRENGTH)
1301                 activator.strength_finished = 0;
1302         if not(activator.items & IT_INVINCIBLE)
1303                 activator.invincible_finished = 0;
1304
1305         if(activator.health > h0)
1306                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1307         else if(activator.health < h0)
1308                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1309
1310         if(activator.armorvalue > a0)
1311                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1312
1313         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1314                 _switchweapon = TRUE;
1315         if(_switchweapon)
1316                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1317
1318         if(target_item_changed)
1319                 centerprint(activator, self.message);
1320 }
1321
1322 void spawnfunc_target_items (void)
1323 {
1324         float n, i, j;
1325         entity e;
1326         self.use = target_items_use;
1327         if(!self.strength_finished)
1328                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1329         if(!self.invincible_finished)
1330                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1331
1332         precache_sound("misc/itempickup.wav");
1333         precache_sound("misc/itempickup.wav");
1334         precache_sound("misc/itempickup.wav");
1335         precache_sound("misc/itempickup.wav");
1336         precache_sound("misc/megahealth.wav");
1337         precache_sound("misc/armor25.wav");
1338         precache_sound("misc/powerup.wav");
1339         precache_sound("misc/poweroff.wav");
1340         precache_sound("weapons/weaponpickup.wav");
1341
1342         n = tokenize_console(self.netname);
1343         for(i = 0; i < n; ++i)
1344         {
1345                 if(argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1346                 if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1347                 if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1348                 if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1349                 if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1350                 if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1351                 if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1352                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1353                 {
1354                         e = get_weaponinfo(j);
1355                         if(argv(i) == e.netname)
1356                         {
1357                                 self.weapons |= e.weapons;
1358                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1359                                         weapon_action(e.weapon, WR_PRECACHE);
1360                         }
1361                 }
1362         }
1363 }
1364
1365 void spawnfunc_item_fuel(void)
1366 {
1367         if(!self.ammo_fuel)
1368                 self.ammo_fuel = g_pickup_fuel;
1369         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1370 }
1371
1372 void spawnfunc_item_fuel_regen(void)
1373 {
1374         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1375 }
1376
1377 void spawnfunc_item_jetpack(void)
1378 {
1379         if(g_grappling_hook)
1380                 return; // sorry, but these two can't coexist (same button)
1381         if(!self.ammo_fuel)
1382                 self.ammo_fuel = g_pickup_fuel_jetpack;
1383         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1384 }