data/qcsrc/server/portals.qc

   1 #define PORTALS_ARE_NOT_SOLID
   2
   3 #define SAFENUDGE '1 1 1'
   4 #define SAFERNUDGE '8 8 8'
   5
   6 .vector portal_transform;
   7 .vector portal_safe_origin;
   8 .float portal_wants_to_vanish;
   9 .float portal_activatetime;
  10
  11 float PlayerEdgeDistance(entity p, vector v)
  12 {
  13         vector vbest;
  14
  15         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  16         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  17         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  18
  19         return vbest * v;
  20 }
  21
  22 .vector right_vector;
  23 float Portal_TeleportPlayer(entity teleporter, entity player)
  24 {
  25         vector from, to, safe, step, transform, ang, newvel;
  26         vector new_forward, new_up;
  27         vector old_forward, old_up;
  28         vector new_yawforward;
  29         vector old_yawforward;
  30         float planeshift, s, t;
  31
  32         if not(teleporter.enemy)
  33         {
  34                 backtrace("Portal_TeleportPlayer called without other portal being set. Stop.");
  35                 return 0;
  36         }
  37
  38         from = teleporter.origin;
  39         transform = teleporter.portal_transform;
  40
  41         to = teleporter.enemy.origin;
  42         to = to + AnglesTransform_Apply(teleporter.portal_transform, player.origin - from);
  43         newvel = AnglesTransform_Apply(transform, player.velocity);
  44         // this now is INSIDE the plane... can't use that
  45
  46         // shift it out
  47         fixedmakevectors(teleporter.enemy.angles);
  48
  49         // first shift it ON the plane if needed
  50         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
  51         /*
  52         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
  53                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
  54                 to += newvel * (planeshift / (newvel * v_forward));
  55         else
  56         */
  57                 to += v_forward * planeshift;
  58
  59         s = (to - teleporter.enemy.origin) * v_right;
  60         t = (to - teleporter.enemy.origin) * v_up;
  61         s = bound(-48, s, 48);
  62         t = bound(-48, t, 48);
  63         to = teleporter.enemy.origin
  64            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
  65            +     s                                        * v_right
  66            +     t                                        * v_up;
  67
  68         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
  69         step = to + ((safe - to) * v_forward) * v_forward;
  70         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
  71         if(trace_startsolid)
  72         {
  73                 print("'safe' teleport location is not safe!\n");
  74                 // FAIL TODO why does this happen?
  75                 return 0;
  76         }
  77         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
  78         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
  79         if(trace_startsolid)
  80         {
  81                 print("trace_endpos in solid, this can't be!\n");
  82                 // FAIL TODO why does this happen? (reported by MrBougo)
  83                 return 0;
  84         }
  85         to = trace_endpos + normalize(safe - trace_endpos) * 0;
  86         //print(vtos(to), "\n");
  87
  88         // ang_x stuff works around weird quake angles
  89         if(player.classname == "player")
  90         {
  91                 ang = player.v_angle;
  92                 /*
  93                 ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
  94                 ang = AnglesTransform_Multiply(transform, ang);
  95                 */
  96
  97                 // PLAYERS use different math
  98                 ang_x = -ang_x;
  99
 100                 //print("reference: ", vtos(AnglesTransform_Multiply(transform, ang)), "\n");
 101
 102                 fixedmakevectors(ang);
 103                 old_forward = v_forward;
 104                 old_up = v_up;
 105                 fixedmakevectors(ang_y * '0 1 0');
 106                 old_yawforward = v_forward;
 107
 108                 // their aiming directions are portalled...
 109                 new_forward = AnglesTransform_Apply(transform, old_forward);
 110                 new_up = AnglesTransform_Apply(transform, old_up);
 111                 new_yawforward = AnglesTransform_Apply(transform, old_yawforward);
 112
 113                 // but now find a new sense of direction
 114                 // this is NOT easy!
 115                 // assume new_forward points straight up.
 116                 // What is our yaw?
 117                 //
 118                 // new_up could now point forward OR backward... which direction to choose?
 119
 120                 if(new_forward_z > 0.7 || new_forward_z < -0.7) // far up; in this case, the "up" vector points backwards
 121                 {
 122                         // new_yawforward and new_yawup define the new aiming half-circle
 123                         // we "just" need to find out whether new_up or -new_up is in that half circle
 124                         ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
 125                         if(new_up * new_yawforward < 0)
 126                                 new_up = -1 * new_up;
 127                         ang_y = vectoyaw(new_up); // this vector is the yaw we want
 128                         //print("UP/DOWN path: ", vtos(ang), "\n");
 129                 }
 130                 else
 131                 {
 132                         // good angles; here, "forward" suffices
 133                         ang = fixedvectoangles(new_forward);
 134                         //print("GOOD path: ", vtos(ang), "\n");
 135                 }
 136
 137                 ang_x = -ang_x;
 138                 ang_z = player.angles_z;
 139         }
 140         else
 141         {
 142                 ang = player.angles;
 143                 ang = AnglesTransform_Multiply(transform, player.angles);
 144         }
 145
 146         // factor -1 allows chaining portals, but may be weird
 147         player.right_vector = -1 * AnglesTransform_Apply(transform, player.right_vector);
 148
 149         if(player.flagcarried)
 150                 DropFlag(player.flagcarried, player, world);
 151
 152         if not(teleporter.enemy)
 153         {
 154                 backtrace("Portal_TeleportPlayer ended up without other portal being set BEFORE TeleportPlayer. Stop.");
 155                 return 0;
 156         }
 157
 158         tdeath_hit = 0;
 159         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax);
 160         if(tdeath_hit)
 161         {
 162                 // telefrag within 1 second of portal creation = amazing
 163                 if(time < teleporter.teleport_time + 1)
 164                         announce(player, "announcer/male/amazing.wav");
 165         }
 166
 167         if not(teleporter.enemy)
 168         {
 169                 backtrace("Portal_TeleportPlayer ended up without other portal being set AFTER TeleportPlayer. Stop.");
 170                 return 0;
 171         }
 172
 173         // reset fade counter
 174         teleporter.portal_wants_to_vanish = 0;
 175         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 176         teleporter.health = cvar("g_balance_portal_health");
 177         teleporter.enemy.health = cvar("g_balance_portal_health");
 178
 179         return 1;
 180 }
 181
 182 float Portal_FindSafeOrigin(entity portal)
 183 {
 184         vector o;
 185         o = portal.origin;
 186         portal.mins = PL_MIN - SAFERNUDGE;
 187         portal.maxs = PL_MAX + SAFERNUDGE;
 188         fixedmakevectors(portal.angles);
 189         portal.origin += 16 * v_forward;
 190         if(!move_out_of_solid(portal))
 191         {
 192 #ifdef DEBUG
 193                 print("NO SAFE ORIGIN\n");
 194 #endif
 195                 return 0;
 196         }
 197         portal.portal_safe_origin = portal.origin;
 198         setorigin(portal, o);
 199         return 1;
 200 }
 201
 202 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 203 {
 204         float dist, distpersec, delta;
 205         vector v;
 206
 207         dist = (eorg - porg) * pnorm;
 208         dist += min(emins_x * pnorm_x, emaxs_x * pnorm_x);
 209         dist += min(emins_y * pnorm_y, emaxs_y * pnorm_y);
 210         dist += min(emins_z * pnorm_z, emaxs_z * pnorm_z);
 211         if(dist < -1) // other side?
 212                 return 0;
 213 #ifdef PORTALS_ARE_NOT_SOLID
 214         distpersec = evel * pnorm;
 215         if(distpersec >= 0) // going away from the portal?
 216                 return 0;
 217         // we don't need this check with solid portals, them being SOLID_BSP should suffice
 218         delta = dist / distpersec;
 219         v = eorg - evel * delta - porg;
 220         v = v - pnorm * (pnorm * v);
 221         return vlen(v) < psize;
 222 #else
 223         return 1;
 224 #endif
 225 }
 226
 227 void Portal_Touch()
 228 {
 229         vector g;
 230
 231 #ifdef PORTALS_ARE_NOT_SOLID
 232         // portal is being removed?
 233         if(self.solid != SOLID_TRIGGER)
 234                 return; // possibly engine bug
 235
 236         if(other.classname == "player")
 237                 return; // handled by think
 238 #endif
 239
 240         if(other.classname == "item_flag_team")
 241                 return; // never portal these
 242
 243         if(other.classname == "grapplinghook")
 244                 return; // handled by think
 245
 246         if(!self.enemy)
 247                 error("Portal_Touch called for a broken portal\n");
 248
 249 #ifdef PORTALS_ARE_NOT_SOLID
 250         if(trace_fraction < 1)
 251                 return; // only handle TouchAreaGrid ones (only these can teleport)
 252 #else
 253         if(trace_fraction >= 1)
 254                 return; // only handle impacts
 255 #endif
 256
 257         if(other.classname == "porto")
 258         {
 259                 if(other.portal_id == self.portal_id)
 260                         return;
 261         }
 262         if(time < self.portal_activatetime)
 263                 if(other == self.aiment)
 264                 {
 265                         self.portal_activatetime = time + 0.1;
 266                         return;
 267                 }
 268         if(other != self.aiment)
 269                 if(other.classname == "player")
 270                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 271                                 return; // cannot go through someone else's portal
 272         if(other.aiment != self.aiment)
 273                 if(other.aiment.classname == "player")
 274                         if(IS_INDEPENDENT_PLAYER(other.aiment) || IS_INDEPENDENT_PLAYER(self.aiment))
 275                                 return; // cannot go through someone else's portal
 276         fixedmakevectors(self.angles);
 277         g = frametime * '0 0 -1' * cvar("sv_gravity");
 278         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs_x))
 279                 return;
 280
 281         /*
 282         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 283         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 284         {
 285                 // can't teleport this
 286                 return;
 287         }
 288         */
 289
 290         if(Portal_TeleportPlayer(self, other))
 291                 if(other.classname == "porto")
 292                         if(other.effects & EF_RED)
 293                                 other.effects += EF_BLUE - EF_RED;
 294 }
 295
 296 void Portal_Think();
 297 void Portal_MakeBrokenPortal(entity portal)
 298 {
 299         portal.skin = 2;
 300         portal.solid = SOLID_NOT;
 301         portal.touch = SUB_Null;
 302         portal.think = SUB_Null;
 303         portal.effects = 0;
 304         portal.nextthink = 0;
 305         portal.takedamage = DAMAGE_NO;
 306 }
 307
 308 void Portal_MakeWaitingPortal(entity portal)
 309 {
 310         portal.skin = 2;
 311         portal.solid = SOLID_NOT;
 312         portal.touch = SUB_Null;
 313         portal.think = SUB_Null;
 314         portal.effects = EF_ADDITIVE;
 315         portal.nextthink = 0;
 316         portal.takedamage = DAMAGE_YES;
 317 }
 318
 319 void Portal_MakeInPortal(entity portal)
 320 {
 321         portal.skin = 0;
 322 #ifdef PORTALS_ARE_NOT_SOLID
 323         portal.solid = SOLID_TRIGGER;
 324 #else
 325         portal.solid = SOLID_BSP;
 326 #endif
 327         portal.touch = Portal_Touch;
 328         portal.think = Portal_Think;
 329         portal.effects = EF_RED;
 330         portal.nextthink = time;
 331         portal.takedamage = DAMAGE_NO;
 332 }
 333
 334 void Portal_MakeOutPortal(entity portal)
 335 {
 336         portal.skin = 1;
 337         portal.solid = SOLID_NOT;
 338         portal.touch = SUB_Null;
 339         portal.think = SUB_Null;
 340         portal.effects = EF_STARDUST | EF_BLUE;
 341         portal.nextthink = 0;
 342         portal.takedamage = DAMAGE_YES;
 343 }
 344
 345 void Portal_Disconnect(entity teleporter, entity destination)
 346 {
 347         teleporter.enemy = world;
 348         destination.enemy = world;
 349         Portal_MakeBrokenPortal(teleporter);
 350         Portal_MakeBrokenPortal(destination);
 351 }
 352
 353 void Portal_Connect(entity teleporter, entity destination)
 354 {
 355         teleporter.portal_transform = AnglesTransform_Divide(AnglesTransform_TurnDirection(destination.angles), teleporter.angles);
 356
 357         teleporter.enemy = destination;
 358         destination.enemy = teleporter;
 359         Portal_MakeInPortal(teleporter);
 360         Portal_MakeOutPortal(destination);
 361         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 362         destination.fade_time = teleporter.fade_time;
 363         teleporter.portal_wants_to_vanish = 0;
 364         destination.portal_wants_to_vanish = 0;
 365         teleporter.teleport_time = time;
 366 }
 367
 368 void Portal_Remove(entity portal, float killed)
 369 {
 370         entity e;
 371         e = portal.enemy;
 372
 373         if(e)
 374         {
 375                 Portal_Disconnect(portal, e);
 376                 Portal_Remove(e, killed);
 377         }
 378
 379         if(portal == portal.aiment.portal_in)
 380                 portal.aiment.portal_in = world;
 381         if(portal == portal.aiment.portal_out)
 382                 portal.aiment.portal_out = world;
 383         //portal.aiment = world;
 384
 385         // makes the portal vanish
 386         if(killed)
 387         {
 388                 fixedmakevectors(portal.angles);
 389                 sound(portal, CHAN_PROJECTILE, "porto/explode.wav", VOL_BASE, ATTN_NORM);
 390                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 391                 remove(portal);
 392         }
 393         else
 394         {
 395                 Portal_MakeBrokenPortal(portal);
 396                 sound(portal, CHAN_PROJECTILE, "porto/expire.wav", VOL_BASE, ATTN_NORM);
 397                 SUB_SetFade(portal, time, 0.5);
 398         }
 399 }
 400
 401 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 402 {
 403         if(deathtype == DEATH_TELEFRAG)
 404                 return;
 405         if(attacker != self.aiment)
 406                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.aiment))
 407                         return;
 408         self.health -= damage;
 409         if(self.health < 0)
 410                 Portal_Remove(self, 1);
 411 }
 412
 413 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 414 {
 415         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs_x))
 416                 return;
 417
 418         // if e would hit the portal in a frame...
 419         // already teleport him
 420         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 421         if(trace_ent == self)
 422                 Portal_TeleportPlayer(self, e);
 423 }
 424
 425 void Portal_Think()
 426 {
 427         entity e, o;
 428         vector g;
 429
 430 #ifdef PORTALS_ARE_NOT_SOLID
 431         // portal is being removed?
 432         if(self.solid != SOLID_TRIGGER)
 433                 return; // possibly engine bug
 434
 435         if(!self.enemy)
 436                 error("Portal_Think called for a broken portal\n");
 437
 438         o = self.aiment;
 439         self.solid = SOLID_BBOX;
 440         self.aiment = world;
 441
 442         g = frametime * '0 0 -1' * cvar("sv_gravity");
 443
 444         fixedmakevectors(self.angles);
 445
 446         FOR_EACH_PLAYER(e)
 447         {
 448                 if(e != o)
 449                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 450                                 continue; // cannot go through someone else's portal
 451
 452                 if(e != o || time >= self.portal_activatetime)
 453                         Portal_Think_TryTeleportPlayer(e, g);
 454
 455                 if(e.hook)
 456                         Portal_Think_TryTeleportPlayer(e.hook, g);
 457         }
 458         self.solid = SOLID_TRIGGER;
 459         self.aiment = o;
 460 #endif
 461
 462         self.nextthink = time;
 463
 464         if(time > self.fade_time)
 465                 Portal_Remove(self, 0);
 466 }
 467
 468 float Portal_Customize()
 469 {
 470         if(other.classname == "spectator")
 471                 other = other.enemy;
 472         if(other == self.aiment)
 473         {
 474                 self.modelindex = self.modelindex_lod0;
 475         }
 476         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 477         {
 478                 self.modelindex = 0;
 479         }
 480         else
 481         {
 482                 self.modelindex = self.modelindex_lod0;
 483         }
 484         return TRUE;
 485 }
 486
 487 // cleanup:
 488 //   when creating in-portal:
 489 //     disconnect
 490 //     clear existing in-portal
 491 //     set as in-portal
 492 //     connect
 493 //   when creating out-portal:
 494 //     disconnect
 495 //     clear existing out-portal
 496 //     set as out-portal
 497 //   when player dies:
 498 //     disconnect portals
 499 //     clear both portals
 500 //   after timeout of in-portal:
 501 //     disconnect portals
 502 //     clear both portals
 503 //   TODO: ensure only one portal shot at once
 504 float Portal_SetInPortal(entity own, entity portal)
 505 {
 506         if(own.portal_in)
 507         {
 508                 if(own.portal_out)
 509                         Portal_Disconnect(own.portal_in, own.portal_out);
 510                 Portal_Remove(own.portal_in, 0);
 511         }
 512         own.portal_in = portal;
 513         if(own.portal_out)
 514         {
 515                 own.portal_out.portal_id = portal.portal_id;
 516                 Portal_Connect(own.portal_in, own.portal_out);
 517         }
 518         return 2;
 519 }
 520 float Portal_SetOutPortal(entity own, entity portal)
 521 {
 522         if(own.portal_out)
 523         {
 524                 if(own.portal_in)
 525                         Portal_Disconnect(own.portal_in, own.portal_out);
 526                 Portal_Remove(own.portal_out, 0);
 527         }
 528         own.portal_out = portal;
 529         if(own.portal_in)
 530         {
 531                 own.portal_in.portal_id = portal.portal_id;
 532                 Portal_Connect(own.portal_in, own.portal_out);
 533         }
 534         return 1;
 535 }
 536 void Portal_ClearAll_PortalsOnly(entity own)
 537 {
 538         if(own.portal_in)
 539                 Portal_Remove(own.portal_in, 0);
 540         if(own.portal_out)
 541                 Portal_Remove(own.portal_out, 0);
 542 }
 543 void Portal_ClearAll(entity own)
 544 {
 545         Portal_ClearAll_PortalsOnly(own);
 546         W_Porto_Remove(own);
 547 }
 548 void Portal_RemoveLater_Think()
 549 {
 550         Portal_Remove(self, self.cnt);
 551 }
 552 void Portal_RemoveLater(entity portal, float kill)
 553 {
 554         Portal_MakeBrokenPortal(portal);
 555         portal.cnt = kill;
 556         portal.think = Portal_RemoveLater_Think;
 557         portal.nextthink = time;
 558 }
 559 void Portal_ClearAllLater_PortalsOnly(entity own)
 560 {
 561         if(own.portal_in)
 562                 Portal_RemoveLater(own.portal_in, 0);
 563         if(own.portal_out)
 564                 Portal_RemoveLater(own.portal_out, 0);
 565 }
 566 void Portal_ClearAllLater(entity own)
 567 {
 568         Portal_ClearAllLater_PortalsOnly(own);
 569         W_Porto_Remove(own);
 570 }
 571 void Portal_ClearWithID(entity own, float id)
 572 {
 573         if(own.portal_in)
 574                 if(own.portal_in.portal_id == id)
 575                 {
 576                         if(own.portal_out)
 577                                 Portal_Disconnect(own.portal_in, own.portal_out);
 578                         Portal_Remove(own.portal_in, 0);
 579                 }
 580         if(own.portal_out)
 581                 if(own.portal_out.portal_id == id)
 582                 {
 583                         if(own.portal_in)
 584                                 Portal_Disconnect(own.portal_in, own.portal_out);
 585                         Portal_Remove(own.portal_out, 0);
 586                 }
 587 }
 588
 589 entity Portal_Spawn(entity own, vector org, vector ang)
 590 {
 591         entity portal;
 592
 593         fixedmakevectors(ang);
 594         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 595                 return world;
 596
 597         portal = spawn();
 598         portal.classname = "portal";
 599         portal.aiment = own;
 600         portal.origin = org;
 601         portal.angles = ang;
 602         portal.think = Portal_Think;
 603         portal.nextthink = 0;
 604         portal.portal_activatetime = time + 0.1;
 605         portal.event_damage = Portal_Damage;
 606         portal.fade_time = time + cvar("g_balance_portal_lifetime");
 607         portal.health = cvar("g_balance_portal_health");
 608         setmodel(portal, "models/portal.md3");
 609         portal.modelindex_lod0 = portal.modelindex;
 610         portal.customizeentityforclient = Portal_Customize;
 611
 612         if(!Portal_FindSafeOrigin(portal))
 613         {
 614                 remove(portal);
 615                 return world;
 616         }
 617
 618         setsize(portal, '-48 -48 -48', '48 48 48');
 619         Portal_MakeWaitingPortal(portal);
 620
 621         return portal;
 622 }
 623
 624 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 625 {
 626         entity portal;
 627         vector ang;
 628         vector org;
 629
 630         org = trace_endpos;
 631         ang = fixedvectoangles2(trace_plane_normal, dir);
 632         fixedmakevectors(ang);
 633
 634         portal = Portal_Spawn(own, org, ang);
 635         if(!portal)
 636         {
 637                 // if(!own.portal_out || own.portal_out.portal_id == portal_id_val)
 638                         Portal_ClearAll_PortalsOnly(own);
 639                 return 0;
 640         }
 641
 642         portal.portal_id = portal_id_val;
 643         Portal_SetInPortal(own, portal);
 644
 645         return 1;
 646 }
 647
 648 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 649 {
 650         entity portal;
 651         vector ang;
 652         vector org;
 653
 654         org = trace_endpos;
 655         ang = fixedvectoangles2(trace_plane_normal, dir);
 656         fixedmakevectors(ang);
 657
 658         portal = Portal_Spawn(own, org, ang);
 659         if(!portal)
 660         {
 661                 // if(!own.portal_in || own.portal_in.portal_id == portal_id_val)
 662                         Portal_ClearAll_PortalsOnly(own);
 663                 return 0;
 664         }
 665
 666         portal.portal_id = portal_id_val;
 667         Portal_SetOutPortal(own, portal);
 668
 669         return 1;
 670 }