data/qcsrc/server/portals.qc

   1 #define SAFENUDGE '1 1 1'
   2 #define SAFERNUDGE '8 8 8'
   3
   4 .vector portal_transform;
   5 .vector portal_safe_origin;
   6 .float portal_wants_to_vanish;
   7 .float portal_activatetime;
   8
   9 vector Portal_Transform_Apply(vector transform, vector v)
  10 {
  11         fixedmakevectors(transform);
  12         return v_forward * v_x
  13              + v_right   * (-v_y)
  14                  + v_up      * v_z;
  15 }
  16
  17 vector Portal_Transform_Multiply(vector t1, vector t2)
  18 {
  19         vector m_forward, m_up;
  20         fixedmakevectors(t2); m_forward = v_forward; m_up = v_up;
  21         m_forward = Portal_Transform_Apply(t1, m_forward); m_up = Portal_Transform_Apply(t1, m_up);
  22         return fixedvectoangles2(m_forward, m_up);
  23 }
  24
  25 vector Portal_Transform_Invert(vector transform)
  26 {
  27         vector i_forward, i_up;
  28         fixedmakevectors(transform);
  29         // we want angles that turn v_forward into '1 0 0', v_right into '0 1 0' and v_up into '0 0 1'
  30         // but these are orthogonal unit vectors!
  31         // so to invert, we can simply fixedvectoangles the TRANSPOSED matrix
  32         // TODO is this always -transform?
  33         i_forward_x = v_forward_x;
  34         i_forward_y = -v_right_x;
  35         i_forward_z = v_up_x;
  36         i_up_x = v_forward_z;
  37         i_up_y = -v_right_z;
  38         i_up_z = v_up_z;
  39 #ifdef DEBUG
  40         vector v;
  41         v = fixedvectoangles2(i_forward, i_up);
  42         print("Transform: ", vtos(transform), "\n");
  43         print("Inverted: ", vtos(v), "\n");
  44         print("Verify: ", vtos(Portal_Transform_Multiply(v, transform)), "\n");
  45         fixedmakevectors(Portal_Transform_Multiply(v, transform));
  46         print("Verify: ", vtos(v_forward), "\n");
  47         print("Verify: ", vtos(v_right), "\n");
  48         print("Verify: ", vtos(v_up), "\n");
  49 #endif
  50         return fixedvectoangles2(i_forward, i_up);
  51 }
  52
  53 vector Portal_Transform_TurnDirection(vector transform)
  54 {
  55         // turn 180 degrees around v_up
  56         // changes in-direction to out-direction
  57         fixedmakevectors(transform);
  58         return fixedvectoangles2(-1 * v_forward, 1 * v_up);
  59 }
  60
  61 vector Portal_Transform_Divide(vector to_transform, vector from_transform)
  62 {
  63         return Portal_Transform_Multiply(to_transform, Portal_Transform_Invert(from_transform));
  64 }
  65
  66 float PlayerEdgeDistance(entity p, vector v)
  67 {
  68         vector vbest;
  69
  70         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  71         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  72         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  73
  74         return vbest * v;
  75 }
  76
  77 .vector right_vector;
  78 float Portal_TeleportPlayer(entity teleporter, entity player)
  79 {
  80         vector from, to, safe, step, transform, ang, newvel;
  81         vector new_forward, new_up;
  82         vector old_forward, old_up;
  83         vector new_yawforward;
  84         vector old_yawforward;
  85         float planeshift, s, t;
  86
  87         from = teleporter.origin;
  88         transform = teleporter.portal_transform;
  89
  90         to = teleporter.enemy.origin;
  91         to = to + Portal_Transform_Apply(teleporter.portal_transform, player.origin - from);
  92         newvel = Portal_Transform_Apply(transform, player.velocity);
  93         // this now is INSIDE the plane... can't use that
  94
  95         // shift it out
  96         fixedmakevectors(teleporter.enemy.angles);
  97
  98         // first shift it ON the plane if needed
  99         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
 100         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
 101                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
 102                 to += newvel * (planeshift / (newvel * v_forward));
 103         else
 104                 to += trace_plane_normal * planeshift;
 105
 106         s = (to - teleporter.enemy.origin) * v_right;
 107         t = (to - teleporter.enemy.origin) * v_up;
 108         s = bound(-48, s, 48);
 109         t = bound(-48, t, 48);
 110         to = teleporter.enemy.origin
 111            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 112            +     s                                        * v_right
 113            +     t                                        * v_up;
 114
 115         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 116         step = to + ((safe - to) * v_forward) * v_forward;
 117         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
 118         if(trace_startsolid)
 119         {
 120                 print("'safe' teleport location is not safe!\n");
 121                 // FAIL TODO why does this happen?
 122                 return 0;
 123         }
 124         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
 125         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
 126         if(trace_startsolid)
 127         {
 128                 print("trace_endpos in solid, this can't be!\n");
 129                 // FAIL TODO why does this happen? (reported by MrBougo)
 130                 return 0;
 131         }
 132         to = trace_endpos + normalize(safe - trace_endpos) * 0;
 133         //print(vtos(to), "\n");
 134
 135         // ang_x stuff works around weird quake angles
 136         if(player.classname == "player")
 137         {
 138                 ang = player.v_angle;
 139                 /*
 140                 ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
 141                 ang = Portal_Transform_Multiply(transform, ang);
 142                 */
 143
 144                 // PLAYERS use different math
 145                 ang_x = -ang_x;
 146
 147                 //print("reference: ", vtos(Portal_Transform_Multiply(transform, ang)), "\n");
 148
 149                 fixedmakevectors(ang);
 150                 old_forward = v_forward;
 151                 old_up = v_up;
 152                 fixedmakevectors(ang_y * '0 1 0');
 153                 old_yawforward = v_forward;
 154
 155                 // their aiming directions are portalled...
 156                 new_forward = Portal_Transform_Apply(transform, old_forward);
 157                 new_up = Portal_Transform_Apply(transform, old_up);
 158                 new_yawforward = Portal_Transform_Apply(transform, old_yawforward);
 159
 160                 // but now find a new sense of direction
 161                 // this is NOT easy!
 162                 // assume new_forward points straight up.
 163                 // What is our yaw?
 164                 //
 165                 // new_up could now point forward OR backward... which direction to choose?
 166
 167                 if(new_forward_z > 0.7 || new_forward_z < -0.7) // far up; in this case, the "up" vector points backwards
 168                 {
 169                         // new_yawforward and new_yawup define the new aiming half-circle
 170                         // we "just" need to find out whether new_up or -new_up is in that half circle
 171                         ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
 172                         if(new_up * new_yawforward < 0)
 173                                 new_up = -1 * new_up;
 174                         ang_y = vectoyaw(new_up); // this vector is the yaw we want
 175                         //print("UP/DOWN path: ", vtos(ang), "\n");
 176                 }
 177                 else
 178                 {
 179                         // good angles; here, "forward" suffices
 180                         ang = fixedvectoangles(new_forward);
 181                         //print("GOOD path: ", vtos(ang), "\n");
 182                 }
 183
 184                 ang_x = -ang_x;
 185                 ang_z = player.angles_z;
 186         }
 187         else
 188         {
 189                 ang = player.angles;
 190                 ang = Portal_Transform_Multiply(transform, player.angles);
 191         }
 192
 193         // factor -1 allows chaining portals, but may be weird
 194         player.right_vector = -1 * Portal_Transform_Apply(transform, player.right_vector);
 195
 196         if(player.flagcarried)
 197                 DropFlag(player.flagcarried, player, world);
 198         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax);
 199
 200         // reset fade counter
 201         teleporter.portal_wants_to_vanish = 0;
 202         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 203         teleporter.health = cvar("g_balance_portal_health");
 204         teleporter.enemy.health = cvar("g_balance_portal_health");
 205
 206         return 1;
 207 }
 208
 209 float Portal_FindSafeOrigin(entity portal)
 210 {
 211         vector o;
 212         o = portal.origin;
 213         portal.mins = PL_MIN - SAFERNUDGE;
 214         portal.maxs = PL_MAX + SAFERNUDGE;
 215         fixedmakevectors(portal.angles);
 216         portal.origin += 16 * v_forward;
 217         if(!move_out_of_solid(portal))
 218         {
 219 #ifdef DEBUG
 220                 print("NO SAFE ORIGIN\n");
 221 #endif
 222                 return 0;
 223         }
 224         portal.portal_safe_origin = portal.origin;
 225         setorigin(portal, o);
 226         return 1;
 227 }
 228
 229 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 230 {
 231         float dist, distpersec, delta;
 232         vector v;
 233
 234         dist = (eorg - porg) * pnorm;
 235         dist += min(emins_x * pnorm_x, emaxs_x * pnorm_x);
 236         dist += min(emins_y * pnorm_y, emaxs_y * pnorm_y);
 237         dist += min(emins_z * pnorm_z, emaxs_z * pnorm_z);
 238         if(dist < -1) // other side?
 239                 return 0;
 240         distpersec = evel * pnorm;
 241         if(distpersec >= 0) // going away from the portal?
 242                 return 0;
 243         delta = dist / distpersec;
 244         v = eorg - evel * delta - porg;
 245         v = v - pnorm * (pnorm * v);
 246         return vlen(v) < psize;
 247 }
 248
 249 void Portal_Touch()
 250 {
 251         vector g;
 252
 253         // portal is being removed?
 254         if(self.solid != SOLID_TRIGGER)
 255                 return; // possibly engine bug
 256
 257         if(other.classname == "player")
 258                 return; // handled by think
 259
 260         if(other.classname == "grapplinghook")
 261                 return; // handled by think
 262
 263         if(!self.enemy)
 264                 error("Portal_Touch called for a broken portal\n");
 265
 266         if(trace_fraction < 1)
 267                 return; // only handle TouchAreaGrid ones (only these can teleport)
 268                 // for some unknown reason, this also gets collisions from SV_Impact sometimes
 269
 270         if(other.classname == "porto")
 271         {
 272                 if(other.portal_id == self.portal_id)
 273                         return;
 274         }
 275         if(time < self.portal_activatetime)
 276                 if(other == self.owner)
 277                 {
 278                         self.portal_activatetime = time + 0.1;
 279                         return;
 280                 }
 281         if(other != self.owner)
 282                 if(other.classname == "player")
 283                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 284                                 return; // cannot go through someone else's portal
 285         if(other.owner != self.owner)
 286                 if(other.owner.classname == "player")
 287                         if(IS_INDEPENDENT_PLAYER(other.owner) || IS_INDEPENDENT_PLAYER(self.owner))
 288                                 return; // cannot go through someone else's portal
 289         fixedmakevectors(self.angles);
 290         g = frametime * '0 0 -1' * cvar("sv_gravity");
 291         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs_x))
 292                 return;
 293
 294         /*
 295         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 296         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 297         {
 298                 // can't teleport this
 299                 return;
 300         }
 301         */
 302
 303         if(Portal_TeleportPlayer(self, other))
 304                 if(other.classname == "porto")
 305                         if(other.effects & EF_RED)
 306                                 other.effects += EF_BLUE - EF_RED;
 307 }
 308
 309 void Portal_Think();
 310 void Portal_MakeBrokenPortal(entity portal)
 311 {
 312         portal.solid = SOLID_NOT;
 313         portal.touch = SUB_Null;
 314         portal.think = SUB_Null;
 315         portal.effects = 0;
 316         //portal.colormod = '1 1 1';
 317         portal.nextthink = 0;
 318         portal.takedamage = DAMAGE_NO;
 319 }
 320
 321 void Portal_MakeWaitingPortal(entity portal)
 322 {
 323         portal.solid = SOLID_NOT;
 324         portal.touch = SUB_Null;
 325         portal.think = SUB_Null;
 326         portal.effects = EF_ADDITIVE;
 327         portal.colormod = '1 1 1';
 328         portal.nextthink = 0;
 329         portal.takedamage = DAMAGE_YES;
 330 }
 331
 332 void Portal_MakeInPortal(entity portal)
 333 {
 334         portal.solid = SOLID_TRIGGER;
 335         portal.touch = Portal_Touch;
 336         portal.think = Portal_Think;
 337         portal.effects = EF_RED;
 338         portal.colormod = '1 0 0';
 339         portal.nextthink = time;
 340         portal.takedamage = DAMAGE_NO;
 341 }
 342
 343 void Portal_MakeOutPortal(entity portal)
 344 {
 345         portal.solid = SOLID_NOT;
 346         portal.touch = SUB_Null;
 347         portal.think = SUB_Null;
 348         portal.effects = EF_STARDUST | EF_BLUE;
 349         portal.colormod = '0 0 1';
 350         portal.nextthink = 0;
 351         portal.takedamage = DAMAGE_YES;
 352 }
 353
 354 void Portal_Disconnect(entity teleporter, entity destination)
 355 {
 356         teleporter.enemy = world;
 357         destination.enemy = world;
 358         Portal_MakeBrokenPortal(teleporter);
 359         Portal_MakeBrokenPortal(destination);
 360 }
 361
 362 void Portal_Connect(entity teleporter, entity destination)
 363 {
 364         teleporter.portal_transform = Portal_Transform_Divide(Portal_Transform_TurnDirection(destination.angles), teleporter.angles);
 365
 366 #ifdef DEBUG
 367         {
 368                 // let's verify the transform
 369                 vector in_f, in_r, in_u;
 370                 vector out_f, out_r, out_u;
 371                 fixedmakevectors(teleporter.angles);
 372                 in_f = v_forward;
 373                 in_r = v_right;
 374                 in_u = v_up;
 375                 print("teleporter: ", vtos(in_f), " ", vtos(in_r), " ", vtos(in_u), "\n");
 376                 fixedmakevectors(destination.angles);
 377                 out_f = v_forward;
 378                 out_r = v_right;
 379                 out_u = v_up;
 380                 print("dest: ", vtos(out_f), " ", vtos(out_r), " ", vtos(out_u), "\n");
 381                 // INTENDED TRANSFORM:
 382                 //   in_f -> -out_f
 383                 //   in_r -> -out_r
 384                 //   in_u -> +out_u
 385                 print("FORWARD: ", vtos(in_f), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_f)), ", should be", vtos(-1 * out_f), "\n");
 386                 print("RIGHT: ", vtos(in_r), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_r)), ", should be", vtos(-1 * out_r), "\n");
 387                 print("UP: ", vtos(in_u), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_u)), ", should be", vtos(out_u), "\n");
 388
 389                 te_lightning3(world, teleporter.origin, teleporter.origin + in_r * 1000);
 390                 te_lightning3(world, destination.origin, destination.origin + out_r * 1000);
 391         }
 392 #endif
 393
 394         teleporter.enemy = destination;
 395         destination.enemy = teleporter;
 396         Portal_MakeInPortal(teleporter);
 397         Portal_MakeOutPortal(destination);
 398         teleporter.fade_time = time + 15;
 399         destination.fade_time = time + 15;
 400         teleporter.portal_wants_to_vanish = 0;
 401         destination.portal_wants_to_vanish = 0;
 402 }
 403
 404 void Portal_Remove(entity portal, float killed)
 405 {
 406         entity e;
 407         e = portal.enemy;
 408
 409         if(e)
 410         {
 411                 Portal_Disconnect(portal, e);
 412                 Portal_Remove(e, killed);
 413         }
 414
 415         if(portal == portal.owner.portal_in)
 416                 portal.owner.portal_in = world;
 417         if(portal == portal.owner.portal_out)
 418                 portal.owner.portal_out = world;
 419         //portal.owner = world;
 420
 421         // makes the portal vanish
 422         if(killed)
 423         {
 424                 fixedmakevectors(portal.angles);
 425                 sound(portal, CHAN_PROJECTILE, "porto/explode.ogg", VOL_BASE, ATTN_NORM);
 426                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 427                 remove(portal);
 428         }
 429         else
 430         {
 431                 Portal_MakeBrokenPortal(portal);
 432                 sound(portal, CHAN_PROJECTILE, "porto/expire.ogg", VOL_BASE, ATTN_NORM);
 433                 SUB_SetFade(portal, time, 0.5);
 434         }
 435 }
 436
 437 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 438 {
 439         if(deathtype == DEATH_TELEFRAG)
 440                 return;
 441         if(attacker != self.owner)
 442                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.owner))
 443                         return;
 444         self.health -= damage;
 445         if(self.health < 0)
 446                 Portal_Remove(self, 1);
 447 }
 448
 449 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 450 {
 451         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs_x))
 452                 return;
 453
 454         // if e would hit the portal in a frame...
 455         // already teleport him
 456         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 457         if(trace_ent == self)
 458                 Portal_TeleportPlayer(self, e);
 459 }
 460
 461 void Portal_Think()
 462 {
 463         entity e, o;
 464         vector g;
 465
 466         // portal is being removed?
 467         if(self.solid != SOLID_TRIGGER)
 468                 return; // possibly engine bug
 469
 470         if(!self.enemy)
 471                 error("Portal_Think called for a broken portal\n");
 472
 473         o = self.owner;
 474         self.solid = SOLID_BBOX;
 475         self.owner = world;
 476
 477         g = frametime * '0 0 -1' * cvar("sv_gravity");
 478
 479         fixedmakevectors(self.angles);
 480
 481         FOR_EACH_PLAYER(e)
 482         {
 483                 if(e != o)
 484                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 485                                 continue; // cannot go through someone else's portal
 486
 487                 if(e != o || time >= self.portal_activatetime)
 488                         Portal_Think_TryTeleportPlayer(e, g);
 489
 490                 if(e.hook)
 491                         Portal_Think_TryTeleportPlayer(e.hook, g);
 492         }
 493         self.solid = SOLID_TRIGGER;
 494         self.owner = o;
 495
 496         self.nextthink = time;
 497
 498         if(time > self.fade_time)
 499                 Portal_Remove(self, 0);
 500 }
 501
 502 float Portal_Customize()
 503 {
 504         if(other.classname == "spectator")
 505                 other = other.enemy;
 506         if(other == self.owner)
 507         {
 508                 self.modelindex = self.modelindex_lod0;
 509         }
 510         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 511         {
 512                 self.modelindex = 0;
 513         }
 514         else
 515         {
 516                 self.modelindex = self.modelindex_lod0;
 517         }
 518         return TRUE;
 519 }
 520
 521 // cleanup:
 522 //   when creating in-portal:
 523 //     disconnect
 524 //     clear existing in-portal
 525 //     set as in-portal
 526 //     connect
 527 //   when creating out-portal:
 528 //     disconnect
 529 //     clear existing out-portal
 530 //     set as out-portal
 531 //   when player dies:
 532 //     disconnect portals
 533 //     clear both portals
 534 //   after timeout of in-portal:
 535 //     disconnect portals
 536 //     clear both portals
 537 //   TODO: ensure only one portal shot at once
 538 float Portal_SetInPortal(entity own, entity portal)
 539 {
 540         if(own.portal_in)
 541         {
 542                 if(own.portal_out)
 543                         Portal_Disconnect(own.portal_in, own.portal_out);
 544                 Portal_Remove(own.portal_in, 0);
 545         }
 546         own.portal_in = portal;
 547         if(own.portal_out)
 548         {
 549                 own.portal_out.portal_id = portal.portal_id;
 550                 Portal_Connect(own.portal_in, own.portal_out);
 551         }
 552         return 2;
 553 }
 554 float Portal_SetOutPortal(entity own, entity portal)
 555 {
 556         if(own.portal_out)
 557         {
 558                 if(own.portal_in)
 559                         Portal_Disconnect(own.portal_in, own.portal_out);
 560                 Portal_Remove(own.portal_out, 0);
 561         }
 562         own.portal_out = portal;
 563         if(own.portal_in)
 564         {
 565                 own.portal_in.portal_id = portal.portal_id;
 566                 Portal_Connect(own.portal_in, own.portal_out);
 567         }
 568         return 1;
 569 }
 570 void Portal_ClearAll_PortalsOnly(entity own)
 571 {
 572         if(own.portal_in)
 573                 Portal_Remove(own.portal_in, 0);
 574         if(own.portal_out)
 575                 Portal_Remove(own.portal_out, 0);
 576 }
 577 void Portal_ClearAll(entity own)
 578 {
 579         Portal_ClearAll_PortalsOnly(own);
 580         W_Porto_Remove(own);
 581 }
 582 void Portal_RemoveLater_Think()
 583 {
 584         Portal_Remove(self, self.cnt);
 585 }
 586 void Portal_RemoveLater(entity portal, float kill)
 587 {
 588         Portal_MakeBrokenPortal(portal);
 589         portal.cnt = kill;
 590         portal.think = Portal_RemoveLater_Think;
 591         portal.nextthink = time;
 592 }
 593 void Portal_ClearAllLater_PortalsOnly(entity own)
 594 {
 595         if(own.portal_in)
 596                 Portal_RemoveLater(own.portal_in, 0);
 597         if(own.portal_out)
 598                 Portal_RemoveLater(own.portal_out, 0);
 599 }
 600 void Portal_ClearAllLater(entity own)
 601 {
 602         Portal_ClearAllLater_PortalsOnly(own);
 603         W_Porto_Remove(own);
 604 }
 605 void Portal_ClearWithID(entity own, float id)
 606 {
 607         if(own.portal_in)
 608                 if(own.portal_in.portal_id == id)
 609                 {
 610                         if(own.portal_out)
 611                                 Portal_Disconnect(own.portal_in, own.portal_out);
 612                         Portal_Remove(own.portal_in, 0);
 613                 }
 614         if(own.portal_out)
 615                 if(own.portal_out.portal_id == id)
 616                 {
 617                         if(own.portal_in)
 618                                 Portal_Disconnect(own.portal_in, own.portal_out);
 619                         Portal_Remove(own.portal_out, 0);
 620                 }
 621 }
 622
 623 entity Portal_Spawn(entity own, vector org, vector ang)
 624 {
 625         entity portal;
 626
 627         fixedmakevectors(ang);
 628         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 629                 return world;
 630
 631         portal = spawn();
 632         portal.classname = "portal";
 633         portal.owner = own;
 634         portal.origin = org;
 635         portal.angles = ang;
 636         portal.think = Portal_Think;
 637         portal.nextthink = 0;
 638         portal.portal_activatetime = time + 0.1;
 639         portal.event_damage = Portal_Damage;
 640         portal.health = 200;
 641         portal.fade_time = time + cvar("g_balance_portal_lifetime");
 642         portal.health = cvar("g_balance_portal_health");
 643         setmodel(portal, "models/portal.md3");
 644         portal.modelindex_lod0 = portal.modelindex;
 645         portal.customizeentityforclient = Portal_Customize;
 646
 647         if(!Portal_FindSafeOrigin(portal))
 648         {
 649                 remove(portal);
 650                 return world;
 651         }
 652
 653         setsize(portal, '-48 -48 -48', '48 48 48');
 654         Portal_MakeWaitingPortal(portal);
 655
 656         return portal;
 657 }
 658
 659 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 660 {
 661         entity portal;
 662         vector ang;
 663         vector org;
 664
 665         org = trace_endpos;
 666         ang = fixedvectoangles2(trace_plane_normal, dir);
 667         fixedmakevectors(ang);
 668
 669         portal = Portal_Spawn(own, org, ang);
 670         if(!portal)
 671         {
 672                 // if(!own.portal_out || own.portal_out.portal_id == portal_id_val)
 673                         Portal_ClearAll_PortalsOnly(own);
 674                 return 0;
 675         }
 676
 677         portal.portal_id = portal_id_val;
 678         Portal_SetInPortal(own, portal);
 679
 680         return 1;
 681 }
 682
 683 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 684 {
 685         entity portal;
 686         vector ang;
 687         vector org;
 688
 689         org = trace_endpos;
 690         ang = fixedvectoangles2(trace_plane_normal, dir);
 691         fixedmakevectors(ang);
 692
 693         portal = Portal_Spawn(own, org, ang);
 694         if(!portal)
 695         {
 696                 // if(!own.portal_in || own.portal_in.portal_id == portal_id_val)
 697                         Portal_ClearAll_PortalsOnly(own);
 698                 return 0;
 699         }
 700
 701         portal.portal_id = portal_id_val;
 702         Portal_SetOutPortal(own, portal);
 703
 704         return 1;
 705 }