data/qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   7 void() spawnpoint_use;
   8 string ColoredTeamName(float t);
   9
  10 float RandomSelection_totalweight;
  11 float RandomSelection_best_priority;
  12 entity RandomSelection_chosen_ent;
  13 float RandomSelection_chosen_float;
  14 void RandomSelection_Init()
  15 {
  16         RandomSelection_totalweight = 0;
  17         RandomSelection_chosen_ent = world;
  18         RandomSelection_chosen_float = 0;
  19         RandomSelection_best_priority = -1;
  20 }
  21 void RandomSelection_Add(entity e, float f, float weight, float priority)
  22 {
  23         if(priority > RandomSelection_best_priority)
  24         {
  25                 RandomSelection_best_priority = priority;
  26                 RandomSelection_chosen_ent = e;
  27                 RandomSelection_chosen_float = f;
  28                 RandomSelection_totalweight = weight;
  29         }
  30         else if(priority == RandomSelection_best_priority)
  31         {
  32                 RandomSelection_totalweight += weight;
  33                 if(random() * RandomSelection_totalweight <= weight)
  34                 {
  35                         RandomSelection_chosen_ent = e;
  36                         RandomSelection_chosen_float = f;
  37                 }
  38         }
  39 }
  40
  41 float DistributeEvenly_amount;
  42 float DistributeEvenly_totalweight;
  43 void DistributeEvenly_Init(float amount, float totalweight)
  44 {
  45         if(DistributeEvenly_amount)
  46         {
  47                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  48                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  49         }
  50         if(totalweight == 0)
  51                 DistributeEvenly_amount = 0;
  52         else
  53                 DistributeEvenly_amount = amount;
  54         DistributeEvenly_totalweight = totalweight;
  55 }
  56 float DistributeEvenly_Get(float weight)
  57 {
  58         float f;
  59         if(weight <= 0)
  60                 return 0;
  61         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  62         DistributeEvenly_totalweight -= weight;
  63         DistributeEvenly_amount -= f;
  64         return f;
  65 }
  66
  67 void move_out_of_solid_expand(entity e, vector by)
  68 {
  69         float eps = 0.0625;
  70         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  71         if(trace_startsolid)
  72                 return;
  73         if(trace_fraction < 1)
  74         {
  75                 // hit something
  76                 // adjust origin in the other direction...
  77                 e.origin = e.origin - by * (1 - trace_fraction);
  78         }
  79 }
  80
  81 float move_out_of_solid(entity e)
  82 {
  83         vector o, m0, m1;
  84
  85         o = e.origin;
  86         traceline(o, o, MOVE_WORLDONLY, e);
  87         if(trace_startsolid)
  88                 return 0;
  89
  90         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  91         if(!trace_startsolid)
  92                 return 1;
  93
  94         m0 = e.mins;
  95         m1 = e.maxs;
  96         e.mins = '0 0 0';
  97         e.maxs = '0 0 0';
  98         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  99         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
 100         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
 101         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
 102         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
 103         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
 104         setorigin(e, e.origin);
 105
 106         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 107         if(trace_startsolid)
 108         {
 109                 setorigin(e, o);
 110                 return 0;
 111         }
 112
 113         return 1;
 114 }
 115
 116 string STR_PLAYER = "player";
 117 string STR_SPECTATOR = "spectator";
 118 string STR_OBSERVER = "observer";
 119
 120 #if 0
 121 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 122 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 123 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 124 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 125 #else
 126 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 127 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 128 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 129 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 130 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 131 #endif
 132
 133 // copies a string to a tempstring (so one can strunzone it)
 134 string strcat1(string s) = #115; // FRIK_FILE
 135
 136 float logfile_open;
 137 float logfile;
 138
 139 void bcenterprint(string s)
 140 {
 141         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 142         entity head;
 143         FOR_EACH_PLAYER(head)
 144                 if(clienttype(head) == CLIENTTYPE_REAL)
 145                         centerprint(head, s);
 146 }
 147
 148 void GameLogEcho(string s)
 149 {
 150         string fn;
 151         float matches;
 152
 153         if(cvar("sv_eventlog_files"))
 154         {
 155                 if(!logfile_open)
 156                 {
 157                         logfile_open = TRUE;
 158                         matches = cvar("sv_eventlog_files_counter") + 1;
 159                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 160                         fn = ftos(matches);
 161                         if(strlen(fn) < 8)
 162                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 163                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 164                         logfile = fopen(fn, FILE_APPEND);
 165                         fputs(logfile, ":logversion:3\n");
 166                 }
 167                 if(logfile >= 0)
 168                 {
 169                         if(cvar("sv_eventlog_files_timestamps"))
 170                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 171                         else
 172                                 fputs(logfile, strcat(s, "\n"));
 173                 }
 174         }
 175         if(cvar("sv_eventlog_console"))
 176         {
 177                 print(s, "\n");
 178         }
 179 }
 180
 181 void GameLogInit()
 182 {
 183         logfile_open = 0;
 184         // will be opened later
 185 }
 186
 187 void GameLogClose()
 188 {
 189         if(logfile_open && logfile >= 0)
 190         {
 191                 fclose(logfile);
 192                 logfile = -1;
 193         }
 194 }
 195
 196 float spawnpoint_nag;
 197 void relocate_spawnpoint()
 198 {
 199         // nudge off the floor
 200         setorigin(self, self.origin + '0 0 1');
 201
 202         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 203         if (trace_startsolid)
 204         {
 205                 vector o;
 206                 o = self.origin;
 207                 self.mins = PL_MIN;
 208                 self.maxs = PL_MAX;
 209                 if(!move_out_of_solid(self))
 210                         objerror("could not get out of solid at all!");
 211                 print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 212                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 213                 print(" ", ftos(self.origin_y - o_y));
 214                 print(" ", ftos(self.origin_z - o_z), "'\n");
 215                 if(cvar("g_spawnpoints_auto_move_out_of_solid"))
 216                 {
 217                         if(!spawnpoint_nag)
 218                                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 219                         spawnpoint_nag = 1;
 220                 }
 221                 else
 222                 {
 223                         self.origin = o;
 224                         self.mins = self.maxs = '0 0 0';
 225                         objerror("player spawn point in solid, mapper sucks!\n");
 226                         return;
 227                 }
 228         }
 229
 230         if(cvar("g_spawnpoints_autodrop"))
 231         {
 232                 setsize(self, PL_MIN, PL_MAX);
 233                 droptofloor();
 234         }
 235
 236         self.use = spawnpoint_use;
 237         self.team_saved = self.team;
 238         if(!self.cnt)
 239                 self.cnt = 1;
 240
 241         if(g_ctf || g_assault || g_onslaught || g_domination)
 242         if(self.team)
 243                 have_team_spawns = 1;
 244
 245         if(cvar("r_showbboxes"))
 246         {
 247                 // show where spawnpoints point at too
 248                 makevectors(self.angles);
 249                 entity e;
 250                 e = spawn();
 251                 e.classname = "info_player_foo";
 252                 setorigin(e, self.origin + v_forward * 24);
 253                 setsize(e, '-8 -8 -8', '8 8 8');
 254                 e.solid = SOLID_TRIGGER;
 255         }
 256 }
 257
 258 #define strstr strstrofs
 259 /*
 260 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 261 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 262 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 263 // BE CONSTANT OR strzoneD!
 264 float strstr(string haystack, string needle, float offset)
 265 {
 266         float len, endpos;
 267         string found;
 268         len = strlen(needle);
 269         endpos = strlen(haystack) - len;
 270         while(offset <= endpos)
 271         {
 272                 found = substring(haystack, offset, len);
 273                 if(found == needle)
 274                         return offset;
 275                 offset = offset + 1;
 276         }
 277         return -1;
 278 }
 279 */
 280
 281 float NUM_NEAREST_ENTITIES = 4;
 282 entity nearest_entity[NUM_NEAREST_ENTITIES];
 283 float nearest_length[NUM_NEAREST_ENTITIES];
 284 entity findnearest(vector point, .string field, string value, vector axismod)
 285 {
 286         entity localhead;
 287         float i;
 288         float j;
 289         float len;
 290         vector dist;
 291
 292         float num_nearest;
 293         num_nearest = 0;
 294
 295         localhead = find(world, field, value);
 296         while(localhead)
 297         {
 298                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 299                         dist = localhead.oldorigin;
 300                 else
 301                         dist = localhead.origin;
 302                 dist = dist - point;
 303                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 304                 len = vlen(dist);
 305
 306                 for(i = 0; i < num_nearest; ++i)
 307                 {
 308                         if(len < nearest_length[i])
 309                                 break;
 310                 }
 311
 312                 // now i tells us where to insert at
 313                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 314                 if(i < NUM_NEAREST_ENTITIES)
 315                 {
 316                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 317                         {
 318                                 nearest_length[j + 1] = nearest_length[j];
 319                                 nearest_entity[j + 1] = nearest_entity[j];
 320                         }
 321                         nearest_length[i] = len;
 322                         nearest_entity[i] = localhead;
 323                         if(num_nearest < NUM_NEAREST_ENTITIES)
 324                                 num_nearest = num_nearest + 1;
 325                 }
 326
 327                 localhead = find(localhead, field, value);
 328         }
 329
 330         // now use the first one from our list that we can see
 331         for(i = 0; i < num_nearest; ++i)
 332         {
 333                 traceline(point, nearest_entity[i].origin, TRUE, world);
 334                 if(trace_fraction == 1)
 335                 {
 336                         if(i != 0)
 337                         {
 338                                 dprint("Nearest point (");
 339                                 dprint(nearest_entity[0].netname);
 340                                 dprint(") is not visible, using a visible one.\n");
 341                         }
 342                         return nearest_entity[i];
 343                 }
 344         }
 345
 346         if(num_nearest == 0)
 347                 return world;
 348
 349         dprint("Not seeing any location point, using nearest as fallback.\n");
 350         /* DEBUGGING CODE:
 351         dprint("Candidates were: ");
 352         for(j = 0; j < num_nearest; ++j)
 353         {
 354                 if(j != 0)
 355                         dprint(", ");
 356                 dprint(nearest_entity[j].netname);
 357         }
 358         dprint("\n");
 359         */
 360
 361         return nearest_entity[0];
 362 }
 363
 364 void spawnfunc_target_location()
 365 {
 366         self.classname = "target_location";
 367         // location name in netname
 368         // eventually support: count, teamgame selectors, line of sight?
 369 };
 370
 371 void spawnfunc_info_location()
 372 {
 373         self.classname = "target_location";
 374         self.message = self.netname;
 375 };
 376
 377 string NearestLocation(vector p)
 378 {
 379         entity loc;
 380         string ret;
 381         ret = "somewhere";
 382         loc = findnearest(p, classname, "target_location", '1 1 1');
 383         if(loc)
 384         {
 385                 ret = loc.message;
 386         }
 387         else
 388         {
 389                 loc = findnearest(p, target, "###item###", '1 1 4');
 390                 if(loc)
 391                         ret = loc.netname;
 392         }
 393         return ret;
 394 }
 395
 396 string formatmessage(string msg)
 397 {
 398         float p, p1, p2;
 399         float n;
 400         string escape;
 401         string replacement;
 402         p = 0;
 403         n = 7;
 404         while(1)
 405         {
 406                 if(n < 1)
 407                         break; // too many replacements
 408                 n = n - 1;
 409                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 410                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 411
 412                 if(p1 < 0)
 413                         p1 = p2;
 414                 if(p2 < 0)
 415                         p2 = p1;
 416                 p = min(p1, p2);
 417
 418                 if(p < 0)
 419                         break;
 420                 replacement = substring(msg, p, 2);
 421                 escape = substring(msg, p + 1, 1);
 422                 if(escape == "%")
 423                         replacement = "%";
 424                 else if(escape == "\\")
 425                         replacement = "\\";
 426                 else if(escape == "n")
 427                         replacement = "\n";
 428                 else if(escape == "a")
 429                         replacement = ftos(floor(self.armorvalue));
 430                 else if(escape == "h")
 431                         replacement = ftos(floor(self.health));
 432                 else if(escape == "l")
 433                         replacement = NearestLocation(self.origin);
 434                 else if(escape == "y")
 435                         replacement = NearestLocation(self.cursor_trace_endpos);
 436                 else if(escape == "d")
 437                         replacement = NearestLocation(self.death_origin);
 438                 else if(escape == "w")
 439                 {
 440                         float wep;
 441                         wep = self.weapon;
 442                         if(!wep)
 443                                 wep = self.switchweapon;
 444                         if(!wep)
 445                                 wep = self.cnt;
 446                         replacement = W_Name(wep);
 447                 }
 448                 else if(escape == "W")
 449                 {
 450                         if(self.items & IT_SHELLS) replacement = "shells";
 451                         else if(self.items & IT_NAILS) replacement = "bullets";
 452                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 453                         else if(self.items & IT_CELLS) replacement = "cells";
 454                         else replacement = "batteries"; // ;)
 455                 }
 456                 else if(escape == "x")
 457                 {
 458                         replacement = self.cursor_trace_ent.netname;
 459                         if(!replacement || !self.cursor_trace_ent)
 460                                 replacement = "nothing";
 461                 }
 462                 else if(escape == "p")
 463                 {
 464                         if(self.last_selected_player)
 465                                 replacement = self.last_selected_player.netname;
 466                         else
 467                                 replacement = "(nobody)";
 468                 }
 469                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 470                 p = p + strlen(replacement);
 471         }
 472         return msg;
 473 }
 474
 475 /*
 476 =============
 477 GetCvars
 478 =============
 479 Called with:
 480   0:  sends the request
 481   >0: receives a cvar from name=argv(f) value=argv(f+1)
 482 */
 483 void GetCvars_handleString(string thisname, float f, .string field, string name)
 484 {
 485         if(f < 0)
 486         {
 487                 if(self.field)
 488                         strunzone(self.field);
 489                 self.field = string_null;
 490         }
 491         else if(f > 0)
 492         {
 493                 if(thisname == name)
 494                 {
 495                         if(self.field)
 496                                 strunzone(self.field);
 497                         self.field = strzone(argv(f + 1));
 498                 }
 499         }
 500         else
 501                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 502 }
 503 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 504 {
 505         GetCvars_handleString(thisname, f, field, name);
 506         if(f >= 0) // also initialize to the fitting value for "" when sending cvars out
 507         if(thisname == name)
 508         {
 509                 string s;
 510                 s = func(strcat1(self.field));
 511                 if(s != self.field)
 512                 {
 513                         strunzone(self.field);
 514                         self.field = strzone(s);
 515                 }
 516         }
 517 }
 518 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 519 {
 520         if(f < 0)
 521         {
 522         }
 523         else if(f > 0)
 524         {
 525                 if(thisname == name)
 526                         self.field = stof(argv(f + 1));
 527         }
 528         else
 529                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 530 }
 531 string W_FixWeaponOrder_ForceComplete(string s);
 532 string W_FixWeaponOrder_AllowIncomplete(string s);
 533 float w_getbestweapon(entity e);
 534 void GetCvars(float f)
 535 {
 536         string s;
 537         if(f > 0)
 538                 s = strcat1(argv(f));
 539         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 540         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 541         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 542         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 543         GetCvars_handleString(s, f, cvar_g_nexuizversion, "g_nexuizversion");
 544         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 558         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 559         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 560
 561         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 562         if(f > 0)
 563         {
 564                 if(s == "cl_weaponpriority")
 565                         self.switchweapon = w_getbestweapon(self);
 566         }
 567 }
 568
 569 float fexists(string f)
 570 {
 571         float fh;
 572         fh = fopen(f, FILE_READ);
 573         if(fh < 0)
 574                 return FALSE;
 575         fclose(fh);
 576         return TRUE;
 577 }
 578
 579 void backtrace(string msg)
 580 {
 581         float dev;
 582         dev = cvar("developer");
 583         cvar_set("developer", "1");
 584         dprint("\n");
 585         dprint("--- CUT HERE ---\nWARNING: ");
 586         dprint(msg);
 587         dprint("\n");
 588         remove(world); // isn't there any better way to cause a backtrace?
 589         dprint("\n--- CUT UNTIL HERE ---\n");
 590         cvar_set("developer", ftos(dev));
 591 }
 592
 593 string Team_ColorCode(float teamid)
 594 {
 595         if(teamid == COLOR_TEAM1)
 596                 return "^1";
 597         else if(teamid == COLOR_TEAM2)
 598                 return "^4";
 599         else if(teamid == COLOR_TEAM3)
 600                 return "^3";
 601         else if(teamid == COLOR_TEAM4)
 602                 return "^6";
 603         else
 604                 return "^7";
 605 }
 606 string Team_ColorName(float t)
 607 {
 608         // fixme: Search for team entities and get their .netname's!
 609         if(t == COLOR_TEAM1)
 610                 return "Red";
 611         if(t == COLOR_TEAM2)
 612                 return "Blue";
 613         if(t == COLOR_TEAM3)
 614                 return "Yellow";
 615         if(t == COLOR_TEAM4)
 616                 return "Pink";
 617         return "Neutral";
 618 }
 619 string Team_ColorNameLowerCase(float t)
 620 {
 621         // fixme: Search for team entities and get their .netname's!
 622         if(t == COLOR_TEAM1)
 623                 return "red";
 624         if(t == COLOR_TEAM2)
 625                 return "blue";
 626         if(t == COLOR_TEAM3)
 627                 return "yellow";
 628         if(t == COLOR_TEAM4)
 629                 return "pink";
 630         return "neutral";
 631 }
 632
 633 #define CENTERPRIO_POINT 1
 634 #define CENTERPRIO_SPAM 2
 635 #define CENTERPRIO_VOTE 4
 636 #define CENTERPRIO_NORMAL 5
 637 #define CENTERPRIO_SHIELDING 7
 638 #define CENTERPRIO_MAPVOTE 9
 639 #define CENTERPRIO_IDLEKICK 50
 640 #define CENTERPRIO_ADMIN 99
 641 .float centerprint_priority;
 642 .float centerprint_expires;
 643 void centerprint_atprio(entity e, float prio, string s)
 644 {
 645         if(intermission_running)
 646                 if(prio < CENTERPRIO_MAPVOTE)
 647                         return;
 648         if(time > e.centerprint_expires)
 649                 e.centerprint_priority = 0;
 650         if(prio >= e.centerprint_priority)
 651         {
 652                 e.centerprint_priority = prio;
 653                 if(timeoutStatus == 2)
 654                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 655                 else
 656                         e.centerprint_expires = time + e.cvar_scr_centertime;
 657                 centerprint_builtin(e, s);
 658         }
 659 }
 660 void centerprint_expire(entity e, float prio)
 661 {
 662         if(prio == e.centerprint_priority)
 663         {
 664                 e.centerprint_priority = 0;
 665                 centerprint_builtin(e, "");
 666         }
 667 }
 668 void centerprint(entity e, string s)
 669 {
 670         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 671 }
 672
 673 // decolorizes and team colors the player name when needed
 674 string playername(entity p)
 675 {
 676         string t;
 677         if(teams_matter && !intermission_running && p.classname == "player")
 678         {
 679                 t = Team_ColorCode(p.team);
 680                 return strcat(t, strdecolorize(p.netname));
 681         }
 682         else
 683                 return p.netname;
 684 }
 685
 686 vector randompos(vector m1, vector m2)
 687 {
 688         local vector v;
 689         m2 = m2 - m1;
 690         v_x = m2_x * random() + m1_x;
 691         v_y = m2_y * random() + m1_y;
 692         v_z = m2_z * random() + m1_z;
 693         return  v;
 694 };
 695
 696 float g_pickup_shells;
 697 float g_pickup_shells_max;
 698 float g_pickup_nails;
 699 float g_pickup_nails_max;
 700 float g_pickup_rockets;
 701 float g_pickup_rockets_max;
 702 float g_pickup_cells;
 703 float g_pickup_cells_max;
 704 float g_pickup_armorsmall;
 705 float g_pickup_armorsmall_max;
 706 float g_pickup_armormedium;
 707 float g_pickup_armormedium_max;
 708 float g_pickup_armorlarge;
 709 float g_pickup_armorlarge_max;
 710 float g_pickup_healthsmall;
 711 float g_pickup_healthsmall_max;
 712 float g_pickup_healthmedium;
 713 float g_pickup_healthmedium_max;
 714 float g_pickup_healthlarge;
 715 float g_pickup_healthlarge_max;
 716 float g_pickup_healthmega;
 717 float g_pickup_healthmega_max;
 718 float g_weaponarena;
 719 string g_weaponarena_list;
 720
 721 float start_weapons;
 722 float start_items;
 723 float start_ammo_shells;
 724 float start_ammo_nails;
 725 float start_ammo_rockets;
 726 float start_ammo_cells;
 727 float start_health;
 728 float start_armorvalue;
 729 float warmup_start_weapons;
 730 float warmup_start_ammo_shells;
 731 float warmup_start_ammo_nails;
 732 float warmup_start_ammo_rockets;
 733 float warmup_start_ammo_cells;
 734 float warmup_start_health;
 735 float warmup_start_armorvalue;
 736 float g_weapon_stay;
 737
 738 entity get_weaponinfo(float w);
 739
 740 void readplayerstartcvars()
 741 {
 742         entity e;
 743         float i, j, t;
 744         string s;
 745
 746         // initialize starting values for players
 747         start_weapons = 0;
 748         start_items = 0;
 749         start_ammo_shells = 0;
 750         start_ammo_nails = 0;
 751         start_ammo_rockets = 0;
 752         start_ammo_cells = 0;
 753         start_health = cvar("g_balance_health_start");
 754         start_armorvalue = cvar("g_balance_armor_start");
 755
 756         g_weaponarena = 0;
 757         s = cvar_string("g_weaponarena");
 758         if(s == "0")
 759         {
 760         }
 761         else if(s == "all")
 762         {
 763                 g_weaponarena_list = "All Weapons";
 764                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 765                 {
 766                         e = get_weaponinfo(j);
 767                         g_weaponarena |= e.weapons;
 768                         weapon_action(e.weapon, WR_PRECACHE);
 769                 }
 770         }
 771         else if(s == "most")
 772         {
 773                 g_weaponarena_list = "Most Weapons";
 774                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 775                 {
 776                         e = get_weaponinfo(j);
 777                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 778                         {
 779                                 g_weaponarena |= e.weapons;
 780                                 weapon_action(e.weapon, WR_PRECACHE);
 781                         }
 782                 }
 783         }
 784         else
 785         {
 786                 t = tokenize_sane(s);
 787                 g_weaponarena_list = "";
 788                 for(i = 0; i < t; ++i)
 789                 {
 790                         s = argv(i);
 791                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 792                         {
 793                                 e = get_weaponinfo(j);
 794                                 if(e.netname == s)
 795                                 {
 796                                         g_weaponarena |= e.weapons;
 797                                         weapon_action(e.weapon, WR_PRECACHE);
 798                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 799                                         break;
 800                                 }
 801                         }
 802                         if(j > WEP_LAST)
 803                         {
 804                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 805                         }
 806                 }
 807                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 808         }
 809
 810         if(g_weaponarena)
 811         {
 812                 start_weapons = g_weaponarena;
 813                 start_ammo_rockets = 999;
 814                 start_ammo_shells = 999;
 815                 start_ammo_cells = 999;
 816                 start_ammo_nails = 999;
 817                 start_items |= IT_UNLIMITED_AMMO;
 818         }
 819         else if(g_nixnex)
 820         {
 821                 start_weapons = 0;
 822                 // will be done later
 823                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 824                 {
 825                         e = get_weaponinfo(i);
 826                         if(!(e.weapon))
 827                                 continue;
 828                         weapon_action(e.weapon, WR_PRECACHE);
 829                 }
 830         }
 831         else if(g_minstagib)
 832         {
 833                 start_health = 100;
 834                 start_armorvalue = 0;
 835                 start_weapons = WEPBIT_MINSTANEX;
 836                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 837                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 838                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 839
 840                 if(g_minstagib_invis_alpha <= 0)
 841                         g_minstagib_invis_alpha = -1;
 842         }
 843         else
 844         {
 845                 if(g_lms)
 846                 {
 847                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 848                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 849                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 850                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 851                         start_health = cvar("g_lms_start_health");
 852                         start_armorvalue = cvar("g_lms_start_armor");
 853                 } else if (cvar("g_use_ammunition")) {
 854                         start_ammo_shells = cvar("g_start_ammo_shells");
 855                         start_ammo_nails = cvar("g_start_ammo_nails");
 856                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 857                         start_ammo_cells = cvar("g_start_ammo_cells");
 858                 } else {
 859                         start_ammo_shells = cvar("g_pickup_shells_max");
 860                         start_ammo_nails = cvar("g_pickup_nails_max");
 861                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 862                         start_ammo_cells = cvar("g_pickup_cells_max");
 863                         start_items |= IT_UNLIMITED_AMMO;
 864                 }
 865
 866                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 867                 {
 868                         e = get_weaponinfo(i);
 869                         if(!(e.weapon))
 870                                 continue;
 871
 872                         t = cvar(strcat("g_start_weapon_", e.netname));
 873
 874                         if(t < 0) // "default" weapon selection
 875                         {
 876                                 if(g_lms)
 877                                         t = (e.spawnflags & WEPSPAWNFLAG_NORMAL);
 878                                 else if(g_race)
 879                                         t = (i == WEP_LASER);
 880                                 else
 881                                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 882                                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 883                                         t += (i == WEP_HOOK);
 884                         }
 885
 886                         if(t)
 887                         {
 888                                 start_weapons |= e.weapons;
 889                                 weapon_action(e.weapon, WR_PRECACHE);
 890                         }
 891                 }
 892         }
 893
 894         if(inWarmupStage)
 895         {
 896                 warmup_start_ammo_shells = start_ammo_shells;
 897                 warmup_start_ammo_nails = start_ammo_nails;
 898                 warmup_start_ammo_rockets = start_ammo_rockets;
 899                 warmup_start_ammo_cells = start_ammo_cells;
 900                 warmup_start_health = start_health;
 901                 warmup_start_armorvalue = start_armorvalue;
 902                 warmup_start_weapons = start_weapons;
 903
 904                 if(!g_weaponarena && !g_nixnex && !g_minstagib)
 905                 {
 906                         if(cvar("g_use_ammunition"))
 907                         {
 908                                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 909                                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 910                                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 911                                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 912                         }
 913                         warmup_start_health = cvar("g_warmup_start_health");
 914                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 915                         if(cvar("g_warmup_allguns"))
 916                         {
 917                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 918                                 {
 919                                         e = get_weaponinfo(i);
 920                                         if(!(e.weapon))
 921                                                 continue;
 922                                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 923                                         {
 924                                                 warmup_start_weapons |= e.weapons;
 925                                                 weapon_action(e.weapon, WR_PRECACHE);
 926                                         }
 927                                 }
 928                         }
 929                 }
 930         }
 931
 932         if(start_weapons & WEPBIT_HOOK)
 933         {
 934                 // can't have off-hand hook, if hook weapon is enabled
 935                 g_grappling_hook = 0;
 936         }
 937
 938         if(g_weapon_stay == 2)
 939         {
 940                 if(!start_ammo_shells) start_ammo_shells = g_pickup_shells;
 941                 if(!start_ammo_nails) start_ammo_shells = g_pickup_nails;
 942                 if(!start_ammo_cells) start_ammo_shells = g_pickup_cells;
 943                 if(!start_ammo_rockets) start_ammo_shells = g_pickup_rockets;
 944                 if(!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
 945                 if(!warmup_start_ammo_nails) warmup_start_ammo_shells = g_pickup_nails;
 946                 if(!warmup_start_ammo_cells) warmup_start_ammo_shells = g_pickup_cells;
 947                 if(!warmup_start_ammo_rockets) warmup_start_ammo_shells = g_pickup_rockets;
 948         }
 949
 950         start_ammo_shells = max(0, start_ammo_shells);
 951         start_ammo_nails = max(0, start_ammo_nails);
 952         start_ammo_cells = max(0, start_ammo_cells);
 953         start_ammo_rockets = max(0, start_ammo_rockets);
 954
 955         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 956         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 957         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 958         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 959 }
 960
 961 float g_bugrigs;
 962 float g_bugrigs_planar_movement;
 963 float g_bugrigs_planar_movement_car_jumping;
 964 float g_bugrigs_reverse_spinning;
 965 float g_bugrigs_reverse_speeding;
 966 float g_bugrigs_reverse_stopping;
 967 float g_bugrigs_air_steering;
 968 float g_bugrigs_angle_smoothing;
 969 float g_bugrigs_friction_floor;
 970 float g_bugrigs_friction_brake;
 971 float g_bugrigs_friction_air;
 972 float g_bugrigs_accel;
 973 float g_bugrigs_speed_ref;
 974 float g_bugrigs_speed_pow;
 975 float g_bugrigs_steer;
 976
 977 float g_touchexplode;
 978 float g_touchexplode_radius;
 979 float g_touchexplode_damage;
 980 float g_touchexplode_edgedamage;
 981 float g_touchexplode_force;
 982
 983 void readlevelcvars(void)
 984 {
 985         g_bugrigs = cvar("g_bugrigs");
 986         g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 987         g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 988         g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 989         g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 990         g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 991         g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 992         g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 993         g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 994         g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 995         g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 996         g_bugrigs_accel = cvar("g_bugrigs_accel");
 997         g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 998         g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 999         g_bugrigs_steer = cvar("g_bugrigs_steer");
1000
1001         g_touchexplode = cvar("g_touchexplode");
1002         g_touchexplode_radius = cvar("g_touchexplode_radius");
1003         g_touchexplode_damage = cvar("g_touchexplode_damage");
1004         g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1005         g_touchexplode_force = cvar("g_touchexplode_force");
1006
1007         sv_clones = cvar("sv_clones");
1008         sv_cheats = cvar("sv_cheats");
1009         sv_gentle = cvar("sv_gentle");
1010         sv_foginterval = cvar("sv_foginterval");
1011         g_cloaked = cvar("g_cloaked");
1012         g_jump_grunt = cvar("g_jump_grunt");
1013         g_footsteps = cvar("g_footsteps");
1014         g_grappling_hook = cvar("g_grappling_hook");
1015         g_laserguided_missile = cvar("g_laserguided_missile");
1016         g_midair = cvar("g_midair");
1017         g_minstagib = cvar("g_minstagib");
1018         g_nixnex = cvar("g_nixnex");
1019         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
1020         g_norecoil = cvar("g_norecoil");
1021         g_vampire = cvar("g_vampire");
1022         g_bloodloss = cvar("g_bloodloss");
1023         sv_maxidle = cvar("sv_maxidle");
1024         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1025         sv_pogostick = cvar("sv_pogostick");
1026         sv_doublejump = cvar("sv_doublejump");
1027         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
1028         g_ctf_reverse = cvar("g_ctf_reverse");
1029
1030         inWarmupStage = cvar("g_warmup");
1031         g_warmup_limit = cvar("g_warmup_limit");
1032         g_warmup_allguns = cvar("g_warmup_allguns");
1033         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1034
1035         if(g_race && g_race_qualifying == 2 || g_arena || g_assault || cvar("g_campaign"))
1036                 inWarmupStage = 0; // these modes cannot work together, sorry
1037
1038         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1039         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1040         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1041         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1042         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1043         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1044
1045         if(g_minstagib) g_nixnex = g_weaponarena = 0;
1046         if(g_nixnex) g_weaponarena = 0;
1047         g_weaponarena = 0;
1048
1049         g_pickup_shells                    = cvar("g_pickup_shells");
1050         g_pickup_shells_max                = cvar("g_pickup_shells_max");
1051         g_pickup_nails                     = cvar("g_pickup_nails");
1052         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
1053         g_pickup_rockets                   = cvar("g_pickup_rockets");
1054         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
1055         g_pickup_cells                     = cvar("g_pickup_cells");
1056         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
1057         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
1058         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
1059         g_pickup_armormedium               = cvar("g_pickup_armormedium");
1060         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
1061         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
1062         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
1063         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
1064         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
1065         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
1066         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
1067         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
1068         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
1069         g_pickup_healthmega                = cvar("g_pickup_healthmega");
1070         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
1071
1072         g_weapon_stay = cvar("g_weapon_stay");
1073         if(!g_weapon_stay && (cvar("deathmatch") == 2))
1074                 g_weapon_stay = 1;
1075
1076         if not(inWarmupStage)
1077                 game_starttime                 = cvar("g_start_delay");
1078
1079         readplayerstartcvars();
1080 }
1081
1082 /*
1083 // TODO sound pack system
1084 string soundpack;
1085
1086 string precache_sound_builtin (string s) = #19;
1087 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1088 string precache_sound(string s)
1089 {
1090         return precache_sound_builtin(strcat(soundpack, s));
1091 }
1092 void play2(entity e, string filename)
1093 {
1094         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1095 }
1096 void sound(entity e, float chan, string samp, float vol, float atten)
1097 {
1098         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1099 }
1100 */
1101
1102 // Sound functions
1103 string precache_sound (string s) = #19;
1104 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
1105 float precache_sound_index (string s) = #19;
1106
1107 #define SND_VOLUME      1
1108 #define SND_ATTENUATION 2
1109 #define SND_LARGEENTITY 8
1110 #define SND_LARGESOUND  16
1111
1112 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1113 {
1114         float entno, idx;
1115         entno = num_for_edict(e);
1116         idx = precache_sound_index(samp);
1117
1118         float sflags;
1119         sflags = 0;
1120
1121         atten = floor(atten * 64);
1122         vol = floor(vol * 255);
1123
1124         if(vol != 255)
1125                 sflags |= SND_VOLUME;
1126         if(atten != 64)
1127                 sflags |= SND_ATTENUATION;
1128         if(entno >= 8192)
1129                 sflags |= SND_LARGEENTITY;
1130         if(idx >= 256)
1131                 sflags |= SND_LARGESOUND;
1132
1133         WriteByte(dest, SVC_SOUND);
1134         WriteByte(dest, sflags);
1135         if(sflags & SND_VOLUME)
1136                 WriteByte(dest, vol * 255);
1137         if(sflags & SND_ATTENUATION)
1138                 WriteByte(dest, atten);
1139         if(sflags & SND_LARGEENTITY)
1140         {
1141                 WriteShort(dest, entno);
1142                 WriteByte(dest, chan);
1143         }
1144         else
1145         {
1146                 WriteShort(dest, entno * 8 + chan);
1147         }
1148         if(sflags & SND_LARGESOUND)
1149                 WriteShort(dest, idx);
1150         else
1151                 WriteByte(dest, idx);
1152
1153         WriteCoord(dest, o_x);
1154         WriteCoord(dest, o_y);
1155         WriteCoord(dest, o_z);
1156 }
1157 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1158 {
1159         vector o;
1160         o = e.origin + 0.5 * (e.mins + e.maxs);
1161         soundtoat(dest, e, o, chan, samp, vol, atten);
1162 }
1163 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1164 {
1165         soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1166 }
1167 void stopsoundto(float dest, entity e, float chan)
1168 {
1169         float entno;
1170         entno = num_for_edict(e);
1171
1172         if(entno >= 8192)
1173         {
1174                 float idx, sflags;
1175                 idx = precache_sound_index("misc/null.wav");
1176                 sflags = SND_LARGEENTITY;
1177                 if(idx >= 256)
1178                         sflags |= SND_LARGESOUND;
1179                 WriteByte(dest, SVC_SOUND);
1180                 WriteByte(dest, sflags);
1181                 WriteShort(dest, entno);
1182                 WriteByte(dest, chan);
1183                 if(sflags & SND_LARGESOUND)
1184                         WriteShort(dest, idx);
1185                 else
1186                         WriteByte(dest, idx);
1187                 WriteCoord(dest, e.origin_x);
1188                 WriteCoord(dest, e.origin_y);
1189                 WriteCoord(dest, e.origin_z);
1190         }
1191         else
1192         {
1193                 WriteByte(dest, SVC_STOPSOUND);
1194                 WriteShort(dest, entno * 8 + chan);
1195         }
1196 }
1197 void stopsound(entity e, float chan)
1198 {
1199         stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1200         stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1201 }
1202
1203 void play2(entity e, string filename)
1204 {
1205         //stuffcmd(e, strcat("play2 ", filename, "\n"));
1206         msg_entity = e;
1207         soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1208 }
1209
1210 .float announcetime;
1211 float announce(entity player, string msg)
1212 {
1213         if(time > player.announcetime)
1214         if(clienttype(player) == CLIENTTYPE_REAL)
1215         {
1216                 player.announcetime = time + 0.8;
1217                 play2(player, msg);
1218                 return TRUE;
1219         }
1220         return FALSE;
1221 }
1222
1223 void play2team(float t, string filename)
1224 {
1225         local entity head;
1226         FOR_EACH_REALPLAYER(head)
1227         {
1228                 if (head.team == t)
1229                         play2(head, filename);
1230         }
1231 }
1232
1233 void play2all(string samp)
1234 {
1235         sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1236 }
1237
1238 void PrecachePlayerSounds(string f);
1239 void precache_all_models(string pattern)
1240 {
1241         float globhandle, i, n;
1242         string f;
1243
1244         globhandle = search_begin(pattern, TRUE, FALSE);
1245         if(globhandle < 0)
1246                 return;
1247         n = search_getsize(globhandle);
1248         for(i = 0; i < n; ++i)
1249         {
1250                 //print(search_getfilename(globhandle, i), "\n");
1251                 f = search_getfilename(globhandle, i);
1252                 precache_model(f);
1253                 PrecachePlayerSounds(strcat(f, ".sounds"));
1254         }
1255         search_end(globhandle);
1256 }
1257
1258 void precache()
1259 {
1260         // gamemode related things
1261         precache_model ("null");
1262         precache_model ("models/misc/chatbubble.spr");
1263         precache_model ("models/misc/teambubble.spr");
1264         if (g_runematch)
1265         {
1266                 precache_model ("models/runematch/curse.mdl");
1267                 precache_model ("models/runematch/rune.mdl");
1268         }
1269
1270 #ifdef TTURRETS_ENABLED
1271     if(cvar("g_turrets"))
1272         turrets_precash();
1273 #endif
1274
1275         // Precache all player models if desired
1276         if (cvar("sv_precacheplayermodels"))
1277         {
1278                 PrecachePlayerSounds("sound/player/default.sounds");
1279                 precache_all_models("models/player/*.zym");
1280                 precache_all_models("models/player/*.dpm");
1281                 precache_all_models("models/player/*.md3");
1282                 precache_all_models("models/player/*.psk");
1283                 //precache_model("models/player/carni.zym");
1284                 //precache_model("models/player/crash.zym");
1285                 //precache_model("models/player/grunt.zym");
1286                 //precache_model("models/player/headhunter.zym");
1287                 //precache_model("models/player/insurrectionist.zym");
1288                 //precache_model("models/player/jeandarc.zym");
1289                 //precache_model("models/player/lurk.zym");
1290                 //precache_model("models/player/lycanthrope.zym");
1291                 //precache_model("models/player/marine.zym");
1292                 //precache_model("models/player/nexus.zym");
1293                 //precache_model("models/player/pyria.zym");
1294                 //precache_model("models/player/shock.zym");
1295                 //precache_model("models/player/skadi.zym");
1296                 //precache_model("models/player/specop.zym");
1297                 //precache_model("models/player/visitant.zym");
1298         }
1299
1300         if(cvar("sv_defaultcharacter"))
1301         {
1302                 string s;
1303                 s = cvar_string("sv_defaultplayermodel_red");
1304                 if(s != "")
1305                 {
1306                         precache_model(s);
1307                         PrecachePlayerSounds(strcat(s, ".sounds"));
1308                 }
1309                 s = cvar_string("sv_defaultplayermodel_blue");
1310                 if(s != "")
1311                 {
1312                         precache_model(s);
1313                         PrecachePlayerSounds(strcat(s, ".sounds"));
1314                 }
1315                 s = cvar_string("sv_defaultplayermodel_yellow");
1316                 if(s != "")
1317                 {
1318                         precache_model(s);
1319                         PrecachePlayerSounds(strcat(s, ".sounds"));
1320                 }
1321                 s = cvar_string("sv_defaultplayermodel_pink");
1322                 if(s != "")
1323                 {
1324                         precache_model(s);
1325                         PrecachePlayerSounds(strcat(s, ".sounds"));
1326                 }
1327                 s = cvar_string("sv_defaultplayermodel");
1328                 if(s != "")
1329                 {
1330                         precache_model(s);
1331                         PrecachePlayerSounds(strcat(s, ".sounds"));
1332                 }
1333         }
1334
1335         if (g_footsteps)
1336         {
1337                 PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1338                 PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1339         }
1340
1341         // gore and miscellaneous sounds
1342         //precache_sound ("misc/h2ohit.wav");
1343         precache_model ("models/hook.md3");
1344         precache_sound ("misc/armorimpact.wav");
1345         precache_sound ("misc/bodyimpact1.wav");
1346         precache_sound ("misc/bodyimpact2.wav");
1347         precache_sound ("misc/gib.wav");
1348         precache_sound ("misc/gib_splat01.wav");
1349         precache_sound ("misc/gib_splat02.wav");
1350         precache_sound ("misc/gib_splat03.wav");
1351         precache_sound ("misc/gib_splat04.wav");
1352         precache_sound ("misc/hit.wav");
1353         PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1354         PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1355         precache_sound ("misc/null.wav");
1356         precache_sound ("misc/spawn.wav");
1357         precache_sound ("misc/talk.wav");
1358         precache_sound ("misc/teleport.wav");
1359         precache_sound ("player/lava.wav");
1360         precache_sound ("player/slime.wav");
1361
1362         // announcer sounds - male
1363         precache_sound ("announcer/male/electrobitch.wav");
1364         precache_sound ("announcer/male/airshot.wav");
1365         precache_sound ("announcer/male/03kills.wav");
1366         precache_sound ("announcer/male/05kills.wav");
1367         precache_sound ("announcer/male/10kills.wav");
1368         precache_sound ("announcer/male/15kills.wav");
1369         precache_sound ("announcer/male/20kills.wav");
1370         precache_sound ("announcer/male/25kills.wav");
1371         precache_sound ("announcer/male/30kills.wav");
1372         precache_sound ("announcer/male/botlike.wav");
1373         precache_sound ("announcer/male/yoda.wav");
1374         precache_sound ("announcer/male/headshot.wav");
1375         precache_sound ("announcer/male/impressive.wav");
1376
1377         // announcer sounds - robotic
1378         precache_sound ("announcer/robotic/prepareforbattle.wav");
1379         precache_sound ("announcer/robotic/begin.wav");
1380         precache_sound ("announcer/robotic/timeoutcalled.wav");
1381         precache_sound ("announcer/robotic/1fragleft.wav");
1382         precache_sound ("announcer/robotic/1minuteremains.wav");
1383         precache_sound ("announcer/robotic/2fragsleft.wav");
1384         precache_sound ("announcer/robotic/3fragsleft.wav");
1385         if (g_minstagib)
1386         {
1387                 precache_sound ("announcer/robotic/lastsecond.wav");
1388                 precache_sound ("announcer/robotic/narrowly.wav");
1389         }
1390
1391         precache_model ("models/sprites/1.spr32");
1392         precache_model ("models/sprites/2.spr32");
1393         precache_model ("models/sprites/3.spr32");
1394         precache_model ("models/sprites/4.spr32");
1395         precache_model ("models/sprites/5.spr32");
1396         precache_model ("models/sprites/6.spr32");
1397         precache_model ("models/sprites/7.spr32");
1398         precache_model ("models/sprites/8.spr32");
1399         precache_model ("models/sprites/9.spr32");
1400         precache_model ("models/sprites/10.spr32");
1401         precache_sound ("announcer/robotic/1.wav");
1402         precache_sound ("announcer/robotic/2.wav");
1403         precache_sound ("announcer/robotic/3.wav");
1404         precache_sound ("announcer/robotic/4.wav");
1405         precache_sound ("announcer/robotic/5.wav");
1406         precache_sound ("announcer/robotic/6.wav");
1407         precache_sound ("announcer/robotic/7.wav");
1408         precache_sound ("announcer/robotic/8.wav");
1409         precache_sound ("announcer/robotic/9.wav");
1410         precache_sound ("announcer/robotic/10.wav");
1411
1412         // common weapon precaches
1413         precache_sound ("weapons/weapon_switch.wav");
1414         precache_sound ("weapons/weaponpickup.wav");
1415         if (cvar("g_grappling_hook"))
1416         {
1417                 precache_sound ("weapons/hook_fire.wav"); // hook
1418                 precache_sound ("weapons/hook_impact.wav"); // hook
1419         }
1420
1421         if (cvar("sv_precacheweapons") || g_nixnex)
1422         {
1423                 //precache weapon models/sounds
1424                 local float wep;
1425                 wep = WEP_FIRST;
1426                 while (wep <= WEP_LAST)
1427                 {
1428                         weapon_action(wep, WR_PRECACHE);
1429                         wep = wep + 1;
1430                 }
1431         }
1432
1433         precache_model("models/elaser.mdl");
1434         precache_model("models/laser.mdl");
1435         precache_model("models/ebomb.mdl");
1436
1437 #if 0
1438         // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1439
1440         if (!self.noise && self.music) // quake 3 uses the music field
1441                 self.noise = self.music;
1442
1443         // plays music for the level if there is any
1444         if (self.noise)
1445         {
1446                 precache_sound (self.noise);
1447                 ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1448         }
1449 #endif
1450 }
1451
1452 // sorry, but using \ in macros breaks line numbers
1453 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1454 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1455 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1456
1457 vector ExactTriggerHit_mins;
1458 vector ExactTriggerHit_maxs;
1459 float ExactTriggerHit_Recurse()
1460 {
1461         float s;
1462         entity se;
1463         float f;
1464
1465         tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1466         if not(trace_ent)
1467                 return 0;
1468         if(trace_ent == self)
1469                 return 1;
1470
1471         se = trace_ent;
1472         s = se.solid;
1473         se.solid = SOLID_NOT;
1474         f = ExactTriggerHit_Recurse();
1475         se.solid = s;
1476
1477         return f;
1478 }
1479
1480 float ExactTriggerHit()
1481 {
1482         float f, s;
1483
1484         if not(self.modelindex)
1485                 return 1;
1486
1487         s = self.solid;
1488         self.solid = SOLID_BSP;
1489         ExactTriggerHit_mins = other.absmin;
1490         ExactTriggerHit_maxs = other.absmax;
1491         f = ExactTriggerHit_Recurse();
1492         self.solid = s;
1493
1494         return f;
1495 }
1496
1497 // WARNING: this kills the trace globals
1498 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1499 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1500
1501 #define INITPRIO_FIRST              0
1502 #define INITPRIO_GAMETYPE           0
1503 #define INITPRIO_GAMETYPE_FALLBACK  1
1504 #define INITPRIO_CVARS              5
1505 #define INITPRIO_FINDTARGET        10
1506 #define INITPRIO_DROPTOFLOOR       20
1507 #define INITPRIO_SETLOCATION       90
1508 #define INITPRIO_LINKDOORS         91
1509 #define INITPRIO_LAST              99
1510
1511 .void(void) initialize_entity;
1512 .float initialize_entity_order;
1513 .entity initialize_entity_next;
1514 entity initialize_entity_first;
1515
1516 void make_safe_for_remove(entity e)
1517 {
1518         if(e.initialize_entity)
1519         {
1520                 entity ent, prev;
1521                 for(ent = initialize_entity_first; ent; )
1522                 {
1523                         if((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1524                         {
1525                                 print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1526                                 // skip it in linked list
1527                                 if(prev)
1528                                 {
1529                                         prev.initialize_entity_next = ent.initialize_entity_next;
1530                                         ent = prev.initialize_entity_next;
1531                                 }
1532                                 else
1533                                 {
1534                                         initialize_entity_first = ent.initialize_entity_next;
1535                                         ent = initialize_entity_first;
1536                                 }
1537                         }
1538                         else
1539                         {
1540                                 prev = ent;
1541                                 ent = ent.initialize_entity_next;
1542                         }
1543                 }
1544         }
1545 }
1546
1547 void objerror(string s)
1548 {
1549         make_safe_for_remove(self);
1550         objerror_builtin(s);
1551 }
1552
1553 void remove_unsafely(entity e)
1554 {
1555         remove_builtin(e);
1556 }
1557
1558 void remove_safely(entity e)
1559 {
1560         make_safe_for_remove(e);
1561         remove_builtin(e);
1562 }
1563
1564 void InitializeEntity(entity e, void(void) func, float order)
1565 {
1566         entity prev, cur;
1567
1568         if(!e || e.initialize_entity)
1569         {
1570                 // make a proxy initializer entity
1571                 entity e_old;
1572                 e_old = e;
1573                 e = spawn();
1574                 e.classname = "initialize_entity";
1575                 e.enemy = e_old;
1576         }
1577
1578         e.initialize_entity = func;
1579         e.initialize_entity_order = order;
1580
1581         cur = initialize_entity_first;
1582         for(;;)
1583         {
1584                 if(!cur || cur.initialize_entity_order > order)
1585                 {
1586                         // insert between prev and cur
1587                         if(prev)
1588                                 prev.initialize_entity_next = e;
1589                         else
1590                                 initialize_entity_first = e;
1591                         e.initialize_entity_next = cur;
1592                         return;
1593                 }
1594                 prev = cur;
1595                 cur = cur.initialize_entity_next;
1596         }
1597 }
1598 void InitializeEntitiesRun()
1599 {
1600         entity startoflist;
1601         startoflist = initialize_entity_first;
1602         initialize_entity_first = world;
1603         for(self = startoflist; self; )
1604         {
1605                 entity e;
1606                 var void(void) func;
1607                 e = self.initialize_entity_next;
1608                 func = self.initialize_entity;
1609                 self.initialize_entity_order = 0;
1610                 self.initialize_entity = func_null;
1611                 self.initialize_entity_next = world;
1612                 if(self.classname == "initialize_entity")
1613                 {
1614                         entity e_old;
1615                         e_old = self.enemy;
1616                         remove_builtin(self);
1617                         self = e_old;
1618                 }
1619                 //dprint("Delayed initialization: ", self.classname, "\n");
1620                 func();
1621                 self = e;
1622         }
1623 }
1624
1625 .float uncustomizeentityforclient_set;
1626 .void(void) uncustomizeentityforclient;
1627 void(void) SUB_Nullpointer = #0;
1628 void UncustomizeEntitiesRun()
1629 {
1630         entity oldself;
1631         oldself = self;
1632         for(self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1633                 self.uncustomizeentityforclient();
1634         self = oldself;
1635 }
1636 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1637 {
1638         e.customizeentityforclient = customizer;
1639         e.uncustomizeentityforclient = uncustomizer;
1640         e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1641 }
1642
1643 .float nottargeted;
1644 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1645
1646 void() SUB_Remove;
1647 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1648 {
1649         vector mi, ma;
1650
1651         if(e.classname == "")
1652                 e.classname = "net_linked";
1653
1654         if(e.model == "" || self.modelindex == 0)
1655         {
1656                 mi = e.mins;
1657                 ma = e.maxs;
1658                 setmodel(e, "null");
1659                 setsize(e, mi, ma);
1660         }
1661
1662         e.SendEntity = sendfunc;
1663         e.SendFlags = 0xFFFFFF;
1664
1665         if(!docull)
1666                 e.effects |= EF_NODEPTHTEST;
1667
1668         if(dt)
1669         {
1670                 e.nextthink = time + dt;
1671                 e.think = SUB_Remove;
1672         }
1673 }
1674
1675 void adaptor_think2touch()
1676 {
1677         entity o;
1678         o = other;
1679         other = world;
1680         self.touch();
1681         other = o;
1682 }
1683
1684 void adaptor_think2use()
1685 {
1686         entity o, a;
1687         o = other;
1688         a = activator;
1689         activator = world;
1690         other = world;
1691         self.use();
1692         other = o;
1693         activator = a;
1694 }
1695
1696 // deferred dropping
1697 void DropToFloor_Handler()
1698 {
1699         droptofloor_builtin();
1700         self.dropped_origin = self.origin;
1701 }
1702
1703 void droptofloor()
1704 {
1705         InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1706 }
1707
1708
1709
1710 float trace_hits_box_a0, trace_hits_box_a1;
1711
1712 float trace_hits_box_1d(float end, float thmi, float thma)
1713 {
1714         if(end == 0)
1715         {
1716                 // just check if x is in range
1717                 if(0 < thmi)
1718                         return FALSE;
1719                 if(0 > thma)
1720                         return FALSE;
1721         }
1722         else
1723         {
1724                 // do the trace with respect to x
1725                 // 0 -> end has to stay in thmi -> thma
1726                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1727                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1728                 if(trace_hits_box_a0 > trace_hits_box_a1)
1729                         return FALSE;
1730         }
1731         return TRUE;
1732 }
1733
1734 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1735 {
1736         end -= start;
1737         thmi -= start;
1738         thma -= start;
1739         // now it is a trace from 0 to end
1740
1741         trace_hits_box_a0 = 0;
1742         trace_hits_box_a1 = 1;
1743
1744         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
1745                 return FALSE;
1746         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
1747                 return FALSE;
1748         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
1749                 return FALSE;
1750
1751         return TRUE;
1752 }
1753
1754 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1755 {
1756         return trace_hits_box(start, end, thmi - ma, thma - mi);
1757 }
1758
1759 float SUB_NoImpactCheck()
1760 {
1761         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1762                 return 1;
1763         if(other == world && self.size != '0 0 0')
1764         {
1765                 vector tic;
1766                 tic = self.velocity * sys_ticrate;
1767                 tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1768                 traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1769                 if(trace_fraction >= 1)
1770                 {
1771                         dprint("Odd... did not hit...?\n");
1772                 }
1773                 else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1774                 {
1775                         dprint("Detected and prevented the sky-grapple bug.\n");
1776                         return 1;
1777                 }
1778         }
1779
1780         return 0;
1781 }
1782
1783 #define SUB_OwnerCheck() (other && (other == self.owner))
1784
1785 #define PROJECTILE_TOUCH do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { remove(self); return; } } while(0)
1786 #define PROJECTILE_TOUCH_NOSOUND do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { stopsound(self, CHAN_PAIN); remove(self); return; } } while(0)
1787
1788 float MAX_IPBAN_URIS = 16;
1789
1790 float URI_GET_DISCARD   = 0;
1791 float URI_GET_IPBAN     = 1;
1792 float URI_GET_IPBAN_END = 16;
1793
1794 void URI_Get_Callback(float id, float status, string data)
1795 {
1796         dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is\n:");
1797         dprint(data);
1798         dprint("\nEnd of data.\n");
1799
1800         if(id == URI_GET_DISCARD)
1801         {
1802                 // discard
1803         }
1804         else if(id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1805         {
1806                 // online ban list
1807                 OnlineBanList_URI_Get_Callback(id, status, data);
1808         }
1809         else
1810         {
1811                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1812         }
1813 }
1814
1815 void print_to(entity e, string s)
1816 {
1817         if(e)
1818                 sprint(e, strcat(s, "\n"));
1819         else
1820                 print(s, "\n");
1821 }
1822
1823 string getrecords()
1824 {
1825         float rec;
1826         string h;
1827         float r;
1828         float i;
1829         string s;
1830
1831         rec = 0;
1832
1833         s = "";
1834
1835         if(g_ctf)
1836         {
1837                 for(i = 0; i < MapInfo_count; ++i)
1838                 {
1839                         if(MapInfo_Get_ByID(i))
1840                         {
1841                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
1842                                 if(r == 0)
1843                                         continue;
1844                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
1845                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
1846                                 ++rec;
1847                         }
1848                 }
1849         }
1850
1851         if(g_race)
1852         {
1853                 for(i = 0; i < MapInfo_count; ++i)
1854                 {
1855                         if(MapInfo_Get_ByID(i))
1856                         {
1857                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/time")));
1858                                 if(r == 0)
1859                                         continue;
1860                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/netname"));
1861                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, mmsss(r)), " ", h, "\n");
1862                                 ++rec;
1863                         }
1864                 }
1865         }
1866
1867         if(s == "")
1868                 return "No records are available on this server.\n";
1869         else
1870                 return strcat("Records on this server:\n", s);
1871 }
1872
1873 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1874 {
1875         float m, i;
1876         vector start, org, delta, end, enddown, mstart;
1877
1878         m = e.dphitcontentsmask;
1879         e.dphitcontentsmask = goodcontents | badcontents;
1880
1881         org = world.mins;
1882         delta = world.maxs - world.mins;
1883
1884         for(i = 0; i < attempts; ++i)
1885         {
1886                 start_x = org_x + random() * delta_x;
1887                 start_y = org_y + random() * delta_y;
1888                 start_z = org_z + random() * delta_z;
1889
1890                 // rule 1: start inside world bounds, and outside
1891                 // solid, and don't start from somewhere where you can
1892                 // fall down to evil
1893                 tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1894                 if(trace_fraction >= 1)
1895                         continue;
1896                 if(trace_startsolid)
1897                         continue;
1898                 if(trace_dphitcontents & badcontents)
1899                         continue;
1900                 if(trace_dphitq3surfaceflags & badsurfaceflags)
1901                         continue;
1902
1903                 // rule 2: if we are too high, lower the point
1904                 if(trace_fraction * delta_z > maxaboveground)
1905                         start = trace_endpos + '0 0 1' * maxaboveground;
1906                 enddown = trace_endpos;
1907
1908                 // rule 3: make sure we aren't outside the map. This only works
1909                 // for somewhat well formed maps. A good rule of thumb is that
1910                 // the map should have a convex outside hull.
1911                 // these can be traceLINES as we already verified the starting box
1912                 mstart = start + 0.5 * (e.mins + e.maxs);
1913                 traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1914                 if(trace_fraction >= 1)
1915                         continue;
1916                 traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1917                 if(trace_fraction >= 1)
1918                         continue;
1919                 traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1920                 if(trace_fraction >= 1)
1921                         continue;
1922                 traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1923                 if(trace_fraction >= 1)
1924                         continue;
1925                 traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1926                 if(trace_fraction >= 1)
1927                         continue;
1928
1929                 // find a random vector to "look at"
1930                 end_x = org_x + random() * delta_x;
1931                 end_y = org_y + random() * delta_y;
1932                 end_z = org_z + random() * delta_z;
1933                 end = start + normalize(end - start) * vlen(delta);
1934
1935                 // rule 4: start TO end must not be too short
1936                 tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1937                 if(trace_startsolid)
1938                         continue;
1939                 if(trace_fraction < minviewdistance / vlen(delta))
1940                         continue;
1941
1942                 // rule 5: don't want to look at sky
1943                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1944                         continue;
1945
1946                 // rule 6: we must not end up in trigger_hurt
1947                 if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1948                 {
1949                         dprint("trigger_hurt! ouch! and nothing else could find it!\n");
1950                         continue;
1951                 }
1952
1953                 break;
1954         }
1955
1956         e.dphitcontentsmask = m;
1957
1958         if(i < attempts)
1959         {
1960                 setorigin(e, start);
1961                 e.angles = vectoangles(end - start);
1962                 dprint("Needed ", ftos(i + 1), " attempts\n");
1963                 return TRUE;
1964         }
1965         else
1966                 return FALSE;
1967 }