data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25
  26 // kh_state
  27 //     bits 0-7: player's key status
  28 //     bits 8-15: general key status
  29 .float kh_state;
  30 .float siren_time;  //  time delay the siren
  31 //.float stuff_time;  //  time delay to stuffcmd a cvar
  32
  33 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  34 //test[0] = status of dropped keys, test[1 - 16] = player #
  35 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  36 //for(i = 0; i < maxplayers; ++i)
  37 //      test[i] = "0";
  38
  39 float kh_Team_ByID(float t)
  40 {
  41         if(t == 0) return COLOR_TEAM1;
  42         if(t == 1) return COLOR_TEAM2;
  43         if(t == 2) return COLOR_TEAM3;
  44         if(t == 3) return COLOR_TEAM4;
  45         return 0;
  46 }
  47
  48 entity kh_worldkeylist;
  49 .entity kh_worldkeynext;
  50 entity kh_controller;
  51 float kh_tracking_enabled;
  52 float kh_teams;
  53 float kh_interferemsg_time, kh_interferemsg_team;
  54 .entity kh_next, kh_prev; // linked list
  55 .float kh_droptime;
  56 .float kh_dropperteam;
  57 .entity kh_previous_owner;
  58 .float kh_previous_owner_playerid;
  59
  60 string kh_sound_capture = "sound/kh/capture.wav";
  61 string kh_sound_destroy = "sound/kh/destroy.wav";
  62 string kh_sound_drop = "sound/kh/drop.wav";
  63 string kh_sound_collect = "sound/kh/collect.wav";
  64 string kh_sound_alarm = "sound/kh/alarm.wav";  // the new siren/alarm
  65
  66 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  67 float kh_key_dropped, kh_key_carried;
  68
  69 float kh_GetCarrierSprite(float t, float e)  // runs all the time
  70 {
  71         if(t == e)           return kh_sprite_friend;
  72         if(t == COLOR_TEAM1) return kh_sprite_red;
  73         if(t == COLOR_TEAM2) return kh_sprite_blue;
  74         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  75         if(t == COLOR_TEAM4) return kh_sprite_pink;
  76         return 0;
  77 }
  78
  79 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  80 {
  81         kh_Controller_Thinkfunc = func;
  82         kh_controller.cnt = t;
  83         if(kh_Controller_Waitmsg != "")
  84                 strunzone(kh_Controller_Waitmsg);
  85         if(msg == "")
  86                 kh_Controller_Waitmsg = "";
  87         else
  88                 kh_Controller_Waitmsg = strzone(msg);
  89         if(t == 0)
  90                 kh_controller.nextthink = time; // force
  91 }
  92
  93 void kh_Controller_Think()  // called a lot
  94 {
  95         entity e;
  96         if(intermission_running)
  97                 return;
  98         if(self.cnt > 0)
  99         {
 100                 if(kh_Controller_Waitmsg != "")
 101                 {
 102                         string s;
 103                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 104                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 105                         else
 106                                 s = kh_Controller_Waitmsg;
 107
 108                         //dprint(s, "\n");
 109
 110                         FOR_EACH_PLAYER(e)
 111                                 if(clienttype(e) == CLIENTTYPE_REAL)
 112                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 113                 }
 114                 self.cnt -= 1;
 115         }
 116         else if(self.cnt == 0)
 117         {
 118                 self.cnt -= 1;
 119                 kh_Controller_Thinkfunc();
 120         }
 121         self.nextthink = time + 1;
 122 }
 123
 124 // frags f: take from cvar * f
 125 // frags 0: no frags
 126 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 127 {
 128         string s;
 129         if(intermission_running)
 130                 return;
 131         if(frags_player)
 132                 UpdateFrags(player, frags_player);
 133         if(key && key.owner && frags_owner)
 134                 UpdateFrags(key.owner, frags_owner);
 135         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 136                 return;
 137         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 138         s = strcat(s, ":", ftos(frags_player));
 139         if(key && key.owner)
 140                 s = strcat(s, ":", ftos(key.owner.playerid));
 141         else
 142                 s = strcat(s, ":0");
 143         s = strcat(s, ":", ftos(frags_owner), ":");
 144         if(key)
 145                 s = strcat(s, key.netname);
 146         GameLogEcho(s);
 147 }
 148
 149 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 150 {
 151         if(e.tag_entity)
 152         {
 153                 makevectors(e.tag_entity.angles);
 154                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 155         }
 156         else
 157                 return e.origin;
 158 }
 159
 160 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 161 {
 162 #ifdef KH_PLAYER_USE_ATTACHMENT
 163         entity first;
 164         first = key.owner.kh_next;
 165         if(key == first)
 166         {
 167                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 168                 if(key.kh_next)
 169                 {
 170                         setattachment(key.kh_next, key, "");
 171                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 172                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 173                         key.kh_next.angles = '0 0 0';
 174                 }
 175                 else
 176                         setorigin(key, KH_PLAYER_ATTACHMENT);
 177                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 178         }
 179         else
 180         {
 181                 setattachment(key, key.kh_prev, "");
 182                 if(key.kh_next)
 183                         setattachment(key.kh_next, key, "");
 184                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 185                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 186                 key.angles = '0 0 0';
 187         }
 188 #else
 189         setattachment(key, key.owner, "");
 190         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 191         key.angles_y -= key.owner.angles_y;
 192 #endif
 193         key.flags = 0;
 194         key.solid = SOLID_NOT;
 195         key.movetype = MOVETYPE_NONE;
 196         key.team = key.owner.team;
 197         key.nextthink = time;
 198         key.damageforcescale = 0;
 199         key.modelindex = kh_key_carried;
 200 }
 201
 202 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 203 {
 204         float i;
 205         i = test[key.owner.playerid];
 206                 if(key.netname == "^1red key")
 207                         i -= 1;
 208                 if(key.netname == "^4blue key")
 209                         i -= 2;
 210                 if(key.netname == "^3yellow key")
 211                         i -= 4;
 212                 if(key.netname == "^6pink key")
 213                         i -= 8;
 214         test[key.owner.playerid] = i;
 215
 216         kh_show_temp();
 217         if(key.owner)
 218                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 219         //key.owner.kh_state += test[key.owner.playerid];
 220
 221 #ifdef KH_PLAYER_USE_ATTACHMENT
 222         entity first;
 223         first = key.owner.kh_next;
 224         if(key == first)
 225         {
 226                 if(key.kh_next)
 227                 {
 228                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 229                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 230                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 231                 }
 232         }
 233         else
 234         {
 235                 if(key.kh_next)
 236                         setattachment(key.kh_next, key.kh_prev, "");
 237                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 238         }
 239         // in any case:
 240         setattachment(key, world, "");
 241         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 242         key.angles = key.owner.angles;
 243 #else
 244         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 245         setattachment(key, world, "");
 246         key.angles_y += key.owner.angles_y;
 247 #endif
 248         key.flags = FL_ITEM;
 249         key.solid = SOLID_TRIGGER;
 250         key.movetype = MOVETYPE_TOSS;
 251         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 252         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 253         // let key.team stay
 254         key.modelindex = kh_key_dropped;
 255         key.kh_previous_owner = key.owner;
 256         key.kh_previous_owner_playerid = key.owner.playerid;
 257 }
 258
 259 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 260 {
 261         entity k;
 262         float ownerteam0, ownerteam;
 263         if(key.owner == player)
 264                 return;
 265
 266         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 267
 268         if(key.owner)
 269         {
 270                 kh_Key_Detach(key);
 271
 272                 // remove from linked list
 273                 if(key.kh_next)
 274                         key.kh_next.kh_prev = key.kh_prev;
 275                 key.kh_prev.kh_next = key.kh_next;
 276                 key.kh_next = world;
 277                 key.kh_prev = world;
 278
 279                 if(key.owner.kh_next == world)
 280                 {
 281                         // No longer a key carrier
 282                         WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 283                         WaypointSprite_DetachCarrier(key.owner);
 284                 }
 285         }
 286
 287         key.owner = player;
 288
 289         if(player)
 290         {
 291                 // insert into linked list
 292                 key.kh_next = player.kh_next;
 293                 key.kh_prev = player;
 294                 player.kh_next = key;
 295                 if(key.kh_next)
 296                         key.kh_next.kh_prev = key;
 297
 298                 float i;
 299                 i = test[key.owner.playerid];
 300                         if(key.netname == "^1red key")
 301                                 i += 1;
 302                         if(key.netname == "^4blue key")
 303                                 i += 2;
 304                         if(key.netname == "^3yellow key")
 305                                 i += 4;
 306                         if(key.netname == "^6pink key")
 307                                 i += 8;
 308                 test[key.owner.playerid] = i;
 309
 310                 kh_Key_Attach(key);
 311
 312                 if(key.kh_next == world)
 313                 {
 314                         // player is now a key carrier
 315                         WaypointSprite_AttachCarrier("", player);
 316                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 317                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 318                         if(player.team == COLOR_TEAM1)
 319                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "");
 320                         else if(player.team == COLOR_TEAM2)
 321                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "");
 322                         else if(player.team == COLOR_TEAM3)
 323                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "");
 324                         else if(player.team == COLOR_TEAM4)
 325                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "");
 326                         WaypointSprite_UpdateTeamRadar(player.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1));
 327                         WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 328                 }
 329         }
 330
 331         // moved that here, also update if there's no player
 332         kh_show_temp();
 333         if(key.owner)
 334                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 335
 336         key.pusher = world;
 337
 338         ownerteam = kh_Key_AllOwnedByWhichTeam();
 339         if(ownerteam != ownerteam0)
 340         {
 341                 if(ownerteam != -1)
 342                 {
 343                         kh_interferemsg_time = time + 0.2;
 344                         kh_interferemsg_team = player.team;
 345
 346                         // audit all key carrier sprites, update them to RUN HERE
 347                         FOR_EACH_KH_KEY(k)
 348                         {
 349                                 if(k.owner)
 350                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model, "keycarrier-finish", "");
 351                         }
 352                 }
 353                 else
 354                 {
 355                         // audit all key carrier sprites, update them to RUN HERE
 356                         FOR_EACH_KH_KEY(k)
 357                         {
 358                                 if(k.owner)
 359                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model, "keycarrier-friend", "");
 360                         }
 361                 }
 362         }
 363 }
 364
 365 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 366 {
 367         if(self.owner)
 368                 return;
 369         if(vlen(force) <= 0)
 370                 return;
 371         if(time > self.pushltime)
 372                 if(attacker.classname == "player")
 373                         self.team = attacker.team;
 374 }
 375
 376 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 377 {
 378         entity key;
 379         key = spawn();
 380         key.classname = STR_ITEM_KH_KEY;
 381         key.touch = kh_Key_Touch;
 382         key.think = kh_Key_Think;
 383         key.nextthink = time;
 384         key.items = IT_KEY1 | IT_KEY2;
 385         key.cnt = angle;
 386         key.angles = '0 360 0' * random();
 387         key.event_damage = kh_Key_Damage;
 388         key.takedamage = DAMAGE_YES;
 389         key.modelindex = kh_key_dropped;
 390         key.model = "key";
 391         key.kh_dropperteam = 0;
 392         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 393         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 394         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 395
 396         switch(initial_owner.team)
 397         {
 398                 case COLOR_TEAM1:
 399                         key.netname = "^1red key";
 400                         break;
 401                 case COLOR_TEAM2:
 402                         key.netname = "^4blue key";
 403                         break;
 404                 case COLOR_TEAM3:
 405                         key.netname = "^3yellow key";
 406                         break;
 407                 case COLOR_TEAM4:
 408                         key.netname = "^6pink key";
 409                         break;
 410                 default:
 411                         key.netname = "NETGIER key";
 412                         break;
 413         }
 414
 415         // link into key list
 416         key.kh_worldkeynext = kh_worldkeylist;
 417         kh_worldkeylist = key;
 418
 419         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 420
 421         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 422         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 423         WaypointSprite_UpdateTeamRadar(key.waypointsprite_attachedforcarrier, RADARICON_FLAG, '0 1 1');
 424
 425         kh_Key_AssignTo(key, initial_owner);
 426 }
 427
 428 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 429 {
 430         entity o;
 431         o = key.owner;
 432         kh_Key_AssignTo(key, world);
 433         if(o) // it was attached
 434                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 435         else // it was dropped
 436                 WaypointSprite_DetachCarrier(key);
 437
 438         // remove key from key list
 439         if (kh_worldkeylist == key)
 440                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 441         else
 442         {
 443                 o = kh_worldkeylist;
 444                 while (o)
 445                 {
 446                         if (o.kh_worldkeynext == key)
 447                         {
 448                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 449                                 break;
 450                         }
 451                         o = o.kh_worldkeynext;
 452                 }
 453         }
 454
 455         remove(key);
 456 }
 457
 458 // -1 when no team completely owns all keys yet
 459 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 460 {
 461         entity key;
 462         float teem;
 463
 464         teem = -1;
 465         FOR_EACH_KH_KEY(key)
 466         {
 467                 if(!key.owner)
 468                         return -1;
 469                 if(teem == -1)
 470                         teem = key.team;
 471                 else if(teem != key.team)
 472                         return -1;
 473         }
 474         return teem;
 475 }
 476
 477 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 478 {
 479         float ownerteam;
 480         entity k;
 481
 482         sound(player, CHAN_AUTO, kh_sound_collect, VOL_BASE, ATTN_NORM);
 483
 484         if(key.kh_dropperteam != player.team)
 485         {
 486                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 487                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 488         }
 489         key.kh_dropperteam = 0;
 490         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 491
 492         kh_Key_AssignTo(key, player); // this also updates .kh_state
 493 }
 494
 495 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 496 {
 497         entity key;
 498         entity mypusher;
 499         if(player.kh_next)
 500         {
 501                 mypusher = world;
 502                 if(player.pusher)
 503                         if(time < player.pushltime)
 504                                 mypusher = player.pusher;
 505                 while((key = player.kh_next))
 506                 {
 507                         kh_Scores_Event(player, key, "losekey", 0, 0);
 508                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 509                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 510                         kh_Key_AssignTo(key, world);
 511                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 512                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 513                         key.pusher = mypusher;
 514                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 515                         if(suicide)
 516                                 key.kh_dropperteam = player.team;
 517                 }
 518                 sound(player, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 519         }
 520 }
 521
 522 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 523 {
 524         if(intermission_running)
 525                 return;
 526
 527         if(self.owner) // already carried
 528                 return;
 529         if(other.classname != "player")
 530                 return;
 531         if(other.deadflag != DEAD_NO)
 532                 return;
 533         if(other == self.enemy)
 534                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 535                         return;  // you just dropped it!
 536         kh_Key_Collect(self, other);
 537 }
 538
 539 void kh_Key_Think()  // runs all the time
 540 {
 541         entity head;
 542         //entity player;  // needed by FOR_EACH_PLAYER
 543
 544         if(intermission_running)
 545                 return;
 546         /*
 547         if(time > self.stuff_time)
 548         {
 549                 FOR_EACH_PLAYER(player)
 550                         player.kh_state = test[0]*256 + (player.kh_state&255);
 551
 552                 self.stuff_time = time + 1;  // repeat in 1 second
 553         }
 554         */
 555
 556 #ifdef KH_KEY_ATTACHMENT_DEBUG
 557         if(self.kh_prev == self.owner)
 558         {
 559                 if(cvar_string("_angles") != "")
 560                 {
 561                         self.angles = stov(cvar_string("_angles"));
 562                         self.origin = stov(cvar_string("_origin"));
 563                 }
 564         }
 565 #endif
 566
 567         if(self.owner)
 568         {
 569 #ifndef KH_PLAYER_USE_ATTACHMENT
 570                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 571                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 572 #endif
 573
 574                 if(self.owner.BUTTON_USE)
 575                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 576                 {
 577                         self.owner.kh_droptime = time;
 578                         self.kh_droptime = time;  // prevent collecting this one for some time
 579                         self.enemy = self.owner;
 580                         self.pusher = world;
 581                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 582                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 583                         sound(self.owner, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 584                         makevectors(self.owner.v_angle);
 585                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 586                         kh_Key_AssignTo(self, world);
 587                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 588                         self.kh_dropperteam = self.team;
 589                 }
 590         }
 591
 592         // if in nodrop or time over, end the round
 593         if(!self.owner)
 594                 if(time > self.pain_finished)
 595                         kh_LoserTeam(self.team, self);
 596
 597         if(self.owner)
 598         if(kh_Key_AllOwnedByWhichTeam() != -1)
 599         {
 600                 if(self.siren_time < time)
 601                 {
 602                         sound(self.owner, CHAN_AUTO, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 603                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 604                 }
 605
 606                 entity key;
 607                 vector p;
 608                 p = self.owner.origin;
 609                 FOR_EACH_KH_KEY(key)
 610                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 611                                 goto not_winning;
 612                 kh_WinnerTeam(self.team);
 613 :not_winning
 614         }
 615
 616         if(kh_interferemsg_time && time > kh_interferemsg_time)
 617         {
 618                 kh_interferemsg_time = 0;
 619                 FOR_EACH_PLAYER(head)
 620                 {
 621                         if(head.team == kh_interferemsg_team)
 622                                 if(head.kh_next)
 623                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 624                                 else
 625                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 626                         else
 627                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 628                 }
 629         }
 630
 631         self.nextthink = time + 0.05;
 632 }
 633
 634 void kh_WinnerTeam(float teem)  // runs when a team wins
 635 {
 636         // all key carriers get some points
 637         vector firstorigin, lastorigin, midpoint;
 638         float first;
 639         entity key;
 640         float score;
 641         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 642         DistributeEvenly_Init(score, kh_teams);
 643         // twice the score for 3 team games, three times the score for 4 team games!
 644         // note: for a win by destroying the key, this should NOT be applied
 645         FOR_EACH_KH_KEY(key)
 646         {
 647                 float f;
 648                 f = DistributeEvenly_Get(1);
 649                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 650                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 651         }
 652
 653         first = TRUE;
 654         FOR_EACH_KH_KEY(key)
 655                 if(key.owner.kh_next == key)
 656                 {
 657                         if(!first)
 658                                 bprint("^7, ");
 659                         bprint(key.owner.netname);
 660                         first = FALSE;
 661                 }
 662         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 663
 664         first = TRUE;
 665         midpoint = '0 0 0';
 666         FOR_EACH_KH_KEY(key)
 667         {
 668                 vector thisorigin;
 669
 670                 thisorigin = kh_AttachedOrigin(key);
 671                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 672                 midpoint += thisorigin;
 673
 674                 if(!first)
 675                         te_lightning2(world, lastorigin, thisorigin);
 676                 lastorigin = thisorigin;
 677                 if(first)
 678                         firstorigin = thisorigin;
 679                 first = FALSE;
 680         }
 681         if(kh_teams > 2)
 682         {
 683                 te_lightning2(world, lastorigin, firstorigin);
 684         }
 685         midpoint = midpoint * (1 / kh_teams);
 686         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 687
 688         play2all(kh_sound_capture);
 689         kh_FinishRound();
 690 }
 691
 692 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 693 {
 694         entity player, key, attacker;
 695         float players;
 696         float keys;
 697         float f;
 698
 699         attacker = world;
 700         if(lostkey.pusher)
 701                 if(lostkey.pusher.team != teem)
 702                         if(lostkey.pusher.classname == "player")
 703                                 attacker = lostkey.pusher;
 704
 705         players = keys = 0;
 706
 707         if(attacker)
 708         {
 709                 if(lostkey.kh_previous_owner)
 710                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 711                         // don't actually GIVE him the -nn points, just log
 712                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 713                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 714                 centerprint(attacker, "Your push is the best!\n\n\n");
 715                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 716         }
 717         else
 718         {
 719                 float of, fragsleft, i, j, thisteam;
 720                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 721
 722                 FOR_EACH_PLAYER(player)
 723                         if(player.team != teem)
 724                                 ++players;
 725
 726                 FOR_EACH_KH_KEY(key)
 727                         if(key.owner && key.team != teem)
 728                                 ++keys;
 729
 730                 if(lostkey.kh_previous_owner)
 731                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 732                         // don't actually GIVE him the -nn points, just log
 733
 734                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 735                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 736
 737                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 738
 739                 FOR_EACH_KH_KEY(key)
 740                         if(key.owner && key.team != teem)
 741                         {
 742                                 f = DistributeEvenly_Get(of);
 743                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 744                         }
 745
 746                 fragsleft = DistributeEvenly_Get(players);
 747
 748                 // Now distribute these among all other teams...
 749                 j = kh_teams - 1;
 750                 for(i = 0; i < kh_teams; ++i)
 751                 {
 752                         thisteam = kh_Team_ByID(i);
 753                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 754                                 continue;
 755
 756                         players = 0;
 757                         FOR_EACH_PLAYER(player)
 758                                 if(player.team == thisteam)
 759                                         ++players;
 760
 761                         DistributeEvenly_Init(fragsleft, j);
 762                         fragsleft = DistributeEvenly_Get(j - 1);
 763                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 764
 765                         FOR_EACH_PLAYER(player)
 766                                 if(player.team == thisteam)
 767                                 {
 768                                         f = DistributeEvenly_Get(1);
 769                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 770                                 }
 771
 772                         --j;
 773                 }
 774
 775                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 776         }
 777         play2all(kh_sound_destroy);
 778         te_tarexplosion(lostkey.origin);
 779
 780         kh_FinishRound();
 781 }
 782
 783 void kh_FinishRound()  // runs when a team captures the keys
 784 {
 785         // prepare next round
 786         kh_interferemsg_time = 0;
 787         entity key;
 788         FOR_EACH_KH_KEY(key)
 789                 kh_Key_Remove(key);
 790
 791         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 792 }
 793
 794 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 795 {
 796         float i, players, teem;
 797         entity player;
 798         string result;
 799         result = "";
 800
 801         // find a random player per team
 802         for(i = 0; i < kh_teams; ++i)
 803         {
 804                 teem = kh_Team_ByID(i);
 805                 players = 0;
 806                 FOR_EACH_PLAYER(player)
 807                         if(player.deadflag == DEAD_NO)
 808                                 if(!player.BUTTON_CHAT)
 809                                         if(player.team == teem)
 810                                                 ++players;
 811                 if(players == 0)
 812                 {
 813                         if(result != "")
 814                                 result = strcat(result, ", ");
 815                         result = strcat(result, ColoredTeamName(teem));
 816                 }
 817         }
 818         return result;
 819 }
 820
 821 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 822 {
 823         string teams_missing;
 824         teams_missing = kh_CheckEnoughPlayers();
 825         if(teams_missing == "")
 826                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 827         else
 828                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 829 }
 830
 831 void kh_StartRound()  // runs at the start of each round
 832 {
 833         string teams_missing;
 834         float i, players, teem;
 835         entity player;
 836
 837         teams_missing = kh_CheckEnoughPlayers();
 838         if(teams_missing != "")
 839         {
 840                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 841                 return;
 842         }
 843
 844         FOR_EACH_PLAYER(player)
 845                 if(clienttype(player) == CLIENTTYPE_REAL)
 846                         centerprint_expire(player, CENTERPRIO_SPAM);
 847
 848         for(i = 0; i < kh_teams; ++i)
 849         {
 850                 teem = kh_Team_ByID(i);
 851                 players = 0;
 852                 entity my_player;
 853                 FOR_EACH_PLAYER(player)
 854                         if(player.deadflag == DEAD_NO)
 855                                 if(!player.BUTTON_CHAT)
 856                                         if(player.team == teem)
 857                                         {
 858                                                 ++players;
 859                                                 if(random() * players <= 1)
 860                                                         my_player = player;
 861                                         }
 862                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 863                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 864                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 865         }
 866
 867         kh_tracking_enabled = FALSE;
 868         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 869 }
 870
 871 void kh_setstatus()  // runs all the time
 872 {
 873         if(kh_teams)
 874         {
 875                 float kh_KEY;
 876                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 877                 if(self.kh_next)
 878                         self.items = self.items | kh_KEY;
 879                 else
 880                         self.items = self.items - (self.items & kh_KEY);
 881         }
 882 }
 883
 884 void kh_EnableTrackingDevice()  // runs after each round
 885 {
 886         entity player;
 887
 888         FOR_EACH_PLAYER(player)
 889                 if(clienttype(player) == CLIENTTYPE_REAL)
 890                         centerprint_expire(player, CENTERPRIO_SPAM);
 891
 892         kh_tracking_enabled = TRUE;
 893 }
 894
 895 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
 896 {
 897         if(!kh_tracking_enabled)
 898                 return FALSE;
 899         if(!self.owner)
 900                 return TRUE;
 901         if(!self.owner.owner)
 902                 return TRUE;
 903         return FALSE;  // draw only when key is not owned
 904 }
 905
 906 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
 907 {
 908         if(e.classname != "player" || self.team != e.team)
 909                 if(!kh_tracking_enabled)
 910                         return FALSE;
 911
 912         return TRUE;
 913 }
 914
 915 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 916 {
 917         if(attacker == targ)
 918                 return f;
 919
 920         if(targ.kh_next)
 921         {
 922                 if(attacker.team == targ.team)
 923                 {
 924                         entity k;
 925                         float nk;
 926                         nk = 0;
 927                         for(k = targ.kh_next; k != world; k = k.kh_next)
 928                                 ++nk;
 929                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 930                 }
 931                 else
 932                 {
 933                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 934                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 935                         // the frag gets added later
 936                 }
 937         }
 938
 939         return f;
 940 }
 941
 942 void kh_init()  // sets up th KH environment
 943 {
 944         precache_sound(kh_sound_capture);
 945         precache_sound(kh_sound_destroy);
 946         precache_sound(kh_sound_drop);
 947         precache_sound(kh_sound_collect);
 948         precache_sound(kh_sound_alarm);  // the new siren
 949
 950         precache_model("models/sprites/key-dropped.sp2");
 951         precache_model("models/sprites/keycarrier-finish.sp2");
 952         precache_model("models/sprites/keycarrier-friend.sp2");
 953         precache_model("models/sprites/keycarrier-red.sp2");
 954         precache_model("models/sprites/keycarrier-blue.sp2");
 955         precache_model("models/sprites/keycarrier-yellow.sp2");
 956         precache_model("models/sprites/keycarrier-pink.sp2");
 957 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 958         precache_model("models/keyhunt/key-carried.md3");
 959 #endif
 960         precache_model("models/keyhunt/key.md3");
 961
 962         // setup variables
 963         kh_teams = cvar("g_keyhunt_teams_override");
 964         if(kh_teams < 2)
 965                 kh_teams = cvar("g_keyhunt_teams");
 966         kh_teams = bound(2, kh_teams, 4);
 967
 968         // make a KH entity for controlling the game
 969         kh_controller = spawn();
 970         kh_controller.think = kh_Controller_Think;
 971         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 972
 973         setmodel(kh_controller, "models/keyhunt/key.md3");
 974         kh_key_dropped = kh_controller.modelindex;
 975         /*
 976         dprint(vtos(kh_controller.mins));
 977         dprint(vtos(kh_controller.maxs));
 978         dprint("\n");
 979         */
 980 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 981         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 982         kh_key_carried = kh_controller.modelindex;
 983 #else
 984         kh_key_carried = kh_key_dropped;
 985 #endif
 986         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 987         kh_sprite_dropped = kh_controller.modelindex;
 988         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 989         kh_sprite_finish = kh_controller.modelindex;
 990         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 991         kh_sprite_friend = kh_controller.modelindex;
 992         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 993         kh_sprite_red = kh_controller.modelindex;
 994         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 995         kh_sprite_blue = kh_controller.modelindex;
 996         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 997         kh_sprite_pink = kh_controller.modelindex;
 998         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 999         kh_sprite_yellow = kh_controller.modelindex;
1000         setmodel(kh_controller, "");
1001
1002         addstat(STAT_KH_KEYS, AS_INT, kh_state);
1003
1004         ScoreRules_kh(kh_teams);
1005 }
1006
1007 void kh_finalize()
1008 {
1009         // to be called before intermission
1010         kh_FinishRound();
1011         remove(kh_controller);
1012         kh_controller = world;
1013 }
1014
1015 /**
1016  * kh_show_temp originally by victim.
1017  * changed it to use the kh_state stat var
1018  * Updates the general key stat bits for each player
1019  */
1020 void kh_show_temp()
1021 {
1022         entity player;
1023         float i, j;
1024
1025         j = 0;  // reset/blank j
1026         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
1027                 j += test[i];
1028
1029         test[0] = j;
1030
1031         j *= 256;
1032         FOR_EACH_PLAYER(player)
1033                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
1034 }