data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/misc/mouseclick.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  37         if(t == COLOR_TEAM4) return kh_sprite_pink;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(intermission_running)
  59                 return;
  60         if(self.cnt > 0)
  61         {
  62                 if(kh_Controller_Waitmsg != "")
  63                 {
  64                         string s;
  65                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  66                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  67                         else
  68                                 s = kh_Controller_Waitmsg;
  69
  70                         dprint(s, "\n");
  71
  72                         FOR_EACH_PLAYER(e)
  73                                 if(clienttype(e) == CLIENTTYPE_REAL)
  74                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  75                 }
  76                 self.cnt -= 1;
  77         }
  78         else if(self.cnt == 0)
  79         {
  80                 self.cnt -= 1;
  81                 kh_Controller_Thinkfunc();
  82         }
  83         self.nextthink = time + 1;
  84 }
  85
  86 void kh_Log()
  87 {
  88         string s;
  89         if(!cvar("sv_eventlog"))
  90                 return;
  91         // TODO ...
  92         GameLogEcho(s, FALSE);
  93 }
  94
  95 // frags f: take from cvar * f
  96 // frags 0: no frags
  97 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
  98 {
  99         float basefrags;
 100         basefrags = cvar(strcat("g_balance_keyhunt_score_", what));
 101
 102         if(frags_player)
 103                 player.frags = player.frags + floor(0.5 + basefrags * frags_player);
 104         if(frags_owner)
 105                 key.owner.frags = key.owner.frags + floor(0.5 + basefrags * frags_owner);
 106 }
 107
 108 void kh_Key_Attach(entity key, float wpchange)
 109 {
 110         setattachment(key, key.owner, "");
 111         setorigin(key, '0 0 -15'); // x/y fixed later in think, z has to be -15 to make the key fit even in the crouchbox
 112         key.angles = key.angles - '0 1 0' * key.owner.angles_y;
 113         key.flags = 0;
 114         key.solid = SOLID_NOT;
 115         key.movetype = MOVETYPE_NONE;
 116         key.team = key.owner.team;
 117         key.nextthink = time;
 118         key.damageforcescale = 0;
 119 }
 120
 121 vector kh_AttachedOrigin(entity e)
 122 {
 123         if(e.tag_entity)
 124         {
 125                 /*
 126                 makevectors(e.tag_entity.angles);
 127                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 128                 */
 129                 return e.tag_entity.origin + e.origin_z * '0 0 1'; // not exact, but allows full key hitbox
 130         }
 131         else
 132                 return e.origin;
 133 }
 134
 135 void kh_Key_Detach(entity key, float wpchange)
 136 {
 137         setorigin(key, kh_AttachedOrigin(key));
 138         setattachment(key, world, "");
 139         key.angles_y = key.owner.angles_y;
 140         key.aiment = world;
 141         key.flags = FL_ITEM;
 142         key.solid = SOLID_TRIGGER;
 143         key.movetype = MOVETYPE_TOSS;
 144         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 145         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 146         // let key.team stay
 147 }
 148
 149 void kh_Key_AssignTo(entity key, entity player, float wpchange)
 150 {
 151         if(key.owner == player)
 152                 return;
 153
 154         if(key.owner)
 155         {
 156                 kh_Key_Detach(key, wpchange);
 157
 158                 // remove from linked list
 159                 if(key.kh_next)
 160                         key.kh_next.kh_prev = key.kh_prev;
 161                 key.kh_prev.kh_next = key.kh_next;
 162                 key.kh_next = world;
 163                 key.kh_prev = world;
 164
 165                 if(key.owner.kh_next == world)
 166                 {
 167                         // No longer a key carrier
 168                         if(wpchange)
 169                                 WaypointSprite_Kill(key.owner.waypointsprite_attachedforcarrier);
 170                         else
 171                                 WaypointSprite_DetachCarrier(key.owner);
 172                 }
 173         }
 174
 175         key.owner = player;
 176
 177         if(player)
 178         {
 179                 // insert into linked list
 180                 key.kh_next = player.kh_next;
 181                 key.kh_prev = player;
 182                 player.kh_next = key;
 183                 if(key.kh_next)
 184                         key.kh_next.kh_prev = key;
 185
 186                 kh_Key_Attach(key, wpchange);
 187
 188                 if(key.kh_next == world)
 189                 {
 190                         // player is now a key carrier
 191                         WaypointSprite_AttachCarrier("", player);
 192                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 193                         player.waypointsprite_attachedforcarrier.team = player.team;
 194                 }
 195         }
 196
 197         key.pusher = world;
 198 }
 199
 200 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 201 {
 202         if(self.owner)
 203                 return;
 204         if(vlen(force) <= 0)
 205                 return;
 206         if(time > self.pushltime)
 207                 if(attacker.classname == "player")
 208                         self.team = attacker.team;
 209 }
 210
 211 void kh_Key_Spawn(entity initial_owner, float angle)
 212 {
 213         entity key;
 214         key = spawn();
 215         key.classname = STR_ITEM_KH_KEY;
 216         key.touch = kh_Key_Touch;
 217         key.think = kh_Key_Think;
 218         key.nextthink = time;
 219         key.items = IT_KEY1 | IT_KEY2;
 220         key.cnt = angle;
 221         key.angles = '0 360 0' * random();
 222         key.event_damage = kh_Key_Damage;
 223         setmodel(key, "models/keyhunt/key3.md3");
 224         setsize(key, '-8 -8 -8', '8 8 40');
 225
 226         switch(initial_owner.team)
 227         {
 228                 case COLOR_TEAM1:
 229                         key.netname = "^1red key";
 230                         key.colormod = '1.73 0.10 0.10';
 231                         break;
 232                 case COLOR_TEAM2:
 233                         key.netname = "^4blue key";
 234                         key.colormod = '0.10 0.10 1.73';
 235                         break;
 236                 case COLOR_TEAM3:
 237                         key.netname = "^3yellow key";
 238                         key.colormod = '1.22 1.22 0.10';
 239                         break;
 240                 case COLOR_TEAM4:
 241                         key.netname = "^6pink key";
 242                         key.colormod = '1.22 0.10 1.22';
 243                         break;
 244                 default:
 245                         key.netname = "NETGIER key";
 246                         key.colormod = '1.00 1.00 1.00';
 247                         break;
 248         }
 249
 250         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 251
 252         WaypointSprite_AttachCarrier("", key);
 253         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 254
 255         kh_Key_AssignTo(key, initial_owner, TRUE);
 256 }
 257
 258 void kh_Key_Remove(entity key)
 259 {
 260         entity o;
 261         o = key.owner;
 262         kh_Key_AssignTo(key, world, FALSE);
 263         if(o) // it was attached
 264                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 265         else // it was dropped
 266                 WaypointSprite_DetachCarrier(key);
 267
 268         remove(key);
 269 }
 270
 271 // -1 when no team completely owns all keys yet
 272 float kh_Key_AllOwnedByWhichTeam()
 273 {
 274         entity key;
 275         float teem;
 276
 277         teem = -1;
 278         FOR_EACH_KH_KEY(key)
 279         {
 280                 if(!key.owner)
 281                         return -1;
 282                 if(teem == -1)
 283                         teem = key.team;
 284                 else if(teem != key.team)
 285                         return -1;
 286         }
 287         return teem;
 288 }
 289
 290 void kh_Key_Collect(entity key, entity player)
 291 {
 292         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 293
 294         kh_Scores_Event(player, key, "collect", 1, 0);
 295         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 296         kh_Key_AssignTo(key, player, TRUE);
 297
 298         if(kh_Key_AllOwnedByWhichTeam() != -1)
 299         {
 300                 kh_interferemsg_time = time + 0.2;
 301                 kh_interferemsg_team = player.team;
 302         }
 303 }
 304
 305 void kh_Key_DropAll(entity player)
 306 {
 307         entity key;
 308         entity mypusher;
 309         if(player.kh_next)
 310         {
 311                 mypusher = world;
 312                 if(player.pusher)
 313                         if(time < player.pushltime)
 314                                 mypusher = player.pusher;
 315                 while((key = player.kh_next))
 316                 {
 317                         kh_Scores_Event(player, key, "losekey", 0, 0);
 318                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 319                         kh_Key_AssignTo(key, world, TRUE);
 320                         makevectors('-90 0 0' * random() + '0 360 0' * random());
 321                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 322                         key.pusher = mypusher;
 323                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 324                 }
 325                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 326         }
 327 }
 328
 329 void kh_Key_Touch()
 330 {
 331         if(self.owner) // already carried
 332                 return;
 333         if(other.classname != "player")
 334                 return;
 335         if(other.deadflag != DEAD_NO)
 336                 return;
 337         if(other == self.enemy)
 338                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 339                         return; // you just dropped it!
 340         kh_Key_Collect(self, other);
 341 }
 342
 343 void kh_Key_Think()
 344 {
 345         entity head;
 346
 347         self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 348
 349         if(self.owner)
 350         {
 351                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 352                 setorigin(self, v_forward * 24 + '0 0 1' * self.origin_z);
 353
 354                 if(self.owner.buttonuse)
 355                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 356                 {
 357                         self.owner.kh_droptime = time;
 358                         self.kh_droptime = time; // prevent collecting this one for some time
 359                         self.enemy = self.owner;
 360                         self.pusher = world;
 361                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 362                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 363                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 364                         makevectors(self.owner.v_angle);
 365                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 366                         kh_Key_AssignTo(self, world, TRUE);
 367                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 368                 }
 369         }
 370
 371         // if in nodrop or time over, end the round
 372         if(!self.owner)
 373                 if(time > self.pain_finished)
 374                         kh_LoserTeam(self.team, self);
 375
 376         if(self.owner)
 377         if(kh_Key_AllOwnedByWhichTeam() != -1)
 378         {
 379                 entity key;
 380                 vector p;
 381                 p = self.owner.origin;
 382                 FOR_EACH_KH_KEY(key)
 383                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 384                                 goto not_winning;
 385                 kh_WinnerTeam(self.team);
 386 :not_winning
 387         }
 388
 389         if(kh_interferemsg_time && time > kh_interferemsg_time)
 390         {
 391                 kh_interferemsg_time = 0;
 392                 FOR_EACH_PLAYER(head)
 393                 {
 394                         if(head.team == kh_interferemsg_team)
 395                                 if(head.kh_next)
 396                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 397                                 else
 398                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 399                         else
 400                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 401                 }
 402         }
 403
 404         self.nextthink = time + 0.05;
 405 }
 406
 407 void kh_WinnerTeam(float teem)
 408 {
 409         // all key carriers get some points
 410         vector firstorigin, lastorigin;
 411         float first;
 412         entity key;
 413         float score;
 414         score = (kh_teams - 1) / kh_teams;
 415         // twice the score for 3 team games, three times the score for 4 team games!
 416         // note: for a win by destroying the key, this should NOT be applied
 417         first = TRUE;
 418         FOR_EACH_KH_KEY(key)
 419         {
 420                 kh_Scores_Event(key.owner, key, "capture", score, 0);
 421                 if(key.owner.kh_next == key)
 422                 {
 423                         if(!first)
 424                                 bprint("^7, ");
 425                         bprint(key.owner.netname);
 426                         first = FALSE;
 427                 }
 428         }
 429
 430         first = TRUE;
 431         FOR_EACH_KH_KEY(key)
 432         {
 433                 vector thisorigin;
 434
 435                 thisorigin = kh_AttachedOrigin(key);
 436
 437                 if(!first)
 438                         te_lightning2(world, lastorigin, thisorigin);
 439                 lastorigin = thisorigin;
 440                 if(first)
 441                         firstorigin = thisorigin;
 442                 first = FALSE;
 443         }
 444         if(kh_teams > 2)
 445         {
 446                 te_lightning2(world, lastorigin, firstorigin);
 447         }
 448
 449         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 450         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 451         kh_FinishRound();
 452 }
 453
 454 void kh_LoserTeam(float teem, entity lostkey)
 455 {
 456         entity player, key, attacker;
 457         float players;
 458         float keys;
 459         float score;
 460
 461         attacker = world;
 462         if(lostkey.pusher)
 463                 if(lostkey.pusher.team != teem)
 464                         if(lostkey.pusher.classname == "player")
 465                                 attacker = lostkey.pusher;
 466
 467         players = keys = 0;
 468
 469         if(attacker)
 470         {
 471                 kh_Scores_Event(attacker, world, "push", 1, 0);
 472                 centerprint(attacker, "Your push is the best!\n\n\n");
 473                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 474         }
 475         else
 476         {
 477                 FOR_EACH_PLAYER(player)
 478                         if(player.team != teem)
 479                                 ++players;
 480
 481                 FOR_EACH_KH_KEY(key)
 482                         if(key.owner && key.team != teem)
 483                                 ++keys;
 484
 485                 score = 1.0 / max(1, keys * cvar("g_balance_keyhunt_score_destroyed_ownfactor") + players);
 486
 487                 FOR_EACH_PLAYER(player)
 488                         if(player.team != teem)
 489                                 kh_Scores_Event(player, world, "destroyed", score, 0);
 490
 491                 FOR_EACH_KH_KEY(key)
 492                         if(key.owner && key.team != teem)
 493                                 kh_Scores_Event(key.owner, world, "destroyed", score * cvar("g_balance_keyhunt_score_destroyed_ownfactor"), 0);
 494
 495                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 496         }
 497         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 498
 499         kh_FinishRound();
 500 }
 501
 502 void kh_FinishRound()
 503 {
 504         // prepare next round
 505         kh_interferemsg_time = 0;
 506         entity key;
 507         FOR_EACH_KH_KEY(key)
 508                 kh_Key_Remove(key);
 509
 510         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 511 }
 512
 513 float kh_EnoughPlayers()
 514 {
 515         float i, players, teem;
 516         entity player;
 517
 518         // find a random player per team
 519         for(i = 0; i < kh_teams; ++i)
 520         {
 521                 teem = kh_Team_ByID(i);
 522                 players = 0;
 523                 FOR_EACH_PLAYER(player)
 524                         if(player.deadflag == DEAD_NO)
 525                                 if(player.team == teem)
 526                                         ++players;
 527                 if(players == 0)
 528                         return FALSE;
 529         }
 530         return TRUE;
 531 }
 532
 533 void kh_WaitForPlayers()
 534 {
 535         if(kh_EnoughPlayers())
 536                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 537         else
 538                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 539 }
 540
 541 void kh_StartRound()
 542 {
 543         float i, players, teem;
 544         entity player;
 545
 546         if(!kh_EnoughPlayers())
 547         {
 548                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 549                 return;
 550         }
 551
 552         FOR_EACH_PLAYER(player)
 553                 if(clienttype(player) == CLIENTTYPE_REAL)
 554                         centerprint_expire(player, CENTERPRIO_SPAM);
 555
 556         for(i = 0; i < kh_teams; ++i)
 557         {
 558                 teem = kh_Team_ByID(i);
 559                 players = 0;
 560                 entity my_player;
 561                 FOR_EACH_PLAYER(player)
 562                         if(player.deadflag == DEAD_NO)
 563                                 if(player.team == teem)
 564                                 {
 565                                         ++players;
 566                                         if(random() * players <= 1)
 567                                                 my_player = player;
 568                                 }
 569                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 570         }
 571
 572         kh_tracking_enabled = FALSE;
 573         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 574 }
 575
 576 void kh_setstatus()
 577 {
 578         if(kh_teams)
 579         {
 580                 float kh_KEY;
 581                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 582                 if(self.kh_next)
 583                         self.items = self.items | kh_KEY;
 584                 else
 585                         self.items = self.items - (self.items & kh_KEY);
 586         }
 587 }
 588
 589 void kh_EnableTrackingDevice()
 590 {
 591         entity player;
 592
 593         FOR_EACH_PLAYER(player)
 594                 if(clienttype(player) == CLIENTTYPE_REAL)
 595                         centerprint_expire(player, CENTERPRIO_SPAM);
 596
 597         kh_tracking_enabled = TRUE;
 598 }
 599
 600 float kh_Key_waypointsprite_for_player(entity e)
 601 {
 602         if(!kh_tracking_enabled)
 603                 return 0;
 604         if(!self.owner)
 605                 return kh_sprite_dropped;
 606         if(!self.owner.owner)
 607                 return kh_sprite_dropped;
 608         return 0; // draw only when key is not owned
 609 }
 610
 611 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 612 {
 613         if(e.classname != "player" || self.team != e.team)
 614                 if(!kh_tracking_enabled)
 615                         return 0;
 616
 617         // e is spectator? That's no team mate...
 618         if(e.classname != "player")
 619                 return kh_GetCarrierSprite(self.team, -1);
 620
 621         // e is no key carrier: simple case...
 622         if(!e.kh_next)
 623                 return kh_GetCarrierSprite(self.team, e.team);
 624
 625         // e is a key carrier: if any key is dropped or owned by another team, show
 626         // the carrier sprite; otherwise show run here
 627         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 628                 return kh_sprite_finish;
 629
 630         return kh_GetCarrierSprite(self.team, e.team);
 631 }
 632
 633 float kh_HandleFrags(entity attacker, entity targ, float f)
 634 {
 635         float newfrags;
 636
 637         if(f <= 0)
 638                 return f;
 639         if(attacker == targ)
 640                 return f;
 641
 642         if(targ.kh_next)
 643                 f = f - 1 + cvar("g_balance_keyhunt_score_carrierfrag");
 644
 645         if(newfrags)
 646                 f = f - 1 + newfrags;
 647         return f;
 648 }
 649
 650 void kh_init()
 651 {
 652         precache_sound(kh_sound_capture);
 653         precache_sound(kh_sound_destroy);
 654         precache_sound(kh_sound_drop);
 655         precache_sound(kh_sound_collect);
 656
 657         precache_model("models/sprites/key-dropped.sp2");
 658         precache_model("models/sprites/keycarrier-finish.sp2");
 659         precache_model("models/sprites/keycarrier-friend.sp2");
 660         precache_model("models/sprites/keycarrier-red.sp2");
 661         precache_model("models/sprites/keycarrier-blue.sp2");
 662         precache_model("models/sprites/keycarrier-yellow.sp2");
 663         precache_model("models/sprites/keycarrier-pink.sp2");
 664         precache_model("models/keyhunt/key3.md3");
 665
 666         // setup variables
 667         kh_teams = cvar("g_keyhunt_teams_override");
 668         if(kh_teams < 2)
 669                 kh_teams = cvar("g_keyhunt_teams");
 670         if(kh_teams < 2)
 671                 kh_teams = 2;
 672
 673         // make a KH entity for controlling the game
 674         kh_controller = spawn();
 675         kh_controller.think = kh_Controller_Think;
 676         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 677
 678         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 679         kh_sprite_dropped = kh_controller.modelindex;
 680         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 681         kh_sprite_finish = kh_controller.modelindex;
 682         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 683         kh_sprite_friend = kh_controller.modelindex;
 684         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 685         kh_sprite_red = kh_controller.modelindex;
 686         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 687         kh_sprite_blue = kh_controller.modelindex;
 688         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 689         kh_sprite_pink = kh_controller.modelindex;
 690         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 691         kh_sprite_yellow = kh_controller.modelindex;
 692         setmodel(kh_controller, "");
 693 }
 694
 695 void kh_finalize()
 696 {
 697         // to be called before intermission
 698         kh_FinishRound();
 699         remove(kh_controller);
 700         kh_controller = world;
 701 }