data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/misc/mouseclick.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_pink;
  37         if(t == COLOR_TEAM4) return kh_sprite_yellow;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(self.cnt > 0)
  59         {
  60                 if(kh_Controller_Waitmsg != "")
  61                 {
  62                         string s;
  63                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  64                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  65                         else
  66                                 s = kh_Controller_Waitmsg;
  67
  68                         dprint(s, "\n");
  69
  70                         FOR_EACH_PLAYER(e)
  71                                 if(clienttype(e) == CLIENTTYPE_REAL)
  72                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  73                 }
  74                 self.cnt -= 1;
  75         }
  76         else if(self.cnt == 0)
  77         {
  78                 FOR_EACH_PLAYER(e)
  79                         if(clienttype(e) == CLIENTTYPE_REAL)
  80                                 centerprint_expire(e, CENTERPRIO_SPAM);
  81                 self.cnt -= 1;
  82                 kh_Controller_Thinkfunc();
  83         }
  84         self.nextthink = time + 1;
  85 }
  86
  87 void kh_Log()
  88 {
  89         string s;
  90         if(!cvar("sv_eventlog"))
  91                 return;
  92         // TODO ...
  93         GameLogEcho(s, FALSE);
  94 }
  95
  96 // frags f: take from cvar * f
  97 // frags 0: no frags
  98 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
  99 {
 100         float basefrags;
 101         basefrags = cvar(strcat("g_balance_keyhunt_score_", what));
 102
 103         if(frags_player)
 104                 player.frags = player.frags + floor(0.5 + basefrags * frags_player);
 105         if(frags_owner)
 106                 key.owner.frags = key.owner.frags + floor(0.5 + basefrags * frags_owner);
 107 }
 108
 109 void kh_Key_Attach(entity key, float wpchange)
 110 {
 111         setattachment(key, key.owner, "");
 112         setorigin(key, '0 0 0'); // fixed later in think
 113         key.angles = key.angles - '0 1 0' * key.owner.angles_y;
 114         key.flags = 0;
 115         key.solid = SOLID_NOT;
 116         key.movetype = MOVETYPE_NONE;
 117         key.team = key.owner.team;
 118         key.nextthink = time;
 119 }
 120
 121 vector kh_AttachedOrigin(entity e)
 122 {
 123         if(e.tag_entity)
 124         {
 125                 makevectors(e.tag_entity.angles);
 126                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 127         }
 128         else
 129                 return e.origin;
 130 }
 131
 132 void kh_Key_Detach(entity key, float wpchange)
 133 {
 134         setorigin(key, kh_AttachedOrigin(key));
 135         setattachment(key, world, "");
 136         key.angles_y = key.owner.angles_y;
 137         key.aiment = world;
 138         key.flags = FL_ITEM;
 139         key.solid = SOLID_TRIGGER;
 140         key.movetype = MOVETYPE_TOSS;
 141         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 142         // let key.team stay
 143 }
 144
 145 void kh_Key_AssignTo(entity key, entity player, float wpchange)
 146 {
 147         if(key.owner == player)
 148                 return;
 149
 150         if(key.owner)
 151         {
 152                 kh_Key_Detach(key, wpchange);
 153
 154                 // remove from linked list
 155                 if(key.kh_next)
 156                         key.kh_next.kh_prev = key.kh_prev;
 157                 key.kh_prev.kh_next = key.kh_next;
 158                 key.kh_next = world;
 159                 key.kh_prev = world;
 160
 161                 if(key.owner.kh_next == world)
 162                 {
 163                         // No longer a key carrier
 164                         if(wpchange)
 165                                 WaypointSprite_Kill(key.owner.waypointsprite_attachedforcarrier);
 166                         else
 167                                 WaypointSprite_DetachCarrier(key.owner);
 168                 }
 169         }
 170
 171         key.owner = player;
 172
 173         if(player)
 174         {
 175                 // insert into linked list
 176                 key.kh_next = player.kh_next;
 177                 key.kh_prev = player;
 178                 player.kh_next = key;
 179                 if(key.kh_next)
 180                         key.kh_next.kh_prev = key;
 181
 182                 kh_Key_Attach(key, wpchange);
 183
 184                 if(key.kh_next == world)
 185                 {
 186                         // player is now a key carrier
 187                         WaypointSprite_AttachCarrier("", player);
 188                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 189                         player.waypointsprite_attachedforcarrier.team = player.team;
 190                 }
 191         }
 192
 193         key.pusher = world;
 194 }
 195
 196 void kh_Key_Spawn(entity initial_owner, float angle)
 197 {
 198         entity key;
 199         key = spawn();
 200         key.classname = STR_ITEM_KH_KEY;
 201         key.touch = kh_Key_Touch;
 202         key.think = kh_Key_Think;
 203         key.nextthink = time;
 204         key.items = IT_KEY1 | IT_KEY2;
 205         key.cnt = angle;
 206         key.angles = '0 360 0' * random();
 207         setmodel(key, "models/keyhunt/key3.md3");
 208         setsize(key, '0 0 -24', '0 0 25');
 209
 210         switch(initial_owner.team)
 211         {
 212                 case COLOR_TEAM1:
 213                         key.netname = "^1red key";
 214                         key.colormod = '1.73 0.10 0.10';
 215                         break;
 216                 case COLOR_TEAM2:
 217                         key.netname = "^4blue key";
 218                         key.colormod = '0.10 0.10 1.73';
 219                         break;
 220                 case COLOR_TEAM3:
 221                         key.netname = "^6pink key";
 222                         key.colormod = '1.22 0.10 1.22';
 223                         break;
 224                 case COLOR_TEAM4:
 225                         key.netname = "^3yellow key";
 226                         key.colormod = '1.22 1.22 0.10';
 227                         break;
 228                 default:
 229                         key.netname = "NETGIER key";
 230                         key.colormod = '1.00 1.00 1.00';
 231                         break;
 232         }
 233
 234         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 235
 236         WaypointSprite_AttachCarrier("", key);
 237         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 238
 239         kh_Key_AssignTo(key, initial_owner, TRUE);
 240 }
 241
 242 void kh_Key_Remove(entity key)
 243 {
 244         entity o;
 245         o = key.owner;
 246         kh_Key_AssignTo(key, world, FALSE);
 247         if(o) // it was attached
 248                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 249         else // it was dropped
 250                 WaypointSprite_DetachCarrier(key);
 251
 252         remove(key);
 253 }
 254
 255 void kh_Key_Collect(entity key, entity player)
 256 {
 257         kh_Scores_Event(player, key, "collect", 1, 0);
 258         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 259         kh_Key_AssignTo(key, player, TRUE);
 260
 261         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 262
 263         FOR_EACH_KH_KEY(key)
 264                 if(!key.owner || key.team != player.team)
 265                         goto notallowned;
 266         kh_interferemsg_time = time + 0.2;
 267         kh_interferemsg_team = player.team;
 268 :notallowned
 269 }
 270
 271 void kh_Key_DropAll(entity player)
 272 {
 273         entity key;
 274         entity mypusher;
 275         if(player.kh_next)
 276         {
 277                 mypusher = world;
 278                 if(player.pusher)
 279                         if(time < player.pushltime)
 280                                 mypusher = player.pusher;
 281                 while((key = player.kh_next))
 282                 {
 283                         kh_Scores_Event(player, key, "losekey", 0, 0);
 284                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 285                         kh_Key_AssignTo(key, world, TRUE);
 286                         key.pusher = mypusher;
 287                 }
 288                 sound(world, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 289         }
 290 }
 291
 292 void kh_Key_Touch()
 293 {
 294         if(self.owner) // already carried
 295                 return;
 296         if(other.classname != "player")
 297                 return;
 298         if(other.deadflag != DEAD_NO)
 299                 return;
 300         if(other == self.enemy)
 301                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 302                         return; // you just dropped it!
 303         kh_Key_Collect(self, other);
 304 }
 305
 306 void kh_Key_Think()
 307 {
 308         entity head;
 309
 310         self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 311
 312         if(self.owner)
 313         {
 314                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 315                 setorigin(self, v_forward * 16);
 316
 317                 if(self.owner.buttonuse)
 318                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 319                 {
 320                         self.owner.kh_droptime = time;
 321                         self.kh_droptime = time; // prevent collecting this one for some time
 322                         self.enemy = self.owner;
 323                         self.pusher = world;
 324                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 325                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 326                         kh_Key_AssignTo(self, world, TRUE);
 327                         sound(world, CHAN_AUTO, kh_sound_drop, 1, ATTN_NONE);
 328                 }
 329         }
 330
 331         // if in nodrop or time over, end the round
 332         if(!self.owner)
 333                 if(time > self.pain_finished)
 334                         kh_LoserTeam(self.team, self);
 335
 336         if(self.owner)
 337         {
 338                 entity key;
 339                 vector p;
 340                 float teem;
 341                 teem = self.team;
 342                 p = self.owner.origin;
 343                 FOR_EACH_KH_KEY(key)
 344                 {
 345                         if(key.owner == self.owner)
 346                                 continue;
 347                         if(key.owner)
 348                         if(key.team == teem)
 349                         if(vlen(key.owner.origin - p) < cvar("g_balance_keyhunt_maxdist"))
 350                                 continue;
 351                         goto not_winning;
 352                 }
 353                 kh_WinnerTeam(teem);
 354 :not_winning
 355         }
 356
 357         if(kh_interferemsg_time && time > kh_interferemsg_time)
 358         {
 359                 kh_interferemsg_time = 0;
 360                 FOR_EACH_PLAYER(head)
 361                 {
 362                         if(head.team == kh_interferemsg_team)
 363                                 if(head.kh_next)
 364                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 365                                 else
 366                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 367                         else
 368                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 369                 }
 370         }
 371
 372         self.nextthink = time + 0.05;
 373 }
 374
 375 void kh_WinnerTeam(float teem)
 376 {
 377         // all key carriers get some points
 378         vector firstorigin, lastorigin;
 379         float first;
 380         entity key;
 381         float score;
 382         score = 1.0 / kh_teams;
 383         first = TRUE;
 384         FOR_EACH_KH_KEY(key)
 385         {
 386                 kh_Scores_Event(key.owner, key, "capture", score, 0);
 387                 if(key.owner.kh_next == key)
 388                 {
 389                         if(!first)
 390                                 bprint("^7, ");
 391                         bprint(key.owner.netname);
 392                         first = FALSE;
 393                 }
 394         }
 395
 396         first = TRUE;
 397         FOR_EACH_KH_KEY(key)
 398         {
 399                 vector thisorigin;
 400
 401                 thisorigin = kh_AttachedOrigin(key);
 402
 403                 if(!first)
 404                         te_lightning2(world, lastorigin, thisorigin);
 405                 lastorigin = thisorigin;
 406                 if(first)
 407                         firstorigin = thisorigin;
 408                 first = FALSE;
 409         }
 410         if(kh_teams > 2)
 411         {
 412                 te_lightning2(world, lastorigin, firstorigin);
 413         }
 414
 415         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 416         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 417         kh_FinishRound();
 418 }
 419
 420 void kh_LoserTeam(float teem, entity lostkey)
 421 {
 422         entity player, key, attacker;
 423         float players;
 424         float keys;
 425         float score;
 426
 427         attacker = world;
 428         if(lostkey.pusher)
 429                 if(lostkey.pusher.team != teem)
 430                         if(lostkey.pusher.classname == "player")
 431                                 attacker = lostkey.pusher;
 432
 433         players = keys = 0;
 434
 435         if(attacker)
 436         {
 437                 kh_Scores_Event(attacker, world, "push", 1, 0);
 438                 centerprint(attacker, "Your push is the best!\n\n\n");
 439                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 440         }
 441         else
 442         {
 443                 FOR_EACH_PLAYER(player)
 444                         if(player.team != teem)
 445                                 ++players;
 446
 447                 FOR_EACH_KH_KEY(key)
 448                         if(key.owner && key.team != teem)
 449                                 ++keys;
 450
 451                 score = 1.0 / (keys * cvar("g_balance_keyhunt_score_destroyed_ownfactor") + players);
 452
 453                 FOR_EACH_PLAYER(player)
 454                         if(player.team != teem)
 455                                 kh_Scores_Event(player, world, "destroyed", score, 0);
 456
 457                 FOR_EACH_KH_KEY(key)
 458                         if(key.owner && key.team != teem)
 459                                 kh_Scores_Event(key.owner, world, "destroyed", score * cvar("g_balance_keyhunt_score_destroyed_ownfactor"), 0);
 460
 461                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 462         }
 463         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 464
 465         kh_FinishRound();
 466 }
 467
 468 void kh_FinishRound()
 469 {
 470         // prepare next round
 471         kh_interferemsg_time = 0;
 472         entity key;
 473         FOR_EACH_KH_KEY(key)
 474                 kh_Key_Remove(key);
 475
 476         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 477 }
 478
 479 float kh_EnoughPlayers()
 480 {
 481         float i, players, teem;
 482         entity player;
 483
 484         // find a random player per team
 485         for(i = 0; i < kh_teams; ++i)
 486         {
 487                 teem = kh_Team_ByID(i);
 488                 players = 0;
 489                 FOR_EACH_PLAYER(player)
 490                         if(player.deadflag == DEAD_NO)
 491                                 if(player.team == teem)
 492                                         ++players;
 493                 if(players == 0)
 494                         return FALSE;
 495         }
 496         return TRUE;
 497 }
 498
 499 void kh_WaitForPlayers()
 500 {
 501         if(kh_EnoughPlayers())
 502                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 503         else
 504                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 505 }
 506
 507 void kh_StartRound()
 508 {
 509         float i, players, teem;
 510         entity player;
 511
 512         if(!kh_EnoughPlayers())
 513         {
 514                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 515                 return;
 516         }
 517
 518         for(i = 0; i < kh_teams; ++i)
 519         {
 520                 teem = kh_Team_ByID(i);
 521                 players = 0;
 522                 entity my_player;
 523                 FOR_EACH_PLAYER(player)
 524                         if(player.deadflag == DEAD_NO)
 525                                 if(player.team == teem)
 526                                 {
 527                                         ++players;
 528                                         if(random() * players <= 1)
 529                                                 my_player = player;
 530                                 }
 531                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 532         }
 533
 534         kh_tracking_enabled = FALSE;
 535         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 536 }
 537
 538 void kh_setstatus()
 539 {
 540         if(kh_teams)
 541         {
 542                 float kh_KEY;
 543                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 544                 if(self.kh_next)
 545                         self.items = self.items | kh_KEY;
 546                 else
 547                         self.items = self.items - (self.items & kh_KEY);
 548         }
 549 }
 550
 551 void kh_EnableTrackingDevice()
 552 {
 553         kh_tracking_enabled = TRUE;
 554 }
 555
 556 float kh_Key_waypointsprite_for_player(entity e)
 557 {
 558         if(!kh_tracking_enabled)
 559                 return 0;
 560         if(!self.owner)
 561                 return kh_sprite_dropped;
 562         if(!self.owner.owner)
 563                 return kh_sprite_dropped;
 564         return 0; // draw only when key is not owned
 565 }
 566
 567 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 568 {
 569         entity key;
 570
 571         if(e.classname != "player" || self.team != e.team)
 572                 if(!kh_tracking_enabled)
 573                         return 0;
 574
 575         // e is spectator? That's no team mate...
 576         if(e.classname != "player")
 577                 return kh_GetCarrierSprite(self.team, -1);
 578
 579         // e is no key carrier: simple case...
 580         if(!e.kh_next)
 581                 return kh_GetCarrierSprite(self.team, e.team);
 582
 583         // e is a key carrier: if any key is dropped or owned by another team, show
 584         // the carrier sprite; otherwise show run here
 585         FOR_EACH_KH_KEY(key)
 586                 if(!key.owner || key.team != e.team)
 587                         return kh_GetCarrierSprite(self.team, e.team);
 588
 589         return kh_sprite_finish;
 590 }
 591
 592 float kh_HandleFrags(entity attacker, entity targ, float f)
 593 {
 594         float newfrags;
 595
 596         if(f <= 0)
 597                 return f;
 598         if(attacker == targ)
 599                 return f;
 600
 601         if(targ.kh_next)
 602                 f = f - 1 + cvar("g_balance_keyhunt_score_carrierfrag");
 603
 604         if(newfrags)
 605                 f = f - 1 + newfrags;
 606         return f;
 607 }
 608
 609 void kh_init()
 610 {
 611         precache_sound(kh_sound_capture);
 612         precache_sound(kh_sound_destroy);
 613         precache_sound(kh_sound_drop);
 614         precache_sound(kh_sound_collect);
 615
 616         precache_model("models/sprites/key-dropped.sp2");
 617         precache_model("models/sprites/keycarrier-finish.sp2");
 618         precache_model("models/sprites/keycarrier-friend.sp2");
 619         precache_model("models/sprites/keycarrier-red.sp2");
 620         precache_model("models/sprites/keycarrier-blue.sp2");
 621         precache_model("models/sprites/keycarrier-pink.sp2");
 622         precache_model("models/sprites/keycarrier-yellow.sp2");
 623         precache_model("models/keyhunt/key3.md3");
 624
 625         // setup variables
 626         kh_teams = cvar("g_keyhunt_teams_override");
 627         if(kh_teams < 2)
 628                 kh_teams = cvar("g_keyhunt_teams");
 629         if(kh_teams < 2)
 630                 kh_teams = 2;
 631
 632         // make a KH entity for controlling the game
 633         kh_controller = spawn();
 634         kh_controller.think = kh_Controller_Think;
 635         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 636
 637         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 638         kh_sprite_dropped = kh_controller.modelindex;
 639         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 640         kh_sprite_finish = kh_controller.modelindex;
 641         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 642         kh_sprite_friend = kh_controller.modelindex;
 643         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 644         kh_sprite_red = kh_controller.modelindex;
 645         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 646         kh_sprite_blue = kh_controller.modelindex;
 647         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 648         kh_sprite_pink = kh_controller.modelindex;
 649         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 650         kh_sprite_yellow = kh_controller.modelindex;
 651         setmodel(kh_controller, "");
 652 }
 653
 654 void kh_finalize()
 655 {
 656         // to be called before intermission
 657         kh_FinishRound();
 658         remove(kh_controller);
 659         kh_controller = world;
 660 }