data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25 float kh_no_radar_circles;
  26
  27 // kh_state
  28 //     bits 0-7: player's key status
  29 //     bits 8-15: general key status
  30 .float kh_state;
  31 .float siren_time;  //  time delay the siren
  32 //.float stuff_time;  //  time delay to stuffcmd a cvar
  33
  34 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  35 //test[0] = status of dropped keys, test[1 - 16] = player #
  36 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  37 //for(i = 0; i < maxplayers; ++i)
  38 //      test[i] = "0";
  39
  40 float kh_Team_ByID(float t)
  41 {
  42         if(t == 0) return COLOR_TEAM1;
  43         if(t == 1) return COLOR_TEAM2;
  44         if(t == 2) return COLOR_TEAM3;
  45         if(t == 3) return COLOR_TEAM4;
  46         return 0;
  47 }
  48
  49 entity kh_worldkeylist;
  50 .entity kh_worldkeynext;
  51 entity kh_controller;
  52 float kh_tracking_enabled;
  53 float kh_teams;
  54 float kh_interferemsg_time, kh_interferemsg_team;
  55 .entity kh_next, kh_prev; // linked list
  56 .float kh_droptime;
  57 .float kh_dropperteam;
  58 .entity kh_previous_owner;
  59 .float kh_previous_owner_playerid;
  60
  61 string kh_sound_capture = "sound/kh/capture.wav";
  62 string kh_sound_destroy = "sound/kh/destroy.wav";
  63 string kh_sound_drop = "sound/kh/drop.wav";
  64 string kh_sound_collect = "sound/kh/collect.wav";
  65 string kh_sound_alarm = "sound/kh/alarm.wav";  // the new siren/alarm
  66
  67 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  68 float kh_key_dropped, kh_key_carried;
  69
  70 float kh_GetCarrierSprite(float t, float e)  // runs all the time
  71 {
  72         if(t == e)           return kh_sprite_friend;
  73         if(t == COLOR_TEAM1) return kh_sprite_red;
  74         if(t == COLOR_TEAM2) return kh_sprite_blue;
  75         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  76         if(t == COLOR_TEAM4) return kh_sprite_pink;
  77         return 0;
  78 }
  79
  80 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  81 {
  82         kh_Controller_Thinkfunc = func;
  83         kh_controller.cnt = t;
  84         if(kh_Controller_Waitmsg != "")
  85                 strunzone(kh_Controller_Waitmsg);
  86         if(msg == "")
  87                 kh_Controller_Waitmsg = "";
  88         else
  89                 kh_Controller_Waitmsg = strzone(msg);
  90         if(t == 0)
  91                 kh_controller.nextthink = time; // force
  92 }
  93
  94 void kh_Controller_Think()  // called a lot
  95 {
  96         entity e;
  97         if(intermission_running)
  98                 return;
  99         if(self.cnt > 0)
 100         {
 101                 if(kh_Controller_Waitmsg != "")
 102                 {
 103                         string s;
 104                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 105                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 106                         else
 107                                 s = kh_Controller_Waitmsg;
 108
 109                         //dprint(s, "\n");
 110
 111                         FOR_EACH_PLAYER(e)
 112                                 if(clienttype(e) == CLIENTTYPE_REAL)
 113                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 114                 }
 115                 self.cnt -= 1;
 116         }
 117         else if(self.cnt == 0)
 118         {
 119                 self.cnt -= 1;
 120                 kh_Controller_Thinkfunc();
 121         }
 122         self.nextthink = time + 1;
 123 }
 124
 125 // frags f: take from cvar * f
 126 // frags 0: no frags
 127 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 128 {
 129         string s;
 130         if(intermission_running)
 131                 return;
 132         if(frags_player)
 133                 UpdateFrags(player, frags_player);
 134         if(key && key.owner && frags_owner)
 135                 UpdateFrags(key.owner, frags_owner);
 136         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 137                 return;
 138         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 139         s = strcat(s, ":", ftos(frags_player));
 140         if(key && key.owner)
 141                 s = strcat(s, ":", ftos(key.owner.playerid));
 142         else
 143                 s = strcat(s, ":0");
 144         s = strcat(s, ":", ftos(frags_owner), ":");
 145         if(key)
 146                 s = strcat(s, key.netname);
 147         GameLogEcho(s);
 148 }
 149
 150 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 151 {
 152         if(e.tag_entity)
 153         {
 154                 makevectors(e.tag_entity.angles);
 155                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 156         }
 157         else
 158                 return e.origin;
 159 }
 160
 161 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 162 {
 163 #ifdef KH_PLAYER_USE_ATTACHMENT
 164         entity first;
 165         first = key.owner.kh_next;
 166         if(key == first)
 167         {
 168                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 169                 if(key.kh_next)
 170                 {
 171                         setattachment(key.kh_next, key, "");
 172                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 173                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 174                         key.kh_next.angles = '0 0 0';
 175                 }
 176                 else
 177                         setorigin(key, KH_PLAYER_ATTACHMENT);
 178                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 179         }
 180         else
 181         {
 182                 setattachment(key, key.kh_prev, "");
 183                 if(key.kh_next)
 184                         setattachment(key.kh_next, key, "");
 185                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 186                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 187                 key.angles = '0 0 0';
 188         }
 189 #else
 190         setattachment(key, key.owner, "");
 191         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 192         key.angles_y -= key.owner.angles_y;
 193 #endif
 194         key.flags = 0;
 195         key.solid = SOLID_NOT;
 196         key.movetype = MOVETYPE_NONE;
 197         key.team = key.owner.team;
 198         key.nextthink = time;
 199         key.damageforcescale = 0;
 200         key.modelindex = kh_key_carried;
 201 }
 202
 203 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 204 {
 205         float i;
 206         i = test[key.owner.playerid];
 207                 if(key.netname == "^1red key")
 208                         i -= 1;
 209                 if(key.netname == "^4blue key")
 210                         i -= 2;
 211                 if(key.netname == "^3yellow key")
 212                         i -= 4;
 213                 if(key.netname == "^6pink key")
 214                         i -= 8;
 215         test[key.owner.playerid] = i;
 216
 217         kh_show_temp();
 218         if(key.owner)
 219                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 220         //key.owner.kh_state += test[key.owner.playerid];
 221
 222 #ifdef KH_PLAYER_USE_ATTACHMENT
 223         entity first;
 224         first = key.owner.kh_next;
 225         if(key == first)
 226         {
 227                 if(key.kh_next)
 228                 {
 229                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 230                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 231                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 232                 }
 233         }
 234         else
 235         {
 236                 if(key.kh_next)
 237                         setattachment(key.kh_next, key.kh_prev, "");
 238                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 239         }
 240         // in any case:
 241         setattachment(key, world, "");
 242         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 243         key.angles = key.owner.angles;
 244 #else
 245         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 246         setattachment(key, world, "");
 247         key.angles_y += key.owner.angles_y;
 248 #endif
 249         key.flags = FL_ITEM;
 250         key.solid = SOLID_TRIGGER;
 251         key.movetype = MOVETYPE_TOSS;
 252         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 253         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 254         // let key.team stay
 255         key.modelindex = kh_key_dropped;
 256         key.kh_previous_owner = key.owner;
 257         key.kh_previous_owner_playerid = key.owner.playerid;
 258 }
 259
 260 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 261 {
 262         entity k;
 263         float ownerteam0, ownerteam;
 264         if(key.owner == player)
 265                 return;
 266
 267         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 268
 269         if(key.owner)
 270         {
 271                 kh_Key_Detach(key);
 272
 273                 // remove from linked list
 274                 if(key.kh_next)
 275                         key.kh_next.kh_prev = key.kh_prev;
 276                 key.kh_prev.kh_next = key.kh_next;
 277                 key.kh_next = world;
 278                 key.kh_prev = world;
 279
 280                 if(key.owner.kh_next == world)
 281                 {
 282                         // No longer a key carrier
 283                         if(!kh_no_radar_circles)
 284                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 285                         WaypointSprite_DetachCarrier(key.owner);
 286                 }
 287         }
 288
 289         key.owner = player;
 290
 291         if(player)
 292         {
 293                 // insert into linked list
 294                 key.kh_next = player.kh_next;
 295                 key.kh_prev = player;
 296                 player.kh_next = key;
 297                 if(key.kh_next)
 298                         key.kh_next.kh_prev = key;
 299
 300                 float i;
 301                 i = test[key.owner.playerid];
 302                         if(key.netname == "^1red key")
 303                                 i += 1;
 304                         if(key.netname == "^4blue key")
 305                                 i += 2;
 306                         if(key.netname == "^3yellow key")
 307                                 i += 4;
 308                         if(key.netname == "^6pink key")
 309                                 i += 8;
 310                 test[key.owner.playerid] = i;
 311
 312                 kh_Key_Attach(key);
 313
 314                 if(key.kh_next == world)
 315                 {
 316                         // player is now a key carrier
 317                         WaypointSprite_AttachCarrier("", player);
 318                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 319                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 320                         if(player.team == COLOR_TEAM1)
 321                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "");
 322                         else if(player.team == COLOR_TEAM2)
 323                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "");
 324                         else if(player.team == COLOR_TEAM3)
 325                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "");
 326                         else if(player.team == COLOR_TEAM4)
 327                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "");
 328                         WaypointSprite_UpdateTeamRadar(player.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1));
 329                         if(!kh_no_radar_circles)
 330                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 331                 }
 332         }
 333
 334         // moved that here, also update if there's no player
 335         kh_show_temp();
 336         if(key.owner)
 337                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 338
 339         key.pusher = world;
 340
 341         ownerteam = kh_Key_AllOwnedByWhichTeam();
 342         if(ownerteam != ownerteam0)
 343         {
 344                 if(ownerteam != -1)
 345                 {
 346                         kh_interferemsg_time = time + 0.2;
 347                         kh_interferemsg_team = player.team;
 348
 349                         // audit all key carrier sprites, update them to RUN HERE
 350                         FOR_EACH_KH_KEY(k)
 351                         {
 352                                 if(k.owner)
 353                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model, "keycarrier-finish", "");
 354                         }
 355                 }
 356                 else
 357                 {
 358                         // audit all key carrier sprites, update them to RUN HERE
 359                         FOR_EACH_KH_KEY(k)
 360                         {
 361                                 if(k.owner)
 362                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model, "keycarrier-friend", "");
 363                         }
 364                 }
 365         }
 366 }
 367
 368 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 369 {
 370         if(self.owner)
 371                 return;
 372         if(vlen(force) <= 0)
 373                 return;
 374         if(time > self.pushltime)
 375                 if(attacker.classname == "player")
 376                         self.team = attacker.team;
 377 }
 378
 379 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 380 {
 381         entity key;
 382         key = spawn();
 383         key.classname = STR_ITEM_KH_KEY;
 384         key.touch = kh_Key_Touch;
 385         key.think = kh_Key_Think;
 386         key.nextthink = time;
 387         key.items = IT_KEY1 | IT_KEY2;
 388         key.cnt = angle;
 389         key.angles = '0 360 0' * random();
 390         key.event_damage = kh_Key_Damage;
 391         key.takedamage = DAMAGE_YES;
 392         key.modelindex = kh_key_dropped;
 393         key.model = "key";
 394         key.kh_dropperteam = 0;
 395         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 396         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 397         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 398
 399         switch(initial_owner.team)
 400         {
 401                 case COLOR_TEAM1:
 402                         key.netname = "^1red key";
 403                         break;
 404                 case COLOR_TEAM2:
 405                         key.netname = "^4blue key";
 406                         break;
 407                 case COLOR_TEAM3:
 408                         key.netname = "^3yellow key";
 409                         break;
 410                 case COLOR_TEAM4:
 411                         key.netname = "^6pink key";
 412                         break;
 413                 default:
 414                         key.netname = "NETGIER key";
 415                         break;
 416         }
 417
 418         // link into key list
 419         key.kh_worldkeynext = kh_worldkeylist;
 420         kh_worldkeylist = key;
 421
 422         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 423
 424         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 425         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 426         WaypointSprite_UpdateTeamRadar(key.waypointsprite_attachedforcarrier, RADARICON_FLAG, '0 1 1');
 427
 428         kh_Key_AssignTo(key, initial_owner);
 429 }
 430
 431 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 432 {
 433         entity o;
 434         o = key.owner;
 435         kh_Key_AssignTo(key, world);
 436         if(o) // it was attached
 437                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 438         else // it was dropped
 439                 WaypointSprite_DetachCarrier(key);
 440
 441         // remove key from key list
 442         if (kh_worldkeylist == key)
 443                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 444         else
 445         {
 446                 o = kh_worldkeylist;
 447                 while (o)
 448                 {
 449                         if (o.kh_worldkeynext == key)
 450                         {
 451                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 452                                 break;
 453                         }
 454                         o = o.kh_worldkeynext;
 455                 }
 456         }
 457
 458         remove(key);
 459 }
 460
 461 // -1 when no team completely owns all keys yet
 462 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 463 {
 464         entity key;
 465         float teem;
 466
 467         teem = -1;
 468         FOR_EACH_KH_KEY(key)
 469         {
 470                 if(!key.owner)
 471                         return -1;
 472                 if(teem == -1)
 473                         teem = key.team;
 474                 else if(teem != key.team)
 475                         return -1;
 476         }
 477         return teem;
 478 }
 479
 480 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 481 {
 482         float ownerteam;
 483         entity k;
 484
 485         sound(player, CHAN_AUTO, kh_sound_collect, VOL_BASE, ATTN_NORM);
 486
 487         if(key.kh_dropperteam != player.team)
 488         {
 489                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 490                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 491         }
 492         key.kh_dropperteam = 0;
 493         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 494
 495         kh_Key_AssignTo(key, player); // this also updates .kh_state
 496 }
 497
 498 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 499 {
 500         entity key;
 501         entity mypusher;
 502         if(player.kh_next)
 503         {
 504                 mypusher = world;
 505                 if(player.pusher)
 506                         if(time < player.pushltime)
 507                                 mypusher = player.pusher;
 508                 while((key = player.kh_next))
 509                 {
 510                         kh_Scores_Event(player, key, "losekey", 0, 0);
 511                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 512                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 513                         kh_Key_AssignTo(key, world);
 514                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 515                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 516                         key.pusher = mypusher;
 517                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 518                         if(suicide)
 519                                 key.kh_dropperteam = player.team;
 520                 }
 521                 sound(player, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 522         }
 523 }
 524
 525 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 526 {
 527         if(intermission_running)
 528                 return;
 529
 530         if(self.owner) // already carried
 531                 return;
 532         if(other.classname != "player")
 533                 return;
 534         if(other.deadflag != DEAD_NO)
 535                 return;
 536         if(other == self.enemy)
 537                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 538                         return;  // you just dropped it!
 539         kh_Key_Collect(self, other);
 540 }
 541
 542 void kh_Key_Think()  // runs all the time
 543 {
 544         entity head;
 545         //entity player;  // needed by FOR_EACH_PLAYER
 546
 547         if(intermission_running)
 548                 return;
 549         /*
 550         if(time > self.stuff_time)
 551         {
 552                 FOR_EACH_PLAYER(player)
 553                         player.kh_state = test[0]*256 + (player.kh_state&255);
 554
 555                 self.stuff_time = time + 1;  // repeat in 1 second
 556         }
 557         */
 558
 559 #ifdef KH_KEY_ATTACHMENT_DEBUG
 560         if(self.kh_prev == self.owner)
 561         {
 562                 if(cvar_string("_angles") != "")
 563                 {
 564                         self.angles = stov(cvar_string("_angles"));
 565                         self.origin = stov(cvar_string("_origin"));
 566                 }
 567         }
 568 #endif
 569
 570         if(self.owner)
 571         {
 572 #ifndef KH_PLAYER_USE_ATTACHMENT
 573                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 574                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 575 #endif
 576
 577                 if(self.owner.BUTTON_USE)
 578                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 579                 {
 580                         self.owner.kh_droptime = time;
 581                         self.kh_droptime = time;  // prevent collecting this one for some time
 582                         self.enemy = self.owner;
 583                         self.pusher = world;
 584                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 585                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 586                         sound(self.owner, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 587                         makevectors(self.owner.v_angle);
 588                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 589                         kh_Key_AssignTo(self, world);
 590                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 591                         self.kh_dropperteam = self.team;
 592                 }
 593         }
 594
 595         // if in nodrop or time over, end the round
 596         if(!self.owner)
 597                 if(time > self.pain_finished)
 598                         kh_LoserTeam(self.team, self);
 599
 600         if(self.owner)
 601         if(kh_Key_AllOwnedByWhichTeam() != -1)
 602         {
 603                 if(self.siren_time < time)
 604                 {
 605                         sound(self.owner, CHAN_AUTO, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 606                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 607                 }
 608
 609                 entity key;
 610                 vector p;
 611                 p = self.owner.origin;
 612                 FOR_EACH_KH_KEY(key)
 613                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 614                                 goto not_winning;
 615                 kh_WinnerTeam(self.team);
 616 :not_winning
 617         }
 618
 619         if(kh_interferemsg_time && time > kh_interferemsg_time)
 620         {
 621                 kh_interferemsg_time = 0;
 622                 FOR_EACH_PLAYER(head)
 623                 {
 624                         if(head.team == kh_interferemsg_team)
 625                                 if(head.kh_next)
 626                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 627                                 else
 628                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 629                         else
 630                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 631                 }
 632         }
 633
 634         self.nextthink = time + 0.05;
 635 }
 636
 637 void kh_WinnerTeam(float teem)  // runs when a team wins
 638 {
 639         // all key carriers get some points
 640         vector firstorigin, lastorigin, midpoint;
 641         float first;
 642         entity key;
 643         float score;
 644         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 645         DistributeEvenly_Init(score, kh_teams);
 646         // twice the score for 3 team games, three times the score for 4 team games!
 647         // note: for a win by destroying the key, this should NOT be applied
 648         FOR_EACH_KH_KEY(key)
 649         {
 650                 float f;
 651                 f = DistributeEvenly_Get(1);
 652                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 653                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 654         }
 655
 656         first = TRUE;
 657         FOR_EACH_KH_KEY(key)
 658                 if(key.owner.kh_next == key)
 659                 {
 660                         if(!first)
 661                                 bprint("^7, ");
 662                         bprint(key.owner.netname);
 663                         first = FALSE;
 664                 }
 665         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 666
 667         first = TRUE;
 668         midpoint = '0 0 0';
 669         FOR_EACH_KH_KEY(key)
 670         {
 671                 vector thisorigin;
 672
 673                 thisorigin = kh_AttachedOrigin(key);
 674                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 675                 midpoint += thisorigin;
 676
 677                 if(!first)
 678                         te_lightning2(world, lastorigin, thisorigin);
 679                 lastorigin = thisorigin;
 680                 if(first)
 681                         firstorigin = thisorigin;
 682                 first = FALSE;
 683         }
 684         if(kh_teams > 2)
 685         {
 686                 te_lightning2(world, lastorigin, firstorigin);
 687         }
 688         midpoint = midpoint * (1 / kh_teams);
 689         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 690
 691         play2all(kh_sound_capture);
 692         kh_FinishRound();
 693 }
 694
 695 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 696 {
 697         entity player, key, attacker;
 698         float players;
 699         float keys;
 700         float f;
 701
 702         attacker = world;
 703         if(lostkey.pusher)
 704                 if(lostkey.pusher.team != teem)
 705                         if(lostkey.pusher.classname == "player")
 706                                 attacker = lostkey.pusher;
 707
 708         players = keys = 0;
 709
 710         if(attacker)
 711         {
 712                 if(lostkey.kh_previous_owner)
 713                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 714                         // don't actually GIVE him the -nn points, just log
 715                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 716                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 717                 centerprint(attacker, "Your push is the best!\n\n\n");
 718                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 719         }
 720         else
 721         {
 722                 float of, fragsleft, i, j, thisteam;
 723                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 724
 725                 FOR_EACH_PLAYER(player)
 726                         if(player.team != teem)
 727                                 ++players;
 728
 729                 FOR_EACH_KH_KEY(key)
 730                         if(key.owner && key.team != teem)
 731                                 ++keys;
 732
 733                 if(lostkey.kh_previous_owner)
 734                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 735                         // don't actually GIVE him the -nn points, just log
 736
 737                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 738                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 739
 740                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 741
 742                 FOR_EACH_KH_KEY(key)
 743                         if(key.owner && key.team != teem)
 744                         {
 745                                 f = DistributeEvenly_Get(of);
 746                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 747                         }
 748
 749                 fragsleft = DistributeEvenly_Get(players);
 750
 751                 // Now distribute these among all other teams...
 752                 j = kh_teams - 1;
 753                 for(i = 0; i < kh_teams; ++i)
 754                 {
 755                         thisteam = kh_Team_ByID(i);
 756                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 757                                 continue;
 758
 759                         players = 0;
 760                         FOR_EACH_PLAYER(player)
 761                                 if(player.team == thisteam)
 762                                         ++players;
 763
 764                         DistributeEvenly_Init(fragsleft, j);
 765                         fragsleft = DistributeEvenly_Get(j - 1);
 766                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 767
 768                         FOR_EACH_PLAYER(player)
 769                                 if(player.team == thisteam)
 770                                 {
 771                                         f = DistributeEvenly_Get(1);
 772                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 773                                 }
 774
 775                         --j;
 776                 }
 777
 778                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 779         }
 780         play2all(kh_sound_destroy);
 781         te_tarexplosion(lostkey.origin);
 782
 783         kh_FinishRound();
 784 }
 785
 786 void kh_FinishRound()  // runs when a team captures the keys
 787 {
 788         // prepare next round
 789         kh_interferemsg_time = 0;
 790         entity key;
 791
 792         kh_no_radar_circles = TRUE;
 793         FOR_EACH_KH_KEY(key)
 794                 kh_Key_Remove(key);
 795         kh_no_radar_circles = FALSE;
 796
 797         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 798 }
 799
 800 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 801 {
 802         float i, players, teem;
 803         entity player;
 804         string result;
 805         result = "";
 806
 807         // find a random player per team
 808         for(i = 0; i < kh_teams; ++i)
 809         {
 810                 teem = kh_Team_ByID(i);
 811                 players = 0;
 812                 FOR_EACH_PLAYER(player)
 813                         if(player.deadflag == DEAD_NO)
 814                                 if(!player.BUTTON_CHAT)
 815                                         if(player.team == teem)
 816                                                 ++players;
 817                 if(players == 0)
 818                 {
 819                         if(result != "")
 820                                 result = strcat(result, ", ");
 821                         result = strcat(result, ColoredTeamName(teem));
 822                 }
 823         }
 824         return result;
 825 }
 826
 827 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 828 {
 829         string teams_missing;
 830         teams_missing = kh_CheckEnoughPlayers();
 831         if(teams_missing == "")
 832                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 833         else
 834                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 835 }
 836
 837 void kh_StartRound()  // runs at the start of each round
 838 {
 839         string teams_missing;
 840         float i, players, teem;
 841         entity player;
 842
 843         teams_missing = kh_CheckEnoughPlayers();
 844         if(teams_missing != "")
 845         {
 846                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 847                 return;
 848         }
 849
 850         FOR_EACH_PLAYER(player)
 851                 if(clienttype(player) == CLIENTTYPE_REAL)
 852                         centerprint_expire(player, CENTERPRIO_SPAM);
 853
 854         for(i = 0; i < kh_teams; ++i)
 855         {
 856                 teem = kh_Team_ByID(i);
 857                 players = 0;
 858                 entity my_player;
 859                 FOR_EACH_PLAYER(player)
 860                         if(player.deadflag == DEAD_NO)
 861                                 if(!player.BUTTON_CHAT)
 862                                         if(player.team == teem)
 863                                         {
 864                                                 ++players;
 865                                                 if(random() * players <= 1)
 866                                                         my_player = player;
 867                                         }
 868                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 869                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 870                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 871         }
 872
 873         kh_tracking_enabled = FALSE;
 874         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 875 }
 876
 877 void kh_setstatus()  // runs all the time
 878 {
 879         if(kh_teams)
 880         {
 881                 float kh_KEY;
 882                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 883                 if(self.kh_next)
 884                         self.items = self.items | kh_KEY;
 885                 else
 886                         self.items = self.items - (self.items & kh_KEY);
 887         }
 888 }
 889
 890 void kh_EnableTrackingDevice()  // runs after each round
 891 {
 892         entity player;
 893
 894         FOR_EACH_PLAYER(player)
 895                 if(clienttype(player) == CLIENTTYPE_REAL)
 896                         centerprint_expire(player, CENTERPRIO_SPAM);
 897
 898         kh_tracking_enabled = TRUE;
 899 }
 900
 901 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
 902 {
 903         if(!kh_tracking_enabled)
 904                 return FALSE;
 905         if(!self.owner)
 906                 return TRUE;
 907         if(!self.owner.owner)
 908                 return TRUE;
 909         return FALSE;  // draw only when key is not owned
 910 }
 911
 912 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
 913 {
 914         if(e.classname != "player" || self.team != e.team)
 915                 if(!kh_tracking_enabled)
 916                         return FALSE;
 917
 918         return TRUE;
 919 }
 920
 921 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 922 {
 923         if(attacker == targ)
 924                 return f;
 925
 926         if(targ.kh_next)
 927         {
 928                 if(attacker.team == targ.team)
 929                 {
 930                         entity k;
 931                         float nk;
 932                         nk = 0;
 933                         for(k = targ.kh_next; k != world; k = k.kh_next)
 934                                 ++nk;
 935                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 936                 }
 937                 else
 938                 {
 939                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 940                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 941                         // the frag gets added later
 942                 }
 943         }
 944
 945         return f;
 946 }
 947
 948 void kh_init()  // sets up th KH environment
 949 {
 950         precache_sound(kh_sound_capture);
 951         precache_sound(kh_sound_destroy);
 952         precache_sound(kh_sound_drop);
 953         precache_sound(kh_sound_collect);
 954         precache_sound(kh_sound_alarm);  // the new siren
 955
 956         precache_model("models/sprites/key-dropped.sp2");
 957         precache_model("models/sprites/keycarrier-finish.sp2");
 958         precache_model("models/sprites/keycarrier-friend.sp2");
 959         precache_model("models/sprites/keycarrier-red.sp2");
 960         precache_model("models/sprites/keycarrier-blue.sp2");
 961         precache_model("models/sprites/keycarrier-yellow.sp2");
 962         precache_model("models/sprites/keycarrier-pink.sp2");
 963 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 964         precache_model("models/keyhunt/key-carried.md3");
 965 #endif
 966         precache_model("models/keyhunt/key.md3");
 967
 968         // setup variables
 969         kh_teams = cvar("g_keyhunt_teams_override");
 970         if(kh_teams < 2)
 971                 kh_teams = cvar("g_keyhunt_teams");
 972         kh_teams = bound(2, kh_teams, 4);
 973
 974         // make a KH entity for controlling the game
 975         kh_controller = spawn();
 976         kh_controller.think = kh_Controller_Think;
 977         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 978
 979         setmodel(kh_controller, "models/keyhunt/key.md3");
 980         kh_key_dropped = kh_controller.modelindex;
 981         /*
 982         dprint(vtos(kh_controller.mins));
 983         dprint(vtos(kh_controller.maxs));
 984         dprint("\n");
 985         */
 986 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 987         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 988         kh_key_carried = kh_controller.modelindex;
 989 #else
 990         kh_key_carried = kh_key_dropped;
 991 #endif
 992         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 993         kh_sprite_dropped = kh_controller.modelindex;
 994         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 995         kh_sprite_finish = kh_controller.modelindex;
 996         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 997         kh_sprite_friend = kh_controller.modelindex;
 998         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 999         kh_sprite_red = kh_controller.modelindex;
1000         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
1001         kh_sprite_blue = kh_controller.modelindex;
1002         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
1003         kh_sprite_pink = kh_controller.modelindex;
1004         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
1005         kh_sprite_yellow = kh_controller.modelindex;
1006         setmodel(kh_controller, "");
1007
1008         addstat(STAT_KH_KEYS, AS_INT, kh_state);
1009
1010         ScoreRules_kh(kh_teams);
1011 }
1012
1013 void kh_finalize()
1014 {
1015         // to be called before intermission
1016         kh_FinishRound();
1017         remove(kh_controller);
1018         kh_controller = world;
1019 }
1020
1021 /**
1022  * kh_show_temp originally by victim.
1023  * changed it to use the kh_state stat var
1024  * Updates the general key stat bits for each player
1025  */
1026 void kh_show_temp()
1027 {
1028         entity player;
1029         float i, j;
1030
1031         j = 0;  // reset/blank j
1032         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
1033                 j += test[i];
1034
1035         test[0] = j;
1036
1037         j *= 256;
1038         FOR_EACH_PLAYER(player)
1039                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
1040 }