data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/ctf/respawn.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_pink;
  37         if(t == COLOR_TEAM4) return kh_sprite_yellow;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(self.cnt > 0)
  59         {
  60                 if(kh_Controller_Waitmsg != "")
  61                 {
  62                         string s;
  63                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  64                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  65                         else
  66                                 s = kh_Controller_Waitmsg;
  67
  68                         dprint(s, "\n");
  69
  70                         FOR_EACH_PLAYER(e)
  71                                 if(clienttype(e) == CLIENTTYPE_REAL)
  72                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  73                 }
  74                 self.cnt -= 1;
  75         }
  76         else if(self.cnt == 0)
  77         {
  78                 FOR_EACH_PLAYER(e)
  79                         if(clienttype(e) == CLIENTTYPE_REAL)
  80                                 centerprint_expire(e, CENTERPRIO_SPAM);
  81                 self.cnt -= 1;
  82                 kh_Controller_Thinkfunc();
  83         }
  84         self.nextthink = time + 1;
  85 }
  86
  87 void kh_Log()
  88 {
  89         string s;
  90         if(!cvar("sv_eventlog"))
  91                 return;
  92         // TODO ...
  93         GameLogEcho(s, FALSE);
  94 }
  95
  96 // frags f: take from cvar * f
  97 // frags 0: no frags
  98 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
  99 {
 100         float basefrags;
 101         basefrags = cvar(strcat("g_balance_keyhunt_score_", what));
 102
 103         if(frags_player)
 104                 player.frags = player.frags + floor(0.5 + basefrags * frags_player);
 105         if(frags_owner)
 106                 key.owner.frags = key.owner.frags + floor(0.5 + basefrags * frags_owner);
 107 }
 108
 109 void kh_Key_Attach(entity key, float wpchange)
 110 {
 111         setattachment(key, key.owner, "");
 112         setorigin(key, '0 0 0'); // fixed later in think
 113         key.angles = key.angles - '0 1 0' * key.owner.angles_y;
 114         key.flags = 0;
 115         key.solid = SOLID_NOT;
 116         key.movetype = MOVETYPE_NONE;
 117         key.team = key.owner.team;
 118         key.nextthink = time;
 119 }
 120
 121 vector kh_AttachedOrigin(entity e)
 122 {
 123         if(e.tag_entity)
 124         {
 125                 makevectors(e.tag_entity.angles);
 126                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 127         }
 128         else
 129                 return e.origin;
 130 }
 131
 132 void kh_Key_Detach(entity key, float wpchange)
 133 {
 134         setorigin(key, kh_AttachedOrigin(key));
 135         setattachment(key, world, "");
 136         key.angles_y = key.owner.angles_y;
 137         key.aiment = world;
 138         key.flags = FL_ITEM;
 139         key.solid = SOLID_TRIGGER;
 140         key.movetype = MOVETYPE_TOSS;
 141         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 142         // let key.team stay
 143 }
 144
 145 void kh_Key_AssignTo(entity key, entity player, float wpchange)
 146 {
 147         if(key.owner == player)
 148                 return;
 149
 150         if(key.owner)
 151         {
 152                 kh_Key_Detach(key, wpchange);
 153
 154                 // remove from linked list
 155                 if(key.kh_next)
 156                         key.kh_next.kh_prev = key.kh_prev;
 157                 key.kh_prev.kh_next = key.kh_next;
 158                 key.kh_next = world;
 159                 key.kh_prev = world;
 160
 161                 if(key.owner.kh_next == world)
 162                 {
 163                         // No longer a key carrier
 164                         if(wpchange)
 165                                 WaypointSprite_Kill(key.owner.waypointsprite_attachedforcarrier);
 166                         else
 167                                 WaypointSprite_DetachCarrier(key.owner);
 168                 }
 169         }
 170
 171         key.owner = player;
 172
 173         if(player)
 174         {
 175                 // insert into linked list
 176                 key.kh_next = player.kh_next;
 177                 key.kh_prev = player;
 178                 player.kh_next = key;
 179                 if(key.kh_next)
 180                         key.kh_next.kh_prev = key;
 181
 182                 kh_Key_Attach(key, wpchange);
 183
 184                 if(key.kh_next == world)
 185                 {
 186                         // player is now a key carrier
 187                         WaypointSprite_AttachCarrier("", player);
 188                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 189                         player.waypointsprite_attachedforcarrier.team = player.team;
 190                 }
 191         }
 192
 193         key.pusher = world;
 194 }
 195
 196 void kh_Key_Spawn(entity initial_owner, float angle)
 197 {
 198         entity key;
 199         key = spawn();
 200         key.classname = STR_ITEM_KH_KEY;
 201         key.touch = kh_Key_Touch;
 202         key.think = kh_Key_Think;
 203         key.nextthink = time;
 204         key.items = IT_KEY1 | IT_KEY2;
 205         key.cnt = angle;
 206         key.angles = '0 360 0' * random();
 207         setmodel(key, "models/keyhunt/key3.md3");
 208         setsize(key, '0 0 -24', '0 0 25');
 209
 210         switch(initial_owner.team)
 211         {
 212                 case COLOR_TEAM1:
 213                         key.netname = "^1red key";
 214                         key.colormod = '1.73 0.10 0.10';
 215                         break;
 216                 case COLOR_TEAM2:
 217                         key.netname = "^4blue key";
 218                         key.colormod = '0.10 0.10 1.73';
 219                         break;
 220                 case COLOR_TEAM3:
 221                         key.netname = "^6pink key";
 222                         key.colormod = '1.22 0.10 1.22';
 223                         break;
 224                 case COLOR_TEAM4:
 225                         key.netname = "^3yellow key";
 226                         key.colormod = '1.22 1.22 0.10';
 227                         break;
 228                 default:
 229                         key.netname = "NETGIER key";
 230                         key.colormod = '1.00 1.00 1.00';
 231                         break;
 232         }
 233
 234         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 235
 236         WaypointSprite_AttachCarrier("", key);
 237         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 238
 239         kh_Key_AssignTo(key, initial_owner, TRUE);
 240 }
 241
 242 void kh_Key_Remove(entity key)
 243 {
 244         entity o;
 245         o = key.owner;
 246         kh_Key_AssignTo(key, world, FALSE);
 247         if(o) // it was attached
 248                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 249         else // it was dropped
 250                 WaypointSprite_DetachCarrier(key);
 251
 252         remove(key);
 253 }
 254
 255 void kh_Key_Collect(entity key, entity player)
 256 {
 257         kh_Scores_Event(player, key, "collect", 1, 0);
 258         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 259         kh_Key_AssignTo(key, player, TRUE);
 260
 261         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 262
 263         FOR_EACH_KH_KEY(key)
 264                 if(!key.owner || key.team != player.team)
 265                         goto notallowned;
 266         kh_interferemsg_time = time + 0.2;
 267         kh_interferemsg_team = player.team;
 268 :notallowned
 269 }
 270
 271 void kh_Key_DropAll(entity player)
 272 {
 273         entity key;
 274         entity mypusher;
 275         if(player.kh_next)
 276         {
 277                 mypusher = world;
 278                 if(player.pusher)
 279                         if(time < player.pushltime)
 280                                 mypusher = player.pusher;
 281                 while((key = player.kh_next))
 282                 {
 283                         kh_Scores_Event(player, key, "losekey", 0, 0);
 284                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 285                         kh_Key_AssignTo(key, world, TRUE);
 286                         key.pusher = player.pusher;
 287                         key.pushltime = player.pushltime;
 288                 }
 289                 sound(world, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 290         }
 291 }
 292
 293 void kh_Key_Touch()
 294 {
 295         if(self.owner) // already carried
 296                 return;
 297         if(other.classname != "player")
 298                 return;
 299         if(other.deadflag != DEAD_NO)
 300                 return;
 301         if(other == self.enemy)
 302                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 303                         return; // you just dropped it!
 304         kh_Key_Collect(self, other);
 305 }
 306
 307 void kh_Key_Think()
 308 {
 309         entity head;
 310
 311         self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 312
 313         if(self.owner)
 314         {
 315                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 316                 setorigin(self, v_forward * 16);
 317
 318                 if(self.owner.buttonuse)
 319                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 320                 {
 321                         self.owner.kh_droptime = time;
 322                         self.kh_droptime = time; // prevent collecting this one for some time
 323                         self.enemy = self.owner;
 324                         self.pusher = world;
 325                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 326                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 327                         kh_Key_AssignTo(self, world, TRUE);
 328                         sound(world, CHAN_AUTO, kh_sound_drop, 1, ATTN_NONE);
 329                 }
 330         }
 331
 332         // if in nodrop or time over, end the round
 333         if(!self.owner)
 334                 if(time > self.pain_finished)
 335                         kh_LoserTeam(self.team, self);
 336
 337         if(self.owner)
 338         {
 339                 entity key;
 340                 vector p;
 341                 float teem;
 342                 teem = self.team;
 343                 p = self.owner.origin;
 344                 FOR_EACH_KH_KEY(key)
 345                 {
 346                         if(key.owner == self.owner)
 347                                 continue;
 348                         if(key.owner)
 349                         if(key.team == teem)
 350                         if(vlen(key.owner.origin - p) < cvar("g_balance_keyhunt_maxdist"))
 351                                 continue;
 352                         goto not_winning;
 353                 }
 354                 kh_WinnerTeam(teem);
 355 :not_winning
 356         }
 357
 358         if(kh_interferemsg_time && time > kh_interferemsg_time)
 359         {
 360                 kh_interferemsg_time = 0;
 361                 FOR_EACH_PLAYER(head)
 362                 {
 363                         if(head.team == kh_interferemsg_team)
 364                                 if(head.kh_next)
 365                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 366                                 else
 367                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 368                         else
 369                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 370                 }
 371         }
 372
 373         self.nextthink = time + 0.05;
 374 }
 375
 376 void kh_WinnerTeam(float teem)
 377 {
 378         // all key carriers get some points
 379         vector firstorigin, lastorigin;
 380         float first;
 381         entity key;
 382         float score;
 383         score = 1.0 / kh_teams;
 384         first = TRUE;
 385         FOR_EACH_KH_KEY(key)
 386         {
 387                 kh_Scores_Event(key.owner, key, "capture", score, 0);
 388                 if(key.owner.kh_next == key)
 389                 {
 390                         if(!first)
 391                                 bprint("^7, ");
 392                         bprint(key.owner.netname);
 393                         first = FALSE;
 394                 }
 395         }
 396
 397         first = TRUE;
 398         FOR_EACH_KH_KEY(key)
 399         {
 400                 vector thisorigin;
 401
 402                 thisorigin = kh_AttachedOrigin(key);
 403
 404                 if(!first)
 405                         te_lightning2(world, lastorigin, thisorigin);
 406                 lastorigin = thisorigin;
 407                 if(first)
 408                         firstorigin = thisorigin;
 409                 first = FALSE;
 410         }
 411         if(kh_teams > 2)
 412         {
 413                 te_lightning2(world, lastorigin, firstorigin);
 414         }
 415
 416         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 417         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 418         kh_FinishRound();
 419 }
 420
 421 void kh_LoserTeam(float teem, entity lostkey)
 422 {
 423         entity player, key, attacker;
 424         float players;
 425         float keys;
 426         float score;
 427
 428         attacker = world;
 429         if(lostkey.pusher)
 430                 if(player.pusher.team != player.team)
 431                         if(player.pusher.classname == "player")
 432                                 attacker = lostkey.pusher;
 433
 434         players = keys = 0;
 435
 436         if(attacker)
 437         {
 438                 kh_Scores_Event(attacker, world, "push", 1, 0);
 439                 centerprint(attacker, "Your push is the best!\n\n\n");
 440                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 441         }
 442         else
 443         {
 444                 FOR_EACH_PLAYER(player)
 445                         if(player.team != teem)
 446                                 ++players;
 447
 448                 FOR_EACH_KH_KEY(key)
 449                         if(key.owner && key.team != teem)
 450                                 ++keys;
 451
 452                 score = 1.0 / (keys * cvar("g_balance_keyhunt_score_destroyed_ownfactor") + players);
 453
 454                 FOR_EACH_PLAYER(player)
 455                         if(player.team != teem)
 456                                 kh_Scores_Event(player, world, "destroyed", score, 0);
 457
 458                 FOR_EACH_KH_KEY(key)
 459                         if(key.owner && key.team != teem)
 460                                 kh_Scores_Event(key.owner, world, "destroyed", score * cvar("g_balance_keyhunt_score_destroyed_ownfactor"), 0);
 461
 462                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 463         }
 464         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 465
 466         kh_FinishRound();
 467 }
 468
 469 void kh_FinishRound()
 470 {
 471         // prepare next round
 472         kh_interferemsg_time = 0;
 473         entity key;
 474         FOR_EACH_KH_KEY(key)
 475                 kh_Key_Remove(key);
 476
 477         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 478 }
 479
 480 float kh_EnoughPlayers()
 481 {
 482         float i, players, teem;
 483         entity player;
 484
 485         // find a random player per team
 486         for(i = 0; i < kh_teams; ++i)
 487         {
 488                 teem = kh_Team_ByID(i);
 489                 players = 0;
 490                 FOR_EACH_PLAYER(player)
 491                         if(player.deadflag == DEAD_NO)
 492                                 if(player.team == teem)
 493                                         ++players;
 494                 if(players == 0)
 495                         return FALSE;
 496         }
 497         return TRUE;
 498 }
 499
 500 void kh_WaitForPlayers()
 501 {
 502         if(kh_EnoughPlayers())
 503                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 504         else
 505                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 506 }
 507
 508 void kh_StartRound()
 509 {
 510         float i, players, teem;
 511         entity player;
 512
 513         if(!kh_EnoughPlayers())
 514         {
 515                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 516                 return;
 517         }
 518
 519         for(i = 0; i < kh_teams; ++i)
 520         {
 521                 teem = kh_Team_ByID(i);
 522                 players = 0;
 523                 entity my_player;
 524                 FOR_EACH_PLAYER(player)
 525                         if(player.deadflag == DEAD_NO)
 526                                 if(player.team == teem)
 527                                 {
 528                                         ++players;
 529                                         if(random() * players <= 1)
 530                                                 my_player = player;
 531                                 }
 532                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 533         }
 534
 535         kh_tracking_enabled = FALSE;
 536         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 537 }
 538
 539 void kh_setstatus()
 540 {
 541         if(kh_teams)
 542         {
 543                 float kh_KEY;
 544                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 545                 if(self.kh_next)
 546                         self.items = self.items | kh_KEY;
 547                 else
 548                         self.items = self.items - (self.items & kh_KEY);
 549         }
 550 }
 551
 552 void kh_EnableTrackingDevice()
 553 {
 554         kh_tracking_enabled = TRUE;
 555 }
 556
 557 float kh_Key_waypointsprite_for_player(entity e)
 558 {
 559         if(!kh_tracking_enabled)
 560                 return 0;
 561         if(!self.owner)
 562                 return kh_sprite_dropped;
 563         if(!self.owner.owner)
 564                 return kh_sprite_dropped;
 565         return 0; // draw only when key is not owned
 566 }
 567
 568 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 569 {
 570         entity key;
 571
 572         if(e.classname != "player" || self.team != e.team)
 573                 if(!kh_tracking_enabled)
 574                         return 0;
 575
 576         // e is no key carrier: simple case...
 577         if(!e.kh_next)
 578                 return kh_GetCarrierSprite(self.team, e.team);
 579
 580         // e is a key carrier: if any key is dropped or owned by another team, show
 581         // the carrier sprite; otherwise show run here
 582         FOR_EACH_KH_KEY(key)
 583                 if(!key.owner || key.team != e.team)
 584                         return kh_GetCarrierSprite(self.team, e.team);
 585
 586         return kh_sprite_finish;
 587 }
 588
 589 float kh_HandleFrags(entity attacker, entity targ, float f)
 590 {
 591         float newfrags;
 592
 593         if(f <= 0)
 594                 return f;
 595         if(attacker == targ)
 596                 return f;
 597
 598         if(targ.kh_next)
 599                 f = f - 1 + cvar("g_balance_keyhunt_score_carrierfrag");
 600
 601         if(newfrags)
 602                 f = f - 1 + newfrags;
 603         return f;
 604 }
 605
 606 void kh_init()
 607 {
 608         precache_sound(kh_sound_capture);
 609         precache_sound(kh_sound_destroy);
 610         precache_sound(kh_sound_drop);
 611         precache_sound(kh_sound_collect);
 612
 613         precache_model("models/sprites/key-dropped.sp2");
 614         precache_model("models/sprites/keycarrier-finish.sp2");
 615         precache_model("models/sprites/keycarrier-friend.sp2");
 616         precache_model("models/sprites/keycarrier-red.sp2");
 617         precache_model("models/sprites/keycarrier-blue.sp2");
 618         precache_model("models/sprites/keycarrier-pink.sp2");
 619         precache_model("models/sprites/keycarrier-yellow.sp2");
 620         precache_model("models/keyhunt/key3.md3");
 621
 622         // setup variables
 623         kh_teams = cvar("g_keyhunt_teams_override");
 624         if(kh_teams < 2)
 625                 kh_teams = cvar("g_keyhunt_teams");
 626         if(kh_teams < 2)
 627                 kh_teams = 2;
 628
 629         // make a KH entity for controlling the game
 630         kh_controller = spawn();
 631         kh_controller.think = kh_Controller_Think;
 632         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 633
 634         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 635         kh_sprite_dropped = kh_controller.modelindex;
 636         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 637         kh_sprite_finish = kh_controller.modelindex;
 638         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 639         kh_sprite_friend = kh_controller.modelindex;
 640         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 641         kh_sprite_red = kh_controller.modelindex;
 642         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 643         kh_sprite_blue = kh_controller.modelindex;
 644         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 645         kh_sprite_pink = kh_controller.modelindex;
 646         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 647         kh_sprite_yellow = kh_controller.modelindex;
 648         setmodel(kh_controller, "");
 649 }
 650
 651 void kh_finalize()
 652 {
 653         // to be called before intermission
 654         kh_FinishRound();
 655         remove(kh_controller);
 656         kh_controller = world;
 657 }