data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/misc/mouseclick.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  37         if(t == COLOR_TEAM4) return kh_sprite_pink;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(intermission_running)
  59                 return;
  60         if(self.cnt > 0)
  61         {
  62                 if(kh_Controller_Waitmsg != "")
  63                 {
  64                         string s;
  65                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  66                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  67                         else
  68                                 s = kh_Controller_Waitmsg;
  69
  70                         dprint(s, "\n");
  71
  72                         FOR_EACH_PLAYER(e)
  73                                 if(clienttype(e) == CLIENTTYPE_REAL)
  74                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  75                 }
  76                 self.cnt -= 1;
  77         }
  78         else if(self.cnt == 0)
  79         {
  80                 self.cnt -= 1;
  81                 kh_Controller_Thinkfunc();
  82         }
  83         self.nextthink = time + 1;
  84 }
  85
  86 void kh_Log()
  87 {
  88         string s;
  89         if(!cvar("sv_eventlog"))
  90                 return;
  91         // TODO ...
  92         GameLogEcho(s, FALSE);
  93 }
  94
  95 // frags f: take from cvar * f
  96 // frags 0: no frags
  97 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
  98 {
  99         float basefrags;
 100         basefrags = cvar(strcat("g_balance_keyhunt_score_", what));
 101
 102         if(frags_player)
 103                 player.frags = player.frags + floor(0.5 + basefrags * frags_player);
 104         if(frags_owner)
 105                 key.owner.frags = key.owner.frags + floor(0.5 + basefrags * frags_owner);
 106 }
 107
 108 void kh_Key_Attach(entity key)
 109 {
 110         setattachment(key, key.owner, "");
 111         setorigin(key, '0 0 -15'); // x/y fixed later in think, z has to be -15 to make the key fit even in the crouchbox
 112         key.angles = key.angles - '0 1 0' * key.owner.angles_y;
 113         key.flags = 0;
 114         key.solid = SOLID_NOT;
 115         key.movetype = MOVETYPE_NONE;
 116         key.team = key.owner.team;
 117         key.nextthink = time;
 118         key.damageforcescale = 0;
 119 }
 120
 121 vector kh_AttachedOrigin(entity e)
 122 {
 123         if(e.tag_entity)
 124         {
 125                 makevectors(e.tag_entity.angles);
 126                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 127         }
 128         else
 129                 return e.origin;
 130 }
 131
 132 void kh_Key_Detach(entity key)
 133 {
 134         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 135         setattachment(key, world, "");
 136         key.angles_y = key.owner.angles_y;
 137         key.aiment = world;
 138         key.flags = FL_ITEM;
 139         key.solid = SOLID_TRIGGER;
 140         key.movetype = MOVETYPE_TOSS;
 141         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 142         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 143         // let key.team stay
 144 }
 145
 146 void kh_Key_AssignTo(entity key, entity player)
 147 {
 148         if(key.owner == player)
 149                 return;
 150
 151         if(key.owner)
 152         {
 153                 kh_Key_Detach(key);
 154
 155                 // remove from linked list
 156                 if(key.kh_next)
 157                         key.kh_next.kh_prev = key.kh_prev;
 158                 key.kh_prev.kh_next = key.kh_next;
 159                 key.kh_next = world;
 160                 key.kh_prev = world;
 161
 162                 if(key.owner.kh_next == world)
 163                 {
 164                         // No longer a key carrier
 165                         WaypointSprite_DetachCarrier(key.owner);
 166                 }
 167         }
 168
 169         key.owner = player;
 170
 171         if(player)
 172         {
 173                 // insert into linked list
 174                 key.kh_next = player.kh_next;
 175                 key.kh_prev = player;
 176                 player.kh_next = key;
 177                 if(key.kh_next)
 178                         key.kh_next.kh_prev = key;
 179
 180                 kh_Key_Attach(key);
 181
 182                 if(key.kh_next == world)
 183                 {
 184                         // player is now a key carrier
 185                         WaypointSprite_AttachCarrier("", player);
 186                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 187                         player.waypointsprite_attachedforcarrier.team = player.team;
 188                 }
 189         }
 190
 191         key.pusher = world;
 192 }
 193
 194 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 195 {
 196         if(self.owner)
 197                 return;
 198         if(vlen(force) <= 0)
 199                 return;
 200         if(time > self.pushltime)
 201                 if(attacker.classname == "player")
 202                         self.team = attacker.team;
 203 }
 204
 205 void kh_Key_Spawn(entity initial_owner, float angle)
 206 {
 207         entity key;
 208         key = spawn();
 209         key.classname = STR_ITEM_KH_KEY;
 210         key.touch = kh_Key_Touch;
 211         key.think = kh_Key_Think;
 212         key.nextthink = time;
 213         key.items = IT_KEY1 | IT_KEY2;
 214         key.cnt = angle;
 215         key.angles = '0 360 0' * random();
 216         key.event_damage = kh_Key_Damage;
 217         setmodel(key, "models/keyhunt/key3.md3");
 218         setsize(key, '-8 -8 -8', '8 8 40');
 219
 220         switch(initial_owner.team)
 221         {
 222                 case COLOR_TEAM1:
 223                         key.netname = "^1red key";
 224                         key.colormod = '1.73 0.10 0.10';
 225                         break;
 226                 case COLOR_TEAM2:
 227                         key.netname = "^4blue key";
 228                         key.colormod = '0.10 0.10 1.73';
 229                         break;
 230                 case COLOR_TEAM3:
 231                         key.netname = "^3yellow key";
 232                         key.colormod = '1.22 1.22 0.10';
 233                         break;
 234                 case COLOR_TEAM4:
 235                         key.netname = "^6pink key";
 236                         key.colormod = '1.22 0.10 1.22';
 237                         break;
 238                 default:
 239                         key.netname = "NETGIER key";
 240                         key.colormod = '1.00 1.00 1.00';
 241                         break;
 242         }
 243
 244         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 245
 246         WaypointSprite_AttachCarrier("", key);
 247         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 248
 249         kh_Key_AssignTo(key, initial_owner);
 250 }
 251
 252 void kh_Key_Remove(entity key)
 253 {
 254         entity o;
 255         o = key.owner;
 256         kh_Key_AssignTo(key, world);
 257         if(o) // it was attached
 258                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 259         else // it was dropped
 260                 WaypointSprite_DetachCarrier(key);
 261
 262         remove(key);
 263 }
 264
 265 // -1 when no team completely owns all keys yet
 266 float kh_Key_AllOwnedByWhichTeam()
 267 {
 268         entity key;
 269         float teem;
 270
 271         teem = -1;
 272         FOR_EACH_KH_KEY(key)
 273         {
 274                 if(!key.owner)
 275                         return -1;
 276                 if(teem == -1)
 277                         teem = key.team;
 278                 else if(teem != key.team)
 279                         return -1;
 280         }
 281         return teem;
 282 }
 283
 284 void kh_Key_Collect(entity key, entity player)
 285 {
 286         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 287
 288         kh_Scores_Event(player, key, "collect", 1, 0);
 289         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 290         kh_Key_AssignTo(key, player);
 291
 292         if(kh_Key_AllOwnedByWhichTeam() != -1)
 293         {
 294                 kh_interferemsg_time = time + 0.2;
 295                 kh_interferemsg_team = player.team;
 296         }
 297 }
 298
 299 void kh_Key_DropAll(entity player)
 300 {
 301         entity key;
 302         entity mypusher;
 303         if(player.kh_next)
 304         {
 305                 mypusher = world;
 306                 if(player.pusher)
 307                         if(time < player.pushltime)
 308                                 mypusher = player.pusher;
 309                 while((key = player.kh_next))
 310                 {
 311                         kh_Scores_Event(player, key, "losekey", 0, 0);
 312                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 313                         kh_Key_AssignTo(key, world);
 314                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 315                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 316                         key.pusher = mypusher;
 317                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 318                 }
 319                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 320         }
 321 }
 322
 323 void kh_Key_Touch()
 324 {
 325         if(self.owner) // already carried
 326                 return;
 327         if(other.classname != "player")
 328                 return;
 329         if(other.deadflag != DEAD_NO)
 330                 return;
 331         if(other == self.enemy)
 332                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 333                         return; // you just dropped it!
 334         kh_Key_Collect(self, other);
 335 }
 336
 337 void kh_Key_Think()
 338 {
 339         entity head;
 340
 341         self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 342
 343         if(self.owner)
 344         {
 345                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 346                 setorigin(self, v_forward * 24 + '0 0 1' * self.origin_z);
 347
 348                 if(self.owner.buttonuse)
 349                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 350                 {
 351                         self.owner.kh_droptime = time;
 352                         self.kh_droptime = time; // prevent collecting this one for some time
 353                         self.enemy = self.owner;
 354                         self.pusher = world;
 355                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 356                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 357                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 358                         makevectors(self.owner.v_angle);
 359                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 360                         kh_Key_AssignTo(self, world);
 361                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 362                 }
 363         }
 364
 365         // if in nodrop or time over, end the round
 366         if(!self.owner)
 367                 if(time > self.pain_finished)
 368                         kh_LoserTeam(self.team, self);
 369
 370         if(self.owner)
 371         if(kh_Key_AllOwnedByWhichTeam() != -1)
 372         {
 373                 entity key;
 374                 vector p;
 375                 p = self.owner.origin;
 376                 FOR_EACH_KH_KEY(key)
 377                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 378                                 goto not_winning;
 379                 kh_WinnerTeam(self.team);
 380 :not_winning
 381         }
 382
 383         if(kh_interferemsg_time && time > kh_interferemsg_time)
 384         {
 385                 kh_interferemsg_time = 0;
 386                 FOR_EACH_PLAYER(head)
 387                 {
 388                         if(head.team == kh_interferemsg_team)
 389                                 if(head.kh_next)
 390                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 391                                 else
 392                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 393                         else
 394                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 395                 }
 396         }
 397
 398         self.nextthink = time + 0.05;
 399 }
 400
 401 void kh_WinnerTeam(float teem)
 402 {
 403         // all key carriers get some points
 404         vector firstorigin, lastorigin;
 405         float first;
 406         entity key;
 407         float score;
 408         score = (kh_teams - 1) / kh_teams;
 409         // twice the score for 3 team games, three times the score for 4 team games!
 410         // note: for a win by destroying the key, this should NOT be applied
 411         first = TRUE;
 412         FOR_EACH_KH_KEY(key)
 413         {
 414                 kh_Scores_Event(key.owner, key, "capture", score, 0);
 415                 if(key.owner.kh_next == key)
 416                 {
 417                         if(!first)
 418                                 bprint("^7, ");
 419                         bprint(key.owner.netname);
 420                         first = FALSE;
 421                 }
 422         }
 423
 424         first = TRUE;
 425         FOR_EACH_KH_KEY(key)
 426         {
 427                 vector thisorigin;
 428
 429                 thisorigin = kh_AttachedOrigin(key);
 430
 431                 if(!first)
 432                         te_lightning2(world, lastorigin, thisorigin);
 433                 lastorigin = thisorigin;
 434                 if(first)
 435                         firstorigin = thisorigin;
 436                 first = FALSE;
 437         }
 438         if(kh_teams > 2)
 439         {
 440                 te_lightning2(world, lastorigin, firstorigin);
 441         }
 442
 443         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 444         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 445         kh_FinishRound();
 446 }
 447
 448 void kh_LoserTeam(float teem, entity lostkey)
 449 {
 450         entity player, key, attacker;
 451         float players;
 452         float keys;
 453         float score;
 454
 455         attacker = world;
 456         if(lostkey.pusher)
 457                 if(lostkey.pusher.team != teem)
 458                         if(lostkey.pusher.classname == "player")
 459                                 attacker = lostkey.pusher;
 460
 461         players = keys = 0;
 462
 463         if(attacker)
 464         {
 465                 kh_Scores_Event(attacker, world, "push", 1, 0);
 466                 centerprint(attacker, "Your push is the best!\n\n\n");
 467                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 468         }
 469         else
 470         {
 471                 FOR_EACH_PLAYER(player)
 472                         if(player.team != teem)
 473                                 ++players;
 474
 475                 FOR_EACH_KH_KEY(key)
 476                         if(key.owner && key.team != teem)
 477                                 ++keys;
 478
 479                 score = 1.0 / max(1, keys * cvar("g_balance_keyhunt_score_destroyed_ownfactor") + players);
 480
 481                 FOR_EACH_PLAYER(player)
 482                         if(player.team != teem)
 483                                 kh_Scores_Event(player, world, "destroyed", score, 0);
 484
 485                 FOR_EACH_KH_KEY(key)
 486                         if(key.owner && key.team != teem)
 487                                 kh_Scores_Event(key.owner, world, "destroyed", score * cvar("g_balance_keyhunt_score_destroyed_ownfactor"), 0);
 488
 489                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 490         }
 491         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 492
 493         kh_FinishRound();
 494 }
 495
 496 void kh_FinishRound()
 497 {
 498         // prepare next round
 499         kh_interferemsg_time = 0;
 500         entity key;
 501         FOR_EACH_KH_KEY(key)
 502                 kh_Key_Remove(key);
 503
 504         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 505 }
 506
 507 float kh_EnoughPlayers()
 508 {
 509         float i, players, teem;
 510         entity player;
 511
 512         // find a random player per team
 513         for(i = 0; i < kh_teams; ++i)
 514         {
 515                 teem = kh_Team_ByID(i);
 516                 players = 0;
 517                 FOR_EACH_PLAYER(player)
 518                         if(player.deadflag == DEAD_NO)
 519                                 if(player.team == teem)
 520                                         ++players;
 521                 if(players == 0)
 522                         return FALSE;
 523         }
 524         return TRUE;
 525 }
 526
 527 void kh_WaitForPlayers()
 528 {
 529         if(kh_EnoughPlayers())
 530                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 531         else
 532                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 533 }
 534
 535 void kh_StartRound()
 536 {
 537         float i, players, teem;
 538         entity player;
 539
 540         if(!kh_EnoughPlayers())
 541         {
 542                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 543                 return;
 544         }
 545
 546         FOR_EACH_PLAYER(player)
 547                 if(clienttype(player) == CLIENTTYPE_REAL)
 548                         centerprint_expire(player, CENTERPRIO_SPAM);
 549
 550         for(i = 0; i < kh_teams; ++i)
 551         {
 552                 teem = kh_Team_ByID(i);
 553                 players = 0;
 554                 entity my_player;
 555                 FOR_EACH_PLAYER(player)
 556                         if(player.deadflag == DEAD_NO)
 557                                 if(player.team == teem)
 558                                 {
 559                                         ++players;
 560                                         if(random() * players <= 1)
 561                                                 my_player = player;
 562                                 }
 563                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 564         }
 565
 566         kh_tracking_enabled = FALSE;
 567         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 568 }
 569
 570 void kh_setstatus()
 571 {
 572         if(kh_teams)
 573         {
 574                 float kh_KEY;
 575                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 576                 if(self.kh_next)
 577                         self.items = self.items | kh_KEY;
 578                 else
 579                         self.items = self.items - (self.items & kh_KEY);
 580         }
 581 }
 582
 583 void kh_EnableTrackingDevice()
 584 {
 585         entity player;
 586
 587         FOR_EACH_PLAYER(player)
 588                 if(clienttype(player) == CLIENTTYPE_REAL)
 589                         centerprint_expire(player, CENTERPRIO_SPAM);
 590
 591         kh_tracking_enabled = TRUE;
 592 }
 593
 594 float kh_Key_waypointsprite_for_player(entity e)
 595 {
 596         if(!kh_tracking_enabled)
 597                 return 0;
 598         if(!self.owner)
 599                 return kh_sprite_dropped;
 600         if(!self.owner.owner)
 601                 return kh_sprite_dropped;
 602         return 0; // draw only when key is not owned
 603 }
 604
 605 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 606 {
 607         if(e.classname != "player" || self.team != e.team)
 608                 if(!kh_tracking_enabled)
 609                         return 0;
 610
 611         // e is spectator? That's no team mate...
 612         if(e.classname != "player")
 613                 return kh_GetCarrierSprite(self.team, -1);
 614
 615         // e is no key carrier: simple case...
 616         if(!e.kh_next)
 617                 return kh_GetCarrierSprite(self.team, e.team);
 618
 619         // e is a key carrier: if any key is dropped or owned by another team, show
 620         // the carrier sprite; otherwise show run here
 621         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 622                 return kh_sprite_finish;
 623
 624         return kh_GetCarrierSprite(self.team, e.team);
 625 }
 626
 627 float kh_HandleFrags(entity attacker, entity targ, float f)
 628 {
 629         float newfrags;
 630
 631         if(f <= 0)
 632                 return f;
 633         if(attacker == targ)
 634                 return f;
 635
 636         if(targ.kh_next)
 637                 f = f - 1 + cvar("g_balance_keyhunt_score_carrierfrag");
 638
 639         if(newfrags)
 640                 f = f - 1 + newfrags;
 641         return f;
 642 }
 643
 644 void kh_init()
 645 {
 646         precache_sound(kh_sound_capture);
 647         precache_sound(kh_sound_destroy);
 648         precache_sound(kh_sound_drop);
 649         precache_sound(kh_sound_collect);
 650
 651         precache_model("models/sprites/key-dropped.sp2");
 652         precache_model("models/sprites/keycarrier-finish.sp2");
 653         precache_model("models/sprites/keycarrier-friend.sp2");
 654         precache_model("models/sprites/keycarrier-red.sp2");
 655         precache_model("models/sprites/keycarrier-blue.sp2");
 656         precache_model("models/sprites/keycarrier-yellow.sp2");
 657         precache_model("models/sprites/keycarrier-pink.sp2");
 658         precache_model("models/keyhunt/key3.md3");
 659
 660         // setup variables
 661         kh_teams = cvar("g_keyhunt_teams_override");
 662         if(kh_teams < 2)
 663                 kh_teams = cvar("g_keyhunt_teams");
 664         if(kh_teams < 2)
 665                 kh_teams = 2;
 666
 667         // make a KH entity for controlling the game
 668         kh_controller = spawn();
 669         kh_controller.think = kh_Controller_Think;
 670         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 671
 672         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 673         kh_sprite_dropped = kh_controller.modelindex;
 674         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 675         kh_sprite_finish = kh_controller.modelindex;
 676         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 677         kh_sprite_friend = kh_controller.modelindex;
 678         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 679         kh_sprite_red = kh_controller.modelindex;
 680         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 681         kh_sprite_blue = kh_controller.modelindex;
 682         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 683         kh_sprite_pink = kh_controller.modelindex;
 684         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 685         kh_sprite_yellow = kh_controller.modelindex;
 686         setmodel(kh_controller, "");
 687 }
 688
 689 void kh_finalize()
 690 {
 691         // to be called before intermission
 692         kh_FinishRound();
 693         remove(kh_controller);
 694         kh_controller = world;
 695 }