data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 // #define KH_PLAYER_USE_ATTACHMENT
   5 // #define KH_PLAYER_USE_CARRIEDMODEL
   6 // #define KH_KEY_ATTACHMENT_DEBUG
   7
   8 #ifdef KH_PLAYER_USE_ATTACHMENT
   9 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  10 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  11 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  12 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  13 string KH_PLAYER_ATTACHMENT_BONE = "";
  14 #else
  15 float KH_KEY_ZSHIFT = 22;
  16 float KH_KEY_XYDIST = 24;
  17 float KH_KEY_XYSPEED = 45;
  18 #endif
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22
  23 typedef void(void) kh_Think_t;
  24 var kh_Think_t kh_Controller_Thinkfunc;
  25 string kh_Controller_Waitmsg;
  26
  27 float kh_Team_ByID(float t)
  28 {
  29         if(t == 0) return COLOR_TEAM1;
  30         if(t == 1) return COLOR_TEAM2;
  31         if(t == 2) return COLOR_TEAM3;
  32         if(t == 3) return COLOR_TEAM4;
  33         return 0;
  34 }
  35
  36 entity kh_controller;
  37 float kh_tracking_enabled;
  38 float kh_teams;
  39 float kh_interferemsg_time, kh_interferemsg_team;
  40 .entity kh_next, kh_prev; // linked list
  41 .float kh_droptime;
  42
  43 string kh_sound_capture = "sound/ctf/capture.wav";
  44 string kh_sound_destroy = "sound/ctf/return.wav";
  45 string kh_sound_drop = "sound/misc/mouseclick.wav";
  46 string kh_sound_collect = "sound/ctf/take.wav";
  47
  48 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  49 float kh_key_dropped, kh_key_carried;
  50
  51 float kh_GetCarrierSprite(float t, float e)
  52 {
  53         if(t == e)           return kh_sprite_friend;
  54         if(t == COLOR_TEAM1) return kh_sprite_red;
  55         if(t == COLOR_TEAM2) return kh_sprite_blue;
  56         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  57         if(t == COLOR_TEAM4) return kh_sprite_pink;
  58         return 0;
  59 }
  60
  61 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  62 {
  63         kh_Controller_Thinkfunc = func;
  64         kh_controller.cnt = t;
  65         if(kh_Controller_Waitmsg != "")
  66                 strunzone(kh_Controller_Waitmsg);
  67         if(msg == "")
  68                 kh_Controller_Waitmsg = "";
  69         else
  70                 kh_Controller_Waitmsg = strzone(msg);
  71         if(t == 0)
  72                 kh_controller.nextthink = time; // force
  73 }
  74
  75 void kh_Controller_Think()
  76 {
  77         entity e;
  78         if(intermission_running)
  79                 return;
  80         if(self.cnt > 0)
  81         {
  82                 if(kh_Controller_Waitmsg != "")
  83                 {
  84                         string s;
  85                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  86                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  87                         else
  88                                 s = kh_Controller_Waitmsg;
  89
  90                         //dprint(s, "\n");
  91
  92                         FOR_EACH_PLAYER(e)
  93                                 if(clienttype(e) == CLIENTTYPE_REAL)
  94                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  95                 }
  96                 self.cnt -= 1;
  97         }
  98         else if(self.cnt == 0)
  99         {
 100                 self.cnt -= 1;
 101                 kh_Controller_Thinkfunc();
 102         }
 103         self.nextthink = time + 1;
 104 }
 105
 106 // frags f: take from cvar * f
 107 // frags 0: no frags
 108 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 109 {
 110         string s;
 111         if(intermission_running)
 112                 return;
 113         if(frags_player)
 114                 player.frags = player.frags + floor(0.5 + frags_player);
 115         if(frags_owner)
 116                 key.owner.frags = key.owner.frags + floor(0.5 + frags_owner);
 117         if(!cvar("sv_eventlog"))
 118                 return;
 119         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 120         s = strcat(s, ":", ftos(frags_player));
 121         if(key && key.owner)
 122                 s = strcat(s, ":", ftos(key.owner.playerid));
 123         else
 124                 s = strcat(s, ":0");
 125         s = strcat(s, ":", ftos(frags_owner), ":");
 126         if(key)
 127                 s = strcat(s, key.netname);
 128         GameLogEcho(s, FALSE);
 129 }
 130
 131 vector kh_AttachedOrigin(entity e)
 132 {
 133         if(e.tag_entity)
 134         {
 135                 makevectors(e.tag_entity.angles);
 136                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 137         }
 138         else
 139                 return e.origin;
 140 }
 141
 142 void kh_Key_Attach(entity key)
 143 {
 144 #ifdef KH_PLAYER_USE_ATTACHMENT
 145         entity first;
 146         first = key.owner.kh_next;
 147         if(key == first)
 148         {
 149                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 150                 if(key.kh_next)
 151                 {
 152                         setattachment(key.kh_next, key, "");
 153                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 154                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 155                         key.kh_next.angles = '0 0 0';
 156                 }
 157                 else
 158                         setorigin(key, KH_PLAYER_ATTACHMENT);
 159                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 160         }
 161         else
 162         {
 163                 setattachment(key, key.kh_prev, "");
 164                 if(key.kh_next)
 165                         setattachment(key.kh_next, key, "");
 166                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 167                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 168                 key.angles = '0 0 0';
 169         }
 170 #else
 171         setattachment(key, key.owner, "");
 172         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 173         key.angles_y -= key.owner.angles_y;
 174 #endif
 175         key.flags = 0;
 176         key.solid = SOLID_NOT;
 177         key.movetype = MOVETYPE_NONE;
 178         key.team = key.owner.team;
 179         key.nextthink = time;
 180         key.damageforcescale = 0;
 181         key.modelindex = kh_key_carried;
 182 }
 183
 184 void kh_Key_Detach(entity key)
 185 {
 186 #ifdef KH_PLAYER_USE_ATTACHMENT
 187         entity first;
 188         first = key.owner.kh_next;
 189         if(key == first)
 190         {
 191                 if(key.kh_next)
 192                 {
 193                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 194                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 195                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 196                 }
 197         }
 198         else
 199         {
 200                 if(key.kh_next)
 201                         setattachment(key.kh_next, key.kh_prev, "");
 202                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 203         }
 204         // in any case:
 205         setattachment(key, world, "");
 206         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 207         key.angles = key.owner.angles;
 208 #else
 209         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 210         setattachment(key, world, "");
 211         key.angles_y += key.owner.angles_y;
 212 #endif
 213         key.aiment = world;
 214         key.flags = FL_ITEM;
 215         key.solid = SOLID_TRIGGER;
 216         key.movetype = MOVETYPE_TOSS;
 217         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 218         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 219         // let key.team stay
 220         key.modelindex = kh_key_dropped;
 221 }
 222
 223 void kh_Key_AssignTo(entity key, entity player)
 224 {
 225         if(key.owner == player)
 226                 return;
 227
 228         if(key.owner)
 229         {
 230                 kh_Key_Detach(key);
 231
 232                 // remove from linked list
 233                 if(key.kh_next)
 234                         key.kh_next.kh_prev = key.kh_prev;
 235                 key.kh_prev.kh_next = key.kh_next;
 236                 key.kh_next = world;
 237                 key.kh_prev = world;
 238
 239                 if(key.owner.kh_next == world)
 240                 {
 241                         // No longer a key carrier
 242                         WaypointSprite_DetachCarrier(key.owner);
 243                 }
 244         }
 245
 246         key.owner = player;
 247
 248         if(player)
 249         {
 250                 // insert into linked list
 251                 key.kh_next = player.kh_next;
 252                 key.kh_prev = player;
 253                 player.kh_next = key;
 254                 if(key.kh_next)
 255                         key.kh_next.kh_prev = key;
 256
 257                 kh_Key_Attach(key);
 258
 259                 if(key.kh_next == world)
 260                 {
 261                         // player is now a key carrier
 262                         WaypointSprite_AttachCarrier("", player);
 263                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 264                         player.waypointsprite_attachedforcarrier.team = player.team;
 265                 }
 266         }
 267
 268         key.pusher = world;
 269 }
 270
 271 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 272 {
 273         if(self.owner)
 274                 return;
 275         if(vlen(force) <= 0)
 276                 return;
 277         if(time > self.pushltime)
 278                 if(attacker.classname == "player")
 279                         self.team = attacker.team;
 280 }
 281
 282 void kh_Key_Spawn(entity initial_owner, float angle)
 283 {
 284         entity key;
 285         key = spawn();
 286         key.classname = STR_ITEM_KH_KEY;
 287         key.touch = kh_Key_Touch;
 288         key.think = kh_Key_Think;
 289         key.nextthink = time;
 290         key.items = IT_KEY1 | IT_KEY2;
 291         key.cnt = angle;
 292         key.angles = '0 360 0' * random();
 293         key.event_damage = kh_Key_Damage;
 294         key.modelindex = kh_key_dropped;
 295         key.model = "key";
 296         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 297
 298         switch(initial_owner.team)
 299         {
 300                 case COLOR_TEAM1:
 301                         key.netname = "^1red key";
 302                         key.colormod = '103 0 0' * (1/96);
 303                         break;
 304                 case COLOR_TEAM2:
 305                         key.netname = "^4blue key";
 306                         key.colormod = '35 35 191' * (1/96);
 307                         break;
 308                 case COLOR_TEAM3:
 309                         key.netname = "^3yellow key";
 310                         key.colormod = '187 167 15' * (1/96);
 311                         break;
 312                 case COLOR_TEAM4:
 313                         key.netname = "^6pink key";
 314                         key.colormod = '139 79 107' * (1/96);
 315                         break;
 316                 default:
 317                         key.netname = "NETGIER key";
 318                         key.colormod = '1 1 1';
 319                         break;
 320         }
 321
 322         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 323
 324         WaypointSprite_AttachCarrier("", key);
 325         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 326
 327         kh_Key_AssignTo(key, initial_owner);
 328 }
 329
 330 void kh_Key_Remove(entity key)
 331 {
 332         entity o;
 333         o = key.owner;
 334         kh_Key_AssignTo(key, world);
 335         if(o) // it was attached
 336                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 337         else // it was dropped
 338                 WaypointSprite_DetachCarrier(key);
 339
 340         remove(key);
 341 }
 342
 343 // -1 when no team completely owns all keys yet
 344 float kh_Key_AllOwnedByWhichTeam()
 345 {
 346         entity key;
 347         float teem;
 348
 349         teem = -1;
 350         FOR_EACH_KH_KEY(key)
 351         {
 352                 if(!key.owner)
 353                         return -1;
 354                 if(teem == -1)
 355                         teem = key.team;
 356                 else if(teem != key.team)
 357                         return -1;
 358         }
 359         return teem;
 360 }
 361
 362 void kh_Key_Collect(entity key, entity player)
 363 {
 364         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 365
 366         kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 367         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 368         kh_Key_AssignTo(key, player);
 369
 370         if(kh_Key_AllOwnedByWhichTeam() != -1)
 371         {
 372                 kh_interferemsg_time = time + 0.2;
 373                 kh_interferemsg_team = player.team;
 374         }
 375 }
 376
 377 void kh_Key_DropAll(entity player)
 378 {
 379         entity key;
 380         entity mypusher;
 381         if(player.kh_next)
 382         {
 383                 mypusher = world;
 384                 if(player.pusher)
 385                         if(time < player.pushltime)
 386                                 mypusher = player.pusher;
 387                 while((key = player.kh_next))
 388                 {
 389                         kh_Scores_Event(player, key, "losekey", 0, 0);
 390                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 391                         kh_Key_AssignTo(key, world);
 392                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 393                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 394                         key.pusher = mypusher;
 395                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 396                 }
 397                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 398         }
 399 }
 400
 401 void kh_Key_Touch()
 402 {
 403         if(intermission_running)
 404                 return;
 405
 406         if(self.owner) // already carried
 407                 return;
 408         if(other.classname != "player")
 409                 return;
 410         if(other.deadflag != DEAD_NO)
 411                 return;
 412         if(other == self.enemy)
 413                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 414                         return; // you just dropped it!
 415         kh_Key_Collect(self, other);
 416 }
 417
 418 void kh_Key_Think()
 419 {
 420         entity head;
 421
 422         if(intermission_running)
 423                 return;
 424
 425 #ifdef KH_KEY_ATTACHMENT_DEBUG
 426         if(self.kh_prev == self.owner)
 427         {
 428                 if(cvar_string("_angles") != "")
 429                 {
 430                         self.angles = stov(cvar_string("_angles"));
 431                         self.origin = stov(cvar_string("_origin"));
 432                 }
 433         }
 434 #endif
 435
 436         if(self.owner)
 437         {
 438 #ifndef KH_PLAYER_USE_ATTACHMENT
 439                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * KH_KEY_XYSPEED));
 440                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 441 #endif
 442
 443                 if(self.owner.buttonuse)
 444                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 445                 {
 446                         self.owner.kh_droptime = time;
 447                         self.kh_droptime = time; // prevent collecting this one for some time
 448                         self.enemy = self.owner;
 449                         self.pusher = world;
 450                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 451                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 452                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 453                         makevectors(self.owner.v_angle);
 454                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 455                         kh_Key_AssignTo(self, world);
 456                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 457                 }
 458         }
 459
 460         // if in nodrop or time over, end the round
 461         if(!self.owner)
 462                 if(time > self.pain_finished)
 463                         kh_LoserTeam(self.team, self);
 464
 465         if(self.owner)
 466         if(kh_Key_AllOwnedByWhichTeam() != -1)
 467         {
 468                 entity key;
 469                 vector p;
 470                 p = self.owner.origin;
 471                 FOR_EACH_KH_KEY(key)
 472                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 473                                 goto not_winning;
 474                 kh_WinnerTeam(self.team);
 475 :not_winning
 476         }
 477
 478         if(kh_interferemsg_time && time > kh_interferemsg_time)
 479         {
 480                 kh_interferemsg_time = 0;
 481                 FOR_EACH_PLAYER(head)
 482                 {
 483                         if(head.team == kh_interferemsg_team)
 484                                 if(head.kh_next)
 485                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 486                                 else
 487                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 488                         else
 489                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 490                 }
 491         }
 492
 493         self.nextthink = time + 0.05;
 494 }
 495
 496 void kh_WinnerTeam(float teem)
 497 {
 498         // all key carriers get some points
 499         vector firstorigin, lastorigin;
 500         float first;
 501         entity key;
 502         float score;
 503         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 504         DistributeEvenly_Init(score, kh_teams);
 505         // twice the score for 3 team games, three times the score for 4 team games!
 506         // note: for a win by destroying the key, this should NOT be applied
 507         FOR_EACH_KH_KEY(key)
 508                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 509
 510         first = TRUE;
 511         FOR_EACH_KH_KEY(key)
 512                 if(key.owner.kh_next == key)
 513                 {
 514                         if(!first)
 515                                 bprint("^7, ");
 516                         bprint(key.owner.netname);
 517                         first = FALSE;
 518                 }
 519         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 520
 521         first = TRUE;
 522         FOR_EACH_KH_KEY(key)
 523         {
 524                 vector thisorigin;
 525
 526                 thisorigin = kh_AttachedOrigin(key);
 527
 528                 if(!first)
 529                         te_lightning2(world, lastorigin, thisorigin);
 530                 lastorigin = thisorigin;
 531                 if(first)
 532                         firstorigin = thisorigin;
 533                 first = FALSE;
 534         }
 535         if(kh_teams > 2)
 536         {
 537                 te_lightning2(world, lastorigin, firstorigin);
 538         }
 539
 540         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 541         kh_FinishRound();
 542 }
 543
 544 void kh_LoserTeam(float teem, entity lostkey)
 545 {
 546         entity player, key, attacker;
 547         float players;
 548         float keys;
 549
 550         attacker = world;
 551         if(lostkey.pusher)
 552                 if(lostkey.pusher.team != teem)
 553                         if(lostkey.pusher.classname == "player")
 554                                 attacker = lostkey.pusher;
 555
 556         players = keys = 0;
 557
 558         if(attacker)
 559         {
 560                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 561                 centerprint(attacker, "Your push is the best!\n\n\n");
 562                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 563         }
 564         else
 565         {
 566                 float of, fragsleft, i, j, thisteam;
 567                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 568
 569                 FOR_EACH_PLAYER(player)
 570                         if(player.team != teem)
 571                                 ++players;
 572
 573                 FOR_EACH_KH_KEY(key)
 574                         if(key.owner && key.team != teem)
 575                                 ++keys;
 576
 577                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 578
 579                 FOR_EACH_KH_KEY(key)
 580                         if(key.owner && key.team != teem)
 581                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 582
 583                 fragsleft = DistributeEvenly_Get(players);
 584
 585                 // Now distribute these among all other teams...
 586                 j = kh_teams - 1;
 587                 for(i = 0; i < kh_teams; ++i)
 588                 {
 589                         thisteam = kh_Team_ByID(i);
 590                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 591                                 continue;
 592
 593                         players = 0;
 594                         FOR_EACH_PLAYER(player)
 595                                 if(player.team == thisteam)
 596                                         ++players;
 597
 598                         DistributeEvenly_Init(fragsleft, j);
 599                         fragsleft = DistributeEvenly_Get(j - 1);
 600                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 601
 602                         FOR_EACH_PLAYER(player)
 603                                 if(player.team == thisteam)
 604                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 605
 606                         --j;
 607                 }
 608
 609                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 610         }
 611         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 612
 613         kh_FinishRound();
 614 }
 615
 616 void kh_FinishRound()
 617 {
 618         // prepare next round
 619         kh_interferemsg_time = 0;
 620         entity key;
 621         FOR_EACH_KH_KEY(key)
 622                 kh_Key_Remove(key);
 623
 624         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 625 }
 626
 627 string kh_CheckEnoughPlayers()
 628 {
 629         float i, players, teem;
 630         entity player;
 631         string result;
 632         result = "";
 633
 634         // find a random player per team
 635         for(i = 0; i < kh_teams; ++i)
 636         {
 637                 teem = kh_Team_ByID(i);
 638                 players = 0;
 639                 FOR_EACH_PLAYER(player)
 640                         if(player.deadflag == DEAD_NO)
 641                                 if(!player.buttonchat)
 642                                         if(player.team == teem)
 643                                                 ++players;
 644                 if(players == 0)
 645                 {
 646                         if(result != "")
 647                                 result = strcat(result, ", ");
 648                         result = strcat(result, ColoredTeamName(teem));
 649                 }
 650         }
 651         return result;
 652 }
 653
 654 void kh_WaitForPlayers()
 655 {
 656         string teams_missing;
 657         teams_missing = kh_CheckEnoughPlayers();
 658         if(teams_missing == "")
 659                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 660         else
 661                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 662 }
 663
 664 void kh_StartRound()
 665 {
 666         string teams_missing;
 667         float i, players, teem;
 668         entity player;
 669
 670         teams_missing = kh_CheckEnoughPlayers();
 671         if(teams_missing != "")
 672         {
 673                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 674                 return;
 675         }
 676
 677         FOR_EACH_PLAYER(player)
 678                 if(clienttype(player) == CLIENTTYPE_REAL)
 679                         centerprint_expire(player, CENTERPRIO_SPAM);
 680
 681         for(i = 0; i < kh_teams; ++i)
 682         {
 683                 teem = kh_Team_ByID(i);
 684                 players = 0;
 685                 entity my_player;
 686                 FOR_EACH_PLAYER(player)
 687                         if(player.deadflag == DEAD_NO)
 688                                 if(!player.buttonchat)
 689                                         if(player.team == teem)
 690                                         {
 691                                                 ++players;
 692                                                 if(random() * players <= 1)
 693                                                         my_player = player;
 694                                         }
 695                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 696                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 697                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 698         }
 699
 700         kh_tracking_enabled = FALSE;
 701         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 702 }
 703
 704 void kh_setstatus()
 705 {
 706         if(kh_teams)
 707         {
 708                 float kh_KEY;
 709                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 710                 if(self.kh_next)
 711                         self.items = self.items | kh_KEY;
 712                 else
 713                         self.items = self.items - (self.items & kh_KEY);
 714         }
 715 }
 716
 717 void kh_EnableTrackingDevice()
 718 {
 719         entity player;
 720
 721         FOR_EACH_PLAYER(player)
 722                 if(clienttype(player) == CLIENTTYPE_REAL)
 723                         centerprint_expire(player, CENTERPRIO_SPAM);
 724
 725         kh_tracking_enabled = TRUE;
 726 }
 727
 728 float kh_Key_waypointsprite_for_player(entity e)
 729 {
 730         if(!kh_tracking_enabled)
 731                 return 0;
 732         if(!self.owner)
 733                 return kh_sprite_dropped;
 734         if(!self.owner.owner)
 735                 return kh_sprite_dropped;
 736         return 0; // draw only when key is not owned
 737 }
 738
 739 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 740 {
 741         if(e.classname != "player" || self.team != e.team)
 742                 if(!kh_tracking_enabled)
 743                         return 0;
 744
 745         // e is spectator? That's no team mate...
 746         if(e.classname != "player")
 747                 return kh_GetCarrierSprite(self.team, -1);
 748
 749         // e is no key carrier: simple case...
 750         if(!e.kh_next)
 751                 return kh_GetCarrierSprite(self.team, e.team);
 752
 753         // e is a key carrier: if any key is dropped or owned by another team, show
 754         // the carrier sprite; otherwise show run here
 755         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 756                 return kh_sprite_finish;
 757
 758         return kh_GetCarrierSprite(self.team, e.team);
 759 }
 760
 761 float kh_HandleFrags(entity attacker, entity targ, float f)
 762 {
 763         if(f <= 0)
 764                 return f;
 765         if(attacker == targ)
 766                 return f;
 767
 768         if(targ.kh_next)
 769                 kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 770
 771         return f;
 772 }
 773
 774 void kh_init()
 775 {
 776         precache_sound(kh_sound_capture);
 777         precache_sound(kh_sound_destroy);
 778         precache_sound(kh_sound_drop);
 779         precache_sound(kh_sound_collect);
 780
 781         precache_model("models/sprites/key-dropped.sp2");
 782         precache_model("models/sprites/keycarrier-finish.sp2");
 783         precache_model("models/sprites/keycarrier-friend.sp2");
 784         precache_model("models/sprites/keycarrier-red.sp2");
 785         precache_model("models/sprites/keycarrier-blue.sp2");
 786         precache_model("models/sprites/keycarrier-yellow.sp2");
 787         precache_model("models/sprites/keycarrier-pink.sp2");
 788 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 789         precache_model("models/keyhunt/key-carried.md3");
 790 #endif
 791         precache_model("models/keyhunt/key.md3");
 792
 793         // setup variables
 794         kh_teams = cvar("g_keyhunt_teams_override");
 795         if(kh_teams < 2)
 796                 kh_teams = cvar("g_keyhunt_teams");
 797         kh_teams = bound(2, kh_teams, 4);
 798
 799         // make a KH entity for controlling the game
 800         kh_controller = spawn();
 801         kh_controller.think = kh_Controller_Think;
 802         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 803
 804         setmodel(kh_controller, "models/keyhunt/key.md3");
 805         kh_key_dropped = kh_controller.modelindex;
 806         /*
 807         dprint(vtos(kh_controller.mins));
 808         dprint(vtos(kh_controller.maxs));
 809         dprint("\n");
 810         */
 811 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 812         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 813         kh_key_carried = kh_controller.modelindex;
 814 #else
 815         kh_key_carried = kh_key_dropped;
 816 #endif
 817         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 818         kh_sprite_dropped = kh_controller.modelindex;
 819         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 820         kh_sprite_finish = kh_controller.modelindex;
 821         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 822         kh_sprite_friend = kh_controller.modelindex;
 823         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 824         kh_sprite_red = kh_controller.modelindex;
 825         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 826         kh_sprite_blue = kh_controller.modelindex;
 827         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 828         kh_sprite_pink = kh_controller.modelindex;
 829         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 830         kh_sprite_yellow = kh_controller.modelindex;
 831         setmodel(kh_controller, "");
 832 }
 833
 834 void kh_finalize()
 835 {
 836         // to be called before intermission
 837         kh_FinishRound();
 838         remove(kh_controller);
 839         kh_controller = world;
 840 }