data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/ctf/respawn.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_pink;
  37         if(t == COLOR_TEAM4) return kh_sprite_yellow;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(self.cnt > 0)
  59         {
  60                 if(kh_Controller_Waitmsg != "")
  61                 {
  62                         string s;
  63                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  64                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  65                         else
  66                                 s = kh_Controller_Waitmsg;
  67
  68                         dprint(s, "\n");
  69
  70                         FOR_EACH_PLAYER(e)
  71                                 if(clienttype(e) == CLIENTTYPE_REAL)
  72                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  73                 }
  74                 self.cnt -= 1;
  75         }
  76         else if(self.cnt == 0)
  77         {
  78                 FOR_EACH_PLAYER(e)
  79                         if(clienttype(e) == CLIENTTYPE_REAL)
  80                                 centerprint_expire(e, CENTERPRIO_SPAM);
  81                 self.cnt -= 1;
  82                 kh_Controller_Thinkfunc();
  83         }
  84         self.nextthink = time + 1;
  85 }
  86
  87 void kh_Log()
  88 {
  89         string s;
  90         if(!cvar("sv_eventlog"))
  91                 return;
  92         // TODO ...
  93         GameLogEcho(s, FALSE);
  94 }
  95
  96 // frags f: take from cvar * f
  97 // frags 0: no frags
  98 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
  99 {
 100         float basefrags;
 101         basefrags = cvar(strcat("g_balance_keyhunt_score_", what));
 102
 103         if(frags_player)
 104                 player.frags = player.frags + floor(0.5 + basefrags * frags_player);
 105         if(frags_owner)
 106                 key.owner.frags = key.owner.frags + floor(0.5 + basefrags * frags_owner);
 107 }
 108
 109 void kh_Key_Attach(entity key, float wpchange)
 110 {
 111         setattachment(key, key.owner, "");
 112         setorigin(key, '0 0 0'); // fixed later in think
 113         key.angles = key.angles - '0 1 0' * key.owner.angles_y;
 114         key.flags = 0;
 115         key.solid = SOLID_NOT;
 116         key.movetype = MOVETYPE_NONE;
 117         key.team = key.owner.team;
 118         key.nextthink = time;
 119 }
 120
 121 void kh_Key_Detach(entity key, float wpchange)
 122 {
 123         setattachment(key, world, "");
 124         makevectors(key.owner.angles);
 125         setorigin(key, key.owner.origin + key.origin_x * v_forward - key.origin_y * v_right + key.origin_z * v_up);
 126         key.angles_y = key.owner.angles_y;
 127         key.aiment = world;
 128         key.flags = FL_ITEM;
 129         key.solid = SOLID_TRIGGER;
 130         key.movetype = MOVETYPE_TOSS;
 131         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 132         // let key.team stay
 133 }
 134
 135 void kh_Key_AssignTo(entity key, entity player, float wpchange)
 136 {
 137         if(key.owner == player)
 138                 return;
 139
 140         if(key.owner)
 141         {
 142                 kh_Key_Detach(key, wpchange);
 143
 144                 // remove from linked list
 145                 if(key.kh_next)
 146                         key.kh_next.kh_prev = key.kh_prev;
 147                 key.kh_prev.kh_next = key.kh_next;
 148                 key.kh_next = world;
 149                 key.kh_prev = world;
 150
 151                 if(key.owner.kh_next == world)
 152                 {
 153                         // No longer a key carrier
 154                         if(wpchange)
 155                                 WaypointSprite_Kill(key.owner.waypointsprite_attachedforcarrier);
 156                         else
 157                                 WaypointSprite_DetachCarrier(key.owner);
 158                 }
 159         }
 160
 161         key.owner = player;
 162
 163         if(player)
 164         {
 165                 // insert into linked list
 166                 key.kh_next = player.kh_next;
 167                 key.kh_prev = player;
 168                 player.kh_next = key;
 169                 if(key.kh_next)
 170                         key.kh_next.kh_prev = key;
 171
 172                 kh_Key_Attach(key, wpchange);
 173
 174                 if(key.kh_next == world)
 175                 {
 176                         // player is now a key carrier
 177                         WaypointSprite_AttachCarrier("", player);
 178                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 179                         player.waypointsprite_attachedforcarrier.team = player.team;
 180                 }
 181         }
 182
 183         key.pusher = world;
 184 }
 185
 186 void kh_Key_Spawn(entity initial_owner, float angle)
 187 {
 188         entity key;
 189         key = spawn();
 190         key.classname = STR_ITEM_KH_KEY;
 191         key.touch = kh_Key_Touch;
 192         key.think = kh_Key_Think;
 193         key.nextthink = time;
 194         key.items = IT_KEY1 | IT_KEY2;
 195         key.cnt = angle;
 196         key.angles = '0 360 0' * random();
 197         setmodel(key, "models/keyhunt/key3.md3");
 198         setsize(key, '0 0 -24', '0 0 25');
 199
 200         switch(initial_owner.team)
 201         {
 202                 case COLOR_TEAM1:
 203                         key.netname = "^1red key";
 204                         key.colormod = '1.73 0.10 0.10';
 205                         break;
 206                 case COLOR_TEAM2:
 207                         key.netname = "^4blue key";
 208                         key.colormod = '0.10 0.10 1.73';
 209                         break;
 210                 case COLOR_TEAM3:
 211                         key.netname = "^6pink key";
 212                         key.colormod = '1.22 0.10 1.22';
 213                         break;
 214                 case COLOR_TEAM4:
 215                         key.netname = "^3yellow key";
 216                         key.colormod = '1.22 1.22 0.10';
 217                         break;
 218                 default:
 219                         key.netname = "NETGIER key";
 220                         key.colormod = '1.00 1.00 1.00';
 221                         break;
 222         }
 223
 224         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 225
 226         WaypointSprite_AttachCarrier("", key);
 227         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 228
 229         kh_Key_AssignTo(key, initial_owner, TRUE);
 230 }
 231
 232 void kh_Key_Remove(entity key)
 233 {
 234         entity o;
 235         o = key.owner;
 236         kh_Key_AssignTo(key, world, FALSE);
 237         if(o) // it was attached
 238                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 239         else // it was dropped
 240                 WaypointSprite_DetachCarrier(key);
 241
 242         remove(key);
 243 }
 244
 245 void kh_Key_Collect(entity key, entity player)
 246 {
 247         kh_Scores_Event(player, key, "collect", 1, 0);
 248         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 249         kh_Key_AssignTo(key, player, TRUE);
 250
 251         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NONE);
 252
 253         FOR_EACH_KH_KEY(key)
 254                 if(!key.owner || key.team != player.team)
 255                         goto notallowned;
 256         kh_interferemsg_time = time + 0.2;
 257         kh_interferemsg_team = player.team;
 258 :notallowned
 259 }
 260
 261 void kh_Key_DropAll(entity player)
 262 {
 263         entity key;
 264         entity mypusher;
 265         if(player.kh_next)
 266         {
 267                 mypusher = world;
 268                 if(player.pusher)
 269                         if(time < player.pushltime)
 270                                 mypusher = player.pusher;
 271                 while((key = player.kh_next))
 272                 {
 273                         kh_Scores_Event(player, key, "losekey", 0, 0);
 274                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 275                         kh_Key_AssignTo(key, world, TRUE);
 276                         key.pusher = player.pusher;
 277                         key.pushltime = player.pushltime;
 278                 }
 279                 sound(world, CHAN_AUTO, kh_sound_drop, 1, ATTN_NONE);
 280         }
 281 }
 282
 283 void kh_Key_Touch()
 284 {
 285         if(self.owner) // already carried
 286                 return;
 287         if(other.classname != "player")
 288                 return;
 289         if(other.deadflag != DEAD_NO)
 290                 return;
 291         if(other == self.enemy)
 292                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 293                         return; // you just dropped it!
 294         kh_Key_Collect(self, other);
 295 }
 296
 297 void kh_Key_Think()
 298 {
 299         entity head;
 300
 301         self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 302
 303         if(self.owner)
 304         {
 305                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 306                 setorigin(self, v_forward * 16);
 307
 308                 if(self.owner.buttonuse)
 309                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 310                 {
 311                         self.owner.kh_droptime = time;
 312                         self.kh_droptime = time; // prevent collecting this one for some time
 313                         self.enemy = self.owner;
 314                         self.pusher = world;
 315                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 316                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 317                         kh_Key_AssignTo(self, world, TRUE);
 318                         sound(world, CHAN_AUTO, kh_sound_drop, 1, ATTN_NONE);
 319                 }
 320         }
 321
 322         // if in nodrop or time over, end the round
 323         if(!self.owner)
 324                 if(time > self.pain_finished)
 325                         kh_LoserTeam(self.team, self);
 326
 327         if(self.owner)
 328         {
 329                 entity key;
 330                 vector p;
 331                 float teem;
 332                 teem = self.team;
 333                 p = self.owner.origin;
 334                 FOR_EACH_KH_KEY(key)
 335                 {
 336                         if(key.owner == self.owner)
 337                                 continue;
 338                         if(key.owner)
 339                         if(key.team == teem)
 340                         if(vlen(key.owner.origin - p) < cvar("g_balance_keyhunt_maxdist"))
 341                                 continue;
 342                         goto not_winning;
 343                 }
 344                 kh_WinnerTeam(teem);
 345 :not_winning
 346         }
 347
 348         if(kh_interferemsg_time && time > kh_interferemsg_time)
 349         {
 350                 kh_interferemsg_time = 0;
 351                 FOR_EACH_PLAYER(head)
 352                 {
 353                         if(head.team == kh_interferemsg_team)
 354                                 if(head.kh_next)
 355                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 356                                 else
 357                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 358                         else
 359                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 360                 }
 361         }
 362
 363         self.nextthink = time + 0.05;
 364 }
 365
 366 void kh_WinnerTeam(float teem)
 367 {
 368         // all key carriers get some points
 369         entity key;
 370         float first;
 371         float score;
 372         score = 1.0 / kh_teams;
 373         first = TRUE;
 374         FOR_EACH_KH_KEY(key)
 375         {
 376                 kh_Scores_Event(key.owner, key, "capture", score, 0);
 377                 if(key.owner.kh_next == key)
 378                 {
 379                         if(!first)
 380                                 bprint("^7, ");
 381                         bprint(key.owner.netname);
 382                         first = FALSE;
 383                 }
 384         }
 385         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 386         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 387         kh_FinishRound();
 388 }
 389
 390 void kh_LoserTeam(float teem, entity lostkey)
 391 {
 392         entity player, key, attacker;
 393         float players;
 394         float keys;
 395         float score;
 396
 397         attacker = world;
 398         if(lostkey.pusher)
 399                 if(player.pusher.team != player.team)
 400                         if(player.pusher.classname == "player")
 401                                 attacker = lostkey.pusher;
 402
 403         players = keys = 0;
 404
 405         if(attacker)
 406         {
 407                 kh_Scores_Event(attacker, world, "push", 1, 0);
 408                 centerprint(attacker, "Your push is the best!\n\n\n");
 409                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 410         }
 411         else
 412         {
 413                 FOR_EACH_PLAYER(player)
 414                         if(player.team != teem)
 415                                 ++players;
 416
 417                 FOR_EACH_KH_KEY(key)
 418                         if(key.owner && key.team != teem)
 419                                 ++keys;
 420
 421                 score = 1.0 / (keys * cvar("g_balance_keyhunt_score_destroyed_ownfactor") + players);
 422
 423                 FOR_EACH_PLAYER(player)
 424                         if(player.team != teem)
 425                                 kh_Scores_Event(player, world, "destroyed", score, 0);
 426
 427                 FOR_EACH_KH_KEY(key)
 428                         if(key.owner && key.team != teem)
 429                                 kh_Scores_Event(key.owner, world, "destroyed", score * cvar("g_balance_keyhunt_score_destroyed_ownfactor"), 0);
 430
 431                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 432         }
 433         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 434
 435         kh_FinishRound();
 436 }
 437
 438 void kh_FinishRound()
 439 {
 440         // prepare next round
 441         kh_interferemsg_time = 0;
 442         entity key;
 443         FOR_EACH_KH_KEY(key)
 444                 kh_Key_Remove(key);
 445
 446         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 447 }
 448
 449 float kh_EnoughPlayers()
 450 {
 451         float i, players, teem;
 452         entity player;
 453
 454         // find a random player per team
 455         for(i = 0; i < kh_teams; ++i)
 456         {
 457                 teem = kh_Team_ByID(i);
 458                 players = 0;
 459                 FOR_EACH_PLAYER(player)
 460                         if(player.deadflag == DEAD_NO)
 461                                 if(player.team == teem)
 462                                         ++players;
 463                 if(players == 0)
 464                         return FALSE;
 465         }
 466         return TRUE;
 467 }
 468
 469 void kh_WaitForPlayers()
 470 {
 471         if(kh_EnoughPlayers())
 472                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 473         else
 474                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 475 }
 476
 477 void kh_StartRound()
 478 {
 479         float i, players, teem;
 480         entity player;
 481
 482         if(!kh_EnoughPlayers())
 483         {
 484                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 485                 return;
 486         }
 487
 488         for(i = 0; i < kh_teams; ++i)
 489         {
 490                 teem = kh_Team_ByID(i);
 491                 players = 0;
 492                 entity my_player;
 493                 FOR_EACH_PLAYER(player)
 494                         if(player.deadflag == DEAD_NO)
 495                                 if(player.team == teem)
 496                                 {
 497                                         ++players;
 498                                         if(random() * players <= 1)
 499                                                 my_player = player;
 500                                 }
 501                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 502         }
 503
 504         kh_tracking_enabled = FALSE;
 505         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 506 }
 507
 508 void kh_setstatus()
 509 {
 510         if(kh_teams)
 511         {
 512                 float kh_KEY;
 513                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 514                 if(self.kh_next)
 515                         self.items = self.items | kh_KEY;
 516                 else
 517                         self.items = self.items - (self.items & kh_KEY);
 518         }
 519 }
 520
 521 void kh_EnableTrackingDevice()
 522 {
 523         kh_tracking_enabled = TRUE;
 524 }
 525
 526 float kh_Key_waypointsprite_for_player(entity e)
 527 {
 528         if(!kh_tracking_enabled)
 529                 return 0;
 530         if(!self.owner)
 531                 return kh_sprite_dropped;
 532         if(!self.owner.owner)
 533                 return kh_sprite_dropped;
 534         return 0; // draw only when key is not owned
 535 }
 536
 537 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 538 {
 539         entity key;
 540
 541         if(e.classname != "player" || self.team != e.team)
 542                 if(!kh_tracking_enabled)
 543                         return 0;
 544
 545         // e is no key carrier: simple case...
 546         if(!e.kh_next)
 547                 return kh_GetCarrierSprite(self.team, e.team);
 548
 549         // e is a key carrier: if any key is dropped or owned by another team, show
 550         // the carrier sprite; otherwise show run here
 551         FOR_EACH_KH_KEY(key)
 552                 if(!key.owner || key.team != e.team)
 553                         return kh_GetCarrierSprite(self.team, e.team);
 554
 555         return kh_sprite_finish;
 556 }
 557
 558 float kh_HandleFrags(entity attacker, entity targ, float f)
 559 {
 560         float newfrags;
 561
 562         if(f <= 0)
 563                 return f;
 564         if(attacker == targ)
 565                 return f;
 566
 567         if(targ.kh_next)
 568                 f = f - 1 + cvar("g_balance_keyhunt_score_carrierfrag");
 569
 570         if(newfrags)
 571                 f = f - 1 + newfrags;
 572         return f;
 573 }
 574
 575 void kh_init()
 576 {
 577         precache_sound(kh_sound_capture);
 578         precache_sound(kh_sound_destroy);
 579         precache_sound(kh_sound_drop);
 580         precache_sound(kh_sound_collect);
 581
 582         precache_model("models/sprites/key-dropped.sp2");
 583         precache_model("models/sprites/keycarrier-finish.sp2");
 584         precache_model("models/sprites/keycarrier-friend.sp2");
 585         precache_model("models/sprites/keycarrier-red.sp2");
 586         precache_model("models/sprites/keycarrier-blue.sp2");
 587         precache_model("models/sprites/keycarrier-pink.sp2");
 588         precache_model("models/sprites/keycarrier-yellow.sp2");
 589         precache_model("models/keyhunt/key3.md3");
 590
 591         // setup variables
 592         kh_teams = cvar("g_keyhunt_teams_override");
 593         if(kh_teams < 2)
 594                 kh_teams = cvar("g_keyhunt_teams");
 595         if(kh_teams < 2)
 596                 kh_teams = 2;
 597
 598         // make a KH entity for controlling the game
 599         kh_controller = spawn();
 600         kh_controller.think = kh_Controller_Think;
 601         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 602
 603         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 604         kh_sprite_dropped = kh_controller.modelindex;
 605         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 606         kh_sprite_finish = kh_controller.modelindex;
 607         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 608         kh_sprite_friend = kh_controller.modelindex;
 609         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 610         kh_sprite_red = kh_controller.modelindex;
 611         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 612         kh_sprite_blue = kh_controller.modelindex;
 613         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 614         kh_sprite_pink = kh_controller.modelindex;
 615         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 616         kh_sprite_yellow = kh_controller.modelindex;
 617         setmodel(kh_controller, "");
 618 }
 619
 620 void kh_finalize()
 621 {
 622         // to be called before intermission
 623         kh_FinishRound();
 624         remove(kh_controller);
 625         kh_controller = world;
 626 }