data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/misc/mouseclick.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_pink;
  37         if(t == COLOR_TEAM4) return kh_sprite_yellow;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(intermission_running)
  59                 return;
  60         if(self.cnt > 0)
  61         {
  62                 if(kh_Controller_Waitmsg != "")
  63                 {
  64                         string s;
  65                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  66                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  67                         else
  68                                 s = kh_Controller_Waitmsg;
  69
  70                         dprint(s, "\n");
  71
  72                         FOR_EACH_PLAYER(e)
  73                                 if(clienttype(e) == CLIENTTYPE_REAL)
  74                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  75                 }
  76                 self.cnt -= 1;
  77         }
  78         else if(self.cnt == 0)
  79         {
  80                 FOR_EACH_PLAYER(e)
  81                         if(clienttype(e) == CLIENTTYPE_REAL)
  82                                 centerprint_expire(e, CENTERPRIO_SPAM);
  83                 self.cnt -= 1;
  84                 kh_Controller_Thinkfunc();
  85         }
  86         self.nextthink = time + 1;
  87 }
  88
  89 void kh_Log()
  90 {
  91         string s;
  92         if(!cvar("sv_eventlog"))
  93                 return;
  94         // TODO ...
  95         GameLogEcho(s, FALSE);
  96 }
  97
  98 // frags f: take from cvar * f
  99 // frags 0: no frags
 100 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 101 {
 102         float basefrags;
 103         basefrags = cvar(strcat("g_balance_keyhunt_score_", what));
 104
 105         if(frags_player)
 106                 player.frags = player.frags + floor(0.5 + basefrags * frags_player);
 107         if(frags_owner)
 108                 key.owner.frags = key.owner.frags + floor(0.5 + basefrags * frags_owner);
 109 }
 110
 111 void kh_Key_Attach(entity key, float wpchange)
 112 {
 113         setattachment(key, key.owner, "");
 114         setorigin(key, '0 0 0'); // fixed later in think
 115         key.angles = key.angles - '0 1 0' * key.owner.angles_y;
 116         key.flags = 0;
 117         key.solid = SOLID_NOT;
 118         key.movetype = MOVETYPE_NONE;
 119         key.team = key.owner.team;
 120         key.nextthink = time;
 121 }
 122
 123 vector kh_AttachedOrigin(entity e)
 124 {
 125         if(e.tag_entity)
 126         {
 127                 makevectors(e.tag_entity.angles);
 128                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 129         }
 130         else
 131                 return e.origin;
 132 }
 133
 134 void kh_Key_Detach(entity key, float wpchange)
 135 {
 136         setorigin(key, kh_AttachedOrigin(key));
 137         setattachment(key, world, "");
 138         key.angles_y = key.owner.angles_y;
 139         key.aiment = world;
 140         key.flags = FL_ITEM;
 141         key.solid = SOLID_TRIGGER;
 142         key.movetype = MOVETYPE_TOSS;
 143         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 144         // let key.team stay
 145 }
 146
 147 void kh_Key_AssignTo(entity key, entity player, float wpchange)
 148 {
 149         if(key.owner == player)
 150                 return;
 151
 152         if(key.owner)
 153         {
 154                 kh_Key_Detach(key, wpchange);
 155
 156                 // remove from linked list
 157                 if(key.kh_next)
 158                         key.kh_next.kh_prev = key.kh_prev;
 159                 key.kh_prev.kh_next = key.kh_next;
 160                 key.kh_next = world;
 161                 key.kh_prev = world;
 162
 163                 if(key.owner.kh_next == world)
 164                 {
 165                         // No longer a key carrier
 166                         if(wpchange)
 167                                 WaypointSprite_Kill(key.owner.waypointsprite_attachedforcarrier);
 168                         else
 169                                 WaypointSprite_DetachCarrier(key.owner);
 170                 }
 171         }
 172
 173         key.owner = player;
 174
 175         if(player)
 176         {
 177                 // insert into linked list
 178                 key.kh_next = player.kh_next;
 179                 key.kh_prev = player;
 180                 player.kh_next = key;
 181                 if(key.kh_next)
 182                         key.kh_next.kh_prev = key;
 183
 184                 kh_Key_Attach(key, wpchange);
 185
 186                 if(key.kh_next == world)
 187                 {
 188                         // player is now a key carrier
 189                         WaypointSprite_AttachCarrier("", player);
 190                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 191                         player.waypointsprite_attachedforcarrier.team = player.team;
 192                 }
 193         }
 194
 195         key.pusher = world;
 196 }
 197
 198 void kh_Key_Spawn(entity initial_owner, float angle)
 199 {
 200         entity key;
 201         key = spawn();
 202         key.classname = STR_ITEM_KH_KEY;
 203         key.touch = kh_Key_Touch;
 204         key.think = kh_Key_Think;
 205         key.nextthink = time;
 206         key.items = IT_KEY1 | IT_KEY2;
 207         key.cnt = angle;
 208         key.angles = '0 360 0' * random();
 209         setmodel(key, "models/keyhunt/key3.md3");
 210         setsize(key, '0 0 -24', '0 0 25');
 211
 212         switch(initial_owner.team)
 213         {
 214                 case COLOR_TEAM1:
 215                         key.netname = "^1red key";
 216                         key.colormod = '1.73 0.10 0.10';
 217                         break;
 218                 case COLOR_TEAM2:
 219                         key.netname = "^4blue key";
 220                         key.colormod = '0.10 0.10 1.73';
 221                         break;
 222                 case COLOR_TEAM3:
 223                         key.netname = "^6pink key";
 224                         key.colormod = '1.22 0.10 1.22';
 225                         break;
 226                 case COLOR_TEAM4:
 227                         key.netname = "^3yellow key";
 228                         key.colormod = '1.22 1.22 0.10';
 229                         break;
 230                 default:
 231                         key.netname = "NETGIER key";
 232                         key.colormod = '1.00 1.00 1.00';
 233                         break;
 234         }
 235
 236         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 237
 238         WaypointSprite_AttachCarrier("", key);
 239         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 240
 241         kh_Key_AssignTo(key, initial_owner, TRUE);
 242 }
 243
 244 void kh_Key_Remove(entity key)
 245 {
 246         entity o;
 247         o = key.owner;
 248         kh_Key_AssignTo(key, world, FALSE);
 249         if(o) // it was attached
 250                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 251         else // it was dropped
 252                 WaypointSprite_DetachCarrier(key);
 253
 254         remove(key);
 255 }
 256
 257 // -1 when no team completely owns all keys yet
 258 float kh_Key_AllOwnedByWhichTeam()
 259 {
 260         entity key;
 261         float teem;
 262
 263         teem = -1;
 264         FOR_EACH_KH_KEY(key)
 265         {
 266                 if(!key.owner)
 267                         return -1;
 268                 if(teem == -1)
 269                         teem = key.team;
 270                 else if(teem != key.team)
 271                         return -1;
 272         }
 273         return teem;
 274 }
 275
 276 void kh_Key_Collect(entity key, entity player)
 277 {
 278         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 279
 280         kh_Scores_Event(player, key, "collect", 1, 0);
 281         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 282         kh_Key_AssignTo(key, player, TRUE);
 283
 284         if(kh_Key_AllOwnedByWhichTeam() != -1)
 285         {
 286                 kh_interferemsg_time = time + 0.2;
 287                 kh_interferemsg_team = player.team;
 288         }
 289 }
 290
 291 void kh_Key_DropAll(entity player)
 292 {
 293         entity key;
 294         entity mypusher;
 295         if(player.kh_next)
 296         {
 297                 mypusher = world;
 298                 if(player.pusher)
 299                         if(time < player.pushltime)
 300                                 mypusher = player.pusher;
 301                 while((key = player.kh_next))
 302                 {
 303                         kh_Scores_Event(player, key, "losekey", 0, 0);
 304                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 305                         kh_Key_AssignTo(key, world, TRUE);
 306                         key.pusher = mypusher;
 307                 }
 308                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 309         }
 310 }
 311
 312 void kh_Key_Touch()
 313 {
 314         if(self.owner) // already carried
 315                 return;
 316         if(other.classname != "player")
 317                 return;
 318         if(other.deadflag != DEAD_NO)
 319                 return;
 320         if(other == self.enemy)
 321                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 322                         return; // you just dropped it!
 323         kh_Key_Collect(self, other);
 324 }
 325
 326 void kh_Key_Think()
 327 {
 328         entity head;
 329
 330         self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 331
 332         if(self.owner)
 333         {
 334                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 335                 setorigin(self, v_forward * 16);
 336
 337                 if(self.owner.buttonuse)
 338                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 339                 {
 340                         self.owner.kh_droptime = time;
 341                         self.kh_droptime = time; // prevent collecting this one for some time
 342                         self.enemy = self.owner;
 343                         self.pusher = world;
 344                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 345                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 346                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 347                         kh_Key_AssignTo(self, world, TRUE);
 348                 }
 349         }
 350
 351         // if in nodrop or time over, end the round
 352         if(!self.owner)
 353                 if(time > self.pain_finished)
 354                         kh_LoserTeam(self.team, self);
 355
 356         if(self.owner)
 357         if(kh_Key_AllOwnedByWhichTeam() != -1)
 358         {
 359                 entity key;
 360                 vector p;
 361                 p = self.owner.origin;
 362                 FOR_EACH_KH_KEY(key)
 363                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 364                                 goto not_winning;
 365                 kh_WinnerTeam(self.team);
 366 :not_winning
 367         }
 368
 369         if(kh_interferemsg_time && time > kh_interferemsg_time)
 370         {
 371                 kh_interferemsg_time = 0;
 372                 FOR_EACH_PLAYER(head)
 373                 {
 374                         if(head.team == kh_interferemsg_team)
 375                                 if(head.kh_next)
 376                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 377                                 else
 378                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 379                         else
 380                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 381                 }
 382         }
 383
 384         self.nextthink = time + 0.05;
 385 }
 386
 387 void kh_WinnerTeam(float teem)
 388 {
 389         // all key carriers get some points
 390         vector firstorigin, lastorigin;
 391         float first;
 392         entity key;
 393         float score;
 394         score = (kh_teams - 1) / kh_teams;
 395         // twice the score for 3 team games, three times the score for 4 team games!
 396         // note: for a win by destroying the key, this should NOT be applied
 397         first = TRUE;
 398         FOR_EACH_KH_KEY(key)
 399         {
 400                 kh_Scores_Event(key.owner, key, "capture", score, 0);
 401                 if(key.owner.kh_next == key)
 402                 {
 403                         if(!first)
 404                                 bprint("^7, ");
 405                         bprint(key.owner.netname);
 406                         first = FALSE;
 407                 }
 408         }
 409
 410         first = TRUE;
 411         FOR_EACH_KH_KEY(key)
 412         {
 413                 vector thisorigin;
 414
 415                 thisorigin = kh_AttachedOrigin(key);
 416
 417                 if(!first)
 418                         te_lightning2(world, lastorigin, thisorigin);
 419                 lastorigin = thisorigin;
 420                 if(first)
 421                         firstorigin = thisorigin;
 422                 first = FALSE;
 423         }
 424         if(kh_teams > 2)
 425         {
 426                 te_lightning2(world, lastorigin, firstorigin);
 427         }
 428
 429         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 430         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 431         kh_FinishRound();
 432 }
 433
 434 void kh_LoserTeam(float teem, entity lostkey)
 435 {
 436         entity player, key, attacker;
 437         float players;
 438         float keys;
 439         float score;
 440
 441         attacker = world;
 442         if(lostkey.pusher)
 443                 if(lostkey.pusher.team != teem)
 444                         if(lostkey.pusher.classname == "player")
 445                                 attacker = lostkey.pusher;
 446
 447         players = keys = 0;
 448
 449         if(attacker)
 450         {
 451                 kh_Scores_Event(attacker, world, "push", 1, 0);
 452                 centerprint(attacker, "Your push is the best!\n\n\n");
 453                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 454         }
 455         else
 456         {
 457                 FOR_EACH_PLAYER(player)
 458                         if(player.team != teem)
 459                                 ++players;
 460
 461                 FOR_EACH_KH_KEY(key)
 462                         if(key.owner && key.team != teem)
 463                                 ++keys;
 464
 465                 score = 1.0 / max(1, keys * cvar("g_balance_keyhunt_score_destroyed_ownfactor") + players);
 466
 467                 FOR_EACH_PLAYER(player)
 468                         if(player.team != teem)
 469                                 kh_Scores_Event(player, world, "destroyed", score, 0);
 470
 471                 FOR_EACH_KH_KEY(key)
 472                         if(key.owner && key.team != teem)
 473                                 kh_Scores_Event(key.owner, world, "destroyed", score * cvar("g_balance_keyhunt_score_destroyed_ownfactor"), 0);
 474
 475                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 476         }
 477         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 478
 479         kh_FinishRound();
 480 }
 481
 482 void kh_FinishRound()
 483 {
 484         // prepare next round
 485         kh_interferemsg_time = 0;
 486         entity key;
 487         FOR_EACH_KH_KEY(key)
 488                 kh_Key_Remove(key);
 489
 490         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 491 }
 492
 493 float kh_EnoughPlayers()
 494 {
 495         float i, players, teem;
 496         entity player;
 497
 498         // find a random player per team
 499         for(i = 0; i < kh_teams; ++i)
 500         {
 501                 teem = kh_Team_ByID(i);
 502                 players = 0;
 503                 FOR_EACH_PLAYER(player)
 504                         if(player.deadflag == DEAD_NO)
 505                                 if(player.team == teem)
 506                                         ++players;
 507                 if(players == 0)
 508                         return FALSE;
 509         }
 510         return TRUE;
 511 }
 512
 513 void kh_WaitForPlayers()
 514 {
 515         if(kh_EnoughPlayers())
 516                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 517         else
 518                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 519 }
 520
 521 void kh_StartRound()
 522 {
 523         float i, players, teem;
 524         entity player;
 525
 526         if(!kh_EnoughPlayers())
 527         {
 528                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 529                 return;
 530         }
 531
 532         for(i = 0; i < kh_teams; ++i)
 533         {
 534                 teem = kh_Team_ByID(i);
 535                 players = 0;
 536                 entity my_player;
 537                 FOR_EACH_PLAYER(player)
 538                         if(player.deadflag == DEAD_NO)
 539                                 if(player.team == teem)
 540                                 {
 541                                         ++players;
 542                                         if(random() * players <= 1)
 543                                                 my_player = player;
 544                                 }
 545                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 546         }
 547
 548         kh_tracking_enabled = FALSE;
 549         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 550 }
 551
 552 void kh_setstatus()
 553 {
 554         if(kh_teams)
 555         {
 556                 float kh_KEY;
 557                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 558                 if(self.kh_next)
 559                         self.items = self.items | kh_KEY;
 560                 else
 561                         self.items = self.items - (self.items & kh_KEY);
 562         }
 563 }
 564
 565 void kh_EnableTrackingDevice()
 566 {
 567         kh_tracking_enabled = TRUE;
 568 }
 569
 570 float kh_Key_waypointsprite_for_player(entity e)
 571 {
 572         if(!kh_tracking_enabled)
 573                 return 0;
 574         if(!self.owner)
 575                 return kh_sprite_dropped;
 576         if(!self.owner.owner)
 577                 return kh_sprite_dropped;
 578         return 0; // draw only when key is not owned
 579 }
 580
 581 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 582 {
 583         if(e.classname != "player" || self.team != e.team)
 584                 if(!kh_tracking_enabled)
 585                         return 0;
 586
 587         // e is spectator? That's no team mate...
 588         if(e.classname != "player")
 589                 return kh_GetCarrierSprite(self.team, -1);
 590
 591         // e is no key carrier: simple case...
 592         if(!e.kh_next)
 593                 return kh_GetCarrierSprite(self.team, e.team);
 594
 595         // e is a key carrier: if any key is dropped or owned by another team, show
 596         // the carrier sprite; otherwise show run here
 597         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 598                 return kh_sprite_finish;
 599
 600         return kh_GetCarrierSprite(self.team, e.team);
 601 }
 602
 603 float kh_HandleFrags(entity attacker, entity targ, float f)
 604 {
 605         float newfrags;
 606
 607         if(f <= 0)
 608                 return f;
 609         if(attacker == targ)
 610                 return f;
 611
 612         if(targ.kh_next)
 613                 f = f - 1 + cvar("g_balance_keyhunt_score_carrierfrag");
 614
 615         if(newfrags)
 616                 f = f - 1 + newfrags;
 617         return f;
 618 }
 619
 620 void kh_init()
 621 {
 622         precache_sound(kh_sound_capture);
 623         precache_sound(kh_sound_destroy);
 624         precache_sound(kh_sound_drop);
 625         precache_sound(kh_sound_collect);
 626
 627         precache_model("models/sprites/key-dropped.sp2");
 628         precache_model("models/sprites/keycarrier-finish.sp2");
 629         precache_model("models/sprites/keycarrier-friend.sp2");
 630         precache_model("models/sprites/keycarrier-red.sp2");
 631         precache_model("models/sprites/keycarrier-blue.sp2");
 632         precache_model("models/sprites/keycarrier-pink.sp2");
 633         precache_model("models/sprites/keycarrier-yellow.sp2");
 634         precache_model("models/keyhunt/key3.md3");
 635
 636         // setup variables
 637         kh_teams = cvar("g_keyhunt_teams_override");
 638         if(kh_teams < 2)
 639                 kh_teams = cvar("g_keyhunt_teams");
 640         if(kh_teams < 2)
 641                 kh_teams = 2;
 642
 643         // make a KH entity for controlling the game
 644         kh_controller = spawn();
 645         kh_controller.think = kh_Controller_Think;
 646         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 647
 648         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 649         kh_sprite_dropped = kh_controller.modelindex;
 650         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 651         kh_sprite_finish = kh_controller.modelindex;
 652         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 653         kh_sprite_friend = kh_controller.modelindex;
 654         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 655         kh_sprite_red = kh_controller.modelindex;
 656         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 657         kh_sprite_blue = kh_controller.modelindex;
 658         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 659         kh_sprite_pink = kh_controller.modelindex;
 660         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 661         kh_sprite_yellow = kh_controller.modelindex;
 662         setmodel(kh_controller, "");
 663 }
 664
 665 void kh_finalize()
 666 {
 667         // to be called before intermission
 668         kh_FinishRound();
 669         remove(kh_controller);
 670         kh_controller = world;
 671 }