data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 // #define KH_PLAYER_USE_ATTACHMENT
   5 // #define KH_PLAYER_USE_CARRIEDMODEL
   6 // #define KH_KEY_ATTACHMENT_DEBUG
   7
   8 #ifdef KH_PLAYER_USE_ATTACHMENT
   9 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  10 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  11 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  12 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  13 string KH_PLAYER_ATTACHMENT_BONE = "";
  14 #else
  15 float KH_KEY_ZSHIFT = 22;
  16 float KH_KEY_XYDIST = 24;
  17 float KH_KEY_XYSPEED = 45;
  18 #endif
  19 float KH_KEY_WP_ZSHIFT = 20;
  20
  21 vector KH_KEY_MIN = '-10 -10 -46';
  22 vector KH_KEY_MAX = '10 10 3';
  23 float KH_KEY_BRIGHTNESS = 4;
  24
  25 typedef void(void) kh_Think_t;
  26 var kh_Think_t kh_Controller_Thinkfunc;
  27 string kh_Controller_Waitmsg;
  28
  29 float kh_Team_ByID(float t)
  30 {
  31         if(t == 0) return COLOR_TEAM1;
  32         if(t == 1) return COLOR_TEAM2;
  33         if(t == 2) return COLOR_TEAM3;
  34         if(t == 3) return COLOR_TEAM4;
  35         return 0;
  36 }
  37
  38 entity kh_controller;
  39 float kh_tracking_enabled;
  40 float kh_teams;
  41 float kh_interferemsg_time, kh_interferemsg_team;
  42 .entity kh_next, kh_prev; // linked list
  43 .float kh_droptime;
  44 .float kh_dropperteam;
  45
  46 string kh_sound_capture = "sound/ctf/capture.wav";
  47 string kh_sound_destroy = "sound/ctf/return.wav";
  48 string kh_sound_drop = "sound/misc/mouseclick.wav";
  49 string kh_sound_collect = "sound/ctf/take.wav";
  50
  51 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  52 float kh_key_dropped, kh_key_carried;
  53
  54 float kh_GetCarrierSprite(float t, float e)
  55 {
  56         if(t == e)           return kh_sprite_friend;
  57         if(t == COLOR_TEAM1) return kh_sprite_red;
  58         if(t == COLOR_TEAM2) return kh_sprite_blue;
  59         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  60         if(t == COLOR_TEAM4) return kh_sprite_pink;
  61         return 0;
  62 }
  63
  64 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  65 {
  66         kh_Controller_Thinkfunc = func;
  67         kh_controller.cnt = t;
  68         if(kh_Controller_Waitmsg != "")
  69                 strunzone(kh_Controller_Waitmsg);
  70         if(msg == "")
  71                 kh_Controller_Waitmsg = "";
  72         else
  73                 kh_Controller_Waitmsg = strzone(msg);
  74         if(t == 0)
  75                 kh_controller.nextthink = time; // force
  76 }
  77
  78 void kh_Controller_Think()
  79 {
  80         entity e;
  81         if(intermission_running)
  82                 return;
  83         if(self.cnt > 0)
  84         {
  85                 if(kh_Controller_Waitmsg != "")
  86                 {
  87                         string s;
  88                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  89                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  90                         else
  91                                 s = kh_Controller_Waitmsg;
  92
  93                         //dprint(s, "\n");
  94
  95                         FOR_EACH_PLAYER(e)
  96                                 if(clienttype(e) == CLIENTTYPE_REAL)
  97                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  98                 }
  99                 self.cnt -= 1;
 100         }
 101         else if(self.cnt == 0)
 102         {
 103                 self.cnt -= 1;
 104                 kh_Controller_Thinkfunc();
 105         }
 106         self.nextthink = time + 1;
 107 }
 108
 109 // frags f: take from cvar * f
 110 // frags 0: no frags
 111 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 112 {
 113         string s;
 114         if(intermission_running)
 115                 return;
 116         if(frags_player)
 117                 player.frags = player.frags + floor(0.5 + frags_player);
 118         if(frags_owner)
 119                 key.owner.frags = key.owner.frags + floor(0.5 + frags_owner);
 120         if(!cvar("sv_eventlog"))
 121                 return;
 122         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 123         s = strcat(s, ":", ftos(frags_player));
 124         if(key && key.owner)
 125                 s = strcat(s, ":", ftos(key.owner.playerid));
 126         else
 127                 s = strcat(s, ":0");
 128         s = strcat(s, ":", ftos(frags_owner), ":");
 129         if(key)
 130                 s = strcat(s, key.netname);
 131         GameLogEcho(s, FALSE);
 132 }
 133
 134 vector kh_AttachedOrigin(entity e)
 135 {
 136         if(e.tag_entity)
 137         {
 138                 makevectors(e.tag_entity.angles);
 139                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 140         }
 141         else
 142                 return e.origin;
 143 }
 144
 145 void kh_Key_Attach(entity key)
 146 {
 147 #ifdef KH_PLAYER_USE_ATTACHMENT
 148         entity first;
 149         first = key.owner.kh_next;
 150         if(key == first)
 151         {
 152                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 153                 if(key.kh_next)
 154                 {
 155                         setattachment(key.kh_next, key, "");
 156                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 157                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 158                         key.kh_next.angles = '0 0 0';
 159                 }
 160                 else
 161                         setorigin(key, KH_PLAYER_ATTACHMENT);
 162                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 163         }
 164         else
 165         {
 166                 setattachment(key, key.kh_prev, "");
 167                 if(key.kh_next)
 168                         setattachment(key.kh_next, key, "");
 169                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 170                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 171                 key.angles = '0 0 0';
 172         }
 173 #else
 174         setattachment(key, key.owner, "");
 175         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 176         key.angles_y -= key.owner.angles_y;
 177 #endif
 178         key.flags = 0;
 179         key.solid = SOLID_NOT;
 180         key.movetype = MOVETYPE_NONE;
 181         key.team = key.owner.team;
 182         key.nextthink = time;
 183         key.damageforcescale = 0;
 184         key.modelindex = kh_key_carried;
 185 }
 186
 187 void kh_Key_Detach(entity key)
 188 {
 189 #ifdef KH_PLAYER_USE_ATTACHMENT
 190         entity first;
 191         first = key.owner.kh_next;
 192         if(key == first)
 193         {
 194                 if(key.kh_next)
 195                 {
 196                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 197                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 198                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 199                 }
 200         }
 201         else
 202         {
 203                 if(key.kh_next)
 204                         setattachment(key.kh_next, key.kh_prev, "");
 205                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 206         }
 207         // in any case:
 208         setattachment(key, world, "");
 209         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 210         key.angles = key.owner.angles;
 211 #else
 212         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 213         setattachment(key, world, "");
 214         key.angles_y += key.owner.angles_y;
 215 #endif
 216         key.aiment = world;
 217         key.flags = FL_ITEM;
 218         key.solid = SOLID_TRIGGER;
 219         key.movetype = MOVETYPE_TOSS;
 220         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 221         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 222         // let key.team stay
 223         key.modelindex = kh_key_dropped;
 224 }
 225
 226 void kh_Key_AssignTo(entity key, entity player)
 227 {
 228         if(key.owner == player)
 229                 return;
 230
 231         if(key.owner)
 232         {
 233                 kh_Key_Detach(key);
 234
 235                 // remove from linked list
 236                 if(key.kh_next)
 237                         key.kh_next.kh_prev = key.kh_prev;
 238                 key.kh_prev.kh_next = key.kh_next;
 239                 key.kh_next = world;
 240                 key.kh_prev = world;
 241
 242                 if(key.owner.kh_next == world)
 243                 {
 244                         // No longer a key carrier
 245                         WaypointSprite_DetachCarrier(key.owner);
 246                 }
 247         }
 248
 249         key.owner = player;
 250
 251         if(player)
 252         {
 253                 // insert into linked list
 254                 key.kh_next = player.kh_next;
 255                 key.kh_prev = player;
 256                 player.kh_next = key;
 257                 if(key.kh_next)
 258                         key.kh_next.kh_prev = key;
 259
 260                 kh_Key_Attach(key);
 261
 262                 if(key.kh_next == world)
 263                 {
 264                         // player is now a key carrier
 265                         WaypointSprite_AttachCarrier("", player);
 266                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 267                         player.waypointsprite_attachedforcarrier.team = player.team;
 268                 }
 269         }
 270
 271         key.pusher = world;
 272 }
 273
 274 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 275 {
 276         if(self.owner)
 277                 return;
 278         if(vlen(force) <= 0)
 279                 return;
 280         if(time > self.pushltime)
 281                 if(attacker.classname == "player")
 282                         self.team = attacker.team;
 283 }
 284
 285 vector kh_TeamColor(float teem)
 286 {
 287         switch(teem)
 288         {
 289                 case COLOR_TEAM1:
 290                         //return '103 0 0' / 255.0;
 291                         return '0.4039 0.0000 0.0000';
 292                 case COLOR_TEAM2:
 293                         //return '35 35 191' / 255.0;
 294                         return '0.1373 0.1373 0.7490';
 295                 case COLOR_TEAM3:
 296                         //return '187 167 15' / 255.0;
 297                         return '0.7333 0.6549 0.0588';
 298                 case COLOR_TEAM4:
 299                         //return '139 79 107' / 255.0;
 300                         return '0.5451 0.3099 0.4196';
 301                 default:
 302                         return '1 1 1';
 303         }
 304 }
 305
 306 void kh_Key_Spawn(entity initial_owner, float angle)
 307 {
 308         entity key;
 309         key = spawn();
 310         key.classname = STR_ITEM_KH_KEY;
 311         key.touch = kh_Key_Touch;
 312         key.think = kh_Key_Think;
 313         key.nextthink = time;
 314         key.items = IT_KEY1 | IT_KEY2;
 315         key.cnt = angle;
 316         key.angles = '0 360 0' * random();
 317         key.event_damage = kh_Key_Damage;
 318         key.modelindex = kh_key_dropped;
 319         key.model = "key";
 320         key.kh_dropperteam = 0;
 321         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 322         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 323         key.colormod = kh_TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 324
 325         switch(initial_owner.team)
 326         {
 327                 case COLOR_TEAM1:
 328                         key.netname = "^1red key";
 329                         break;
 330                 case COLOR_TEAM2:
 331                         key.netname = "^4blue key";
 332                         break;
 333                 case COLOR_TEAM3:
 334                         key.netname = "^3yellow key";
 335                         break;
 336                 case COLOR_TEAM4:
 337                         key.netname = "^6pink key";
 338                         break;
 339                 default:
 340                         key.netname = "NETGIER key";
 341                         break;
 342         }
 343
 344         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 345
 346         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 347         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 348
 349         kh_Key_AssignTo(key, initial_owner);
 350 }
 351
 352 void kh_Key_Remove(entity key)
 353 {
 354         entity o;
 355         o = key.owner;
 356         kh_Key_AssignTo(key, world);
 357         if(o) // it was attached
 358                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 359         else // it was dropped
 360                 WaypointSprite_DetachCarrier(key);
 361
 362         remove(key);
 363 }
 364
 365 // -1 when no team completely owns all keys yet
 366 float kh_Key_AllOwnedByWhichTeam()
 367 {
 368         entity key;
 369         float teem;
 370
 371         teem = -1;
 372         FOR_EACH_KH_KEY(key)
 373         {
 374                 if(!key.owner)
 375                         return -1;
 376                 if(teem == -1)
 377                         teem = key.team;
 378                 else if(teem != key.team)
 379                         return -1;
 380         }
 381         return teem;
 382 }
 383
 384 void kh_Key_Collect(entity key, entity player)
 385 {
 386         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 387
 388         if(key.kh_dropperteam != player.team)
 389                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 390         key.kh_dropperteam = 0;
 391         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 392         kh_Key_AssignTo(key, player);
 393
 394         if(kh_Key_AllOwnedByWhichTeam() != -1)
 395         {
 396                 kh_interferemsg_time = time + 0.2;
 397                 kh_interferemsg_team = player.team;
 398         }
 399 }
 400
 401 void kh_Key_DropAll(entity player, float suicide)
 402 {
 403         entity key;
 404         entity mypusher;
 405         if(player.kh_next)
 406         {
 407                 mypusher = world;
 408                 if(player.pusher)
 409                         if(time < player.pushltime)
 410                                 mypusher = player.pusher;
 411                 while((key = player.kh_next))
 412                 {
 413                         kh_Scores_Event(player, key, "losekey", 0, 0);
 414                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 415                         kh_Key_AssignTo(key, world);
 416                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 417                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 418                         key.pusher = mypusher;
 419                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 420                         if(suicide)
 421                                 key.kh_dropperteam = player.team;
 422                 }
 423                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 424         }
 425 }
 426
 427 void kh_Key_Touch()
 428 {
 429         if(intermission_running)
 430                 return;
 431
 432         if(self.owner) // already carried
 433                 return;
 434         if(other.classname != "player")
 435                 return;
 436         if(other.deadflag != DEAD_NO)
 437                 return;
 438         if(other == self.enemy)
 439                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 440                         return; // you just dropped it!
 441         kh_Key_Collect(self, other);
 442 }
 443
 444 void kh_Key_Think()
 445 {
 446         entity head;
 447
 448         if(intermission_running)
 449                 return;
 450
 451 #ifdef KH_KEY_ATTACHMENT_DEBUG
 452         if(self.kh_prev == self.owner)
 453         {
 454                 if(cvar_string("_angles") != "")
 455                 {
 456                         self.angles = stov(cvar_string("_angles"));
 457                         self.origin = stov(cvar_string("_origin"));
 458                 }
 459         }
 460 #endif
 461
 462         if(self.owner)
 463         {
 464 #ifndef KH_PLAYER_USE_ATTACHMENT
 465                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * KH_KEY_XYSPEED));
 466                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 467 #endif
 468
 469                 if(self.owner.buttonuse)
 470                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 471                 {
 472                         self.owner.kh_droptime = time;
 473                         self.kh_droptime = time; // prevent collecting this one for some time
 474                         self.enemy = self.owner;
 475                         self.pusher = world;
 476                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 477                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 478                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 479                         makevectors(self.owner.v_angle);
 480                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 481                         kh_Key_AssignTo(self, world);
 482                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 483                         self.kh_dropperteam = self.team;
 484                 }
 485         }
 486
 487         // if in nodrop or time over, end the round
 488         if(!self.owner)
 489                 if(time > self.pain_finished)
 490                         kh_LoserTeam(self.team, self);
 491
 492         if(self.owner)
 493         if(kh_Key_AllOwnedByWhichTeam() != -1)
 494         {
 495                 entity key;
 496                 vector p;
 497                 p = self.owner.origin;
 498                 FOR_EACH_KH_KEY(key)
 499                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 500                                 goto not_winning;
 501                 kh_WinnerTeam(self.team);
 502 :not_winning
 503         }
 504
 505         if(kh_interferemsg_time && time > kh_interferemsg_time)
 506         {
 507                 kh_interferemsg_time = 0;
 508                 FOR_EACH_PLAYER(head)
 509                 {
 510                         if(head.team == kh_interferemsg_team)
 511                                 if(head.kh_next)
 512                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 513                                 else
 514                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 515                         else
 516                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 517                 }
 518         }
 519
 520         self.nextthink = time + 0.05;
 521 }
 522
 523 void kh_WinnerTeam(float teem)
 524 {
 525         // all key carriers get some points
 526         vector firstorigin, lastorigin, midpoint;
 527         float first;
 528         entity key;
 529         float score;
 530         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 531         DistributeEvenly_Init(score, kh_teams);
 532         // twice the score for 3 team games, three times the score for 4 team games!
 533         // note: for a win by destroying the key, this should NOT be applied
 534         FOR_EACH_KH_KEY(key)
 535                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 536
 537         first = TRUE;
 538         FOR_EACH_KH_KEY(key)
 539                 if(key.owner.kh_next == key)
 540                 {
 541                         if(!first)
 542                                 bprint("^7, ");
 543                         bprint(key.owner.netname);
 544                         first = FALSE;
 545                 }
 546         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 547
 548         first = TRUE;
 549         midpoint = '0 0 0';
 550         FOR_EACH_KH_KEY(key)
 551         {
 552                 vector thisorigin;
 553
 554                 thisorigin = kh_AttachedOrigin(key);
 555                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 556                 midpoint += thisorigin;
 557
 558                 if(!first)
 559                         te_lightning2(world, lastorigin, thisorigin);
 560                 lastorigin = thisorigin;
 561                 if(first)
 562                         firstorigin = thisorigin;
 563                 first = FALSE;
 564         }
 565         if(kh_teams > 2)
 566         {
 567                 te_lightning2(world, lastorigin, firstorigin);
 568         }
 569         midpoint = midpoint * (1 / kh_teams);
 570         te_customflash(midpoint, 1000, 1, kh_TeamColor(teem) * 0.5 + '0.5 0.5 0.5'); // make the color >=0.5 in each component
 571
 572         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 573         kh_FinishRound();
 574 }
 575
 576 void kh_LoserTeam(float teem, entity lostkey)
 577 {
 578         entity player, key, attacker;
 579         float players;
 580         float keys;
 581
 582         attacker = world;
 583         if(lostkey.pusher)
 584                 if(lostkey.pusher.team != teem)
 585                         if(lostkey.pusher.classname == "player")
 586                                 attacker = lostkey.pusher;
 587
 588         players = keys = 0;
 589
 590         if(attacker)
 591         {
 592                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 593                 centerprint(attacker, "Your push is the best!\n\n\n");
 594                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 595         }
 596         else
 597         {
 598                 float of, fragsleft, i, j, thisteam;
 599                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 600
 601                 FOR_EACH_PLAYER(player)
 602                         if(player.team != teem)
 603                                 ++players;
 604
 605                 FOR_EACH_KH_KEY(key)
 606                         if(key.owner && key.team != teem)
 607                                 ++keys;
 608
 609                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 610
 611                 FOR_EACH_KH_KEY(key)
 612                         if(key.owner && key.team != teem)
 613                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 614
 615                 fragsleft = DistributeEvenly_Get(players);
 616
 617                 // Now distribute these among all other teams...
 618                 j = kh_teams - 1;
 619                 for(i = 0; i < kh_teams; ++i)
 620                 {
 621                         thisteam = kh_Team_ByID(i);
 622                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 623                                 continue;
 624
 625                         players = 0;
 626                         FOR_EACH_PLAYER(player)
 627                                 if(player.team == thisteam)
 628                                         ++players;
 629
 630                         DistributeEvenly_Init(fragsleft, j);
 631                         fragsleft = DistributeEvenly_Get(j - 1);
 632                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 633
 634                         FOR_EACH_PLAYER(player)
 635                                 if(player.team == thisteam)
 636                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 637
 638                         --j;
 639                 }
 640
 641                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 642         }
 643         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 644         te_tarexplosion(lostkey.origin);
 645
 646         kh_FinishRound();
 647 }
 648
 649 void kh_FinishRound()
 650 {
 651         // prepare next round
 652         kh_interferemsg_time = 0;
 653         entity key;
 654         FOR_EACH_KH_KEY(key)
 655                 kh_Key_Remove(key);
 656
 657         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 658 }
 659
 660 string kh_CheckEnoughPlayers()
 661 {
 662         float i, players, teem;
 663         entity player;
 664         string result;
 665         result = "";
 666
 667         // find a random player per team
 668         for(i = 0; i < kh_teams; ++i)
 669         {
 670                 teem = kh_Team_ByID(i);
 671                 players = 0;
 672                 FOR_EACH_PLAYER(player)
 673                         if(player.deadflag == DEAD_NO)
 674                                 if(!player.buttonchat)
 675                                         if(player.team == teem)
 676                                                 ++players;
 677                 if(players == 0)
 678                 {
 679                         if(result != "")
 680                                 result = strcat(result, ", ");
 681                         result = strcat(result, ColoredTeamName(teem));
 682                 }
 683         }
 684         return result;
 685 }
 686
 687 void kh_WaitForPlayers()
 688 {
 689         string teams_missing;
 690         teams_missing = kh_CheckEnoughPlayers();
 691         if(teams_missing == "")
 692                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 693         else
 694                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 695 }
 696
 697 void kh_StartRound()
 698 {
 699         string teams_missing;
 700         float i, players, teem;
 701         entity player;
 702
 703         teams_missing = kh_CheckEnoughPlayers();
 704         if(teams_missing != "")
 705         {
 706                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 707                 return;
 708         }
 709
 710         FOR_EACH_PLAYER(player)
 711                 if(clienttype(player) == CLIENTTYPE_REAL)
 712                         centerprint_expire(player, CENTERPRIO_SPAM);
 713
 714         for(i = 0; i < kh_teams; ++i)
 715         {
 716                 teem = kh_Team_ByID(i);
 717                 players = 0;
 718                 entity my_player;
 719                 FOR_EACH_PLAYER(player)
 720                         if(player.deadflag == DEAD_NO)
 721                                 if(!player.buttonchat)
 722                                         if(player.team == teem)
 723                                         {
 724                                                 ++players;
 725                                                 if(random() * players <= 1)
 726                                                         my_player = player;
 727                                         }
 728                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 729                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 730                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 731         }
 732
 733         kh_tracking_enabled = FALSE;
 734         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 735 }
 736
 737 void kh_setstatus()
 738 {
 739         if(kh_teams)
 740         {
 741                 float kh_KEY;
 742                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 743                 if(self.kh_next)
 744                         self.items = self.items | kh_KEY;
 745                 else
 746                         self.items = self.items - (self.items & kh_KEY);
 747         }
 748 }
 749
 750 void kh_EnableTrackingDevice()
 751 {
 752         entity player;
 753
 754         FOR_EACH_PLAYER(player)
 755                 if(clienttype(player) == CLIENTTYPE_REAL)
 756                         centerprint_expire(player, CENTERPRIO_SPAM);
 757
 758         kh_tracking_enabled = TRUE;
 759 }
 760
 761 float kh_Key_waypointsprite_for_player(entity e)
 762 {
 763         if(!kh_tracking_enabled)
 764                 return 0;
 765         if(!self.owner)
 766                 return kh_sprite_dropped;
 767         if(!self.owner.owner)
 768                 return kh_sprite_dropped;
 769         return 0; // draw only when key is not owned
 770 }
 771
 772 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 773 {
 774         if(e.classname != "player" || self.team != e.team)
 775                 if(!kh_tracking_enabled)
 776                         return 0;
 777
 778         // e is spectator? That's no team mate...
 779         if(e.classname != "player")
 780                 return kh_GetCarrierSprite(self.team, -1);
 781
 782         // e is no key carrier: simple case...
 783         if(!e.kh_next)
 784                 return kh_GetCarrierSprite(self.team, e.team);
 785
 786         // e is a key carrier: if any key is dropped or owned by another team, show
 787         // the carrier sprite; otherwise show run here
 788         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 789                 return kh_sprite_finish;
 790
 791         return kh_GetCarrierSprite(self.team, e.team);
 792 }
 793
 794 float kh_HandleFrags(entity attacker, entity targ, float f)
 795 {
 796         if(attacker == targ)
 797                 return f;
 798
 799         if(targ.kh_next)
 800         {
 801                 if(attacker.team == targ.team)
 802                 {
 803                         entity k;
 804                         float nk;
 805                         nk = 0;
 806                         for(k = targ.kh_next; k != world; k = k.kh_next)
 807                                 ++nk;
 808                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 809                 }
 810                 else
 811                 {
 812                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 813                 }
 814         }
 815
 816         return f;
 817 }
 818
 819 void kh_init()
 820 {
 821         precache_sound(kh_sound_capture);
 822         precache_sound(kh_sound_destroy);
 823         precache_sound(kh_sound_drop);
 824         precache_sound(kh_sound_collect);
 825
 826         precache_model("models/sprites/key-dropped.sp2");
 827         precache_model("models/sprites/keycarrier-finish.sp2");
 828         precache_model("models/sprites/keycarrier-friend.sp2");
 829         precache_model("models/sprites/keycarrier-red.sp2");
 830         precache_model("models/sprites/keycarrier-blue.sp2");
 831         precache_model("models/sprites/keycarrier-yellow.sp2");
 832         precache_model("models/sprites/keycarrier-pink.sp2");
 833 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 834         precache_model("models/keyhunt/key-carried.md3");
 835 #endif
 836         precache_model("models/keyhunt/key.md3");
 837
 838         // setup variables
 839         kh_teams = cvar("g_keyhunt_teams_override");
 840         if(kh_teams < 2)
 841                 kh_teams = cvar("g_keyhunt_teams");
 842         kh_teams = bound(2, kh_teams, 4);
 843
 844         // make a KH entity for controlling the game
 845         kh_controller = spawn();
 846         kh_controller.think = kh_Controller_Think;
 847         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 848
 849         setmodel(kh_controller, "models/keyhunt/key.md3");
 850         kh_key_dropped = kh_controller.modelindex;
 851         /*
 852         dprint(vtos(kh_controller.mins));
 853         dprint(vtos(kh_controller.maxs));
 854         dprint("\n");
 855         */
 856 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 857         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 858         kh_key_carried = kh_controller.modelindex;
 859 #else
 860         kh_key_carried = kh_key_dropped;
 861 #endif
 862         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 863         kh_sprite_dropped = kh_controller.modelindex;
 864         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 865         kh_sprite_finish = kh_controller.modelindex;
 866         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 867         kh_sprite_friend = kh_controller.modelindex;
 868         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 869         kh_sprite_red = kh_controller.modelindex;
 870         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 871         kh_sprite_blue = kh_controller.modelindex;
 872         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 873         kh_sprite_pink = kh_controller.modelindex;
 874         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 875         kh_sprite_yellow = kh_controller.modelindex;
 876         setmodel(kh_controller, "");
 877 }
 878
 879 void kh_finalize()
 880 {
 881         // to be called before intermission
 882         kh_FinishRound();
 883         remove(kh_controller);
 884         kh_controller = world;
 885 }