data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/misc/mouseclick.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  37         if(t == COLOR_TEAM4) return kh_sprite_pink;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(intermission_running)
  59                 return;
  60         if(self.cnt > 0)
  61         {
  62                 if(kh_Controller_Waitmsg != "")
  63                 {
  64                         string s;
  65                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  66                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  67                         else
  68                                 s = kh_Controller_Waitmsg;
  69
  70                         dprint(s, "\n");
  71
  72                         FOR_EACH_PLAYER(e)
  73                                 if(clienttype(e) == CLIENTTYPE_REAL)
  74                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  75                 }
  76                 self.cnt -= 1;
  77         }
  78         else if(self.cnt == 0)
  79         {
  80                 self.cnt -= 1;
  81                 kh_Controller_Thinkfunc();
  82         }
  83         self.nextthink = time + 1;
  84 }
  85
  86 // frags f: take from cvar * f
  87 // frags 0: no frags
  88 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
  89 {
  90         string s;
  91         if(frags_player)
  92                 player.frags = player.frags + floor(0.5 + frags_player);
  93         if(frags_owner)
  94                 key.owner.frags = key.owner.frags + floor(0.5 + frags_owner);
  95         if(!cvar("sv_eventlog"))
  96                 return;
  97         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
  98         s = strcat(s, ":", ftos(frags_player));
  99         if(key.owner)
 100                 s = strcat(s, ":", ftos(key.owner.playerid));
 101         else
 102                 s = strcat(s, ":0");
 103         s = strcat(s, ":", ftos(frags_owner));
 104         s = strcat(s, ":", key.netname);
 105         GameLogEcho(s, FALSE);
 106 }
 107
 108 void kh_Key_Attach(entity key)
 109 {
 110         setattachment(key, key.owner, "");
 111         setorigin(key, '0 0 -15'); // x/y fixed later in think, z has to be -15 to make the key fit even in the crouchbox
 112         key.angles_y -= key.owner.angles_y;
 113         key.flags = 0;
 114         key.solid = SOLID_NOT;
 115         key.movetype = MOVETYPE_NONE;
 116         key.team = key.owner.team;
 117         key.nextthink = time;
 118         key.damageforcescale = 0;
 119 }
 120
 121 vector kh_AttachedOrigin(entity e)
 122 {
 123         if(e.tag_entity)
 124         {
 125                 makevectors(e.tag_entity.angles);
 126                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 127         }
 128         else
 129                 return e.origin;
 130 }
 131
 132 void kh_Key_Detach(entity key)
 133 {
 134         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 135         setattachment(key, world, "");
 136         key.angles_y += key.owner.angles_y;
 137         key.aiment = world;
 138         key.flags = FL_ITEM;
 139         key.solid = SOLID_TRIGGER;
 140         key.movetype = MOVETYPE_TOSS;
 141         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 142         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 143         // let key.team stay
 144 }
 145
 146 void kh_Key_AssignTo(entity key, entity player)
 147 {
 148         if(key.owner == player)
 149                 return;
 150
 151         if(key.owner)
 152         {
 153                 kh_Key_Detach(key);
 154
 155                 // remove from linked list
 156                 if(key.kh_next)
 157                         key.kh_next.kh_prev = key.kh_prev;
 158                 key.kh_prev.kh_next = key.kh_next;
 159                 key.kh_next = world;
 160                 key.kh_prev = world;
 161
 162                 if(key.owner.kh_next == world)
 163                 {
 164                         // No longer a key carrier
 165                         WaypointSprite_DetachCarrier(key.owner);
 166                 }
 167         }
 168
 169         key.owner = player;
 170
 171         if(player)
 172         {
 173                 // insert into linked list
 174                 key.kh_next = player.kh_next;
 175                 key.kh_prev = player;
 176                 player.kh_next = key;
 177                 if(key.kh_next)
 178                         key.kh_next.kh_prev = key;
 179
 180                 kh_Key_Attach(key);
 181
 182                 if(key.kh_next == world)
 183                 {
 184                         // player is now a key carrier
 185                         WaypointSprite_AttachCarrier("", player);
 186                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 187                         player.waypointsprite_attachedforcarrier.team = player.team;
 188                 }
 189         }
 190
 191         key.pusher = world;
 192 }
 193
 194 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 195 {
 196         if(self.owner)
 197                 return;
 198         if(vlen(force) <= 0)
 199                 return;
 200         if(time > self.pushltime)
 201                 if(attacker.classname == "player")
 202                         self.team = attacker.team;
 203 }
 204
 205 void kh_Key_Spawn(entity initial_owner, float angle)
 206 {
 207         entity key;
 208         key = spawn();
 209         key.classname = STR_ITEM_KH_KEY;
 210         key.touch = kh_Key_Touch;
 211         key.think = kh_Key_Think;
 212         key.nextthink = time;
 213         key.items = IT_KEY1 | IT_KEY2;
 214         key.cnt = angle;
 215         key.angles = '0 360 0' * random();
 216         key.event_damage = kh_Key_Damage;
 217         setmodel(key, "models/keyhunt/key.md3");
 218         setsize(key, '-8 -8 -8', '8 8 40');
 219
 220         switch(initial_owner.team)
 221         {
 222                 case COLOR_TEAM1:
 223                         key.netname = "^1red key";
 224                         key.colormod = '103 0 0' * (1/96);
 225                         break;
 226                 case COLOR_TEAM2:
 227                         key.netname = "^4blue key";
 228                         key.colormod = '35 35 191' * (1/96);
 229                         break;
 230                 case COLOR_TEAM3:
 231                         key.netname = "^3yellow key";
 232                         key.colormod = '187 167 15' * (1/96);
 233                         break;
 234                 case COLOR_TEAM4:
 235                         key.netname = "^6pink key";
 236                         key.colormod = '139 79 107' * (1/96);
 237                         break;
 238                 default:
 239                         key.netname = "NETGIER key";
 240                         key.colormod = '1 1 1';
 241                         break;
 242         }
 243
 244         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 245
 246         WaypointSprite_AttachCarrier("", key);
 247         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 248
 249         kh_Key_AssignTo(key, initial_owner);
 250 }
 251
 252 void kh_Key_Remove(entity key)
 253 {
 254         entity o;
 255         o = key.owner;
 256         kh_Key_AssignTo(key, world);
 257         if(o) // it was attached
 258                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 259         else // it was dropped
 260                 WaypointSprite_DetachCarrier(key);
 261
 262         remove(key);
 263 }
 264
 265 // -1 when no team completely owns all keys yet
 266 float kh_Key_AllOwnedByWhichTeam()
 267 {
 268         entity key;
 269         float teem;
 270
 271         teem = -1;
 272         FOR_EACH_KH_KEY(key)
 273         {
 274                 if(!key.owner)
 275                         return -1;
 276                 if(teem == -1)
 277                         teem = key.team;
 278                 else if(teem != key.team)
 279                         return -1;
 280         }
 281         return teem;
 282 }
 283
 284 void kh_Key_Collect(entity key, entity player)
 285 {
 286         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 287
 288         kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 289         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 290         kh_Key_AssignTo(key, player);
 291
 292         if(kh_Key_AllOwnedByWhichTeam() != -1)
 293         {
 294                 kh_interferemsg_time = time + 0.2;
 295                 kh_interferemsg_team = player.team;
 296         }
 297 }
 298
 299 void kh_Key_DropAll(entity player)
 300 {
 301         entity key;
 302         entity mypusher;
 303         if(player.kh_next)
 304         {
 305                 mypusher = world;
 306                 if(player.pusher)
 307                         if(time < player.pushltime)
 308                                 mypusher = player.pusher;
 309                 while((key = player.kh_next))
 310                 {
 311                         kh_Scores_Event(player, key, "losekey", 0, 0);
 312                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 313                         kh_Key_AssignTo(key, world);
 314                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 315                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 316                         key.pusher = mypusher;
 317                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 318                 }
 319                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 320         }
 321 }
 322
 323 void kh_Key_Touch()
 324 {
 325         if(self.owner) // already carried
 326                 return;
 327         if(other.classname != "player")
 328                 return;
 329         if(other.deadflag != DEAD_NO)
 330                 return;
 331         if(other == self.enemy)
 332                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 333                         return; // you just dropped it!
 334         kh_Key_Collect(self, other);
 335 }
 336
 337 void kh_Key_Think()
 338 {
 339         entity head;
 340
 341         //self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 342         // model is EF_ROTATING now
 343
 344         if(self.owner)
 345         {
 346                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 347                 setorigin(self, v_forward * 24 + '0 0 1' * self.origin_z);
 348
 349                 if(self.owner.buttonuse)
 350                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 351                 {
 352                         self.owner.kh_droptime = time;
 353                         self.kh_droptime = time; // prevent collecting this one for some time
 354                         self.enemy = self.owner;
 355                         self.pusher = world;
 356                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 357                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 358                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 359                         makevectors(self.owner.v_angle);
 360                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 361                         kh_Key_AssignTo(self, world);
 362                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 363                 }
 364         }
 365
 366         // if in nodrop or time over, end the round
 367         if(!self.owner)
 368                 if(time > self.pain_finished)
 369                         kh_LoserTeam(self.team, self);
 370
 371         if(self.owner)
 372         if(kh_Key_AllOwnedByWhichTeam() != -1)
 373         {
 374                 entity key;
 375                 vector p;
 376                 p = self.owner.origin;
 377                 FOR_EACH_KH_KEY(key)
 378                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 379                                 goto not_winning;
 380                 kh_WinnerTeam(self.team);
 381 :not_winning
 382         }
 383
 384         if(kh_interferemsg_time && time > kh_interferemsg_time)
 385         {
 386                 kh_interferemsg_time = 0;
 387                 FOR_EACH_PLAYER(head)
 388                 {
 389                         if(head.team == kh_interferemsg_team)
 390                                 if(head.kh_next)
 391                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 392                                 else
 393                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 394                         else
 395                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 396                 }
 397         }
 398
 399         self.nextthink = time + 0.05;
 400 }
 401
 402 void kh_WinnerTeam(float teem)
 403 {
 404         // all key carriers get some points
 405         vector firstorigin, lastorigin;
 406         float first;
 407         entity key;
 408         float score;
 409         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 410         DistributeEvenly_Init(score, kh_teams);
 411         // twice the score for 3 team games, three times the score for 4 team games!
 412         // note: for a win by destroying the key, this should NOT be applied
 413         first = TRUE;
 414         FOR_EACH_KH_KEY(key)
 415         {
 416                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 417                 if(key.owner.kh_next == key)
 418                 {
 419                         if(!first)
 420                                 bprint("^7, ");
 421                         bprint(key.owner.netname);
 422                         first = FALSE;
 423                 }
 424         }
 425
 426         first = TRUE;
 427         FOR_EACH_KH_KEY(key)
 428         {
 429                 vector thisorigin;
 430
 431                 thisorigin = kh_AttachedOrigin(key);
 432
 433                 if(!first)
 434                         te_lightning2(world, lastorigin, thisorigin);
 435                 lastorigin = thisorigin;
 436                 if(first)
 437                         firstorigin = thisorigin;
 438                 first = FALSE;
 439         }
 440         if(kh_teams > 2)
 441         {
 442                 te_lightning2(world, lastorigin, firstorigin);
 443         }
 444
 445         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 446         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 447         kh_FinishRound();
 448 }
 449
 450 void kh_LoserTeam(float teem, entity lostkey)
 451 {
 452         entity player, key, attacker;
 453         float players;
 454         float keys;
 455
 456         attacker = world;
 457         if(lostkey.pusher)
 458                 if(lostkey.pusher.team != teem)
 459                         if(lostkey.pusher.classname == "player")
 460                                 attacker = lostkey.pusher;
 461
 462         players = keys = 0;
 463
 464         if(attacker)
 465         {
 466                 kh_Scores_Event(attacker, world, "push", 1, 0);
 467                 centerprint(attacker, "Your push is the best!\n\n\n");
 468                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 469         }
 470         else
 471         {
 472                 float of, fragsleft, i, thisteam;
 473                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 474
 475                 FOR_EACH_PLAYER(player)
 476                         if(player.team != teem)
 477                                 ++players;
 478
 479                 FOR_EACH_KH_KEY(key)
 480                         if(key.owner && key.team != teem)
 481                                 ++keys;
 482
 483                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 484
 485                 FOR_EACH_KH_KEY(key)
 486                         if(key.owner && key.team != teem)
 487                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 488
 489                 fragsleft = DistributeEvenly_Get(players);
 490
 491                 // Now distribute these among all other teams...
 492                 for(i = 0; i < kh_teams; ++i)
 493                 {
 494                         thisteam = kh_Team_ByID(i);
 495                         players = 0;
 496                         FOR_EACH_PLAYER(player)
 497                                 if(player.team == thisteam)
 498                                         ++players;
 499
 500                         DistributeEvenly_Init(fragsleft, kh_teams - i);
 501                         fragsleft = DistributeEvenly_Get(kh_teams - i - 1);
 502                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 503
 504                         FOR_EACH_PLAYER(player)
 505                                 if(player.team == thisteam)
 506                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 507                 }
 508
 509                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 510         }
 511         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 512
 513         kh_FinishRound();
 514 }
 515
 516 void kh_FinishRound()
 517 {
 518         // prepare next round
 519         kh_interferemsg_time = 0;
 520         entity key;
 521         FOR_EACH_KH_KEY(key)
 522                 kh_Key_Remove(key);
 523
 524         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 525 }
 526
 527 float kh_EnoughPlayers()
 528 {
 529         float i, players, teem;
 530         entity player;
 531
 532         // find a random player per team
 533         for(i = 0; i < kh_teams; ++i)
 534         {
 535                 teem = kh_Team_ByID(i);
 536                 players = 0;
 537                 FOR_EACH_PLAYER(player)
 538                         if(player.deadflag == DEAD_NO)
 539                                 if(player.team == teem)
 540                                         ++players;
 541                 if(players == 0)
 542                         return FALSE;
 543         }
 544         return TRUE;
 545 }
 546
 547 void kh_WaitForPlayers()
 548 {
 549         if(kh_EnoughPlayers())
 550                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 551         else
 552                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 553 }
 554
 555 void kh_StartRound()
 556 {
 557         float i, players, teem;
 558         entity player;
 559
 560         if(!kh_EnoughPlayers())
 561         {
 562                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 563                 return;
 564         }
 565
 566         FOR_EACH_PLAYER(player)
 567                 if(clienttype(player) == CLIENTTYPE_REAL)
 568                         centerprint_expire(player, CENTERPRIO_SPAM);
 569
 570         for(i = 0; i < kh_teams; ++i)
 571         {
 572                 teem = kh_Team_ByID(i);
 573                 players = 0;
 574                 entity my_player;
 575                 FOR_EACH_PLAYER(player)
 576                         if(player.deadflag == DEAD_NO)
 577                                 if(player.team == teem)
 578                                 {
 579                                         ++players;
 580                                         if(random() * players <= 1)
 581                                                 my_player = player;
 582                                 }
 583                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 584         }
 585
 586         kh_tracking_enabled = FALSE;
 587         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 588 }
 589
 590 void kh_setstatus()
 591 {
 592         if(kh_teams)
 593         {
 594                 float kh_KEY;
 595                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 596                 if(self.kh_next)
 597                         self.items = self.items | kh_KEY;
 598                 else
 599                         self.items = self.items - (self.items & kh_KEY);
 600         }
 601 }
 602
 603 void kh_EnableTrackingDevice()
 604 {
 605         entity player;
 606
 607         FOR_EACH_PLAYER(player)
 608                 if(clienttype(player) == CLIENTTYPE_REAL)
 609                         centerprint_expire(player, CENTERPRIO_SPAM);
 610
 611         kh_tracking_enabled = TRUE;
 612 }
 613
 614 float kh_Key_waypointsprite_for_player(entity e)
 615 {
 616         if(!kh_tracking_enabled)
 617                 return 0;
 618         if(!self.owner)
 619                 return kh_sprite_dropped;
 620         if(!self.owner.owner)
 621                 return kh_sprite_dropped;
 622         return 0; // draw only when key is not owned
 623 }
 624
 625 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 626 {
 627         if(e.classname != "player" || self.team != e.team)
 628                 if(!kh_tracking_enabled)
 629                         return 0;
 630
 631         // e is spectator? That's no team mate...
 632         if(e.classname != "player")
 633                 return kh_GetCarrierSprite(self.team, -1);
 634
 635         // e is no key carrier: simple case...
 636         if(!e.kh_next)
 637                 return kh_GetCarrierSprite(self.team, e.team);
 638
 639         // e is a key carrier: if any key is dropped or owned by another team, show
 640         // the carrier sprite; otherwise show run here
 641         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 642                 return kh_sprite_finish;
 643
 644         return kh_GetCarrierSprite(self.team, e.team);
 645 }
 646
 647 float kh_HandleFrags(entity attacker, entity targ, float f)
 648 {
 649         if(f <= 0)
 650                 return f;
 651         if(attacker == targ)
 652                 return f;
 653
 654         if(targ.kh_next)
 655                 kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 656
 657         return f;
 658 }
 659
 660 void kh_init()
 661 {
 662         precache_sound(kh_sound_capture);
 663         precache_sound(kh_sound_destroy);
 664         precache_sound(kh_sound_drop);
 665         precache_sound(kh_sound_collect);
 666
 667         precache_model("models/sprites/key-dropped.sp2");
 668         precache_model("models/sprites/keycarrier-finish.sp2");
 669         precache_model("models/sprites/keycarrier-friend.sp2");
 670         precache_model("models/sprites/keycarrier-red.sp2");
 671         precache_model("models/sprites/keycarrier-blue.sp2");
 672         precache_model("models/sprites/keycarrier-yellow.sp2");
 673         precache_model("models/sprites/keycarrier-pink.sp2");
 674         precache_model("models/keyhunt/key.md3");
 675
 676         // setup variables
 677         kh_teams = cvar("g_keyhunt_teams_override");
 678         if(kh_teams < 2)
 679                 kh_teams = cvar("g_keyhunt_teams");
 680         kh_teams = bound(2, kh_teams, 4);
 681
 682         // make a KH entity for controlling the game
 683         kh_controller = spawn();
 684         kh_controller.think = kh_Controller_Think;
 685         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 686
 687         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 688         kh_sprite_dropped = kh_controller.modelindex;
 689         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 690         kh_sprite_finish = kh_controller.modelindex;
 691         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 692         kh_sprite_friend = kh_controller.modelindex;
 693         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 694         kh_sprite_red = kh_controller.modelindex;
 695         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 696         kh_sprite_blue = kh_controller.modelindex;
 697         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 698         kh_sprite_pink = kh_controller.modelindex;
 699         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 700         kh_sprite_yellow = kh_controller.modelindex;
 701         setmodel(kh_controller, "");
 702 }
 703
 704 void kh_finalize()
 705 {
 706         // to be called before intermission
 707         kh_FinishRound();
 708         remove(kh_controller);
 709         kh_controller = world;
 710 }