data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25
  26 float kh_Team_ByID(float t)
  27 {
  28         if(t == 0) return COLOR_TEAM1;
  29         if(t == 1) return COLOR_TEAM2;
  30         if(t == 2) return COLOR_TEAM3;
  31         if(t == 3) return COLOR_TEAM4;
  32         return 0;
  33 }
  34
  35 entity kh_controller;
  36 float kh_tracking_enabled;
  37 float kh_teams;
  38 float kh_interferemsg_time, kh_interferemsg_team;
  39 .entity kh_next, kh_prev; // linked list
  40 .float kh_droptime;
  41 .float kh_dropperteam;
  42 .entity kh_previous_owner;
  43
  44 string kh_sound_capture = "sound/kh/capture.wav";
  45 string kh_sound_destroy = "sound/kh/destroy.wav";
  46 string kh_sound_drop = "sound/kh/drop.wav";
  47 string kh_sound_collect = "sound/kh/collect.wav";
  48
  49 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  50 float kh_key_dropped, kh_key_carried;
  51
  52 float kh_GetCarrierSprite(float t, float e)
  53 {
  54         if(t == e)           return kh_sprite_friend;
  55         if(t == COLOR_TEAM1) return kh_sprite_red;
  56         if(t == COLOR_TEAM2) return kh_sprite_blue;
  57         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  58         if(t == COLOR_TEAM4) return kh_sprite_pink;
  59         return 0;
  60 }
  61
  62 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  63 {
  64         kh_Controller_Thinkfunc = func;
  65         kh_controller.cnt = t;
  66         if(kh_Controller_Waitmsg != "")
  67                 strunzone(kh_Controller_Waitmsg);
  68         if(msg == "")
  69                 kh_Controller_Waitmsg = "";
  70         else
  71                 kh_Controller_Waitmsg = strzone(msg);
  72         if(t == 0)
  73                 kh_controller.nextthink = time; // force
  74 }
  75
  76 void kh_Controller_Think()
  77 {
  78         entity e;
  79         if(intermission_running)
  80                 return;
  81         if(self.cnt > 0)
  82         {
  83                 if(kh_Controller_Waitmsg != "")
  84                 {
  85                         string s;
  86                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  87                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  88                         else
  89                                 s = kh_Controller_Waitmsg;
  90
  91                         //dprint(s, "\n");
  92
  93                         FOR_EACH_PLAYER(e)
  94                                 if(clienttype(e) == CLIENTTYPE_REAL)
  95                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  96                 }
  97                 self.cnt -= 1;
  98         }
  99         else if(self.cnt == 0)
 100         {
 101                 self.cnt -= 1;
 102                 kh_Controller_Thinkfunc();
 103         }
 104         self.nextthink = time + 1;
 105 }
 106
 107 // frags f: take from cvar * f
 108 // frags 0: no frags
 109 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 110 {
 111         string s;
 112         if(intermission_running)
 113                 return;
 114         if(frags_player)
 115                 UpdateFrags(player, frags_player);
 116         if(key && key.owner && frags_owner)
 117                 UpdateFrags(key.owner, frags_owner);
 118         if(!cvar("sv_eventlog"))
 119                 return;
 120         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 121         s = strcat(s, ":", ftos(frags_player));
 122         if(key && key.owner)
 123                 s = strcat(s, ":", ftos(key.owner.playerid));
 124         else
 125                 s = strcat(s, ":0");
 126         s = strcat(s, ":", ftos(frags_owner), ":");
 127         if(key)
 128                 s = strcat(s, key.netname);
 129         GameLogEcho(s, FALSE);
 130 }
 131
 132 vector kh_AttachedOrigin(entity e)
 133 {
 134         if(e.tag_entity)
 135         {
 136                 makevectors(e.tag_entity.angles);
 137                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 138         }
 139         else
 140                 return e.origin;
 141 }
 142
 143 void kh_Key_Attach(entity key)
 144 {
 145 #ifdef KH_PLAYER_USE_ATTACHMENT
 146         entity first;
 147         first = key.owner.kh_next;
 148         if(key == first)
 149         {
 150                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 151                 if(key.kh_next)
 152                 {
 153                         setattachment(key.kh_next, key, "");
 154                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 155                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 156                         key.kh_next.angles = '0 0 0';
 157                 }
 158                 else
 159                         setorigin(key, KH_PLAYER_ATTACHMENT);
 160                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 161         }
 162         else
 163         {
 164                 setattachment(key, key.kh_prev, "");
 165                 if(key.kh_next)
 166                         setattachment(key.kh_next, key, "");
 167                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 168                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 169                 key.angles = '0 0 0';
 170         }
 171 #else
 172         setattachment(key, key.owner, "");
 173         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 174         key.angles_y -= key.owner.angles_y;
 175 #endif
 176         key.flags = 0;
 177         key.solid = SOLID_NOT;
 178         key.movetype = MOVETYPE_NONE;
 179         key.team = key.owner.team;
 180         key.nextthink = time;
 181         key.damageforcescale = 0;
 182         key.modelindex = kh_key_carried;
 183 }
 184
 185 void kh_Key_Detach(entity key)
 186 {
 187 #ifdef KH_PLAYER_USE_ATTACHMENT
 188         entity first;
 189         first = key.owner.kh_next;
 190         if(key == first)
 191         {
 192                 if(key.kh_next)
 193                 {
 194                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 195                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 196                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 197                 }
 198         }
 199         else
 200         {
 201                 if(key.kh_next)
 202                         setattachment(key.kh_next, key.kh_prev, "");
 203                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 204         }
 205         // in any case:
 206         setattachment(key, world, "");
 207         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 208         key.angles = key.owner.angles;
 209 #else
 210         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 211         setattachment(key, world, "");
 212         key.angles_y += key.owner.angles_y;
 213 #endif
 214         key.aiment = world;
 215         key.flags = FL_ITEM;
 216         key.solid = SOLID_TRIGGER;
 217         key.movetype = MOVETYPE_TOSS;
 218         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 219         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 220         // let key.team stay
 221         key.modelindex = kh_key_dropped;
 222         key.kh_previous_owner = key.owner;
 223 }
 224
 225 void kh_Key_AssignTo(entity key, entity player)
 226 {
 227         if(key.owner == player)
 228                 return;
 229
 230         if(key.owner)
 231         {
 232                 kh_Key_Detach(key);
 233
 234                 // remove from linked list
 235                 if(key.kh_next)
 236                         key.kh_next.kh_prev = key.kh_prev;
 237                 key.kh_prev.kh_next = key.kh_next;
 238                 key.kh_next = world;
 239                 key.kh_prev = world;
 240
 241                 if(key.owner.kh_next == world)
 242                 {
 243                         // No longer a key carrier
 244                         WaypointSprite_DetachCarrier(key.owner);
 245                 }
 246         }
 247
 248         key.owner = player;
 249
 250         if(player)
 251         {
 252                 // insert into linked list
 253                 key.kh_next = player.kh_next;
 254                 key.kh_prev = player;
 255                 player.kh_next = key;
 256                 if(key.kh_next)
 257                         key.kh_next.kh_prev = key;
 258
 259                 kh_Key_Attach(key);
 260
 261                 if(key.kh_next == world)
 262                 {
 263                         // player is now a key carrier
 264                         WaypointSprite_AttachCarrier("", player);
 265                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 266                         player.waypointsprite_attachedforcarrier.team = player.team;
 267                 }
 268         }
 269
 270         key.pusher = world;
 271 }
 272
 273 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 274 {
 275         if(self.owner)
 276                 return;
 277         if(vlen(force) <= 0)
 278                 return;
 279         if(time > self.pushltime)
 280                 if(attacker.classname == "player")
 281                         self.team = attacker.team;
 282 }
 283
 284 void kh_Key_Spawn(entity initial_owner, float angle)
 285 {
 286         entity key;
 287         key = spawn();
 288         key.classname = STR_ITEM_KH_KEY;
 289         key.touch = kh_Key_Touch;
 290         key.think = kh_Key_Think;
 291         key.nextthink = time;
 292         key.items = IT_KEY1 | IT_KEY2;
 293         key.cnt = angle;
 294         key.angles = '0 360 0' * random();
 295         key.event_damage = kh_Key_Damage;
 296         key.takedamage = DAMAGE_YES;
 297         key.modelindex = kh_key_dropped;
 298         key.model = "key";
 299         key.kh_dropperteam = 0;
 300         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 301         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 302         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 303
 304         switch(initial_owner.team)
 305         {
 306                 case COLOR_TEAM1:
 307                         key.netname = "^1red key";
 308                         break;
 309                 case COLOR_TEAM2:
 310                         key.netname = "^4blue key";
 311                         break;
 312                 case COLOR_TEAM3:
 313                         key.netname = "^3yellow key";
 314                         break;
 315                 case COLOR_TEAM4:
 316                         key.netname = "^6pink key";
 317                         break;
 318                 default:
 319                         key.netname = "NETGIER key";
 320                         break;
 321         }
 322
 323         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 324
 325         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 326         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 327
 328         kh_Key_AssignTo(key, initial_owner);
 329 }
 330
 331 void kh_Key_Remove(entity key)
 332 {
 333         entity o;
 334         o = key.owner;
 335         kh_Key_AssignTo(key, world);
 336         if(o) // it was attached
 337                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 338         else // it was dropped
 339                 WaypointSprite_DetachCarrier(key);
 340
 341         remove(key);
 342 }
 343
 344 // -1 when no team completely owns all keys yet
 345 float kh_Key_AllOwnedByWhichTeam()
 346 {
 347         entity key;
 348         float teem;
 349
 350         teem = -1;
 351         FOR_EACH_KH_KEY(key)
 352         {
 353                 if(!key.owner)
 354                         return -1;
 355                 if(teem == -1)
 356                         teem = key.team;
 357                 else if(teem != key.team)
 358                         return -1;
 359         }
 360         return teem;
 361 }
 362
 363 void kh_Key_Collect(entity key, entity player)
 364 {
 365         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 366
 367         if(key.kh_dropperteam != player.team)
 368                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 369         key.kh_dropperteam = 0;
 370         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 371         kh_Key_AssignTo(key, player);
 372
 373         if(kh_Key_AllOwnedByWhichTeam() != -1)
 374         {
 375                 kh_interferemsg_time = time + 0.2;
 376                 kh_interferemsg_team = player.team;
 377         }
 378 }
 379
 380 void kh_Key_DropAll(entity player, float suicide)
 381 {
 382         entity key;
 383         entity mypusher;
 384         if(player.kh_next)
 385         {
 386                 mypusher = world;
 387                 if(player.pusher)
 388                         if(time < player.pushltime)
 389                                 mypusher = player.pusher;
 390                 while((key = player.kh_next))
 391                 {
 392                         kh_Scores_Event(player, key, "losekey", 0, 0);
 393                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 394                         kh_Key_AssignTo(key, world);
 395                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 396                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 397                         key.pusher = mypusher;
 398                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 399                         if(suicide)
 400                                 key.kh_dropperteam = player.team;
 401                 }
 402                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 403         }
 404 }
 405
 406 void kh_Key_Touch()
 407 {
 408         if(intermission_running)
 409                 return;
 410
 411         if(self.owner) // already carried
 412                 return;
 413         if(other.classname != "player")
 414                 return;
 415         if(other.deadflag != DEAD_NO)
 416                 return;
 417         if(other == self.enemy)
 418                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 419                         return; // you just dropped it!
 420         kh_Key_Collect(self, other);
 421 }
 422
 423 void kh_Key_Think()
 424 {
 425         entity head;
 426
 427         if(intermission_running)
 428                 return;
 429
 430 #ifdef KH_KEY_ATTACHMENT_DEBUG
 431         if(self.kh_prev == self.owner)
 432         {
 433                 if(cvar_string("_angles") != "")
 434                 {
 435                         self.angles = stov(cvar_string("_angles"));
 436                         self.origin = stov(cvar_string("_origin"));
 437                 }
 438         }
 439 #endif
 440
 441         if(self.owner)
 442         {
 443 #ifndef KH_PLAYER_USE_ATTACHMENT
 444                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 445                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 446 #endif
 447
 448                 if(self.owner.buttonuse)
 449                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 450                 {
 451                         self.owner.kh_droptime = time;
 452                         self.kh_droptime = time; // prevent collecting this one for some time
 453                         self.enemy = self.owner;
 454                         self.pusher = world;
 455                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 456                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 457                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 458                         makevectors(self.owner.v_angle);
 459                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 460                         kh_Key_AssignTo(self, world);
 461                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 462                         self.kh_dropperteam = self.team;
 463                 }
 464         }
 465
 466         // if in nodrop or time over, end the round
 467         if(!self.owner)
 468                 if(time > self.pain_finished)
 469                         kh_LoserTeam(self.team, self);
 470
 471         if(self.owner)
 472         if(kh_Key_AllOwnedByWhichTeam() != -1)
 473         {
 474                 entity key;
 475                 vector p;
 476                 p = self.owner.origin;
 477                 FOR_EACH_KH_KEY(key)
 478                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 479                                 goto not_winning;
 480                 kh_WinnerTeam(self.team);
 481 :not_winning
 482         }
 483
 484         if(kh_interferemsg_time && time > kh_interferemsg_time)
 485         {
 486                 kh_interferemsg_time = 0;
 487                 FOR_EACH_PLAYER(head)
 488                 {
 489                         if(head.team == kh_interferemsg_team)
 490                                 if(head.kh_next)
 491                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 492                                 else
 493                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 494                         else
 495                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 496                 }
 497         }
 498
 499         self.nextthink = time + 0.05;
 500 }
 501
 502 void kh_WinnerTeam(float teem)
 503 {
 504         // all key carriers get some points
 505         vector firstorigin, lastorigin, midpoint;
 506         float first;
 507         entity key;
 508         float score;
 509         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 510         DistributeEvenly_Init(score, kh_teams);
 511         // twice the score for 3 team games, three times the score for 4 team games!
 512         // note: for a win by destroying the key, this should NOT be applied
 513         FOR_EACH_KH_KEY(key)
 514                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 515
 516         first = TRUE;
 517         FOR_EACH_KH_KEY(key)
 518                 if(key.owner.kh_next == key)
 519                 {
 520                         if(!first)
 521                                 bprint("^7, ");
 522                         bprint(key.owner.netname);
 523                         first = FALSE;
 524                 }
 525         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 526
 527         first = TRUE;
 528         midpoint = '0 0 0';
 529         FOR_EACH_KH_KEY(key)
 530         {
 531                 vector thisorigin;
 532
 533                 thisorigin = kh_AttachedOrigin(key);
 534                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 535                 midpoint += thisorigin;
 536
 537                 if(!first)
 538                         te_lightning2(world, lastorigin, thisorigin);
 539                 lastorigin = thisorigin;
 540                 if(first)
 541                         firstorigin = thisorigin;
 542                 first = FALSE;
 543         }
 544         if(kh_teams > 2)
 545         {
 546                 te_lightning2(world, lastorigin, firstorigin);
 547         }
 548         midpoint = midpoint * (1 / kh_teams);
 549         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5'); // make the color >=0.5 in each component
 550
 551         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 552         kh_FinishRound();
 553 }
 554
 555 void kh_LoserTeam(float teem, entity lostkey)
 556 {
 557         entity player, key, attacker;
 558         float players;
 559         float keys;
 560
 561         attacker = world;
 562         if(lostkey.pusher)
 563                 if(lostkey.pusher.team != teem)
 564                         if(lostkey.pusher.classname == "player")
 565                                 attacker = lostkey.pusher;
 566
 567         players = keys = 0;
 568
 569         if(attacker)
 570         {
 571                 if(lostkey.kh_previous_owner)
 572                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 573                         // don't actually GIVE him the -nn points, just log
 574                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 575                 centerprint(attacker, "Your push is the best!\n\n\n");
 576                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 577         }
 578         else
 579         {
 580                 float of, fragsleft, i, j, thisteam;
 581                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 582
 583                 FOR_EACH_PLAYER(player)
 584                         if(player.team != teem)
 585                                 ++players;
 586
 587                 FOR_EACH_KH_KEY(key)
 588                         if(key.owner && key.team != teem)
 589                                 ++keys;
 590
 591                 if(lostkey.kh_previous_owner)
 592                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 593                         // don't actually GIVE him the -nn points, just log
 594
 595                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 596
 597                 FOR_EACH_KH_KEY(key)
 598                         if(key.owner && key.team != teem)
 599                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 600
 601                 fragsleft = DistributeEvenly_Get(players);
 602
 603                 // Now distribute these among all other teams...
 604                 j = kh_teams - 1;
 605                 for(i = 0; i < kh_teams; ++i)
 606                 {
 607                         thisteam = kh_Team_ByID(i);
 608                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 609                                 continue;
 610
 611                         players = 0;
 612                         FOR_EACH_PLAYER(player)
 613                                 if(player.team == thisteam)
 614                                         ++players;
 615
 616                         DistributeEvenly_Init(fragsleft, j);
 617                         fragsleft = DistributeEvenly_Get(j - 1);
 618                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 619
 620                         FOR_EACH_PLAYER(player)
 621                                 if(player.team == thisteam)
 622                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 623
 624                         --j;
 625                 }
 626
 627                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 628         }
 629         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 630         te_tarexplosion(lostkey.origin);
 631
 632         kh_FinishRound();
 633 }
 634
 635 void kh_FinishRound()
 636 {
 637         // prepare next round
 638         kh_interferemsg_time = 0;
 639         entity key;
 640         FOR_EACH_KH_KEY(key)
 641                 kh_Key_Remove(key);
 642
 643         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 644 }
 645
 646 string kh_CheckEnoughPlayers()
 647 {
 648         float i, players, teem;
 649         entity player;
 650         string result;
 651         result = "";
 652
 653         // find a random player per team
 654         for(i = 0; i < kh_teams; ++i)
 655         {
 656                 teem = kh_Team_ByID(i);
 657                 players = 0;
 658                 FOR_EACH_PLAYER(player)
 659                         if(player.deadflag == DEAD_NO)
 660                                 if(!player.buttonchat)
 661                                         if(player.team == teem)
 662                                                 ++players;
 663                 if(players == 0)
 664                 {
 665                         if(result != "")
 666                                 result = strcat(result, ", ");
 667                         result = strcat(result, ColoredTeamName(teem));
 668                 }
 669         }
 670         return result;
 671 }
 672
 673 void kh_WaitForPlayers()
 674 {
 675         string teams_missing;
 676         teams_missing = kh_CheckEnoughPlayers();
 677         if(teams_missing == "")
 678                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 679         else
 680                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 681 }
 682
 683 void kh_StartRound()
 684 {
 685         string teams_missing;
 686         float i, players, teem;
 687         entity player;
 688
 689         teams_missing = kh_CheckEnoughPlayers();
 690         if(teams_missing != "")
 691         {
 692                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 693                 return;
 694         }
 695
 696         FOR_EACH_PLAYER(player)
 697                 if(clienttype(player) == CLIENTTYPE_REAL)
 698                         centerprint_expire(player, CENTERPRIO_SPAM);
 699
 700         for(i = 0; i < kh_teams; ++i)
 701         {
 702                 teem = kh_Team_ByID(i);
 703                 players = 0;
 704                 entity my_player;
 705                 FOR_EACH_PLAYER(player)
 706                         if(player.deadflag == DEAD_NO)
 707                                 if(!player.buttonchat)
 708                                         if(player.team == teem)
 709                                         {
 710                                                 ++players;
 711                                                 if(random() * players <= 1)
 712                                                         my_player = player;
 713                                         }
 714                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 715                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 716                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 717         }
 718
 719         kh_tracking_enabled = FALSE;
 720         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 721 }
 722
 723 void kh_setstatus()
 724 {
 725         if(kh_teams)
 726         {
 727                 float kh_KEY;
 728                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 729                 if(self.kh_next)
 730                         self.items = self.items | kh_KEY;
 731                 else
 732                         self.items = self.items - (self.items & kh_KEY);
 733         }
 734 }
 735
 736 void kh_EnableTrackingDevice()
 737 {
 738         entity player;
 739
 740         FOR_EACH_PLAYER(player)
 741                 if(clienttype(player) == CLIENTTYPE_REAL)
 742                         centerprint_expire(player, CENTERPRIO_SPAM);
 743
 744         kh_tracking_enabled = TRUE;
 745 }
 746
 747 float kh_Key_waypointsprite_for_player(entity e)
 748 {
 749         if(!kh_tracking_enabled)
 750                 return 0;
 751         if(!self.owner)
 752                 return kh_sprite_dropped;
 753         if(!self.owner.owner)
 754                 return kh_sprite_dropped;
 755         return 0; // draw only when key is not owned
 756 }
 757
 758 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 759 {
 760         if(e.classname != "player" || self.team != e.team)
 761                 if(!kh_tracking_enabled)
 762                         return 0;
 763
 764         // e is spectator? That's no team mate...
 765         if(e.classname != "player")
 766                 return kh_GetCarrierSprite(self.team, -1);
 767
 768         // e is no key carrier: simple case...
 769         if(!e.kh_next)
 770                 return kh_GetCarrierSprite(self.team, e.team);
 771
 772         // e is a key carrier: if any key is dropped or owned by another team, show
 773         // the carrier sprite; otherwise show run here
 774         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 775                 return kh_sprite_finish;
 776
 777         return kh_GetCarrierSprite(self.team, e.team);
 778 }
 779
 780 float kh_HandleFrags(entity attacker, entity targ, float f)
 781 {
 782         if(attacker == targ)
 783                 return f;
 784
 785         if(targ.kh_next)
 786         {
 787                 if(attacker.team == targ.team)
 788                 {
 789                         entity k;
 790                         float nk;
 791                         nk = 0;
 792                         for(k = targ.kh_next; k != world; k = k.kh_next)
 793                                 ++nk;
 794                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 795                 }
 796                 else
 797                 {
 798                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 799                 }
 800         }
 801
 802         return f;
 803 }
 804
 805 void kh_init()
 806 {
 807         precache_sound(kh_sound_capture);
 808         precache_sound(kh_sound_destroy);
 809         precache_sound(kh_sound_drop);
 810         precache_sound(kh_sound_collect);
 811
 812         precache_model("models/sprites/key-dropped.sp2");
 813         precache_model("models/sprites/keycarrier-finish.sp2");
 814         precache_model("models/sprites/keycarrier-friend.sp2");
 815         precache_model("models/sprites/keycarrier-red.sp2");
 816         precache_model("models/sprites/keycarrier-blue.sp2");
 817         precache_model("models/sprites/keycarrier-yellow.sp2");
 818         precache_model("models/sprites/keycarrier-pink.sp2");
 819 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 820         precache_model("models/keyhunt/key-carried.md3");
 821 #endif
 822         precache_model("models/keyhunt/key.md3");
 823
 824         // setup variables
 825         kh_teams = cvar("g_keyhunt_teams_override");
 826         if(kh_teams < 2)
 827                 kh_teams = cvar("g_keyhunt_teams");
 828         kh_teams = bound(2, kh_teams, 4);
 829
 830         // make a KH entity for controlling the game
 831         kh_controller = spawn();
 832         kh_controller.think = kh_Controller_Think;
 833         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 834
 835         setmodel(kh_controller, "models/keyhunt/key.md3");
 836         kh_key_dropped = kh_controller.modelindex;
 837         /*
 838         dprint(vtos(kh_controller.mins));
 839         dprint(vtos(kh_controller.maxs));
 840         dprint("\n");
 841         */
 842 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 843         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 844         kh_key_carried = kh_controller.modelindex;
 845 #else
 846         kh_key_carried = kh_key_dropped;
 847 #endif
 848         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 849         kh_sprite_dropped = kh_controller.modelindex;
 850         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 851         kh_sprite_finish = kh_controller.modelindex;
 852         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 853         kh_sprite_friend = kh_controller.modelindex;
 854         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 855         kh_sprite_red = kh_controller.modelindex;
 856         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 857         kh_sprite_blue = kh_controller.modelindex;
 858         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 859         kh_sprite_pink = kh_controller.modelindex;
 860         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 861         kh_sprite_yellow = kh_controller.modelindex;
 862         setmodel(kh_controller, "");
 863 }
 864
 865 void kh_finalize()
 866 {
 867         // to be called before intermission
 868         kh_FinishRound();
 869         remove(kh_controller);
 870         kh_controller = world;
 871 }