data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/misc/mouseclick.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  37         if(t == COLOR_TEAM4) return kh_sprite_pink;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(intermission_running)
  59                 return;
  60         if(self.cnt > 0)
  61         {
  62                 if(kh_Controller_Waitmsg != "")
  63                 {
  64                         string s;
  65                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  66                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  67                         else
  68                                 s = kh_Controller_Waitmsg;
  69
  70                         dprint(s, "\n");
  71
  72                         FOR_EACH_PLAYER(e)
  73                                 if(clienttype(e) == CLIENTTYPE_REAL)
  74                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  75                 }
  76                 self.cnt -= 1;
  77         }
  78         else if(self.cnt == 0)
  79         {
  80                 self.cnt -= 1;
  81                 kh_Controller_Thinkfunc();
  82         }
  83         self.nextthink = time + 1;
  84 }
  85
  86 void kh_Log()
  87 {
  88         string s;
  89         if(!cvar("sv_eventlog"))
  90                 return;
  91         // TODO ...
  92         GameLogEcho(s, FALSE);
  93 }
  94
  95 // frags f: take from cvar * f
  96 // frags 0: no frags
  97 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
  98 {
  99         float basefrags;
 100         basefrags = cvar(strcat("g_balance_keyhunt_score_", what));
 101
 102         if(frags_player)
 103                 player.frags = player.frags + floor(0.5 + basefrags * frags_player);
 104         if(frags_owner)
 105                 key.owner.frags = key.owner.frags + floor(0.5 + basefrags * frags_owner);
 106 }
 107
 108 void kh_Key_Attach(entity key)
 109 {
 110         setattachment(key, key.owner, "");
 111         setorigin(key, '0 0 -15'); // x/y fixed later in think, z has to be -15 to make the key fit even in the crouchbox
 112         key.angles = key.angles - '0 1 0' * key.owner.angles_y;
 113         key.flags = 0;
 114         key.solid = SOLID_NOT;
 115         key.movetype = MOVETYPE_NONE;
 116         key.team = key.owner.team;
 117         key.nextthink = time;
 118         key.damageforcescale = 0;
 119 }
 120
 121 vector kh_AttachedOrigin(entity e)
 122 {
 123         if(e.tag_entity)
 124         {
 125                 /*
 126                 makevectors(e.tag_entity.angles);
 127                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 128                 */
 129                 return e.tag_entity.origin + e.origin_z * '0 0 1'; // not exact, but allows full key hitbox
 130         }
 131         else
 132                 return e.origin;
 133 }
 134
 135 void kh_Key_Detach(entity key)
 136 {
 137         setorigin(key, kh_AttachedOrigin(key));
 138         setattachment(key, world, "");
 139         key.angles_y = key.owner.angles_y;
 140         key.aiment = world;
 141         key.flags = FL_ITEM;
 142         key.solid = SOLID_TRIGGER;
 143         key.movetype = MOVETYPE_TOSS;
 144         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 145         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 146         // let key.team stay
 147 }
 148
 149 void kh_Key_AssignTo(entity key, entity player)
 150 {
 151         if(key.owner == player)
 152                 return;
 153
 154         if(key.owner)
 155         {
 156                 kh_Key_Detach(key);
 157
 158                 // remove from linked list
 159                 if(key.kh_next)
 160                         key.kh_next.kh_prev = key.kh_prev;
 161                 key.kh_prev.kh_next = key.kh_next;
 162                 key.kh_next = world;
 163                 key.kh_prev = world;
 164
 165                 if(key.owner.kh_next == world)
 166                 {
 167                         // No longer a key carrier
 168                         WaypointSprite_DetachCarrier(key.owner);
 169                 }
 170         }
 171
 172         key.owner = player;
 173
 174         if(player)
 175         {
 176                 // insert into linked list
 177                 key.kh_next = player.kh_next;
 178                 key.kh_prev = player;
 179                 player.kh_next = key;
 180                 if(key.kh_next)
 181                         key.kh_next.kh_prev = key;
 182
 183                 kh_Key_Attach(key);
 184
 185                 if(key.kh_next == world)
 186                 {
 187                         // player is now a key carrier
 188                         WaypointSprite_AttachCarrier("", player);
 189                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 190                         player.waypointsprite_attachedforcarrier.team = player.team;
 191                 }
 192         }
 193
 194         key.pusher = world;
 195 }
 196
 197 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 198 {
 199         if(self.owner)
 200                 return;
 201         if(vlen(force) <= 0)
 202                 return;
 203         if(time > self.pushltime)
 204                 if(attacker.classname == "player")
 205                         self.team = attacker.team;
 206 }
 207
 208 void kh_Key_Spawn(entity initial_owner, float angle)
 209 {
 210         entity key;
 211         key = spawn();
 212         key.classname = STR_ITEM_KH_KEY;
 213         key.touch = kh_Key_Touch;
 214         key.think = kh_Key_Think;
 215         key.nextthink = time;
 216         key.items = IT_KEY1 | IT_KEY2;
 217         key.cnt = angle;
 218         key.angles = '0 360 0' * random();
 219         key.event_damage = kh_Key_Damage;
 220         setmodel(key, "models/keyhunt/key3.md3");
 221         setsize(key, '-8 -8 -8', '8 8 40');
 222
 223         switch(initial_owner.team)
 224         {
 225                 case COLOR_TEAM1:
 226                         key.netname = "^1red key";
 227                         key.colormod = '1.73 0.10 0.10';
 228                         break;
 229                 case COLOR_TEAM2:
 230                         key.netname = "^4blue key";
 231                         key.colormod = '0.10 0.10 1.73';
 232                         break;
 233                 case COLOR_TEAM3:
 234                         key.netname = "^3yellow key";
 235                         key.colormod = '1.22 1.22 0.10';
 236                         break;
 237                 case COLOR_TEAM4:
 238                         key.netname = "^6pink key";
 239                         key.colormod = '1.22 0.10 1.22';
 240                         break;
 241                 default:
 242                         key.netname = "NETGIER key";
 243                         key.colormod = '1.00 1.00 1.00';
 244                         break;
 245         }
 246
 247         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 248
 249         WaypointSprite_AttachCarrier("", key);
 250         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 251
 252         kh_Key_AssignTo(key, initial_owner);
 253 }
 254
 255 void kh_Key_Remove(entity key)
 256 {
 257         entity o;
 258         o = key.owner;
 259         kh_Key_AssignTo(key, world);
 260         if(o) // it was attached
 261                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 262         else // it was dropped
 263                 WaypointSprite_DetachCarrier(key);
 264
 265         remove(key);
 266 }
 267
 268 // -1 when no team completely owns all keys yet
 269 float kh_Key_AllOwnedByWhichTeam()
 270 {
 271         entity key;
 272         float teem;
 273
 274         teem = -1;
 275         FOR_EACH_KH_KEY(key)
 276         {
 277                 if(!key.owner)
 278                         return -1;
 279                 if(teem == -1)
 280                         teem = key.team;
 281                 else if(teem != key.team)
 282                         return -1;
 283         }
 284         return teem;
 285 }
 286
 287 void kh_Key_Collect(entity key, entity player)
 288 {
 289         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 290
 291         kh_Scores_Event(player, key, "collect", 1, 0);
 292         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 293         kh_Key_AssignTo(key, player);
 294
 295         if(kh_Key_AllOwnedByWhichTeam() != -1)
 296         {
 297                 kh_interferemsg_time = time + 0.2;
 298                 kh_interferemsg_team = player.team;
 299         }
 300 }
 301
 302 void kh_Key_DropAll(entity player)
 303 {
 304         entity key;
 305         entity mypusher;
 306         if(player.kh_next)
 307         {
 308                 mypusher = world;
 309                 if(player.pusher)
 310                         if(time < player.pushltime)
 311                                 mypusher = player.pusher;
 312                 while((key = player.kh_next))
 313                 {
 314                         kh_Scores_Event(player, key, "losekey", 0, 0);
 315                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 316                         kh_Key_AssignTo(key, world);
 317                         makevectors('-90 0 0' * random() + '0 360 0' * random());
 318                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 319                         key.pusher = mypusher;
 320                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 321                 }
 322                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 323         }
 324 }
 325
 326 void kh_Key_Touch()
 327 {
 328         if(self.owner) // already carried
 329                 return;
 330         if(other.classname != "player")
 331                 return;
 332         if(other.deadflag != DEAD_NO)
 333                 return;
 334         if(other == self.enemy)
 335                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 336                         return; // you just dropped it!
 337         kh_Key_Collect(self, other);
 338 }
 339
 340 void kh_Key_Think()
 341 {
 342         entity head;
 343
 344         self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 345
 346         if(self.owner)
 347         {
 348                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 349                 setorigin(self, v_forward * 24 + '0 0 1' * self.origin_z);
 350
 351                 if(self.owner.buttonuse)
 352                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 353                 {
 354                         self.owner.kh_droptime = time;
 355                         self.kh_droptime = time; // prevent collecting this one for some time
 356                         self.enemy = self.owner;
 357                         self.pusher = world;
 358                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 359                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 360                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 361                         makevectors(self.owner.v_angle);
 362                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 363                         kh_Key_AssignTo(self, world);
 364                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 365                 }
 366         }
 367
 368         // if in nodrop or time over, end the round
 369         if(!self.owner)
 370                 if(time > self.pain_finished)
 371                         kh_LoserTeam(self.team, self);
 372
 373         if(self.owner)
 374         if(kh_Key_AllOwnedByWhichTeam() != -1)
 375         {
 376                 entity key;
 377                 vector p;
 378                 p = self.owner.origin;
 379                 FOR_EACH_KH_KEY(key)
 380                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 381                                 goto not_winning;
 382                 kh_WinnerTeam(self.team);
 383 :not_winning
 384         }
 385
 386         if(kh_interferemsg_time && time > kh_interferemsg_time)
 387         {
 388                 kh_interferemsg_time = 0;
 389                 FOR_EACH_PLAYER(head)
 390                 {
 391                         if(head.team == kh_interferemsg_team)
 392                                 if(head.kh_next)
 393                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 394                                 else
 395                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 396                         else
 397                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 398                 }
 399         }
 400
 401         self.nextthink = time + 0.05;
 402 }
 403
 404 void kh_WinnerTeam(float teem)
 405 {
 406         // all key carriers get some points
 407         vector firstorigin, lastorigin;
 408         float first;
 409         entity key;
 410         float score;
 411         score = (kh_teams - 1) / kh_teams;
 412         // twice the score for 3 team games, three times the score for 4 team games!
 413         // note: for a win by destroying the key, this should NOT be applied
 414         first = TRUE;
 415         FOR_EACH_KH_KEY(key)
 416         {
 417                 kh_Scores_Event(key.owner, key, "capture", score, 0);
 418                 if(key.owner.kh_next == key)
 419                 {
 420                         if(!first)
 421                                 bprint("^7, ");
 422                         bprint(key.owner.netname);
 423                         first = FALSE;
 424                 }
 425         }
 426
 427         first = TRUE;
 428         FOR_EACH_KH_KEY(key)
 429         {
 430                 vector thisorigin;
 431
 432                 thisorigin = kh_AttachedOrigin(key);
 433
 434                 if(!first)
 435                         te_lightning2(world, lastorigin, thisorigin);
 436                 lastorigin = thisorigin;
 437                 if(first)
 438                         firstorigin = thisorigin;
 439                 first = FALSE;
 440         }
 441         if(kh_teams > 2)
 442         {
 443                 te_lightning2(world, lastorigin, firstorigin);
 444         }
 445
 446         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 447         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 448         kh_FinishRound();
 449 }
 450
 451 void kh_LoserTeam(float teem, entity lostkey)
 452 {
 453         entity player, key, attacker;
 454         float players;
 455         float keys;
 456         float score;
 457
 458         attacker = world;
 459         if(lostkey.pusher)
 460                 if(lostkey.pusher.team != teem)
 461                         if(lostkey.pusher.classname == "player")
 462                                 attacker = lostkey.pusher;
 463
 464         players = keys = 0;
 465
 466         if(attacker)
 467         {
 468                 kh_Scores_Event(attacker, world, "push", 1, 0);
 469                 centerprint(attacker, "Your push is the best!\n\n\n");
 470                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 471         }
 472         else
 473         {
 474                 FOR_EACH_PLAYER(player)
 475                         if(player.team != teem)
 476                                 ++players;
 477
 478                 FOR_EACH_KH_KEY(key)
 479                         if(key.owner && key.team != teem)
 480                                 ++keys;
 481
 482                 score = 1.0 / max(1, keys * cvar("g_balance_keyhunt_score_destroyed_ownfactor") + players);
 483
 484                 FOR_EACH_PLAYER(player)
 485                         if(player.team != teem)
 486                                 kh_Scores_Event(player, world, "destroyed", score, 0);
 487
 488                 FOR_EACH_KH_KEY(key)
 489                         if(key.owner && key.team != teem)
 490                                 kh_Scores_Event(key.owner, world, "destroyed", score * cvar("g_balance_keyhunt_score_destroyed_ownfactor"), 0);
 491
 492                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 493         }
 494         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 495
 496         kh_FinishRound();
 497 }
 498
 499 void kh_FinishRound()
 500 {
 501         // prepare next round
 502         kh_interferemsg_time = 0;
 503         entity key;
 504         FOR_EACH_KH_KEY(key)
 505                 kh_Key_Remove(key);
 506
 507         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 508 }
 509
 510 float kh_EnoughPlayers()
 511 {
 512         float i, players, teem;
 513         entity player;
 514
 515         // find a random player per team
 516         for(i = 0; i < kh_teams; ++i)
 517         {
 518                 teem = kh_Team_ByID(i);
 519                 players = 0;
 520                 FOR_EACH_PLAYER(player)
 521                         if(player.deadflag == DEAD_NO)
 522                                 if(player.team == teem)
 523                                         ++players;
 524                 if(players == 0)
 525                         return FALSE;
 526         }
 527         return TRUE;
 528 }
 529
 530 void kh_WaitForPlayers()
 531 {
 532         if(kh_EnoughPlayers())
 533                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 534         else
 535                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 536 }
 537
 538 void kh_StartRound()
 539 {
 540         float i, players, teem;
 541         entity player;
 542
 543         if(!kh_EnoughPlayers())
 544         {
 545                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 546                 return;
 547         }
 548
 549         FOR_EACH_PLAYER(player)
 550                 if(clienttype(player) == CLIENTTYPE_REAL)
 551                         centerprint_expire(player, CENTERPRIO_SPAM);
 552
 553         for(i = 0; i < kh_teams; ++i)
 554         {
 555                 teem = kh_Team_ByID(i);
 556                 players = 0;
 557                 entity my_player;
 558                 FOR_EACH_PLAYER(player)
 559                         if(player.deadflag == DEAD_NO)
 560                                 if(player.team == teem)
 561                                 {
 562                                         ++players;
 563                                         if(random() * players <= 1)
 564                                                 my_player = player;
 565                                 }
 566                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 567         }
 568
 569         kh_tracking_enabled = FALSE;
 570         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 571 }
 572
 573 void kh_setstatus()
 574 {
 575         if(kh_teams)
 576         {
 577                 float kh_KEY;
 578                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 579                 if(self.kh_next)
 580                         self.items = self.items | kh_KEY;
 581                 else
 582                         self.items = self.items - (self.items & kh_KEY);
 583         }
 584 }
 585
 586 void kh_EnableTrackingDevice()
 587 {
 588         entity player;
 589
 590         FOR_EACH_PLAYER(player)
 591                 if(clienttype(player) == CLIENTTYPE_REAL)
 592                         centerprint_expire(player, CENTERPRIO_SPAM);
 593
 594         kh_tracking_enabled = TRUE;
 595 }
 596
 597 float kh_Key_waypointsprite_for_player(entity e)
 598 {
 599         if(!kh_tracking_enabled)
 600                 return 0;
 601         if(!self.owner)
 602                 return kh_sprite_dropped;
 603         if(!self.owner.owner)
 604                 return kh_sprite_dropped;
 605         return 0; // draw only when key is not owned
 606 }
 607
 608 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 609 {
 610         if(e.classname != "player" || self.team != e.team)
 611                 if(!kh_tracking_enabled)
 612                         return 0;
 613
 614         // e is spectator? That's no team mate...
 615         if(e.classname != "player")
 616                 return kh_GetCarrierSprite(self.team, -1);
 617
 618         // e is no key carrier: simple case...
 619         if(!e.kh_next)
 620                 return kh_GetCarrierSprite(self.team, e.team);
 621
 622         // e is a key carrier: if any key is dropped or owned by another team, show
 623         // the carrier sprite; otherwise show run here
 624         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 625                 return kh_sprite_finish;
 626
 627         return kh_GetCarrierSprite(self.team, e.team);
 628 }
 629
 630 float kh_HandleFrags(entity attacker, entity targ, float f)
 631 {
 632         float newfrags;
 633
 634         if(f <= 0)
 635                 return f;
 636         if(attacker == targ)
 637                 return f;
 638
 639         if(targ.kh_next)
 640                 f = f - 1 + cvar("g_balance_keyhunt_score_carrierfrag");
 641
 642         if(newfrags)
 643                 f = f - 1 + newfrags;
 644         return f;
 645 }
 646
 647 void kh_init()
 648 {
 649         precache_sound(kh_sound_capture);
 650         precache_sound(kh_sound_destroy);
 651         precache_sound(kh_sound_drop);
 652         precache_sound(kh_sound_collect);
 653
 654         precache_model("models/sprites/key-dropped.sp2");
 655         precache_model("models/sprites/keycarrier-finish.sp2");
 656         precache_model("models/sprites/keycarrier-friend.sp2");
 657         precache_model("models/sprites/keycarrier-red.sp2");
 658         precache_model("models/sprites/keycarrier-blue.sp2");
 659         precache_model("models/sprites/keycarrier-yellow.sp2");
 660         precache_model("models/sprites/keycarrier-pink.sp2");
 661         precache_model("models/keyhunt/key3.md3");
 662
 663         // setup variables
 664         kh_teams = cvar("g_keyhunt_teams_override");
 665         if(kh_teams < 2)
 666                 kh_teams = cvar("g_keyhunt_teams");
 667         if(kh_teams < 2)
 668                 kh_teams = 2;
 669
 670         // make a KH entity for controlling the game
 671         kh_controller = spawn();
 672         kh_controller.think = kh_Controller_Think;
 673         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 674
 675         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 676         kh_sprite_dropped = kh_controller.modelindex;
 677         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 678         kh_sprite_finish = kh_controller.modelindex;
 679         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 680         kh_sprite_friend = kh_controller.modelindex;
 681         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 682         kh_sprite_red = kh_controller.modelindex;
 683         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 684         kh_sprite_blue = kh_controller.modelindex;
 685         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 686         kh_sprite_pink = kh_controller.modelindex;
 687         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 688         kh_sprite_yellow = kh_controller.modelindex;
 689         setmodel(kh_controller, "");
 690 }
 691
 692 void kh_finalize()
 693 {
 694         // to be called before intermission
 695         kh_FinishRound();
 696         remove(kh_controller);
 697         kh_controller = world;
 698 }