data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25 float kh_no_radar_circles;
  26
  27 // kh_state
  28 //     bits 0-7: player's key status
  29 //     bits 8-15: general key status
  30 .float kh_state;
  31 .float siren_time;  //  time delay the siren
  32 //.float stuff_time;  //  time delay to stuffcmd a cvar
  33
  34 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  35 //test[0] = status of dropped keys, test[1 - 16] = player #
  36 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  37 //for(i = 0; i < maxplayers; ++i)
  38 //      test[i] = "0";
  39
  40 float kh_Team_ByID(float t)
  41 {
  42         if(t == 0) return COLOR_TEAM1;
  43         if(t == 1) return COLOR_TEAM2;
  44         if(t == 2) return COLOR_TEAM3;
  45         if(t == 3) return COLOR_TEAM4;
  46         return 0;
  47 }
  48
  49 entity kh_worldkeylist;
  50 .entity kh_worldkeynext;
  51 entity kh_controller;
  52 float kh_tracking_enabled;
  53 float kh_teams;
  54 float kh_interferemsg_time, kh_interferemsg_team;
  55 .entity kh_next, kh_prev; // linked list
  56 .float kh_droptime;
  57 .float kh_dropperteam;
  58 .entity kh_previous_owner;
  59 .float kh_previous_owner_playerid;
  60
  61 string kh_sound_capture = "sound/kh/capture.wav";
  62 string kh_sound_destroy = "sound/kh/destroy.wav";
  63 string kh_sound_drop = "sound/kh/drop.wav";
  64 string kh_sound_collect = "sound/kh/collect.wav";
  65 string kh_sound_alarm = "sound/kh/alarm.wav";  // the new siren/alarm
  66
  67 float kh_key_dropped, kh_key_carried;
  68
  69 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  70 {
  71         kh_Controller_Thinkfunc = func;
  72         kh_controller.cnt = t;
  73         if(kh_Controller_Waitmsg != "")
  74                 strunzone(kh_Controller_Waitmsg);
  75         if(msg == "")
  76                 kh_Controller_Waitmsg = "";
  77         else
  78                 kh_Controller_Waitmsg = strzone(msg);
  79         if(t == 0)
  80                 kh_controller.nextthink = time; // force
  81 }
  82
  83 void kh_Controller_Think()  // called a lot
  84 {
  85         entity e;
  86         if(intermission_running)
  87                 return;
  88         if(self.cnt > 0)
  89         {
  90                 if(kh_Controller_Waitmsg != "")
  91                 {
  92                         string s;
  93                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  94                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  95                         else
  96                                 s = kh_Controller_Waitmsg;
  97
  98                         //dprint(s, "\n");
  99
 100                         FOR_EACH_PLAYER(e)
 101                                 if(clienttype(e) == CLIENTTYPE_REAL)
 102                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 103                 }
 104                 self.cnt -= 1;
 105         }
 106         else if(self.cnt == 0)
 107         {
 108                 self.cnt -= 1;
 109                 kh_Controller_Thinkfunc();
 110         }
 111         self.nextthink = time + 1;
 112 }
 113
 114 // frags f: take from cvar * f
 115 // frags 0: no frags
 116 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 117 {
 118         string s;
 119         if(intermission_running)
 120                 return;
 121         if(frags_player)
 122                 UpdateFrags(player, frags_player);
 123         if(key && key.owner && frags_owner)
 124                 UpdateFrags(key.owner, frags_owner);
 125         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 126                 return;
 127         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 128         s = strcat(s, ":", ftos(frags_player));
 129         if(key && key.owner)
 130                 s = strcat(s, ":", ftos(key.owner.playerid));
 131         else
 132                 s = strcat(s, ":0");
 133         s = strcat(s, ":", ftos(frags_owner), ":");
 134         if(key)
 135                 s = strcat(s, key.netname);
 136         GameLogEcho(s);
 137 }
 138
 139 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 140 {
 141         if(e.tag_entity)
 142         {
 143                 makevectors(e.tag_entity.angles);
 144                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 145         }
 146         else
 147                 return e.origin;
 148 }
 149
 150 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 151 {
 152 #ifdef KH_PLAYER_USE_ATTACHMENT
 153         entity first;
 154         first = key.owner.kh_next;
 155         if(key == first)
 156         {
 157                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 158                 if(key.kh_next)
 159                 {
 160                         setattachment(key.kh_next, key, "");
 161                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 162                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 163                         key.kh_next.angles = '0 0 0';
 164                 }
 165                 else
 166                         setorigin(key, KH_PLAYER_ATTACHMENT);
 167                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 168         }
 169         else
 170         {
 171                 setattachment(key, key.kh_prev, "");
 172                 if(key.kh_next)
 173                         setattachment(key.kh_next, key, "");
 174                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 175                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 176                 key.angles = '0 0 0';
 177         }
 178 #else
 179         setattachment(key, key.owner, "");
 180         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 181         key.angles_y -= key.owner.angles_y;
 182 #endif
 183         key.flags = 0;
 184         key.solid = SOLID_NOT;
 185         key.movetype = MOVETYPE_NONE;
 186         key.team = key.owner.team;
 187         key.nextthink = time;
 188         key.damageforcescale = 0;
 189         key.modelindex = kh_key_carried;
 190 }
 191
 192 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 193 {
 194         float i;
 195         i = test[key.owner.playerid];
 196                 if(key.netname == "^1red key")
 197                         i -= 1;
 198                 if(key.netname == "^4blue key")
 199                         i -= 2;
 200                 if(key.netname == "^3yellow key")
 201                         i -= 4;
 202                 if(key.netname == "^6pink key")
 203                         i -= 8;
 204         test[key.owner.playerid] = i;
 205
 206         kh_show_temp();
 207         if(key.owner)
 208                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 209         //key.owner.kh_state += test[key.owner.playerid];
 210
 211 #ifdef KH_PLAYER_USE_ATTACHMENT
 212         entity first;
 213         first = key.owner.kh_next;
 214         if(key == first)
 215         {
 216                 if(key.kh_next)
 217                 {
 218                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 219                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 220                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 221                 }
 222         }
 223         else
 224         {
 225                 if(key.kh_next)
 226                         setattachment(key.kh_next, key.kh_prev, "");
 227                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 228         }
 229         // in any case:
 230         setattachment(key, world, "");
 231         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 232         key.angles = key.owner.angles;
 233 #else
 234         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 235         setattachment(key, world, "");
 236         key.angles_y += key.owner.angles_y;
 237 #endif
 238         key.flags = FL_ITEM;
 239         key.solid = SOLID_TRIGGER;
 240         key.movetype = MOVETYPE_TOSS;
 241         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 242         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 243         // let key.team stay
 244         key.modelindex = kh_key_dropped;
 245         key.kh_previous_owner = key.owner;
 246         key.kh_previous_owner_playerid = key.owner.playerid;
 247 }
 248
 249 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 250 {
 251         entity k;
 252         float ownerteam0, ownerteam;
 253         if(key.owner == player)
 254                 return;
 255
 256         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 257
 258         if(key.owner)
 259         {
 260                 kh_Key_Detach(key);
 261
 262                 // remove from linked list
 263                 if(key.kh_next)
 264                         key.kh_next.kh_prev = key.kh_prev;
 265                 key.kh_prev.kh_next = key.kh_next;
 266                 key.kh_next = world;
 267                 key.kh_prev = world;
 268
 269                 if(key.owner.kh_next == world)
 270                 {
 271                         // No longer a key carrier
 272                         if(!kh_no_radar_circles)
 273                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 274                         WaypointSprite_DetachCarrier(key.owner);
 275                 }
 276         }
 277
 278         key.owner = player;
 279
 280         if(player)
 281         {
 282                 // insert into linked list
 283                 key.kh_next = player.kh_next;
 284                 key.kh_prev = player;
 285                 player.kh_next = key;
 286                 if(key.kh_next)
 287                         key.kh_next.kh_prev = key;
 288
 289                 float i;
 290                 i = test[key.owner.playerid];
 291                         if(key.netname == "^1red key")
 292                                 i += 1;
 293                         if(key.netname == "^4blue key")
 294                                 i += 2;
 295                         if(key.netname == "^3yellow key")
 296                                 i += 4;
 297                         if(key.netname == "^6pink key")
 298                                 i += 8;
 299                 test[key.owner.playerid] = i;
 300
 301                 kh_Key_Attach(key);
 302
 303                 if(key.kh_next == world)
 304                 {
 305                         // player is now a key carrier
 306                         WaypointSprite_AttachCarrier("", player);
 307                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 308                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 309                         if(player.team == COLOR_TEAM1)
 310                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "");
 311                         else if(player.team == COLOR_TEAM2)
 312                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "");
 313                         else if(player.team == COLOR_TEAM3)
 314                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "");
 315                         else if(player.team == COLOR_TEAM4)
 316                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "");
 317                         WaypointSprite_UpdateTeamRadar(player.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1));
 318                         if(!kh_no_radar_circles)
 319                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 320                 }
 321         }
 322
 323         // moved that here, also update if there's no player
 324         kh_show_temp();
 325         if(key.owner)
 326                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 327
 328         key.pusher = world;
 329
 330         ownerteam = kh_Key_AllOwnedByWhichTeam();
 331         if(ownerteam != ownerteam0)
 332         {
 333                 if(ownerteam != -1)
 334                 {
 335                         kh_interferemsg_time = time + 0.2;
 336                         kh_interferemsg_team = player.team;
 337
 338                         // audit all key carrier sprites, update them to RUN HERE
 339                         FOR_EACH_KH_KEY(k)
 340                         {
 341                                 if(k.owner)
 342                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model, "keycarrier-finish", "");
 343                         }
 344                 }
 345                 else
 346                 {
 347                         // audit all key carrier sprites, update them to RUN HERE
 348                         FOR_EACH_KH_KEY(k)
 349                         {
 350                                 if(k.owner)
 351                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model, "keycarrier-friend", "");
 352                         }
 353                 }
 354         }
 355 }
 356
 357 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 358 {
 359         if(self.owner)
 360                 return;
 361         if(vlen(force) <= 0)
 362                 return;
 363         if(time > self.pushltime)
 364                 if(attacker.classname == "player")
 365                         self.team = attacker.team;
 366 }
 367
 368 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 369 {
 370         entity key;
 371         key = spawn();
 372         key.classname = STR_ITEM_KH_KEY;
 373         key.touch = kh_Key_Touch;
 374         key.think = kh_Key_Think;
 375         key.nextthink = time;
 376         key.items = IT_KEY1 | IT_KEY2;
 377         key.cnt = angle;
 378         key.angles = '0 360 0' * random();
 379         key.event_damage = kh_Key_Damage;
 380         key.takedamage = DAMAGE_YES;
 381         key.modelindex = kh_key_dropped;
 382         key.model = "key";
 383         key.kh_dropperteam = 0;
 384         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 385         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 386         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 387
 388         switch(initial_owner.team)
 389         {
 390                 case COLOR_TEAM1:
 391                         key.netname = "^1red key";
 392                         break;
 393                 case COLOR_TEAM2:
 394                         key.netname = "^4blue key";
 395                         break;
 396                 case COLOR_TEAM3:
 397                         key.netname = "^3yellow key";
 398                         break;
 399                 case COLOR_TEAM4:
 400                         key.netname = "^6pink key";
 401                         break;
 402                 default:
 403                         key.netname = "NETGIER key";
 404                         break;
 405         }
 406
 407         // link into key list
 408         key.kh_worldkeynext = kh_worldkeylist;
 409         kh_worldkeylist = key;
 410
 411         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 412
 413         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 414         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 415         WaypointSprite_UpdateTeamRadar(key.waypointsprite_attachedforcarrier, RADARICON_FLAG, '0 1 1');
 416
 417         kh_Key_AssignTo(key, initial_owner);
 418 }
 419
 420 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 421 {
 422         entity o;
 423         o = key.owner;
 424         kh_Key_AssignTo(key, world);
 425         if(o) // it was attached
 426                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 427         else // it was dropped
 428                 WaypointSprite_DetachCarrier(key);
 429
 430         // remove key from key list
 431         if (kh_worldkeylist == key)
 432                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 433         else
 434         {
 435                 o = kh_worldkeylist;
 436                 while (o)
 437                 {
 438                         if (o.kh_worldkeynext == key)
 439                         {
 440                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 441                                 break;
 442                         }
 443                         o = o.kh_worldkeynext;
 444                 }
 445         }
 446
 447         remove(key);
 448 }
 449
 450 // -1 when no team completely owns all keys yet
 451 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 452 {
 453         entity key;
 454         float teem;
 455
 456         teem = -1;
 457         FOR_EACH_KH_KEY(key)
 458         {
 459                 if(!key.owner)
 460                         return -1;
 461                 if(teem == -1)
 462                         teem = key.team;
 463                 else if(teem != key.team)
 464                         return -1;
 465         }
 466         return teem;
 467 }
 468
 469 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 470 {
 471         float ownerteam;
 472         entity k;
 473
 474         sound(player, CHAN_AUTO, kh_sound_collect, VOL_BASE, ATTN_NORM);
 475
 476         if(key.kh_dropperteam != player.team)
 477         {
 478                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 479                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 480         }
 481         key.kh_dropperteam = 0;
 482         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 483
 484         kh_Key_AssignTo(key, player); // this also updates .kh_state
 485 }
 486
 487 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 488 {
 489         entity key;
 490         entity mypusher;
 491         if(player.kh_next)
 492         {
 493                 mypusher = world;
 494                 if(player.pusher)
 495                         if(time < player.pushltime)
 496                                 mypusher = player.pusher;
 497                 while((key = player.kh_next))
 498                 {
 499                         kh_Scores_Event(player, key, "losekey", 0, 0);
 500                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 501                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 502                         kh_Key_AssignTo(key, world);
 503                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 504                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 505                         key.pusher = mypusher;
 506                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 507                         if(suicide)
 508                                 key.kh_dropperteam = player.team;
 509                 }
 510                 sound(player, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 511         }
 512 }
 513
 514 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 515 {
 516         if(intermission_running)
 517                 return;
 518
 519         if(self.owner) // already carried
 520                 return;
 521         if(other.classname != "player")
 522                 return;
 523         if(other.deadflag != DEAD_NO)
 524                 return;
 525         if(other == self.enemy)
 526                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 527                         return;  // you just dropped it!
 528         kh_Key_Collect(self, other);
 529 }
 530
 531 void kh_Key_Think()  // runs all the time
 532 {
 533         entity head;
 534         //entity player;  // needed by FOR_EACH_PLAYER
 535
 536         if(intermission_running)
 537                 return;
 538         /*
 539         if(time > self.stuff_time)
 540         {
 541                 FOR_EACH_PLAYER(player)
 542                         player.kh_state = test[0]*256 + (player.kh_state&255);
 543
 544                 self.stuff_time = time + 1;  // repeat in 1 second
 545         }
 546         */
 547
 548 #ifdef KH_KEY_ATTACHMENT_DEBUG
 549         if(self.kh_prev == self.owner)
 550         {
 551                 if(cvar_string("_angles") != "")
 552                 {
 553                         self.angles = stov(cvar_string("_angles"));
 554                         self.origin = stov(cvar_string("_origin"));
 555                 }
 556         }
 557 #endif
 558
 559         if(self.owner)
 560         {
 561 #ifndef KH_PLAYER_USE_ATTACHMENT
 562                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 563                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 564 #endif
 565
 566                 if(self.owner.BUTTON_USE)
 567                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 568                 {
 569                         self.owner.kh_droptime = time;
 570                         self.kh_droptime = time;  // prevent collecting this one for some time
 571                         self.enemy = self.owner;
 572                         self.pusher = world;
 573                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 574                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 575                         sound(self.owner, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 576                         makevectors(self.owner.v_angle);
 577                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 578                         kh_Key_AssignTo(self, world);
 579                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 580                         self.kh_dropperteam = self.team;
 581                 }
 582         }
 583
 584         // if in nodrop or time over, end the round
 585         if(!self.owner)
 586                 if(time > self.pain_finished)
 587                         kh_LoserTeam(self.team, self);
 588
 589         if(self.owner)
 590         if(kh_Key_AllOwnedByWhichTeam() != -1)
 591         {
 592                 if(self.siren_time < time)
 593                 {
 594                         sound(self.owner, CHAN_AUTO, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 595                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 596                 }
 597
 598                 entity key;
 599                 vector p;
 600                 p = self.owner.origin;
 601                 FOR_EACH_KH_KEY(key)
 602                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 603                                 goto not_winning;
 604                 kh_WinnerTeam(self.team);
 605 :not_winning
 606         }
 607
 608         if(kh_interferemsg_time && time > kh_interferemsg_time)
 609         {
 610                 kh_interferemsg_time = 0;
 611                 FOR_EACH_PLAYER(head)
 612                 {
 613                         if(head.team == kh_interferemsg_team)
 614                                 if(head.kh_next)
 615                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 616                                 else
 617                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 618                         else
 619                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 620                 }
 621         }
 622
 623         self.nextthink = time + 0.05;
 624 }
 625
 626 void kh_WinnerTeam(float teem)  // runs when a team wins
 627 {
 628         // all key carriers get some points
 629         vector firstorigin, lastorigin, midpoint;
 630         float first;
 631         entity key;
 632         float score;
 633         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 634         DistributeEvenly_Init(score, kh_teams);
 635         // twice the score for 3 team games, three times the score for 4 team games!
 636         // note: for a win by destroying the key, this should NOT be applied
 637         FOR_EACH_KH_KEY(key)
 638         {
 639                 float f;
 640                 f = DistributeEvenly_Get(1);
 641                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 642                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 643         }
 644
 645         first = TRUE;
 646         FOR_EACH_KH_KEY(key)
 647                 if(key.owner.kh_next == key)
 648                 {
 649                         if(!first)
 650                                 bprint("^7, ");
 651                         bprint(key.owner.netname);
 652                         first = FALSE;
 653                 }
 654         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 655
 656         first = TRUE;
 657         midpoint = '0 0 0';
 658         FOR_EACH_KH_KEY(key)
 659         {
 660                 vector thisorigin;
 661
 662                 thisorigin = kh_AttachedOrigin(key);
 663                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 664                 midpoint += thisorigin;
 665
 666                 if(!first)
 667                         te_lightning2(world, lastorigin, thisorigin);
 668                 lastorigin = thisorigin;
 669                 if(first)
 670                         firstorigin = thisorigin;
 671                 first = FALSE;
 672         }
 673         if(kh_teams > 2)
 674         {
 675                 te_lightning2(world, lastorigin, firstorigin);
 676         }
 677         midpoint = midpoint * (1 / kh_teams);
 678         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 679
 680         play2all(kh_sound_capture);
 681         kh_FinishRound();
 682 }
 683
 684 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 685 {
 686         entity player, key, attacker;
 687         float players;
 688         float keys;
 689         float f;
 690
 691         attacker = world;
 692         if(lostkey.pusher)
 693                 if(lostkey.pusher.team != teem)
 694                         if(lostkey.pusher.classname == "player")
 695                                 attacker = lostkey.pusher;
 696
 697         players = keys = 0;
 698
 699         if(attacker)
 700         {
 701                 if(lostkey.kh_previous_owner)
 702                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 703                         // don't actually GIVE him the -nn points, just log
 704                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 705                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 706                 centerprint(attacker, "Your push is the best!\n\n\n");
 707                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 708         }
 709         else
 710         {
 711                 float of, fragsleft, i, j, thisteam;
 712                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 713
 714                 FOR_EACH_PLAYER(player)
 715                         if(player.team != teem)
 716                                 ++players;
 717
 718                 FOR_EACH_KH_KEY(key)
 719                         if(key.owner && key.team != teem)
 720                                 ++keys;
 721
 722                 if(lostkey.kh_previous_owner)
 723                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 724                         // don't actually GIVE him the -nn points, just log
 725
 726                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 727                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 728
 729                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 730
 731                 FOR_EACH_KH_KEY(key)
 732                         if(key.owner && key.team != teem)
 733                         {
 734                                 f = DistributeEvenly_Get(of);
 735                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 736                         }
 737
 738                 fragsleft = DistributeEvenly_Get(players);
 739
 740                 // Now distribute these among all other teams...
 741                 j = kh_teams - 1;
 742                 for(i = 0; i < kh_teams; ++i)
 743                 {
 744                         thisteam = kh_Team_ByID(i);
 745                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 746                                 continue;
 747
 748                         players = 0;
 749                         FOR_EACH_PLAYER(player)
 750                                 if(player.team == thisteam)
 751                                         ++players;
 752
 753                         DistributeEvenly_Init(fragsleft, j);
 754                         fragsleft = DistributeEvenly_Get(j - 1);
 755                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 756
 757                         FOR_EACH_PLAYER(player)
 758                                 if(player.team == thisteam)
 759                                 {
 760                                         f = DistributeEvenly_Get(1);
 761                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 762                                 }
 763
 764                         --j;
 765                 }
 766
 767                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 768         }
 769         play2all(kh_sound_destroy);
 770         te_tarexplosion(lostkey.origin);
 771
 772         kh_FinishRound();
 773 }
 774
 775 void kh_FinishRound()  // runs when a team captures the keys
 776 {
 777         // prepare next round
 778         kh_interferemsg_time = 0;
 779         entity key;
 780
 781         kh_no_radar_circles = TRUE;
 782         FOR_EACH_KH_KEY(key)
 783                 kh_Key_Remove(key);
 784         kh_no_radar_circles = FALSE;
 785
 786         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 787 }
 788
 789 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 790 {
 791         float i, players, teem;
 792         entity player;
 793         string result;
 794         result = "";
 795
 796         // find a random player per team
 797         for(i = 0; i < kh_teams; ++i)
 798         {
 799                 teem = kh_Team_ByID(i);
 800                 players = 0;
 801                 FOR_EACH_PLAYER(player)
 802                         if(player.deadflag == DEAD_NO)
 803                                 if(!player.BUTTON_CHAT)
 804                                         if(player.team == teem)
 805                                                 ++players;
 806                 if(players == 0)
 807                 {
 808                         if(result != "")
 809                                 result = strcat(result, ", ");
 810                         result = strcat(result, ColoredTeamName(teem));
 811                 }
 812         }
 813         return result;
 814 }
 815
 816 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 817 {
 818         string teams_missing;
 819         teams_missing = kh_CheckEnoughPlayers();
 820         if(teams_missing == "")
 821                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 822         else
 823                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 824 }
 825
 826 void kh_StartRound()  // runs at the start of each round
 827 {
 828         string teams_missing;
 829         float i, players, teem;
 830         entity player;
 831
 832         teams_missing = kh_CheckEnoughPlayers();
 833         if(teams_missing != "")
 834         {
 835                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 836                 return;
 837         }
 838
 839         FOR_EACH_PLAYER(player)
 840                 if(clienttype(player) == CLIENTTYPE_REAL)
 841                         centerprint_expire(player, CENTERPRIO_SPAM);
 842
 843         for(i = 0; i < kh_teams; ++i)
 844         {
 845                 teem = kh_Team_ByID(i);
 846                 players = 0;
 847                 entity my_player;
 848                 FOR_EACH_PLAYER(player)
 849                         if(player.deadflag == DEAD_NO)
 850                                 if(!player.BUTTON_CHAT)
 851                                         if(player.team == teem)
 852                                         {
 853                                                 ++players;
 854                                                 if(random() * players <= 1)
 855                                                         my_player = player;
 856                                         }
 857                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 858                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 859                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 860         }
 861
 862         kh_tracking_enabled = FALSE;
 863         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 864 }
 865
 866 void kh_setstatus()  // runs all the time
 867 {
 868         if(kh_teams)
 869         {
 870                 float kh_KEY;
 871                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 872                 if(self.kh_next)
 873                         self.items = self.items | kh_KEY;
 874                 else
 875                         self.items = self.items - (self.items & kh_KEY);
 876         }
 877 }
 878
 879 void kh_EnableTrackingDevice()  // runs after each round
 880 {
 881         entity player;
 882
 883         FOR_EACH_PLAYER(player)
 884                 if(clienttype(player) == CLIENTTYPE_REAL)
 885                         centerprint_expire(player, CENTERPRIO_SPAM);
 886
 887         kh_tracking_enabled = TRUE;
 888 }
 889
 890 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
 891 {
 892         if(!kh_tracking_enabled)
 893                 return FALSE;
 894         if(!self.owner)
 895                 return TRUE;
 896         if(!self.owner.owner)
 897                 return TRUE;
 898         return FALSE;  // draw only when key is not owned
 899 }
 900
 901 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
 902 {
 903         if(e.classname != "player" || self.team != e.team)
 904                 if(!kh_tracking_enabled)
 905                         return FALSE;
 906
 907         return TRUE;
 908 }
 909
 910 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 911 {
 912         if(attacker == targ)
 913                 return f;
 914
 915         if(targ.kh_next)
 916         {
 917                 if(attacker.team == targ.team)
 918                 {
 919                         entity k;
 920                         float nk;
 921                         nk = 0;
 922                         for(k = targ.kh_next; k != world; k = k.kh_next)
 923                                 ++nk;
 924                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 925                 }
 926                 else
 927                 {
 928                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 929                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 930                         // the frag gets added later
 931                 }
 932         }
 933
 934         return f;
 935 }
 936
 937 void kh_init()  // sets up th KH environment
 938 {
 939         precache_sound(kh_sound_capture);
 940         precache_sound(kh_sound_destroy);
 941         precache_sound(kh_sound_drop);
 942         precache_sound(kh_sound_collect);
 943         precache_sound(kh_sound_alarm);  // the new siren
 944
 945 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 946         precache_model("models/keyhunt/key-carried.md3");
 947 #endif
 948         precache_model("models/keyhunt/key.md3");
 949
 950         // setup variables
 951         kh_teams = cvar("g_keyhunt_teams_override");
 952         if(kh_teams < 2)
 953                 kh_teams = cvar("g_keyhunt_teams");
 954         kh_teams = bound(2, kh_teams, 4);
 955
 956         // make a KH entity for controlling the game
 957         kh_controller = spawn();
 958         kh_controller.think = kh_Controller_Think;
 959         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 960
 961         setmodel(kh_controller, "models/keyhunt/key.md3");
 962         kh_key_dropped = kh_controller.modelindex;
 963         /*
 964         dprint(vtos(kh_controller.mins));
 965         dprint(vtos(kh_controller.maxs));
 966         dprint("\n");
 967         */
 968 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 969         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 970         kh_key_carried = kh_controller.modelindex;
 971 #else
 972         kh_key_carried = kh_key_dropped;
 973 #endif
 974
 975         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 976
 977         ScoreRules_kh(kh_teams);
 978 }
 979
 980 void kh_finalize()
 981 {
 982         // to be called before intermission
 983         kh_FinishRound();
 984         remove(kh_controller);
 985         kh_controller = world;
 986 }
 987
 988 /**
 989  * kh_show_temp originally by victim.
 990  * changed it to use the kh_state stat var
 991  * Updates the general key stat bits for each player
 992  */
 993 void kh_show_temp()
 994 {
 995         entity player;
 996         float i, j;
 997
 998         j = 0;  // reset/blank j
 999         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
1000                 j += test[i];
1001
1002         test[0] = j;
1003
1004         j *= 256;
1005         FOR_EACH_PLAYER(player)
1006                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
1007 }