data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 // #define KH_PLAYER_USE_ATTACHMENT
   5 // #define KH_PLAYER_USE_CARRIEDMODEL
   6 // #define KH_KEY_ATTACHMENT_DEBUG
   7
   8 #ifdef KH_PLAYER_USE_ATTACHMENT
   9 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  10 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  11 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  12 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  13 string KH_PLAYER_ATTACHMENT_BONE = "";
  14 #else
  15 float KH_KEY_ZSHIFT = 22;
  16 float KH_KEY_XYDIST = 24;
  17 float KH_KEY_XYSPEED = 45;
  18 #endif
  19 float KH_KEY_WP_ZSHIFT = 20;
  20
  21 vector KH_KEY_MIN = '-10 -10 -46';
  22 vector KH_KEY_MAX = '10 10 3';
  23 float KH_KEY_BRIGHTNESS = 0.015625;
  24
  25 typedef void(void) kh_Think_t;
  26 var kh_Think_t kh_Controller_Thinkfunc;
  27 string kh_Controller_Waitmsg;
  28
  29 float kh_Team_ByID(float t)
  30 {
  31         if(t == 0) return COLOR_TEAM1;
  32         if(t == 1) return COLOR_TEAM2;
  33         if(t == 2) return COLOR_TEAM3;
  34         if(t == 3) return COLOR_TEAM4;
  35         return 0;
  36 }
  37
  38 vector kh_average_teamcolor;
  39 entity kh_controller;
  40 float kh_tracking_enabled;
  41 float kh_teams;
  42 float kh_interferemsg_time, kh_interferemsg_team;
  43 .entity kh_next, kh_prev; // linked list
  44 .float kh_droptime;
  45 .float kh_dropperteam;
  46
  47 string kh_sound_capture = "sound/ctf/capture.wav";
  48 string kh_sound_destroy = "sound/ctf/return.wav";
  49 string kh_sound_drop = "sound/misc/mouseclick.wav";
  50 string kh_sound_collect = "sound/ctf/take.wav";
  51
  52 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  53 float kh_key_dropped, kh_key_carried;
  54
  55 float kh_GetCarrierSprite(float t, float e)
  56 {
  57         if(t == e)           return kh_sprite_friend;
  58         if(t == COLOR_TEAM1) return kh_sprite_red;
  59         if(t == COLOR_TEAM2) return kh_sprite_blue;
  60         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  61         if(t == COLOR_TEAM4) return kh_sprite_pink;
  62         return 0;
  63 }
  64
  65 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  66 {
  67         kh_Controller_Thinkfunc = func;
  68         kh_controller.cnt = t;
  69         if(kh_Controller_Waitmsg != "")
  70                 strunzone(kh_Controller_Waitmsg);
  71         if(msg == "")
  72                 kh_Controller_Waitmsg = "";
  73         else
  74                 kh_Controller_Waitmsg = strzone(msg);
  75         if(t == 0)
  76                 kh_controller.nextthink = time; // force
  77 }
  78
  79 void kh_Controller_Think()
  80 {
  81         entity e;
  82         if(intermission_running)
  83                 return;
  84         if(self.cnt > 0)
  85         {
  86                 if(kh_Controller_Waitmsg != "")
  87                 {
  88                         string s;
  89                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  90                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  91                         else
  92                                 s = kh_Controller_Waitmsg;
  93
  94                         //dprint(s, "\n");
  95
  96                         FOR_EACH_PLAYER(e)
  97                                 if(clienttype(e) == CLIENTTYPE_REAL)
  98                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  99                 }
 100                 self.cnt -= 1;
 101         }
 102         else if(self.cnt == 0)
 103         {
 104                 self.cnt -= 1;
 105                 kh_Controller_Thinkfunc();
 106         }
 107         self.nextthink = time + 1;
 108 }
 109
 110 // frags f: take from cvar * f
 111 // frags 0: no frags
 112 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 113 {
 114         string s;
 115         if(intermission_running)
 116                 return;
 117         if(frags_player)
 118                 player.frags = player.frags + floor(0.5 + frags_player);
 119         if(frags_owner)
 120                 key.owner.frags = key.owner.frags + floor(0.5 + frags_owner);
 121         if(!cvar("sv_eventlog"))
 122                 return;
 123         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 124         s = strcat(s, ":", ftos(frags_player));
 125         if(key && key.owner)
 126                 s = strcat(s, ":", ftos(key.owner.playerid));
 127         else
 128                 s = strcat(s, ":0");
 129         s = strcat(s, ":", ftos(frags_owner), ":");
 130         if(key)
 131                 s = strcat(s, key.netname);
 132         GameLogEcho(s, FALSE);
 133 }
 134
 135 vector kh_AttachedOrigin(entity e)
 136 {
 137         if(e.tag_entity)
 138         {
 139                 makevectors(e.tag_entity.angles);
 140                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 141         }
 142         else
 143                 return e.origin;
 144 }
 145
 146 void kh_Key_Attach(entity key)
 147 {
 148 #ifdef KH_PLAYER_USE_ATTACHMENT
 149         entity first;
 150         first = key.owner.kh_next;
 151         if(key == first)
 152         {
 153                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 154                 if(key.kh_next)
 155                 {
 156                         setattachment(key.kh_next, key, "");
 157                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 158                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 159                         key.kh_next.angles = '0 0 0';
 160                 }
 161                 else
 162                         setorigin(key, KH_PLAYER_ATTACHMENT);
 163                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 164         }
 165         else
 166         {
 167                 setattachment(key, key.kh_prev, "");
 168                 if(key.kh_next)
 169                         setattachment(key.kh_next, key, "");
 170                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 171                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 172                 key.angles = '0 0 0';
 173         }
 174 #else
 175         setattachment(key, key.owner, "");
 176         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 177         key.angles_y -= key.owner.angles_y;
 178 #endif
 179         key.flags = 0;
 180         key.solid = SOLID_NOT;
 181         key.movetype = MOVETYPE_NONE;
 182         key.team = key.owner.team;
 183         key.nextthink = time;
 184         key.damageforcescale = 0;
 185         key.modelindex = kh_key_carried;
 186 }
 187
 188 void kh_Key_Detach(entity key)
 189 {
 190 #ifdef KH_PLAYER_USE_ATTACHMENT
 191         entity first;
 192         first = key.owner.kh_next;
 193         if(key == first)
 194         {
 195                 if(key.kh_next)
 196                 {
 197                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 198                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 199                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 200                 }
 201         }
 202         else
 203         {
 204                 if(key.kh_next)
 205                         setattachment(key.kh_next, key.kh_prev, "");
 206                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 207         }
 208         // in any case:
 209         setattachment(key, world, "");
 210         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 211         key.angles = key.owner.angles;
 212 #else
 213         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 214         setattachment(key, world, "");
 215         key.angles_y += key.owner.angles_y;
 216 #endif
 217         key.aiment = world;
 218         key.flags = FL_ITEM;
 219         key.solid = SOLID_TRIGGER;
 220         key.movetype = MOVETYPE_TOSS;
 221         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 222         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 223         // let key.team stay
 224         key.modelindex = kh_key_dropped;
 225 }
 226
 227 void kh_Key_AssignTo(entity key, entity player)
 228 {
 229         if(key.owner == player)
 230                 return;
 231
 232         if(key.owner)
 233         {
 234                 kh_Key_Detach(key);
 235
 236                 // remove from linked list
 237                 if(key.kh_next)
 238                         key.kh_next.kh_prev = key.kh_prev;
 239                 key.kh_prev.kh_next = key.kh_next;
 240                 key.kh_next = world;
 241                 key.kh_prev = world;
 242
 243                 if(key.owner.kh_next == world)
 244                 {
 245                         // No longer a key carrier
 246                         WaypointSprite_DetachCarrier(key.owner);
 247                 }
 248         }
 249
 250         key.owner = player;
 251
 252         if(player)
 253         {
 254                 // insert into linked list
 255                 key.kh_next = player.kh_next;
 256                 key.kh_prev = player;
 257                 player.kh_next = key;
 258                 if(key.kh_next)
 259                         key.kh_next.kh_prev = key;
 260
 261                 kh_Key_Attach(key);
 262
 263                 if(key.kh_next == world)
 264                 {
 265                         // player is now a key carrier
 266                         WaypointSprite_AttachCarrier("", player);
 267                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 268                         player.waypointsprite_attachedforcarrier.team = player.team;
 269                 }
 270         }
 271
 272         key.pusher = world;
 273 }
 274
 275 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 276 {
 277         if(self.owner)
 278                 return;
 279         if(vlen(force) <= 0)
 280                 return;
 281         if(time > self.pushltime)
 282                 if(attacker.classname == "player")
 283                         self.team = attacker.team;
 284 }
 285
 286 void kh_Key_Spawn(entity initial_owner, float angle)
 287 {
 288         entity key;
 289         key = spawn();
 290         key.classname = STR_ITEM_KH_KEY;
 291         key.touch = kh_Key_Touch;
 292         key.think = kh_Key_Think;
 293         key.nextthink = time;
 294         key.items = IT_KEY1 | IT_KEY2;
 295         key.cnt = angle;
 296         key.angles = '0 360 0' * random();
 297         key.event_damage = kh_Key_Damage;
 298         key.modelindex = kh_key_dropped;
 299         key.model = "key";
 300         key.kh_dropperteam = 0;
 301         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 302
 303         switch(initial_owner.team)
 304         {
 305                 case COLOR_TEAM1:
 306                         key.netname = "^1red key";
 307                         key.colormod = '103 0 0' * KH_KEY_BRIGHTNESS;
 308                         kh_average_teamcolor += key.colormod;
 309                         break;
 310                 case COLOR_TEAM2:
 311                         key.netname = "^4blue key";
 312                         key.colormod = '35 35 191' * KH_KEY_BRIGHTNESS;
 313                         kh_average_teamcolor += key.colormod;
 314                         break;
 315                 case COLOR_TEAM3:
 316                         key.netname = "^3yellow key";
 317                         key.colormod = '187 167 15' * KH_KEY_BRIGHTNESS;
 318                         kh_average_teamcolor += key.colormod;
 319                         break;
 320                 case COLOR_TEAM4:
 321                         key.netname = "^6pink key";
 322                         key.colormod = '139 79 107' * KH_KEY_BRIGHTNESS;
 323                         kh_average_teamcolor += key.colormod;
 324                         break;
 325                 default:
 326                         key.netname = "NETGIER key";
 327                         key.colormod = '1 1 1';
 328                         break;
 329         }
 330
 331         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 332
 333         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 334         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 335
 336         kh_Key_AssignTo(key, initial_owner);
 337 }
 338
 339 void kh_Key_Remove(entity key)
 340 {
 341         entity o;
 342         o = key.owner;
 343         kh_Key_AssignTo(key, world);
 344         if(o) // it was attached
 345                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 346         else // it was dropped
 347                 WaypointSprite_DetachCarrier(key);
 348
 349         remove(key);
 350 }
 351
 352 // -1 when no team completely owns all keys yet
 353 float kh_Key_AllOwnedByWhichTeam()
 354 {
 355         entity key;
 356         float teem;
 357
 358         teem = -1;
 359         FOR_EACH_KH_KEY(key)
 360         {
 361                 if(!key.owner)
 362                         return -1;
 363                 if(teem == -1)
 364                         teem = key.team;
 365                 else if(teem != key.team)
 366                         return -1;
 367         }
 368         return teem;
 369 }
 370
 371 void kh_Key_Collect(entity key, entity player)
 372 {
 373         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 374
 375         if(key.kh_dropperteam != player.team)
 376                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 377         key.kh_dropperteam = 0;
 378         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 379         kh_Key_AssignTo(key, player);
 380
 381         if(kh_Key_AllOwnedByWhichTeam() != -1)
 382         {
 383                 kh_interferemsg_time = time + 0.2;
 384                 kh_interferemsg_team = player.team;
 385         }
 386 }
 387
 388 void kh_Key_DropAll(entity player, float suicide)
 389 {
 390         entity key;
 391         entity mypusher;
 392         if(player.kh_next)
 393         {
 394                 mypusher = world;
 395                 if(player.pusher)
 396                         if(time < player.pushltime)
 397                                 mypusher = player.pusher;
 398                 while((key = player.kh_next))
 399                 {
 400                         kh_Scores_Event(player, key, "losekey", 0, 0);
 401                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 402                         kh_Key_AssignTo(key, world);
 403                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 404                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 405                         key.pusher = mypusher;
 406                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 407                         if(suicide)
 408                                 key.kh_dropperteam = player.team;
 409                 }
 410                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 411         }
 412 }
 413
 414 void kh_Key_Touch()
 415 {
 416         if(intermission_running)
 417                 return;
 418
 419         if(self.owner) // already carried
 420                 return;
 421         if(other.classname != "player")
 422                 return;
 423         if(other.deadflag != DEAD_NO)
 424                 return;
 425         if(other == self.enemy)
 426                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 427                         return; // you just dropped it!
 428         kh_Key_Collect(self, other);
 429 }
 430
 431 void kh_Key_Think()
 432 {
 433         entity head;
 434
 435         if(intermission_running)
 436                 return;
 437
 438 #ifdef KH_KEY_ATTACHMENT_DEBUG
 439         if(self.kh_prev == self.owner)
 440         {
 441                 if(cvar_string("_angles") != "")
 442                 {
 443                         self.angles = stov(cvar_string("_angles"));
 444                         self.origin = stov(cvar_string("_origin"));
 445                 }
 446         }
 447 #endif
 448
 449         if(self.owner)
 450         {
 451 #ifndef KH_PLAYER_USE_ATTACHMENT
 452                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * KH_KEY_XYSPEED));
 453                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 454 #endif
 455
 456                 if(self.owner.buttonuse)
 457                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 458                 {
 459                         self.owner.kh_droptime = time;
 460                         self.kh_droptime = time; // prevent collecting this one for some time
 461                         self.enemy = self.owner;
 462                         self.pusher = world;
 463                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 464                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 465                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 466                         makevectors(self.owner.v_angle);
 467                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 468                         kh_Key_AssignTo(self, world);
 469                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 470                         self.kh_dropperteam = self.team;
 471                 }
 472         }
 473
 474         // if in nodrop or time over, end the round
 475         if(!self.owner)
 476                 if(time > self.pain_finished)
 477                         kh_LoserTeam(self.team, self);
 478
 479         if(self.owner)
 480         if(kh_Key_AllOwnedByWhichTeam() != -1)
 481         {
 482                 entity key;
 483                 vector p;
 484                 p = self.owner.origin;
 485                 FOR_EACH_KH_KEY(key)
 486                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 487                                 goto not_winning;
 488                 kh_WinnerTeam(self.team);
 489 :not_winning
 490         }
 491
 492         if(kh_interferemsg_time && time > kh_interferemsg_time)
 493         {
 494                 kh_interferemsg_time = 0;
 495                 FOR_EACH_PLAYER(head)
 496                 {
 497                         if(head.team == kh_interferemsg_team)
 498                                 if(head.kh_next)
 499                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 500                                 else
 501                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 502                         else
 503                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 504                 }
 505         }
 506
 507         self.nextthink = time + 0.05;
 508 }
 509
 510 void kh_WinnerTeam(float teem)
 511 {
 512         // all key carriers get some points
 513         vector firstorigin, lastorigin, midpoint;
 514         float first;
 515         entity key;
 516         float score;
 517         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 518         DistributeEvenly_Init(score, kh_teams);
 519         // twice the score for 3 team games, three times the score for 4 team games!
 520         // note: for a win by destroying the key, this should NOT be applied
 521         FOR_EACH_KH_KEY(key)
 522                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 523
 524         first = TRUE;
 525         FOR_EACH_KH_KEY(key)
 526                 if(key.owner.kh_next == key)
 527                 {
 528                         if(!first)
 529                                 bprint("^7, ");
 530                         bprint(key.owner.netname);
 531                         first = FALSE;
 532                 }
 533         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 534
 535         first = TRUE;
 536         midpoint = '0 0 0';
 537         FOR_EACH_KH_KEY(key)
 538         {
 539                 vector thisorigin;
 540
 541                 thisorigin = kh_AttachedOrigin(key);
 542                 dprint("Key origin: ", vtos(thisorigin), "\n");
 543                 midpoint += thisorigin;
 544
 545                 if(!first)
 546                         te_lightning2(world, lastorigin, thisorigin);
 547                 lastorigin = thisorigin;
 548                 if(first)
 549                         firstorigin = thisorigin;
 550                 first = FALSE;
 551         }
 552         if(kh_teams > 2)
 553         {
 554                 te_lightning2(world, lastorigin, firstorigin);
 555         }
 556         midpoint = midpoint * (1 / kh_teams);
 557         //dprint("Custom flash around ", vtos(midpoint), " color ", vtos(kh_average_teamcolor), "\n");
 558         te_customflash(midpoint, 1000, 1, kh_average_teamcolor);
 559
 560         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 561         kh_FinishRound();
 562 }
 563
 564 void kh_LoserTeam(float teem, entity lostkey)
 565 {
 566         entity player, key, attacker;
 567         float players;
 568         float keys;
 569
 570         attacker = world;
 571         if(lostkey.pusher)
 572                 if(lostkey.pusher.team != teem)
 573                         if(lostkey.pusher.classname == "player")
 574                                 attacker = lostkey.pusher;
 575
 576         players = keys = 0;
 577
 578         if(attacker)
 579         {
 580                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 581                 centerprint(attacker, "Your push is the best!\n\n\n");
 582                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 583         }
 584         else
 585         {
 586                 float of, fragsleft, i, j, thisteam;
 587                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 588
 589                 FOR_EACH_PLAYER(player)
 590                         if(player.team != teem)
 591                                 ++players;
 592
 593                 FOR_EACH_KH_KEY(key)
 594                         if(key.owner && key.team != teem)
 595                                 ++keys;
 596
 597                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 598
 599                 FOR_EACH_KH_KEY(key)
 600                         if(key.owner && key.team != teem)
 601                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 602
 603                 fragsleft = DistributeEvenly_Get(players);
 604
 605                 // Now distribute these among all other teams...
 606                 j = kh_teams - 1;
 607                 for(i = 0; i < kh_teams; ++i)
 608                 {
 609                         thisteam = kh_Team_ByID(i);
 610                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 611                                 continue;
 612
 613                         players = 0;
 614                         FOR_EACH_PLAYER(player)
 615                                 if(player.team == thisteam)
 616                                         ++players;
 617
 618                         DistributeEvenly_Init(fragsleft, j);
 619                         fragsleft = DistributeEvenly_Get(j - 1);
 620                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 621
 622                         FOR_EACH_PLAYER(player)
 623                                 if(player.team == thisteam)
 624                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 625
 626                         --j;
 627                 }
 628
 629                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 630         }
 631         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 632         te_tarexplosion(lostkey.origin);
 633
 634         kh_FinishRound();
 635 }
 636
 637 void kh_FinishRound()
 638 {
 639         // prepare next round
 640         kh_interferemsg_time = 0;
 641         entity key;
 642         FOR_EACH_KH_KEY(key)
 643                 kh_Key_Remove(key);
 644
 645         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 646 }
 647
 648 string kh_CheckEnoughPlayers()
 649 {
 650         float i, players, teem;
 651         entity player;
 652         string result;
 653         result = "";
 654
 655         // find a random player per team
 656         for(i = 0; i < kh_teams; ++i)
 657         {
 658                 teem = kh_Team_ByID(i);
 659                 players = 0;
 660                 FOR_EACH_PLAYER(player)
 661                         if(player.deadflag == DEAD_NO)
 662                                 if(!player.buttonchat)
 663                                         if(player.team == teem)
 664                                                 ++players;
 665                 if(players == 0)
 666                 {
 667                         if(result != "")
 668                                 result = strcat(result, ", ");
 669                         result = strcat(result, ColoredTeamName(teem));
 670                 }
 671         }
 672         return result;
 673 }
 674
 675 void kh_WaitForPlayers()
 676 {
 677         string teams_missing;
 678         teams_missing = kh_CheckEnoughPlayers();
 679         if(teams_missing == "")
 680                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 681         else
 682                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 683 }
 684
 685 void kh_StartRound()
 686 {
 687         string teams_missing;
 688         float i, players, teem;
 689         entity player;
 690
 691         teams_missing = kh_CheckEnoughPlayers();
 692         if(teams_missing != "")
 693         {
 694                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 695                 return;
 696         }
 697
 698         FOR_EACH_PLAYER(player)
 699                 if(clienttype(player) == CLIENTTYPE_REAL)
 700                         centerprint_expire(player, CENTERPRIO_SPAM);
 701
 702         kh_average_teamcolor = '0 0 0';
 703         for(i = 0; i < kh_teams; ++i)
 704         {
 705                 teem = kh_Team_ByID(i);
 706                 players = 0;
 707                 entity my_player;
 708                 FOR_EACH_PLAYER(player)
 709                         if(player.deadflag == DEAD_NO)
 710                                 if(!player.buttonchat)
 711                                         if(player.team == teem)
 712                                         {
 713                                                 ++players;
 714                                                 if(random() * players <= 1)
 715                                                         my_player = player;
 716                                         }
 717                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 718                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 719                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 720         }
 721
 722         kh_average_teamcolor = kh_average_teamcolor * (1 / max3(kh_average_teamcolor_x, kh_average_teamcolor_y, kh_average_teamcolor_z));
 723
 724         kh_tracking_enabled = FALSE;
 725         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 726 }
 727
 728 void kh_setstatus()
 729 {
 730         if(kh_teams)
 731         {
 732                 float kh_KEY;
 733                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 734                 if(self.kh_next)
 735                         self.items = self.items | kh_KEY;
 736                 else
 737                         self.items = self.items - (self.items & kh_KEY);
 738         }
 739 }
 740
 741 void kh_EnableTrackingDevice()
 742 {
 743         entity player;
 744
 745         FOR_EACH_PLAYER(player)
 746                 if(clienttype(player) == CLIENTTYPE_REAL)
 747                         centerprint_expire(player, CENTERPRIO_SPAM);
 748
 749         kh_tracking_enabled = TRUE;
 750 }
 751
 752 float kh_Key_waypointsprite_for_player(entity e)
 753 {
 754         if(!kh_tracking_enabled)
 755                 return 0;
 756         if(!self.owner)
 757                 return kh_sprite_dropped;
 758         if(!self.owner.owner)
 759                 return kh_sprite_dropped;
 760         return 0; // draw only when key is not owned
 761 }
 762
 763 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 764 {
 765         if(e.classname != "player" || self.team != e.team)
 766                 if(!kh_tracking_enabled)
 767                         return 0;
 768
 769         // e is spectator? That's no team mate...
 770         if(e.classname != "player")
 771                 return kh_GetCarrierSprite(self.team, -1);
 772
 773         // e is no key carrier: simple case...
 774         if(!e.kh_next)
 775                 return kh_GetCarrierSprite(self.team, e.team);
 776
 777         // e is a key carrier: if any key is dropped or owned by another team, show
 778         // the carrier sprite; otherwise show run here
 779         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 780                 return kh_sprite_finish;
 781
 782         return kh_GetCarrierSprite(self.team, e.team);
 783 }
 784
 785 float kh_HandleFrags(entity attacker, entity targ, float f)
 786 {
 787         if(attacker == targ)
 788                 return f;
 789
 790         if(targ.kh_next)
 791         {
 792                 if(attacker.team == targ.team)
 793                 {
 794                         entity k;
 795                         float nk;
 796                         nk = 0;
 797                         for(k = targ.kh_next; k != world; k = k.kh_next)
 798                                 ++nk;
 799                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 800                 }
 801                 else
 802                 {
 803                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 804                 }
 805         }
 806
 807         return f;
 808 }
 809
 810 void kh_init()
 811 {
 812         precache_sound(kh_sound_capture);
 813         precache_sound(kh_sound_destroy);
 814         precache_sound(kh_sound_drop);
 815         precache_sound(kh_sound_collect);
 816
 817         precache_model("models/sprites/key-dropped.sp2");
 818         precache_model("models/sprites/keycarrier-finish.sp2");
 819         precache_model("models/sprites/keycarrier-friend.sp2");
 820         precache_model("models/sprites/keycarrier-red.sp2");
 821         precache_model("models/sprites/keycarrier-blue.sp2");
 822         precache_model("models/sprites/keycarrier-yellow.sp2");
 823         precache_model("models/sprites/keycarrier-pink.sp2");
 824 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 825         precache_model("models/keyhunt/key-carried.md3");
 826 #endif
 827         precache_model("models/keyhunt/key.md3");
 828
 829         // setup variables
 830         kh_teams = cvar("g_keyhunt_teams_override");
 831         if(kh_teams < 2)
 832                 kh_teams = cvar("g_keyhunt_teams");
 833         kh_teams = bound(2, kh_teams, 4);
 834
 835         // make a KH entity for controlling the game
 836         kh_controller = spawn();
 837         kh_controller.think = kh_Controller_Think;
 838         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 839
 840         setmodel(kh_controller, "models/keyhunt/key.md3");
 841         kh_key_dropped = kh_controller.modelindex;
 842         /*
 843         dprint(vtos(kh_controller.mins));
 844         dprint(vtos(kh_controller.maxs));
 845         dprint("\n");
 846         */
 847 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 848         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 849         kh_key_carried = kh_controller.modelindex;
 850 #else
 851         kh_key_carried = kh_key_dropped;
 852 #endif
 853         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 854         kh_sprite_dropped = kh_controller.modelindex;
 855         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 856         kh_sprite_finish = kh_controller.modelindex;
 857         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 858         kh_sprite_friend = kh_controller.modelindex;
 859         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 860         kh_sprite_red = kh_controller.modelindex;
 861         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 862         kh_sprite_blue = kh_controller.modelindex;
 863         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 864         kh_sprite_pink = kh_controller.modelindex;
 865         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 866         kh_sprite_yellow = kh_controller.modelindex;
 867         setmodel(kh_controller, "");
 868 }
 869
 870 void kh_finalize()
 871 {
 872         // to be called before intermission
 873         kh_FinishRound();
 874         remove(kh_controller);
 875         kh_controller = world;
 876 }