data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 // #define KH_PLAYER_USE_ATTACHMENT
   5 // #define KH_PLAYER_USE_CARRIEDMODEL
   6 // #define KH_KEY_ATTACHMENT_DEBUG
   7
   8 #ifdef KH_PLAYER_USE_ATTACHMENT
   9 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  10 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  11 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  12 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  13 string KH_PLAYER_ATTACHMENT_BONE = "";
  14 #else
  15 float KH_KEY_ZSHIFT = -15;
  16 float KH_KEY_XYDIST = 24;
  17 float KH_KEY_XYSPEED = 45;
  18 #endif
  19
  20 vector KH_KEY_MIN = '-8 -8 -8';
  21 vector KH_KEY_MAX = '8 8 40';
  22
  23 typedef void(void) kh_Think_t;
  24 var kh_Think_t kh_Controller_Thinkfunc;
  25 string kh_Controller_Waitmsg;
  26
  27 float kh_Team_ByID(float t)
  28 {
  29         if(t == 0) return COLOR_TEAM1;
  30         if(t == 1) return COLOR_TEAM2;
  31         if(t == 2) return COLOR_TEAM3;
  32         if(t == 3) return COLOR_TEAM4;
  33         return 0;
  34 }
  35
  36 entity kh_controller;
  37 float kh_tracking_enabled;
  38 float kh_teams;
  39 float kh_interferemsg_time, kh_interferemsg_team;
  40 .entity kh_next, kh_prev; // linked list
  41 .float kh_droptime;
  42
  43 string kh_sound_capture = "sound/ctf/capture.wav";
  44 string kh_sound_destroy = "sound/ctf/return.wav";
  45 string kh_sound_drop = "sound/misc/mouseclick.wav";
  46 string kh_sound_collect = "sound/ctf/take.wav";
  47
  48 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  49 float kh_key_dropped, kh_key_carried;
  50
  51 float kh_GetCarrierSprite(float t, float e)
  52 {
  53         if(t == e)           return kh_sprite_friend;
  54         if(t == COLOR_TEAM1) return kh_sprite_red;
  55         if(t == COLOR_TEAM2) return kh_sprite_blue;
  56         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  57         if(t == COLOR_TEAM4) return kh_sprite_pink;
  58         return 0;
  59 }
  60
  61 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  62 {
  63         kh_Controller_Thinkfunc = func;
  64         kh_controller.cnt = t;
  65         if(kh_Controller_Waitmsg != "")
  66                 strunzone(kh_Controller_Waitmsg);
  67         if(msg == "")
  68                 kh_Controller_Waitmsg = "";
  69         else
  70                 kh_Controller_Waitmsg = strzone(msg);
  71         if(t == 0)
  72                 kh_controller.nextthink = time; // force
  73 }
  74
  75 void kh_Controller_Think()
  76 {
  77         entity e;
  78         if(intermission_running)
  79                 return;
  80         if(self.cnt > 0)
  81         {
  82                 if(kh_Controller_Waitmsg != "")
  83                 {
  84                         string s;
  85                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  86                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  87                         else
  88                                 s = kh_Controller_Waitmsg;
  89
  90                         //dprint(s, "\n");
  91
  92                         FOR_EACH_PLAYER(e)
  93                                 if(clienttype(e) == CLIENTTYPE_REAL)
  94                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  95                 }
  96                 self.cnt -= 1;
  97         }
  98         else if(self.cnt == 0)
  99         {
 100                 self.cnt -= 1;
 101                 kh_Controller_Thinkfunc();
 102         }
 103         self.nextthink = time + 1;
 104 }
 105
 106 // frags f: take from cvar * f
 107 // frags 0: no frags
 108 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 109 {
 110         string s;
 111         if(intermission_running)
 112                 return;
 113         if(frags_player)
 114                 player.frags = player.frags + floor(0.5 + frags_player);
 115         if(frags_owner)
 116                 key.owner.frags = key.owner.frags + floor(0.5 + frags_owner);
 117         if(!cvar("sv_eventlog"))
 118                 return;
 119         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 120         s = strcat(s, ":", ftos(frags_player));
 121         if(key && key.owner)
 122                 s = strcat(s, ":", ftos(key.owner.playerid));
 123         else
 124                 s = strcat(s, ":0");
 125         s = strcat(s, ":", ftos(frags_owner), ":");
 126         if(key)
 127                 s = strcat(s, key.netname);
 128         GameLogEcho(s, FALSE);
 129 }
 130
 131 vector kh_AttachedOrigin(entity e)
 132 {
 133         if(e.tag_entity)
 134         {
 135                 makevectors(e.tag_entity.angles);
 136                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 137         }
 138         else
 139                 return e.origin;
 140 }
 141
 142 void kh_Key_Attach(entity key)
 143 {
 144 #ifdef KH_PLAYER_USE_ATTACHMENT
 145         entity first;
 146         first = key.owner.kh_next;
 147         if(key == first)
 148         {
 149                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 150                 if(key.kh_next)
 151                 {
 152                         setattachment(key.kh_next, key, "");
 153                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 154                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 155                         key.kh_next.angles = '0 0 0';
 156                 }
 157                 else
 158                         setorigin(key, KH_PLAYER_ATTACHMENT);
 159                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 160         }
 161         else
 162         {
 163                 setattachment(key, key.kh_prev, "");
 164                 if(key.kh_next)
 165                         setattachment(key.kh_next, key, "");
 166                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 167                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 168                 key.angles = '0 0 0';
 169         }
 170 #else
 171         setattachment(key, key.owner, "");
 172         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 173         key.angles_y -= key.owner.angles_y;
 174 #endif
 175         key.flags = 0;
 176         key.solid = SOLID_NOT;
 177         key.movetype = MOVETYPE_NONE;
 178         key.team = key.owner.team;
 179         key.nextthink = time;
 180         key.damageforcescale = 0;
 181         key.modelindex = kh_key_carried;
 182 }
 183
 184 void kh_Key_Detach(entity key)
 185 {
 186 #ifdef KH_PLAYER_USE_ATTACHMENT
 187         entity first;
 188         first = key.owner.kh_next;
 189         if(key == first)
 190         {
 191                 if(key.kh_next)
 192                 {
 193                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 194                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 195                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 196                 }
 197         }
 198         else
 199         {
 200                 if(key.kh_next)
 201                         setattachment(key.kh_next, key.kh_prev, "");
 202                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 203         }
 204         // in any case:
 205         setattachment(key, world, "");
 206         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 207         key.angles = key.owner.angles;
 208 #else
 209         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 210         setattachment(key, world, "");
 211         key.angles_y += key.owner.angles_y;
 212 #endif
 213         key.aiment = world;
 214         key.flags = FL_ITEM;
 215         key.solid = SOLID_TRIGGER;
 216         key.movetype = MOVETYPE_TOSS;
 217         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 218         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 219         // let key.team stay
 220         key.modelindex = kh_key_dropped;
 221 }
 222
 223 void kh_Key_AssignTo(entity key, entity player)
 224 {
 225         if(key.owner == player)
 226                 return;
 227
 228         if(key.owner)
 229         {
 230                 kh_Key_Detach(key);
 231
 232                 // remove from linked list
 233                 if(key.kh_next)
 234                         key.kh_next.kh_prev = key.kh_prev;
 235                 key.kh_prev.kh_next = key.kh_next;
 236                 key.kh_next = world;
 237                 key.kh_prev = world;
 238
 239                 if(key.owner.kh_next == world)
 240                 {
 241                         // No longer a key carrier
 242                         WaypointSprite_DetachCarrier(key.owner);
 243                 }
 244         }
 245
 246         key.owner = player;
 247
 248         if(player)
 249         {
 250                 // insert into linked list
 251                 key.kh_next = player.kh_next;
 252                 key.kh_prev = player;
 253                 player.kh_next = key;
 254                 if(key.kh_next)
 255                         key.kh_next.kh_prev = key;
 256
 257                 kh_Key_Attach(key);
 258
 259                 if(key.kh_next == world)
 260                 {
 261                         // player is now a key carrier
 262                         WaypointSprite_AttachCarrier("", player);
 263                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 264                         player.waypointsprite_attachedforcarrier.team = player.team;
 265                 }
 266         }
 267
 268         key.pusher = world;
 269 }
 270
 271 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 272 {
 273         if(self.owner)
 274                 return;
 275         if(vlen(force) <= 0)
 276                 return;
 277         if(time > self.pushltime)
 278                 if(attacker.classname == "player")
 279                         self.team = attacker.team;
 280 }
 281
 282 void kh_Key_Spawn(entity initial_owner, float angle)
 283 {
 284         entity key;
 285         key = spawn();
 286         key.classname = STR_ITEM_KH_KEY;
 287         key.touch = kh_Key_Touch;
 288         key.think = kh_Key_Think;
 289         key.nextthink = time;
 290         key.items = IT_KEY1 | IT_KEY2;
 291         key.cnt = angle;
 292         key.angles = '0 360 0' * random();
 293         key.event_damage = kh_Key_Damage;
 294         key.modelindex = kh_key_dropped;
 295         key.model = "key";
 296         setsize(key, '-8 -8 -8', '8 8 40');
 297         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 298
 299         switch(initial_owner.team)
 300         {
 301                 case COLOR_TEAM1:
 302                         key.netname = "^1red key";
 303                         key.colormod = '103 0 0' * (1/96);
 304                         break;
 305                 case COLOR_TEAM2:
 306                         key.netname = "^4blue key";
 307                         key.colormod = '35 35 191' * (1/96);
 308                         break;
 309                 case COLOR_TEAM3:
 310                         key.netname = "^3yellow key";
 311                         key.colormod = '187 167 15' * (1/96);
 312                         break;
 313                 case COLOR_TEAM4:
 314                         key.netname = "^6pink key";
 315                         key.colormod = '139 79 107' * (1/96);
 316                         break;
 317                 default:
 318                         key.netname = "NETGIER key";
 319                         key.colormod = '1 1 1';
 320                         break;
 321         }
 322
 323         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 324
 325         WaypointSprite_AttachCarrier("", key);
 326         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 327
 328         kh_Key_AssignTo(key, initial_owner);
 329 }
 330
 331 void kh_Key_Remove(entity key)
 332 {
 333         entity o;
 334         o = key.owner;
 335         kh_Key_AssignTo(key, world);
 336         if(o) // it was attached
 337                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 338         else // it was dropped
 339                 WaypointSprite_DetachCarrier(key);
 340
 341         remove(key);
 342 }
 343
 344 // -1 when no team completely owns all keys yet
 345 float kh_Key_AllOwnedByWhichTeam()
 346 {
 347         entity key;
 348         float teem;
 349
 350         teem = -1;
 351         FOR_EACH_KH_KEY(key)
 352         {
 353                 if(!key.owner)
 354                         return -1;
 355                 if(teem == -1)
 356                         teem = key.team;
 357                 else if(teem != key.team)
 358                         return -1;
 359         }
 360         return teem;
 361 }
 362
 363 void kh_Key_Collect(entity key, entity player)
 364 {
 365         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 366
 367         kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 368         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 369         kh_Key_AssignTo(key, player);
 370
 371         if(kh_Key_AllOwnedByWhichTeam() != -1)
 372         {
 373                 kh_interferemsg_time = time + 0.2;
 374                 kh_interferemsg_team = player.team;
 375         }
 376 }
 377
 378 void kh_Key_DropAll(entity player)
 379 {
 380         entity key;
 381         entity mypusher;
 382         if(player.kh_next)
 383         {
 384                 mypusher = world;
 385                 if(player.pusher)
 386                         if(time < player.pushltime)
 387                                 mypusher = player.pusher;
 388                 while((key = player.kh_next))
 389                 {
 390                         kh_Scores_Event(player, key, "losekey", 0, 0);
 391                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 392                         kh_Key_AssignTo(key, world);
 393                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 394                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 395                         key.pusher = mypusher;
 396                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 397                 }
 398                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 399         }
 400 }
 401
 402 void kh_Key_Touch()
 403 {
 404         if(intermission_running)
 405                 return;
 406
 407         if(self.owner) // already carried
 408                 return;
 409         if(other.classname != "player")
 410                 return;
 411         if(other.deadflag != DEAD_NO)
 412                 return;
 413         if(other == self.enemy)
 414                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 415                         return; // you just dropped it!
 416         kh_Key_Collect(self, other);
 417 }
 418
 419 void kh_Key_Think()
 420 {
 421         entity head;
 422
 423         if(intermission_running)
 424                 return;
 425
 426 #ifdef KH_KEY_ATTACHMENT_DEBUG
 427         if(self.kh_prev == self.owner)
 428         {
 429                 if(cvar_string("_angles") != "")
 430                 {
 431                         self.angles = stov(cvar_string("_angles"));
 432                         self.origin = stov(cvar_string("_origin"));
 433                 }
 434         }
 435 #endif
 436
 437         if(self.owner)
 438         {
 439 #ifndef KH_PLAYER_USE_ATTACHMENT
 440                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * KH_KEY_XYSPEED));
 441                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 442 #endif
 443
 444                 if(self.owner.buttonuse)
 445                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 446                 {
 447                         self.owner.kh_droptime = time;
 448                         self.kh_droptime = time; // prevent collecting this one for some time
 449                         self.enemy = self.owner;
 450                         self.pusher = world;
 451                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 452                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 453                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 454                         makevectors(self.owner.v_angle);
 455                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 456                         kh_Key_AssignTo(self, world);
 457                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 458                 }
 459         }
 460
 461         // if in nodrop or time over, end the round
 462         if(!self.owner)
 463                 if(time > self.pain_finished)
 464                         kh_LoserTeam(self.team, self);
 465
 466         if(self.owner)
 467         if(kh_Key_AllOwnedByWhichTeam() != -1)
 468         {
 469                 entity key;
 470                 vector p;
 471                 p = self.owner.origin;
 472                 FOR_EACH_KH_KEY(key)
 473                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 474                                 goto not_winning;
 475                 kh_WinnerTeam(self.team);
 476 :not_winning
 477         }
 478
 479         if(kh_interferemsg_time && time > kh_interferemsg_time)
 480         {
 481                 kh_interferemsg_time = 0;
 482                 FOR_EACH_PLAYER(head)
 483                 {
 484                         if(head.team == kh_interferemsg_team)
 485                                 if(head.kh_next)
 486                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 487                                 else
 488                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 489                         else
 490                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 491                 }
 492         }
 493
 494         self.nextthink = time + 0.05;
 495 }
 496
 497 void kh_WinnerTeam(float teem)
 498 {
 499         // all key carriers get some points
 500         vector firstorigin, lastorigin;
 501         float first;
 502         entity key;
 503         float score;
 504         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 505         DistributeEvenly_Init(score, kh_teams);
 506         // twice the score for 3 team games, three times the score for 4 team games!
 507         // note: for a win by destroying the key, this should NOT be applied
 508         FOR_EACH_KH_KEY(key)
 509                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 510
 511         first = TRUE;
 512         FOR_EACH_KH_KEY(key)
 513                 if(key.owner.kh_next == key)
 514                 {
 515                         if(!first)
 516                                 bprint("^7, ");
 517                         bprint(key.owner.netname);
 518                         first = FALSE;
 519                 }
 520         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 521
 522         first = TRUE;
 523         FOR_EACH_KH_KEY(key)
 524         {
 525                 vector thisorigin;
 526
 527                 thisorigin = kh_AttachedOrigin(key);
 528
 529                 if(!first)
 530                         te_lightning2(world, lastorigin, thisorigin);
 531                 lastorigin = thisorigin;
 532                 if(first)
 533                         firstorigin = thisorigin;
 534                 first = FALSE;
 535         }
 536         if(kh_teams > 2)
 537         {
 538                 te_lightning2(world, lastorigin, firstorigin);
 539         }
 540
 541         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 542         kh_FinishRound();
 543 }
 544
 545 void kh_LoserTeam(float teem, entity lostkey)
 546 {
 547         entity player, key, attacker;
 548         float players;
 549         float keys;
 550
 551         attacker = world;
 552         if(lostkey.pusher)
 553                 if(lostkey.pusher.team != teem)
 554                         if(lostkey.pusher.classname == "player")
 555                                 attacker = lostkey.pusher;
 556
 557         players = keys = 0;
 558
 559         if(attacker)
 560         {
 561                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 562                 centerprint(attacker, "Your push is the best!\n\n\n");
 563                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 564         }
 565         else
 566         {
 567                 float of, fragsleft, i, j, thisteam;
 568                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 569
 570                 FOR_EACH_PLAYER(player)
 571                         if(player.team != teem)
 572                                 ++players;
 573
 574                 FOR_EACH_KH_KEY(key)
 575                         if(key.owner && key.team != teem)
 576                                 ++keys;
 577
 578                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 579
 580                 FOR_EACH_KH_KEY(key)
 581                         if(key.owner && key.team != teem)
 582                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 583
 584                 fragsleft = DistributeEvenly_Get(players);
 585
 586                 // Now distribute these among all other teams...
 587                 j = kh_teams - 1;
 588                 for(i = 0; i < kh_teams; ++i)
 589                 {
 590                         thisteam = kh_Team_ByID(i);
 591                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 592                                 continue;
 593
 594                         players = 0;
 595                         FOR_EACH_PLAYER(player)
 596                                 if(player.team == thisteam)
 597                                         ++players;
 598
 599                         DistributeEvenly_Init(fragsleft, j);
 600                         fragsleft = DistributeEvenly_Get(j - 1);
 601                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 602
 603                         FOR_EACH_PLAYER(player)
 604                                 if(player.team == thisteam)
 605                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 606
 607                         --j;
 608                 }
 609
 610                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 611         }
 612         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 613
 614         kh_FinishRound();
 615 }
 616
 617 void kh_FinishRound()
 618 {
 619         // prepare next round
 620         kh_interferemsg_time = 0;
 621         entity key;
 622         FOR_EACH_KH_KEY(key)
 623                 kh_Key_Remove(key);
 624
 625         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 626 }
 627
 628 string kh_CheckEnoughPlayers()
 629 {
 630         float i, players, teem;
 631         entity player;
 632         string result;
 633         result = "";
 634
 635         // find a random player per team
 636         for(i = 0; i < kh_teams; ++i)
 637         {
 638                 teem = kh_Team_ByID(i);
 639                 players = 0;
 640                 FOR_EACH_PLAYER(player)
 641                         if(player.deadflag == DEAD_NO)
 642                                 if(!player.buttonchat)
 643                                         if(player.team == teem)
 644                                                 ++players;
 645                 if(players == 0)
 646                 {
 647                         if(result != "")
 648                                 result = strcat(result, ", ");
 649                         result = strcat(result, ColoredTeamName(teem));
 650                 }
 651         }
 652         return result;
 653 }
 654
 655 void kh_WaitForPlayers()
 656 {
 657         string teams_missing;
 658         teams_missing = kh_CheckEnoughPlayers();
 659         if(teams_missing == "")
 660                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 661         else
 662                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 663 }
 664
 665 void kh_StartRound()
 666 {
 667         string teams_missing;
 668         float i, players, teem;
 669         entity player;
 670
 671         teams_missing = kh_CheckEnoughPlayers();
 672         if(teams_missing != "")
 673         {
 674                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 675                 return;
 676         }
 677
 678         FOR_EACH_PLAYER(player)
 679                 if(clienttype(player) == CLIENTTYPE_REAL)
 680                         centerprint_expire(player, CENTERPRIO_SPAM);
 681
 682         for(i = 0; i < kh_teams; ++i)
 683         {
 684                 teem = kh_Team_ByID(i);
 685                 players = 0;
 686                 entity my_player;
 687                 FOR_EACH_PLAYER(player)
 688                         if(player.deadflag == DEAD_NO)
 689                                 if(!player.buttonchat)
 690                                         if(player.team == teem)
 691                                         {
 692                                                 ++players;
 693                                                 if(random() * players <= 1)
 694                                                         my_player = player;
 695                                         }
 696                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 697                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 698                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 699         }
 700
 701         kh_tracking_enabled = FALSE;
 702         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 703 }
 704
 705 void kh_setstatus()
 706 {
 707         if(kh_teams)
 708         {
 709                 float kh_KEY;
 710                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 711                 if(self.kh_next)
 712                         self.items = self.items | kh_KEY;
 713                 else
 714                         self.items = self.items - (self.items & kh_KEY);
 715         }
 716 }
 717
 718 void kh_EnableTrackingDevice()
 719 {
 720         entity player;
 721
 722         FOR_EACH_PLAYER(player)
 723                 if(clienttype(player) == CLIENTTYPE_REAL)
 724                         centerprint_expire(player, CENTERPRIO_SPAM);
 725
 726         kh_tracking_enabled = TRUE;
 727 }
 728
 729 float kh_Key_waypointsprite_for_player(entity e)
 730 {
 731         if(!kh_tracking_enabled)
 732                 return 0;
 733         if(!self.owner)
 734                 return kh_sprite_dropped;
 735         if(!self.owner.owner)
 736                 return kh_sprite_dropped;
 737         return 0; // draw only when key is not owned
 738 }
 739
 740 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 741 {
 742         if(e.classname != "player" || self.team != e.team)
 743                 if(!kh_tracking_enabled)
 744                         return 0;
 745
 746         // e is spectator? That's no team mate...
 747         if(e.classname != "player")
 748                 return kh_GetCarrierSprite(self.team, -1);
 749
 750         // e is no key carrier: simple case...
 751         if(!e.kh_next)
 752                 return kh_GetCarrierSprite(self.team, e.team);
 753
 754         // e is a key carrier: if any key is dropped or owned by another team, show
 755         // the carrier sprite; otherwise show run here
 756         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 757                 return kh_sprite_finish;
 758
 759         return kh_GetCarrierSprite(self.team, e.team);
 760 }
 761
 762 float kh_HandleFrags(entity attacker, entity targ, float f)
 763 {
 764         if(f <= 0)
 765                 return f;
 766         if(attacker == targ)
 767                 return f;
 768
 769         if(targ.kh_next)
 770                 kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 771
 772         return f;
 773 }
 774
 775 void kh_init()
 776 {
 777         precache_sound(kh_sound_capture);
 778         precache_sound(kh_sound_destroy);
 779         precache_sound(kh_sound_drop);
 780         precache_sound(kh_sound_collect);
 781
 782         precache_model("models/sprites/key-dropped.sp2");
 783         precache_model("models/sprites/keycarrier-finish.sp2");
 784         precache_model("models/sprites/keycarrier-friend.sp2");
 785         precache_model("models/sprites/keycarrier-red.sp2");
 786         precache_model("models/sprites/keycarrier-blue.sp2");
 787         precache_model("models/sprites/keycarrier-yellow.sp2");
 788         precache_model("models/sprites/keycarrier-pink.sp2");
 789 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 790         precache_model("models/keyhunt/key-carried.md3");
 791 #endif
 792         precache_model("models/keyhunt/key.md3");
 793
 794         // setup variables
 795         kh_teams = cvar("g_keyhunt_teams_override");
 796         if(kh_teams < 2)
 797                 kh_teams = cvar("g_keyhunt_teams");
 798         kh_teams = bound(2, kh_teams, 4);
 799
 800         // make a KH entity for controlling the game
 801         kh_controller = spawn();
 802         kh_controller.think = kh_Controller_Think;
 803         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 804
 805         setmodel(kh_controller, "models/keyhunt/key.md3");
 806         kh_key_dropped = kh_controller.modelindex;
 807 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 808         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 809         kh_key_carried = kh_controller.modelindex;
 810 #else
 811         kh_key_carried = kh_key_dropped;
 812 #endif
 813         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 814         kh_sprite_dropped = kh_controller.modelindex;
 815         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 816         kh_sprite_finish = kh_controller.modelindex;
 817         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 818         kh_sprite_friend = kh_controller.modelindex;
 819         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 820         kh_sprite_red = kh_controller.modelindex;
 821         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 822         kh_sprite_blue = kh_controller.modelindex;
 823         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 824         kh_sprite_pink = kh_controller.modelindex;
 825         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 826         kh_sprite_yellow = kh_controller.modelindex;
 827         setmodel(kh_controller, "");
 828 }
 829
 830 void kh_finalize()
 831 {
 832         // to be called before intermission
 833         kh_FinishRound();
 834         remove(kh_controller);
 835         kh_controller = world;
 836 }