data/qcsrc/server/ipban.qc

   1 /*
   2  * Protocol of online ban list:
   3  *
   4  * - Reporting a ban:
   5  *     GET g_ban_sync_uri?action=ban&hostname=...&ip=xxx.xxx.xxx&duration=nnnn&reason=...................
   6  *     (IP 1, 2, 3, or 4 octets, 3 octets for example is a /24 mask)
   7  * - Removing a ban:
   8  *     GET g_ban_sync_uri?action=unban&hostname=...&ip=xxx.xxx.xxx
   9  * - Querying the ban list
  10  *     GET g_ban_sync_uri?action=list&hostname=...&servers=xxx.xxx.xxx.xxx;xxx.xxx.xxx.xxx;...
  11  *
  12  *     shows the bans from the listed servers, and possibly others.
  13  *     Format of a ban is ASCII plain text, four lines per ban, delimited by
  14  *     newline ONLY (no carriage return):
  15  *
  16  *     IP address (also 1, 2, 3, or 4 octets, delimited by dot)
  17  *     time left in seconds
  18  *     reason of the ban
  19  *     server IP that registered the ban
  20  */
  21
  22 float Ban_Insert(string ip, float bantime, string reason, float dosync);
  23
  24 void OnlineBanList_SendBan(string ip, float bantime, string reason)
  25 {
  26         string uri;
  27         float i, n;
  28
  29         uri = strcat(     "?action=ban&hostname=", uri_escape(cvar_string("hostname")));
  30         uri = strcat(uri, "&ip=", uri_escape(ip));
  31         uri = strcat(uri, "&duration=", ftos(bantime));
  32         uri = strcat(uri, "&reason=", uri_escape(reason));
  33
  34         n = tokenize_sane(cvar_string("g_ban_sync_uri"));
  35         if(n >= MAX_IPBAN_URIS)
  36                 n = MAX_IPBAN_URIS;
  37         for(i = 0; i < n; ++i)
  38                 uri_get(strcat(argv(i), uri), URI_GET_DISCARD); // 0 = "discard" callback target
  39 }
  40
  41 void OnlineBanList_SendUnban(string ip)
  42 {
  43         string uri;
  44         float i, n;
  45
  46         uri = strcat(     "?action=unban&hostname=", uri_escape(cvar_string("hostname")));
  47         uri = strcat(uri, "&ip=", uri_escape(ip));
  48
  49         n = tokenize_sane(cvar_string("g_ban_sync_uri"));
  50         if(n >= MAX_IPBAN_URIS)
  51                 n = MAX_IPBAN_URIS;
  52         for(i = 0; i < n; ++i)
  53                 uri_get(strcat(argv(i), uri), URI_GET_DISCARD); // 0 = "discard" callback target
  54 }
  55
  56 string OnlineBanList_Servers;
  57 float OnlineBanList_Timeout;
  58 float OnlineBanList_RequestWaiting[MAX_IPBAN_URIS];
  59
  60 void OnlineBanList_URI_Get_Callback(float id, float status, string data)
  61 {
  62         float n, i, j, l;
  63         string ip;
  64         float timeleft;
  65         string reason;
  66         string serverip;
  67         float syncinterval;
  68         string uri;
  69
  70         id -= URI_GET_IPBAN;
  71
  72         if(id >= MAX_IPBAN_URIS)
  73         {
  74                 print("Received ban list for invalid ID\n");
  75                 return;
  76         }
  77
  78         tokenize_sane(cvar_string("g_ban_sync_uri"));
  79         uri = argv(id);
  80
  81         print("Received ban list from ", uri, ": ");
  82
  83         if(OnlineBanList_RequestWaiting[id] == 0)
  84         {
  85                 print("rejected (unexpected)\n");
  86                 return;
  87         }
  88
  89         OnlineBanList_RequestWaiting[id] = 0;
  90
  91         if(time > OnlineBanList_Timeout)
  92         {
  93                 print("rejected (too late)\n");
  94                 return;
  95         }
  96
  97         syncinterval = cvar("g_ban_sync_interval");
  98         if(syncinterval == 0)
  99         {
 100                 print("rejected (syncing disabled)\n");
 101                 return;
 102         }
 103         if(syncinterval > 0)
 104                 syncinterval *= 60;
 105
 106         if(status != 0)
 107         {
 108                 print("error: status is ", ftos(status), "\n");
 109                 return;
 110         }
 111
 112         if(substring(data, 0, 1) == "<")
 113         {
 114                 print("error: received HTML instead of a ban list: ");
 115                 return;
 116         }
 117
 118         if(strstrofs(data, "\r", 0) != -1)
 119         {
 120                 print("error: received carriage returns: ");
 121                 return;
 122         }
 123
 124         if(data == "")
 125                 n = 0;
 126         else
 127                 n = tokenizebyseparator(data, "\n");
 128
 129         if(mod(n, 4) != 0)
 130         {
 131                 print("error: received invalid item count: ", ftos(n), "\n");
 132                 return;
 133         }
 134
 135         print("OK, ", ftos(n / 4), " items\n");
 136
 137         for(i = 0; i < n; i += 4)
 138         {
 139                 ip = argv(i);
 140                 timeleft = stof(argv(i + 1));
 141                 reason = argv(i + 2);
 142                 serverip = argv(i + 3);
 143
 144                 dprint("received ban list item ", ftos(i / n), ": ip=", ip);
 145                 dprint(" timeleft=", ftos(timeleft), " reason=", reason);
 146                 dprint(" serverip=", serverip, "\n");
 147
 148                 timeleft -= 1.5 * cvar("g_ban_sync_timeout");
 149                 if(timeleft < 0)
 150                         continue;
 151
 152                 l = strlen(ip);
 153                 for(j = 0; j < l; ++j)
 154                         if(strstrofs("0123456789.", substring(ip, j, 1), 0) == -1)
 155                         {
 156                                 print("Invalid character ", substring(ip, j, 1), " in IP address ", ip, ". Skipping this ban.\n");
 157                                 goto skip;
 158                         }
 159
 160                 if(cvar("g_ban_sync_trusted_servers_verify"))
 161                         if((strstrofs(strcat(";", OnlineBanList_Servers, ";"), strcat(";", serverip, ";"), 0) == -1))
 162                                 continue;
 163
 164                 if(syncinterval > 0)
 165                         timeleft = min(syncinterval + (OnlineBanList_Timeout - time) + 5, timeleft);
 166                         // the ban will be prolonged on the next sync
 167                         // or expire 5 seconds after the next timeout
 168                 Ban_Insert(ip, timeleft, strcat("ban synced from ", serverip, " at ", uri), 0);
 169                 print("Ban list syncing: accepted ban of ", ip, " by ", serverip, " at ", uri, ": ");
 170                 print(reason, "\n");
 171
 172 :skip
 173         }
 174 }
 175
 176 void OnlineBanList_Think()
 177 {
 178         float argc;
 179         string uri;
 180         float i, n;
 181
 182         if(cvar_string("g_ban_sync_uri") == "")
 183                 return;
 184         if(cvar("g_ban_sync_interval") == 0) // < 0 is okay, it means "sync on level start only"
 185                 return;
 186         argc = tokenize_sane(cvar_string("g_ban_sync_trusted_servers"));
 187         if(argc == 0)
 188                 return;
 189
 190         if(OnlineBanList_Servers)
 191                 strunzone(OnlineBanList_Servers);
 192         OnlineBanList_Servers = argv(0);
 193         for(i = 1; i < argc; ++i)
 194                 OnlineBanList_Servers = strcat(OnlineBanList_Servers, ";", argv(i));
 195         OnlineBanList_Servers = strzone(OnlineBanList_Servers);
 196
 197         uri = strcat(     "?action=list&hostname=", uri_escape(cvar_string("hostname")));
 198         uri = strcat(uri, "&servers=", uri_escape(OnlineBanList_Servers));
 199
 200         OnlineBanList_Timeout = time + cvar("g_ban_sync_timeout");
 201
 202         n = tokenize_sane(cvar_string("g_ban_sync_uri"));
 203         if(n >= MAX_IPBAN_URIS)
 204                 n = MAX_IPBAN_URIS;
 205         for(i = 0; i < n; ++i)
 206         {
 207                 if(OnlineBanList_RequestWaiting[i])
 208                         continue;
 209                 OnlineBanList_RequestWaiting[i] = 1;
 210                 uri_get(strcat(argv(i), uri), URI_GET_IPBAN + i); // 1000 = "banlist" callback target
 211         }
 212
 213         if(cvar("g_ban_sync_interval") > 0)
 214                 self.nextthink = time + max(60, cvar("g_ban_sync_interval") * 60);
 215 }
 216
 217 #define BAN_MAX 64
 218 float ban_loaded;
 219 string ban_ip[BAN_MAX];
 220 float ban_expire[BAN_MAX];
 221 float ban_count;
 222
 223 string ban_ip1;
 224 string ban_ip2;
 225 string ban_ip3;
 226 string ban_ip4;
 227
 228 void Ban_SaveBans()
 229 {
 230         string out;
 231         float i;
 232
 233         if(!ban_loaded)
 234                 return;
 235
 236         // version of list
 237         out = "1";
 238         for(i = 0; i < ban_count; ++i)
 239         {
 240                 if(time > ban_expire[i])
 241                         continue;
 242                 out = strcat(out, " ", ban_ip[i]);
 243                 out = strcat(out, " ", ftos(ban_expire[i] - time));
 244         }
 245         if(strlen(out) <= 1) // no real entries
 246                 cvar_set("g_banned_list", "");
 247         else
 248                 cvar_set("g_banned_list", out);
 249 }
 250
 251 float Ban_Delete(float i)
 252 {
 253         if(i < 0)
 254                 return FALSE;
 255         if(i >= ban_count)
 256                 return FALSE;
 257         if(ban_expire[i] == 0)
 258                 return FALSE;
 259         if(ban_expire[i] > 0)
 260         {
 261                 OnlineBanList_SendUnban(ban_ip[i]);
 262                 strunzone(ban_ip[i]);
 263         }
 264         ban_expire[i] = 0;
 265         ban_ip[i] = "";
 266         Ban_SaveBans();
 267         return TRUE;
 268 }
 269
 270 void Ban_LoadBans()
 271 {
 272         float i, n;
 273         for(i = 0; i < ban_count; ++i)
 274                 Ban_Delete(i);
 275         ban_count = 0;
 276         ban_loaded = TRUE;
 277         n = tokenize_sane(cvar_string("g_banned_list"));
 278         if(stof(argv(0)) == 1)
 279         {
 280                 ban_count = (n - 1) / 2;
 281                 for(i = 0; i < ban_count; ++i)
 282                 {
 283                         ban_ip[i] = strzone(argv(2*i+1));
 284                         ban_expire[i] = time + stof(argv(2*i+2));
 285                 }
 286         }
 287
 288         entity e;
 289         e = spawn();
 290         e.classname = "bansyncer";
 291         e.think = OnlineBanList_Think;
 292         e.nextthink = time + 1;
 293 }
 294
 295 void Ban_View()
 296 {
 297         float i;
 298         string msg;
 299         for(i = 0; i < ban_count; ++i)
 300         {
 301                 if(time > ban_expire[i])
 302                         continue;
 303                 msg = strcat("#", ftos(i), ": ");
 304                 msg = strcat(msg, ban_ip[i], " is still banned for ");
 305                 msg = strcat(msg, ftos(ban_expire[i] - time), " seconds");
 306                 print(msg, "\n");
 307         }
 308 }
 309
 310 float Ban_GetClientIP(entity client)
 311 {
 312         float n;
 313         n = tokenizebyseparator(client.netaddress, ".");
 314         if(n != 4)
 315                 return FALSE;
 316         ban_ip1 = strcat1(argv(0));
 317         ban_ip2 = strcat(ban_ip1, ".", argv(1));
 318         ban_ip3 = strcat(ban_ip2, ".", argv(2));
 319         ban_ip4 = strcat(ban_ip3, ".", argv(3));
 320         return TRUE;
 321 }
 322
 323 float Ban_IsClientBanned(entity client, float idx)
 324 {
 325         float i, b, e;
 326         if(!ban_loaded)
 327                 Ban_LoadBans();
 328         if(!Ban_GetClientIP(client))
 329                 return FALSE;
 330         if(idx < 0)
 331         {
 332                 b = 0;
 333                 e = ban_count;
 334         }
 335         else
 336         {
 337                 b = idx;
 338                 e = idx + 1;
 339         }
 340         for(i = b; i < e; ++i)
 341         {
 342                 string s;
 343                 if(time > ban_expire[i])
 344                         continue;
 345                 s = ban_ip[i];
 346                 if(ban_ip1 == s) return TRUE;
 347                 if(ban_ip2 == s) return TRUE;
 348                 if(ban_ip3 == s) return TRUE;
 349                 if(ban_ip4 == s) return TRUE;
 350         }
 351         return FALSE;
 352 }
 353
 354 float Ban_MaybeEnforceBan(entity client)
 355 {
 356         if(Ban_IsClientBanned(client, -1))
 357         {
 358                 string s;
 359                 s = strcat("^1NOTE:^7 banned client ", client.netaddress, " just tried to enter\n");
 360                 dropclient(client);
 361                 bprint(s);
 362                 return TRUE;
 363         }
 364         return FALSE;
 365 }
 366
 367 string Ban_Enforce(float i, string reason)
 368 {
 369         string s;
 370         entity e;
 371
 372         // Enforce our new ban
 373         s = "";
 374         FOR_EACH_REALCLIENT(e)
 375                 if(Ban_IsClientBanned(e, i))
 376                 {
 377                         if(reason != "")
 378                         {
 379                                 if(s == "")
 380                                         reason = strcat(reason, ": affects ");
 381                                 else
 382                                         reason = strcat(reason, ", ");
 383                                 reason = strcat(reason, e.netname);
 384                         }
 385                         s = strcat(s, "^1NOTE:^7 banned client ", e.netname, "^7 has to go\n");
 386                         dropclient(e);
 387                 }
 388         bprint(s);
 389
 390         return reason;
 391 }
 392
 393 float Ban_Insert(string ip, float bantime, string reason, float dosync)
 394 {
 395         float i;
 396         float j;
 397         float bestscore;
 398
 399         // already banned?
 400         for(i = 0; i < ban_count; ++i)
 401                 if(ban_ip[i] == ip)
 402                 {
 403                         // prolong the ban
 404                         if(time + bantime > ban_expire[i])
 405                         {
 406                                 ban_expire[i] = time + bantime;
 407                                 dprint(ip, "'s ban has been prolonged to ", ftos(bantime), " seconds from now\n");
 408                         }
 409                         else
 410                                 dprint(ip, "'s ban is still active until ", ftos(ban_expire[i] - time), " seconds from now\n");
 411
 412                         // and enforce
 413                         reason = Ban_Enforce(i, reason);
 414
 415                         // and abort
 416                         if(dosync)
 417                                 if(reason != "")
 418                                         if(substring(reason, 0, 1) != "~") // like IRC: unauthenticated banner
 419                                                 OnlineBanList_SendBan(ip, bantime, reason);
 420
 421                         return FALSE;
 422                 }
 423
 424         // do we have a free slot?
 425         for(i = 0; i < ban_count; ++i)
 426                 if(time > ban_expire[i])
 427                         break;
 428         // no free slot? Then look for the one who would get unbanned next
 429         if(i >= BAN_MAX)
 430         {
 431                 i = 0;
 432                 bestscore = ban_expire[i];
 433                 for(j = 1; j < ban_count; ++j)
 434                 {
 435                         if(ban_expire[j] < bestscore)
 436                         {
 437                                 i = j;
 438                                 bestscore = ban_expire[i];
 439                         }
 440                 }
 441         }
 442         // if we replace someone, will we be banned longer than him (so long-term
 443         // bans never get overridden by short-term bans)
 444         if(i < ban_count)
 445         if(ban_expire[i] > time + bantime)
 446         {
 447                 print(ip, " could not get banned due to no free ban slot\n");
 448                 return FALSE;
 449         }
 450         // okay, insert our new victim as i
 451         Ban_Delete(i);
 452         dprint(ip, " has been banned for ", ftos(bantime), " seconds\n");
 453         ban_expire[i] = time + bantime;
 454         ban_ip[i] = strzone(ip);
 455         ban_count = max(ban_count, i + 1);
 456
 457         Ban_SaveBans();
 458
 459         reason = Ban_Enforce(i, reason);
 460
 461         // and abort
 462         if(dosync)
 463                 if(reason != "")
 464                         if(substring(reason, 0, 1) != "~") // like IRC: unauthenticated banner
 465                                 OnlineBanList_SendBan(ip, bantime, reason);
 466
 467         return TRUE;
 468 }
 469
 470 void Ban_KickBanClient(entity client, float bantime, float masksize, string reason)
 471 {
 472         if(!Ban_GetClientIP(client))
 473         {
 474                 sprint(client, strcat("Kickbanned: ", reason, "\n"));
 475                 dropclient(client);
 476                 return;
 477         }
 478         // now ban him
 479         switch(masksize)
 480         {
 481                 case 1:
 482                         Ban_Insert(ban_ip1, bantime, reason, 1);
 483                         break;
 484                 case 2:
 485                         Ban_Insert(ban_ip2, bantime, reason, 1);
 486                         break;
 487                 case 3:
 488                         Ban_Insert(ban_ip3, bantime, reason, 1);
 489                         break;
 490                 default:
 491                         Ban_Insert(ban_ip4, bantime, reason, 1);
 492                         break;
 493         }
 494         /*
 495          * not needed, as we enforce the ban in Ban_Insert anyway
 496         // and kick him
 497         sprint(client, strcat("Kickbanned: ", reason, "\n"));
 498         dropclient(client);
 499          */
 500 }
 501
 502 float GameCommand_Ban(string command)
 503 {
 504         float argc;
 505         float bantime;
 506         entity client;
 507         float entno;
 508         float masksize;
 509         string reason;
 510         float reasonarg;
 511
 512         argc = tokenize_sane(command);
 513         if(argv(0) == "help")
 514         {
 515                 print("  kickban # n m p reason - kickban player n for m seconds, using mask size p (1 to 4)\n");
 516                 print("  ban ip m reason - ban an IP or range (incomplete IP, like 1.2.3) for m seconds\n");
 517                 print("  bans - list all existing bans\n");
 518                 print("  unban n - delete the entry #n from the bans list\n");
 519                 return TRUE;
 520         }
 521         if(argv(0) == "kickban")
 522         {
 523 #define INITARG(c) reasonarg = c
 524 #define GETARG(v,d) if((argc > reasonarg) && ((v = stof(argv(reasonarg))) != 0)) ++reasonarg; else v = d
 525 #define RESTARG(v) if(argc > reasonarg) v = substring(command, argv_start_index(reasonarg), strlen(command) - argv_start_index(reasonarg)); else v = ""
 526                 if(argc >= 3)
 527                 {
 528                         entno = stof(argv(2));
 529                         if(entno > maxclients || entno < 1)
 530                                 return TRUE;
 531                         client = edict_num(entno);
 532
 533                         INITARG(3);
 534                         GETARG(bantime, cvar("g_ban_default_bantime"));
 535                         GETARG(masksize, cvar("g_ban_default_masksize"));
 536                         RESTARG(reason);
 537
 538                         Ban_KickBanClient(client, bantime, masksize, reason);
 539                         return TRUE;
 540                 }
 541         }
 542         else if(argv(0) == "ban")
 543         {
 544                 if(argc >= 2)
 545                 {
 546                         string ip;
 547                         ip = argv(1);
 548
 549                         INITARG(2);
 550                         GETARG(bantime, cvar("g_ban_default_bantime"));
 551                         RESTARG(reason);
 552
 553                         Ban_Insert(ip, bantime, reason, 1);
 554                         return TRUE;
 555                 }
 556 #undef INITARG
 557 #undef GETARG
 558 #undef RESTARG
 559         }
 560         else if(argv(0) == "bans")
 561         {
 562                 Ban_View();
 563                 return TRUE;
 564         }
 565         else if(argv(0) == "unban")
 566         {
 567                 if(argc >= 2)
 568                 {
 569                         float who;
 570                         who = stof(argv(1));
 571                         Ban_Delete(who);
 572                         return TRUE;
 573                 }
 574         }
 575         return FALSE;
 576 }