data/qcsrc/server/havocbot.qc

   1 .void() havocbot_role;
   2 void() havocbot_chooserole;
   3 .float havocbot_keyboardskill;
   4 .float facingwalltime, ignoregoaltime;
   5 .entity ignoregoal;
   6 .float lastfiredweapon;
   7 .float lastcombotime;
   8 .float havocbot_blockhead;
   9
  10 #ifdef DEBUG_BOT_GOALSTACK
  11 void debuggoalstack();
  12 #endif
  13
  14 vector havocbot_dodge()
  15 {
  16         // LordHavoc: disabled because this is too expensive
  17         return '0 0 0';
  18         /*
  19         local entity head;
  20         local vector dodge, v, n;
  21         local float danger, bestdanger, vl, d;
  22         dodge = '0 0 0';
  23         bestdanger = -20;
  24         // check for dangerous objects near bot or approaching bot
  25         head = findchainfloat(bot_dodge, TRUE);
  26         while(head)
  27         {
  28                 if (head.owner != self)
  29                 {
  30                         vl = vlen(head.velocity);
  31                         if (vl > sv_maxspeed * 0.3)
  32                         {
  33                                 n = normalize(head.velocity);
  34                                 v = self.origin - head.origin;
  35                                 d = v * n;
  36                                 if (d > (0 - head.bot_dodgerating))
  37                                 if (d < (vl * 0.2 + head.bot_dodgerating))
  38                                 {
  39                                         // calculate direction and distance from the flight path, by removing the forward axis
  40                                         v = v - (n * (v * n));
  41                                         danger = head.bot_dodgerating - vlen(v);
  42                                         if (bestdanger < danger)
  43                                         {
  44                                                 bestdanger = danger;
  45                                                 // dodge to the side of the object
  46                                                 dodge = normalize(v);
  47                                         }
  48                                 }
  49                         }
  50                         else
  51                         {
  52                                 danger = head.bot_dodgerating - vlen(head.origin - self.origin);
  53                                 if (bestdanger < danger)
  54                                 {
  55                                         bestdanger = danger;
  56                                         dodge = normalize(self.origin - head.origin);
  57                                 }
  58                         }
  59                 }
  60                 head = head.chain;
  61         }
  62         return dodge;
  63         */
  64 };
  65
  66 .float havocbot_keyboardtime;
  67 .float havocbot_ducktime;
  68 .vector havocbot_keyboard;
  69 void havocbot_keyboard_movement(vector destorg)
  70 {
  71         local vector keyboard;
  72         local float blend, maxspeed;
  73
  74         maxspeed = cvar("sv_maxspeed");
  75
  76         if (time < self.havocbot_keyboardtime)
  77                 return;
  78
  79         self.havocbot_keyboardtime =
  80                 max(
  81                         self.havocbot_keyboardtime
  82                                 + bound(0,0.05/(skill+self.havocbot_keyboardskill),0.05)
  83                                 +random()*bound(0,0.025/(skill+self.havocbot_keyboardskill),100)
  84                 , time);
  85         keyboard = self.movement * (1.0 / maxspeed);
  86
  87         local float trigger, trigger1;
  88         blend = bound(0,skill*0.1,1);
  89         trigger = cvar("bot_ai_keyboard_treshold");
  90         trigger1 = 0 - trigger;
  91
  92         // categorize forward movement
  93         // at skill < 1.5 only forward
  94         // at skill < 2.5 only individual directions
  95         // at skill < 4.5 only individual directions, and forward diagonals
  96         // at skill >= 4.5, all cases allowed
  97         if (keyboard_x > trigger)
  98         {
  99                 keyboard_x = 1;
 100                 if (skill < 2.5)
 101                         keyboard_y = 0;
 102         }
 103         else if (keyboard_x < trigger1 && skill > 1.5)
 104         {
 105                 keyboard_x = -1;
 106                 if (skill < 4.5)
 107                         keyboard_y = 0;
 108         }
 109         else
 110         {
 111                 keyboard_x = 0;
 112                 if (skill < 1.5)
 113                         keyboard_y = 0;
 114         }
 115         if (skill < 4.5)
 116                 keyboard_z = 0;
 117
 118         if (keyboard_y > trigger)
 119                 keyboard_y = 1;
 120         else if (keyboard_y < trigger1)
 121                 keyboard_y = -1;
 122         else
 123                 keyboard_y = 0;
 124
 125         if (keyboard_z > trigger)
 126                 keyboard_z = 1;
 127         else if (keyboard_z < trigger1)
 128                 keyboard_z = -1;
 129         else
 130                 keyboard_z = 0;
 131
 132         self.havocbot_keyboard = keyboard * maxspeed;
 133         if (self.havocbot_ducktime>time) self.BUTTON_CROUCH=TRUE;
 134
 135         keyboard = self.havocbot_keyboard;
 136         blend = bound(0,vlen(destorg-self.origin)/cvar("bot_ai_keyboard_distance"),1); // When getting close move with 360 degree
 137         //dprint("movement ", vtos(self.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 138         self.movement = self.movement + (keyboard - self.movement) * blend;
 139 };
 140
 141 .entity bot_lastseengoal;
 142 .float bot_timelastseengoal;
 143 .float bot_canruntogoal;
 144 void havocbot_bunnyhop(vector dir)
 145 {
 146         local float bunnyhopdistance;
 147         local vector deviation;
 148         local float maxspeed;
 149
 150         if(cvar("g_midair"))
 151                 return;
 152
 153         if(self.goalcurrent.classname == "player")
 154                 return;
 155
 156         maxspeed = cvar("sv_maxspeed");
 157
 158         if(self.aistatus & AI_STATUS_DANGER_AHEAD)
 159         {
 160                 self.aistatus &~= AI_STATUS_RUNNING;
 161                 self.BUTTON_JUMP = FALSE;
 162                 self.bot_canruntogoal = 0;
 163                 self.bot_timelastseengoal = 0;
 164                 return;
 165         }
 166
 167         if(self.waterlevel > WATERLEVEL_WETFEET)
 168         {
 169                 self.aistatus &~= AI_STATUS_RUNNING;
 170                 return;
 171         }
 172
 173         if(self.bot_lastseengoal != self.goalcurrent && !(self.aistatus & AI_STATUS_RUNNING))
 174         {
 175                 self.bot_canruntogoal = 0;
 176                 self.bot_timelastseengoal = 0;
 177         }
 178
 179         bunnyhopdistance = vlen(self.origin - self.goalcurrent.origin);
 180
 181         // Run only to visible goals
 182         if(self.flags & FL_ONGROUND)
 183         if(self.speed==maxspeed)
 184         if(checkpvs(self.origin + self.view_ofs, self.goalcurrent))
 185         {
 186                         self.bot_lastseengoal = self.goalcurrent;
 187
 188                         // seen it before
 189                         if(self.bot_timelastseengoal)
 190                         {
 191                                 // for a period of time
 192                                 if(time - self.bot_timelastseengoal > cvar("bot_ai_bunnyhop_firstjumpdelay"))
 193                                 {
 194                                         local float checkdistance;
 195                                         checkdistance = TRUE;
 196
 197                                         // don't run if it is too close
 198                                         if(self.bot_canruntogoal==0)
 199                                         {
 200                                                 if(bunnyhopdistance > cvar("bot_ai_bunnyhop_startdistance"))
 201                                                         self.bot_canruntogoal = 1;
 202                                                 else
 203                                                         self.bot_canruntogoal = -1;
 204                                         }
 205
 206                                         if(self.bot_canruntogoal != 1)
 207                                                 return;
 208
 209                                         if(self.aistatus & AI_STATUS_ROAMING)
 210                                         if(self.goalcurrent.classname=="waypoint")
 211                                         if(fabs(self.goalcurrent.origin_z - self.origin_z) < self.maxs_z - self.mins_z)
 212                                         if(self.goalstack01!=world)
 213                                         {
 214                                                 deviation = vectoangles(self.goalstack01.origin - self.origin) - vectoangles(self.goalcurrent.origin - self.origin);
 215                                                 while (deviation_y < -180) deviation_y = deviation_y + 360;
 216                                                 while (deviation_y > 180) deviation_y = deviation_y - 360;
 217
 218                                                 if(fabs(deviation_y) < 20)
 219                                                 if(bunnyhopdistance < vlen(self.origin - self.goalstack01.origin))
 220                                                 if(fabs(self.goalstack01.origin_z - self.goalcurrent.origin_z) < self.maxs_z - self.mins_z)
 221                                                 {
 222                                                         if(vlen(self.goalcurrent.origin - self.goalstack01.origin) > cvar("bot_ai_bunnyhop_startdistance"))
 223                                                         if(checkpvs(self.origin + self.view_ofs, self.goalstack01))
 224                                                         {
 225                                                                 checkdistance = FALSE;
 226                                                         }
 227                                                 }
 228                                         }
 229
 230                                         if(checkdistance)
 231                                         {
 232                                                 self.aistatus &~= AI_STATUS_RUNNING;
 233                                                 if(bunnyhopdistance > cvar("bot_ai_bunnyhop_stopdistance"))
 234                                                         self.BUTTON_JUMP = TRUE;
 235                                         }
 236                                         else
 237                                         {
 238                                                 self.aistatus |= AI_STATUS_RUNNING;
 239                                                 self.BUTTON_JUMP = TRUE;
 240                                         }
 241                                 }
 242                         }
 243                         else
 244                         {
 245                                 self.bot_timelastseengoal = time;
 246                         }
 247         }
 248         else
 249         {
 250                 self.bot_timelastseengoal = 0;
 251         }
 252
 253         // Release jump button
 254         if(self.flags & FL_ONGROUND == 0)
 255         {
 256                 if(self.velocity_z < 0 || vlen(self.velocity)<maxspeed)
 257                         self.BUTTON_JUMP = FALSE;
 258
 259                 // Strafe
 260                 if(self.aistatus & AI_STATUS_RUNNING)
 261                 if(vlen(self.velocity)>maxspeed)
 262                 {
 263                         deviation = vectoangles(dir) - vectoangles(self.velocity);
 264                         while (deviation_y < -180) deviation_y = deviation_y + 360;
 265                         while (deviation_y > 180) deviation_y = deviation_y - 360;
 266
 267                         if(fabs(deviation_y)>10)
 268                                 self.movement_x = 0;
 269
 270                         if(deviation_y>10)
 271                                 self.movement_y = maxspeed * -1;
 272                         else if(deviation_y<10)
 273                                 self.movement_y = maxspeed;
 274
 275                 }
 276         }
 277 };
 278
 279 //.float havocbotignoretime;
 280 //.vector bot_dodgevector;
 281 //.float bot_dodgevector_time;
 282 //.float bot_dodgevector_jumpbutton;
 283 .float ladder_time;
 284 .entity ladder_entity;
 285 .float rocketjumptime;
 286 void havocbot_movetogoal()
 287 {
 288         local vector destorg;
 289         local vector diff;
 290         local vector dir;
 291         local vector flatdir;
 292         local vector m1;
 293         local vector m2;
 294         local vector evadeobstacle;
 295         local vector evadelava;
 296         local float s;
 297         local float maxspeed;
 298         //local float dist;
 299         local vector dodge;
 300         //if (self.goalentity)
 301         //      te_lightning2(self, self.origin, (self.goalentity.absmin + self.goalentity.absmax) * 0.5);
 302         self.movement = '0 0 0';
 303         maxspeed = cvar("sv_maxspeed");
 304
 305         if(self.jumppadcount)
 306         {
 307                 if(self.flags & FL_ONGROUND)
 308                 {
 309                         self.jumppadcount = FALSE;
 310                         if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 311                                 self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 312                 }
 313
 314                 // If got stuck on the jump pad try to reach the farther visible item
 315                 if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 316                 {
 317                         if(fabs(self.velocity_z)<50)
 318                         {
 319                                 local entity head, newgoal;
 320                                 local float distance, bestdistance;
 321
 322                                 for (head = findchainfloat(bot_pickup, TRUE); head; head = head.chain)
 323                                 {
 324                                         if(head.classname=="worldspawn")
 325                                                 continue;
 326
 327                                         distance = vlen(head.origin - self.origin);
 328                                         if(distance>1000)
 329                                                 continue;
 330
 331                                         traceline(self.origin + self.view_ofs , head.origin, TRUE, world);
 332
 333                                         if(trace_fraction<1)
 334                                                 continue;
 335
 336                                         if(distance>bestdistance)
 337                                         {
 338                                                 newgoal = head;
 339                                                 bestdistance = distance;
 340                                         }
 341                                 }
 342
 343                                 if(newgoal)
 344                                 {
 345                                         self.ignoregoal = self.goalcurrent;
 346                                         self.ignoregoaltime = time + cvar("bot_ai_ignoregoal_timeout");
 347                                         navigation_clearroute();
 348                                         navigation_routetogoal(newgoal, self.origin);
 349                                         self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 350                                 }
 351                         }
 352                         else
 353                                 return;
 354                 }
 355                 else
 356                 {
 357                         if(self.velocity_z>0)
 358                         {
 359                                 local float threshold;
 360                                 threshold = maxspeed * 0.2;
 361                                 if(fabs(self.velocity_x) < threshold  &&  fabs(self.velocity_y) < threshold)
 362                                         self.aistatus |= AI_STATUS_OUT_JUMPPAD;
 363                                 return;
 364                         }
 365                 }
 366         }
 367
 368         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 369         if(skill>6)
 370         if not(self.flags & FL_ONGROUND)
 371         {
 372                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 -65536', MOVE_NOMONSTERS, self);
 373                 if(tracebox_hits_trigger_hurt(self.origin, self.mins, self.maxs, trace_endpos ))
 374                 if(self.items & IT_JETPACK)
 375                 {
 376                         tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 65536', MOVE_NOMONSTERS, self);
 377                         if(tracebox_hits_trigger_hurt(self.origin, self.mins, self.maxs, trace_endpos + '0 0 1' ))
 378                         {
 379                                 if(self.velocity_z<0)
 380                                 {
 381                                         self.BUTTON_HOOK = TRUE;
 382                                 }
 383                         }
 384                         else
 385                                 self.BUTTON_HOOK = TRUE;
 386
 387                         // If there is no goal try to move forward
 388
 389                         if(self.goalcurrent==world)
 390                                 dir = v_forward;
 391                         else
 392                                 dir = normalize(self.goalcurrent.origin - self.origin);
 393
 394                         local vector xyvelocity = self.velocity; xyvelocity_z = 0;
 395                         local float xyspeed = xyvelocity * dir;
 396
 397                         if(xyspeed < (maxspeed / 2))
 398                         {
 399                                 makevectors(self.v_angle_y * '0 1 0');
 400                                 tracebox(self.origin, self.mins, self.maxs, self.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, self);
 401                                 if(trace_fraction==1)
 402                                 {
 403                                         self.movement_x = dir * v_forward * maxspeed;
 404                                         self.movement_y = dir * v_right * maxspeed;
 405                                         if (skill < 10)
 406                                                 havocbot_keyboard_movement(self.origin + dir * 100);
 407                                 }
 408                         }
 409
 410                         self.havocbot_blockhead = TRUE;
 411
 412                         return;
 413                 }
 414                 else if(self.health>cvar("g_balance_rocketlauncher_damage")*0.5)
 415                 {
 416                         if(self.velocity_z < 0)
 417                         if(client_hasweapon(self, WEP_ROCKET_LAUNCHER, TRUE, FALSE))
 418                         {
 419                                 self.movement_x = maxspeed;
 420
 421                                 if(self.rocketjumptime)
 422                                 {
 423                                         if(time > self.rocketjumptime)
 424                                         {
 425                                                 self.BUTTON_ATCK2 = TRUE;
 426                                                 self.rocketjumptime = 0;
 427                                         }
 428                                         return;
 429                                 }
 430
 431                                 self.switchweapon = WEP_ROCKET_LAUNCHER;
 432                                 self.v_angle_x = 90;
 433                                 self.BUTTON_ATCK = TRUE;
 434                                 self.rocketjumptime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 435                                 return;
 436                         }
 437                 }
 438                 else
 439                 {
 440                         // If there is no goal try to move forward
 441                         if(self.goalcurrent==world)
 442                                 self.movement_x = maxspeed;
 443                 }
 444         }
 445
 446         // If we are under water with no goals, swim up
 447         if(self.waterlevel)
 448         if(self.goalcurrent==world)
 449         {
 450                 dir = '0 0 0';
 451                 if(self.waterlevel>WATERLEVEL_SWIMMING)
 452                         dir_z = 1;
 453                 else if(self.velocity_z >= 0 && !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER))
 454                         self.BUTTON_JUMP = TRUE;
 455                 else
 456                         self.BUTTON_JUMP = FALSE;
 457                 makevectors(self.v_angle_y * '0 1 0');
 458                 self.movement_x = dir * v_forward * maxspeed;
 459                 self.movement_y = dir * v_right * maxspeed;
 460                 self.movement_z = dir * v_up * maxspeed;
 461         }
 462
 463         // if there is nowhere to go, exit
 464         if (self.goalcurrent == world)
 465                 return;
 466
 467         if (self.goalcurrent)
 468                 navigation_poptouchedgoals();
 469
 470         // if ran out of goals try to use an alternative goal or get a new strategy asap
 471         if(self.goalcurrent == world)
 472         {
 473                 self.bot_strategytime = 0;
 474                 return;
 475         }
 476
 477 #ifdef DEBUG_BOT_GOALSTACK
 478         debuggoalstack();
 479 #endif
 480
 481         m1 = self.goalcurrent.origin + self.goalcurrent.mins;
 482         m2 = self.goalcurrent.origin + self.goalcurrent.maxs;
 483         destorg = self.origin;
 484         destorg_x = bound(m1_x, destorg_x, m2_x);
 485         destorg_y = bound(m1_y, destorg_y, m2_y);
 486         destorg_z = bound(m1_z, destorg_z, m2_z);
 487         diff = destorg - self.origin;
 488         //dist = vlen(diff);
 489         dir = normalize(diff);
 490         flatdir = diff;flatdir_z = 0;
 491         flatdir = normalize(flatdir);
 492
 493         //if (self.bot_dodgevector_time < time)
 494         {
 495         //      self.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 496         //      self.bot_dodgevector_jumpbutton = 1;
 497                 evadeobstacle = '0 0 0';
 498                 evadelava = '0 0 0';
 499
 500                 if (self.waterlevel)
 501                 {
 502                         if(self.waterlevel>WATERLEVEL_SWIMMING)
 503                         {
 504                         //      flatdir_z = 1;
 505                                 self.aistatus |= AI_STATUS_OUT_WATER;
 506                         }
 507                         else
 508                         {
 509                                 if(self.velocity_z >= 0 && !(self.watertype == CONTENT_WATER && self.goalcurrent.origin_z < self.origin_z) &&
 510                                         ( !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER) || self.aistatus & AI_STATUS_OUT_WATER))
 511                                         self.BUTTON_JUMP = TRUE;
 512                                 else
 513                                         self.BUTTON_JUMP = FALSE;
 514                         }
 515                         dir = normalize(flatdir);
 516                         makevectors(self.v_angle_y * '0 1 0');
 517                 }
 518                 else
 519                 {
 520                         if(self.aistatus & AI_STATUS_OUT_WATER)
 521                                 self.aistatus &~= AI_STATUS_OUT_WATER;
 522
 523                         // jump if going toward an obstacle that doesn't look like stairs we
 524                         // can walk up directly
 525                         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.2, FALSE, self);
 526                         if (trace_fraction < 1)
 527                         if (trace_plane_normal_z < 0.7)
 528                         {
 529                                 s = trace_fraction;
 530                                 tracebox(self.origin + '0 0 16', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 16', FALSE, self);
 531                                 if (trace_fraction < s + 0.01)
 532                                 if (trace_plane_normal_z < 0.7)
 533                                 {
 534                                         s = trace_fraction;
 535                                         tracebox(self.origin + '0 0 48', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 48', FALSE, self);
 536                                         if (trace_fraction > s)
 537                                                 self.BUTTON_JUMP = 1;
 538                                 }
 539                         }
 540
 541                         // avoiding dangers and obstacles
 542                         local vector dst_ahead, dst_down;
 543                         makevectors(self.v_angle_y * '0 1 0');
 544                         dst_ahead = self.origin + self.view_ofs + (self.velocity * 0.4) + (v_forward * 32 * 3);
 545                         dst_down = dst_ahead + '0 0 -1500';
 546
 547                         // Look ahead
 548                         traceline(self.origin + self.view_ofs , dst_ahead, TRUE, world);
 549
 550                         // Check head-banging against walls
 551                         if(vlen(self.origin + self.view_ofs - trace_endpos) < 25 && !(self.aistatus & AI_STATUS_OUT_WATER))
 552                         {
 553                                 self.BUTTON_JUMP = TRUE;
 554                                 if(self.facingwalltime && time > self.facingwalltime)
 555                                 {
 556                                         self.ignoregoal = self.goalcurrent;
 557                                         self.ignoregoaltime = time + cvar("bot_ai_ignoregoal_timeout");
 558                                         self.bot_strategytime = 0;
 559                                         return;
 560                                 }
 561                                 else
 562                                 {
 563                                         self.facingwalltime = time + 0.05;
 564                                 }
 565                         }
 566                         else
 567                         {
 568                                 self.facingwalltime = 0;
 569
 570                                 if(self.ignoregoal != world && time > self.ignoregoaltime)
 571                                 {
 572                                         self.ignoregoal = world;
 573                                         self.ignoregoaltime = 0;
 574                                 }
 575                         }
 576
 577                         // Check for water/slime/lava and dangerous edges
 578                         // (only when the bot is on the ground or jumping intentionally)
 579                         self.aistatus &~= AI_STATUS_DANGER_AHEAD;
 580
 581                         if(trace_fraction == 1)
 582                         if(self.flags & FL_ONGROUND || self.aistatus & AI_STATUS_RUNNING || self.BUTTON_JUMP == TRUE)
 583                         {
 584                                 // Look downwards
 585                                 traceline(dst_ahead , dst_down, TRUE, world);
 586                         //      te_lightning2(world, self.origin, dst_ahead);   // Draw "ahead" look
 587                         //      te_lightning2(world, dst_ahead, dst_down);              // Draw "downwards" look
 588                                 if(trace_endpos_z < self.origin_z + self.mins_z)
 589                                 {
 590                                         s = pointcontents(trace_endpos + '0 0 1');
 591                                         if (s != CONTENT_SOLID)
 592                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 593                                                 evadelava = normalize(self.velocity) * -1;
 594                                         else if (s == CONTENT_SKY)
 595                                                 evadeobstacle = normalize(self.velocity) * -1;
 596                                         else if (!boxesoverlap(dst_ahead - self.view_ofs + self.mins, dst_ahead - self.view_ofs + self.maxs,
 597                                                                 self.goalcurrent.absmin, self.goalcurrent.absmax))
 598                                         {
 599                                                 // if ain't a safe goal with "holes" (like the jumpad on soylent)
 600                                                 // and there is a trigger_hurt below
 601                                                 if(tracebox_hits_trigger_hurt(dst_ahead, self.mins, self.maxs, trace_endpos))
 602                                                 {
 603                                                         // Remove dangerous dynamic goals from stack
 604                                                         if (self.goalcurrent.classname == "player" || self.goalcurrent.classname == "droppedweapon")
 605                                                                 navigation_poproute();
 606                                                         // try to stop
 607                                                         flatdir = '0 0 0';
 608                                                         evadeobstacle = normalize(self.velocity) * -1;
 609                                                 }
 610                                         }
 611                                 }
 612                         }
 613
 614                         dir = flatdir;
 615                         evadeobstacle_z = 0;
 616                         evadelava_z = 0;
 617                         makevectors(self.v_angle_y * '0 1 0');
 618
 619                         if(evadeobstacle!='0 0 0'||evadelava!='0 0 0')
 620                                 self.aistatus |= AI_STATUS_DANGER_AHEAD;
 621                 }
 622
 623                 dodge = havocbot_dodge();
 624                 dodge = dodge * bound(0,3+skill*0.1,1);
 625                 evadelava = evadelava * bound(1,3-skill,3); //Noobs fear lava a lot and take more distance from it
 626                 traceline(self.origin, self.enemy.origin, TRUE, world);
 627                 if(trace_ent.classname == "player")
 628                         dir = dir * bound(0,skill/7,1);
 629
 630                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 631         //      self.bot_dodgevector = dir;
 632         //      self.bot_dodgevector_jumpbutton = self.BUTTON_JUMP;
 633         }
 634
 635         if(time < self.ladder_time)
 636         {
 637                 if(self.goalcurrent.origin_z + self.goalcurrent.mins_z > self.origin_z + self.mins_z)
 638                 {
 639                         if(self.origin_z + self.mins_z  < self.ladder_entity.origin_z + self.ladder_entity.maxs_z)
 640                                 dir = '0 0 1';
 641                 }
 642                 else
 643                 {
 644                         if(self.origin_z + self.mins_z  > self.ladder_entity.origin_z + self.ladder_entity.mins_z)
 645                                 dir = '0 0 -1';
 646                 }
 647         }
 648
 649         //dir = self.bot_dodgevector;
 650         //if (self.bot_dodgevector_jumpbutton)
 651         //      self.BUTTON_JUMP = 1;
 652         self.movement_x = dir * v_forward * maxspeed;
 653         self.movement_y = dir * v_right * maxspeed;
 654         self.movement_z = dir * v_up * maxspeed;
 655
 656         // Emulate keyboard interface
 657         if (skill < 10)
 658                 havocbot_keyboard_movement(destorg);
 659
 660         // Bunnyhop!
 661 //      if(self.aistatus & AI_STATUS_ROAMING)
 662         if(skill >= cvar("bot_ai_bunnyhop_skilloffset"))
 663                 havocbot_bunnyhop(dir);
 664
 665         if ((dir * v_up) >= cvar("sv_jumpvelocity")*0.5 && (self.flags & FL_ONGROUND)) self.BUTTON_JUMP=1;
 666         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill)*0.1,1)) self.BUTTON_JUMP=TRUE;
 667         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill)*0.1,1)) self.havocbot_ducktime=time+0.3/bound(0.1,skill,10);
 668 };
 669
 670 .float havocbot_chooseenemy_finished;
 671 .float havocbot_stickenemy;
 672 void havocbot_chooseenemy()
 673 {
 674         local entity head, best;
 675         local float rating, bestrating;
 676         local vector eye, v;
 677         if (cvar("bot_nofire") || IS_INDEPENDENT_PLAYER(self))
 678         {
 679                 self.enemy = world;
 680                 return;
 681         }
 682         if (self.enemy)
 683         {
 684                 if (!bot_shouldattack(self.enemy))
 685                 {
 686                         // enemy died or something, find a new target
 687                         self.enemy = world;
 688                         self.havocbot_chooseenemy_finished = time;
 689                 }
 690                 else if (self.havocbot_stickenemy)
 691                 {
 692                         // tracking last chosen enemy
 693                         // if enemy is visible
 694                         // and not really really far away
 695                         // and we're not severely injured
 696                         // then keep tracking for a half second into the future
 697                         traceline(self.origin+self.view_ofs, self.enemy.origin+self.enemy.view_ofs*0.5,FALSE,world);
 698                         if (trace_ent == self.enemy || trace_fraction == 1)
 699                         if (vlen(self.enemy.origin - self.origin) < 1000)
 700                         if (self.health > 30)
 701                         {
 702                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 703                                 self.havocbot_chooseenemy_finished = time + cvar("bot_ai_enemydetectioninterval");
 704                                 return;
 705                         }
 706                         // enemy isn't visible, or is far away, or we're injured severely
 707                         // so stop preferring this enemy
 708                         // (it will still take a half second until a new one is chosen)
 709                         self.havocbot_stickenemy = 0;
 710                 }
 711         }
 712         if (time < self.havocbot_chooseenemy_finished)
 713                 return;
 714         self.havocbot_chooseenemy_finished = time + cvar("bot_ai_enemydetectioninterval");
 715         eye = (self.origin + self.view_ofs);
 716         best = world;
 717         bestrating = 100000000;
 718         head = findchainfloat(bot_attack, TRUE);
 719         while (head)
 720         {
 721                 v = (head.absmin + head.absmax) * 0.5;
 722                 rating = vlen(v - eye);
 723                 if (bestrating > rating)
 724                 if (bot_shouldattack(head))
 725                 {
 726                         traceline(eye, v, TRUE, self);
 727                         if (trace_ent == head || trace_fraction >= 1)
 728                         {
 729                                 best = head;
 730                                 bestrating = rating;
 731                         }
 732                 }
 733                 head = head.chain;
 734         }
 735         self.enemy = best;
 736         self.havocbot_stickenemy = TRUE;
 737 };
 738
 739 .float bot_chooseweapontime;
 740 float(entity e) w_getbestweapon;
 741 void havocbot_chooseweapon()
 742 {
 743         local float i;
 744
 745         // TODO: clean this up by moving it to weapon code
 746         if(self.enemy.classname!="player")
 747         {
 748                 // If no weapon was chosen get the first available weapon
 749                 if(self.weapon==0)
 750                 for(i=WEP_LASER + 1; i < WEP_COUNT ; ++i)
 751                 {
 752                         if(client_hasweapon(self, i, TRUE, FALSE))
 753                         {
 754                                 self.switchweapon = i;
 755                                 return;
 756                         }
 757                 }
 758                 return;
 759         }
 760
 761         // Do not change weapon during the next second after a combo
 762         i = time - self.lastcombotime;
 763         if(i < 1)
 764                 return;
 765
 766         // Workaround for rifle reloading (..)
 767         if(self.weapon == WEP_CAMPINGRIFLE)
 768         if(i < cvar("g_balance_campingrifle_reloadtime") + 1)
 769                 return;
 770
 771         local float w, s;
 772         local float rocket  ; rocket   =-1000;
 773         local float nex     ; nex      =-1000;
 774         local float hagar   ; hagar    =-1000;
 775         local float grenade ; grenade  =-1000;
 776         local float electro ; electro  =-1000;
 777         local float crylink ; crylink  =-1000;
 778         local float uzi     ; uzi      =-1000;
 779         local float shotgun ; shotgun  =-1000;
 780         local float campingrifle ; campingrifle  =-1000;
 781         local float laser   ; laser    =-1000;
 782         local float minstanex ; minstanex =-1000;
 783         local float currentscore;
 784         local float bestscore; bestscore = 0;
 785         local float bestweapon; bestweapon=self.switchweapon;
 786         local float distance; distance=bound(10,vlen(self.origin-self.enemy.origin)-200,10000);
 787         local float maxdelaytime=0.5;
 788         local float spreadpenalty=10;
 789         local float distancefromfloor;
 790
 791         // Should it do a weapon combo?
 792         local float af, ct, combo_time, combo;
 793
 794         af = ATTACK_FINISHED(self);
 795         ct = cvar("bot_ai_weapon_combo_threshold");
 796
 797         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
 798         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
 799         combo_time = time + ct + (ct * ((-0.3*skill)+3));
 800
 801         combo = FALSE;
 802
 803         if(cvar("bot_ai_weapon_combo"))
 804         if(self.weapon == self.lastfiredweapon)
 805         if(af > combo_time)
 806         {
 807                 combo = TRUE;
 808                 self.lastcombotime = time;
 809         }
 810
 811         // Custom weapon list based on distance to the enemy
 812         if(bot_custom_weapon){
 813
 814                 // Choose weapons for far distance
 815                 if ( distance > bot_distance_far ) {
 816                         for(i=0; i < WEP_COUNT && bot_weapons_far[i] != -1 ; ++i){
 817                                 w = bot_weapons_far[i];
 818                                 if ( client_hasweapon(self, w, TRUE, FALSE) ){
 819                                         if ( self.weapon == w && combo)
 820                                                 continue;
 821                                         self.switchweapon = w;
 822                                         return;
 823                                 }
 824                         }
 825                 }
 826
 827                 // Choose weapons for mid distance
 828                 if ( distance > bot_distance_close ) {
 829                         for(i=0; i < WEP_COUNT && bot_weapons_mid[i] != -1 ; ++i){
 830                                 w = bot_weapons_mid[i];
 831                                 if ( client_hasweapon(self, w, TRUE, FALSE) ){
 832                                         if ( self.weapon == w && combo)
 833                                                 continue;
 834                                         self.switchweapon = w;
 835                                         return;
 836                                 }
 837                         }
 838                 }
 839
 840                 // Choose weapons for close distance
 841                 for(i=0; i < WEP_COUNT && bot_weapons_close[i] != -1 ; ++i){
 842                         w = bot_weapons_close[i];
 843                         if ( client_hasweapon(self, w, TRUE, FALSE) ){
 844                                 if ( self.weapon == w && combo)
 845                                         continue;
 846                                 self.switchweapon = w;
 847                                 return;
 848                         }
 849                 }
 850                 // If now weapon was chosen by this system fall back to the previous one
 851         }
 852
 853         // Formula:
 854         //      (Damage/Sec * Weapon spefic change to get that damage)
 855         //      *(Time to get to target * weapon specfic hitchange bonus) / (in a time of maxdelaytime)
 856         //      *(Spread change of hit) // if it applies
 857         //      *(Penality for target beeing in air)
 858         // %weaponaddpoint
 859
 860         traceline(self.enemy.origin,self.enemy.origin-'0 0 1000',TRUE,world);
 861         distancefromfloor = self.enemy.origin_z - trace_endpos_z;
 862
 863         if (client_hasweapon(self, WEP_MINSTANEX, TRUE, FALSE))
 864                 minstanex = (1000/cvar("g_balance_minstanex_refire")*1.0)
 865                         * (0.5);
 866
 867         if (client_hasweapon(self, WEP_ROCKET_LAUNCHER, TRUE, FALSE)  &&
 868                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_ROCKET_LAUNCHER &&
 869                         af > combo_time
 870                 )
 871         )
 872                 rocket = (cvar("g_balance_rocketlauncher_damage")/cvar("g_balance_rocketlauncher_refire")*0.75)
 873                         * bound(0,(cvar("g_balance_rocketlauncher_speed")/distance*maxdelaytime),1)*1.5;
 874
 875         if (client_hasweapon(self, WEP_NEX, TRUE, FALSE)  &&
 876                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_NEX &&
 877                         af > combo_time
 878                 )
 879         )
 880                 nex = (cvar("g_balance_nex_damage")/cvar("g_balance_nex_refire")*1.0)
 881                         * (0.5);
 882
 883         if (client_hasweapon(self, WEP_HAGAR, TRUE, FALSE) ) // &&
 884         //      !( cvar("bot_ai_weapon_combo") && self.weapon == WEP_HAGAR &&  time < self.bot_lastshot + cvar("g_balance_hagar_primary_refire") ))
 885                 hagar = (cvar("g_balance_hagar_primary_damage")/cvar("g_balance_hagar_primary_refire")*1.0)
 886                         * bound(0,(cvar("g_balance_hagar_primary_speed")/distance*maxdelaytime),1)*0.2;
 887
 888         if (client_hasweapon(self, WEP_GRENADE_LAUNCHER, TRUE, FALSE) &&
 889                 !(
 890                         cvar("bot_ai_weapon_combo") && self.weapon == WEP_GRENADE_LAUNCHER &&
 891                         af > combo_time
 892                 )
 893         )
 894                 grenade = (cvar("g_balance_grenadelauncher_primary_damage")/cvar("g_balance_grenadelauncher_primary_refire")*1.0)
 895                         * bound(0,(cvar("g_balance_grenadelauncher_primary_speed")/distance*maxdelaytime),1)*1.1;
 896
 897         if (client_hasweapon(self, WEP_ELECTRO, TRUE, FALSE) &&
 898                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_ELECTRO &&
 899                         af > combo_time
 900                 )
 901         )
 902                 electro = (cvar("g_balance_electro_primary_damage")/cvar("g_balance_electro_primary_refire")*0.75)
 903                         * bound(0,(cvar("g_balance_electro_primary_speed")/distance*maxdelaytime),1)*1.0;
 904
 905         if (client_hasweapon(self, WEP_CRYLINK, TRUE, FALSE) ) // &&
 906         //      !( self.weapon == WEP_CRYLINK &&  time < self.bot_lastshot + cvar("g_balance_crylink_primary_refire") ))
 907                 crylink = (cvar("g_balance_crylink_primary_damage")/cvar("g_balance_crylink_primary_refire")*1.0)
 908                         * bound(0,(cvar("g_balance_crylink_primary_speed")/distance*maxdelaytime),1)*(64/(32+cvar("g_balance_crylink_primary_spread")*distance))*1.0;
 909
 910         if (client_hasweapon(self, WEP_UZI, TRUE, FALSE) ) // &&
 911         //      !( self.weapon == WEP_UZI &&  time < self.bot_lastshot + cvar("g_balance_uzi_sustained_refire") ))
 912                 uzi = (cvar("g_balance_uzi_sustained_damage")/cvar("g_balance_uzi_sustained_refire")*1.0)
 913                         * bound(0,32/(32+cvar("g_balance_uzi_sustained_spread")*distance),1);
 914
 915         if (client_hasweapon(self, WEP_SHOTGUN, TRUE, FALSE) &&
 916                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_SHOTGUN &&
 917                         af > combo_time
 918                 )
 919         )
 920                 shotgun = (cvar("g_balance_shotgun_primary_damage")*cvar("g_balance_shotgun_primary_bullets")/cvar("g_balance_shotgun_primary_refire")*1.0)
 921                         * bound(0,32/(32+cvar("g_balance_shotgun_primary_spread")*distance),1);
 922
 923         if (client_hasweapon(self, WEP_LASER, FALSE, FALSE) &&
 924                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_LASER &&
 925                         af > combo_time
 926                 )
 927         )
 928                 laser = (cvar("g_balance_laser_primary_damage")/cvar("g_balance_laser_primary_refire")*1.0)
 929                         * bound(0,cvar("g_balance_laser_primary_speed")/distance*maxdelaytime,1);
 930
 931         if((self.enemy.flags & FL_ONGROUND)==FALSE){
 932                 rocket = rocket   * (1.5-bound(0, distancefromfloor/cvar("g_balance_rocketlauncher_radius"         ),0.9)); //slight bigger change
 933                 grenade = grenade * (1.5-bound(0,distancefromfloor/cvar("g_balance_grenadelauncher_primary_radius"),0.95));
 934                 electro = electro * (1.5-bound(0,distancefromfloor/cvar("g_balance_electro_primary_radius"        ),0.95));
 935                 laser = laser     * (1.5-bound(0,distancefromfloor/cvar("g_balance_laser_primary_radius"                  ),0.95));
 936         }
 937         /*
 938         dprint("Floor distance: ",ftos(distancefromfloor),"\n");
 939         dprint("Rocket: " , ftos(rocket  ), "\n");
 940         dprint("Nex: "    , ftos(nex     ), "\n");
 941         dprint("Hagar: "  , ftos(hagar   ), "\n");
 942         dprint("Grenade: ", ftos(grenade ), "\n");
 943         dprint("Electro: ", ftos(electro ), "\n");
 944         dprint("Crylink: ", ftos(crylink ), "\n");
 945         dprint("Uzi: "    , ftos(uzi     ), "\n");
 946         dprint("Shotgun :", ftos(shotgun ), "\n");
 947         dprint("Laser   :", ftos(laser   ), "\n\n");
 948         */
 949         currentscore = -1;
 950         w = WEP_MINSTANEX        ;s = minstanex;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 951         w = WEP_ROCKET_LAUNCHER  ;s = rocket   ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 952         w = WEP_NEX              ;s = nex      ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 953         w = WEP_HAGAR            ;s = hagar    ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 954         w = WEP_GRENADE_LAUNCHER ;s = grenade  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 955         w = WEP_ELECTRO          ;s = electro  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 956         w = WEP_CRYLINK          ;s = crylink  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 957         w = WEP_UZI              ;s = uzi      ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 958         w = WEP_SHOTGUN          ;s = shotgun  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 959         w = WEP_LASER            ;s = laser    ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 960
 961         // switch if the best weapon would provide a significant damage increase
 962         if (bestscore > currentscore*1.5){
 963                 self.switchweapon = bestweapon;
 964
 965                 // buys time for detonating the rocket. not tested yet
 966                 if ( cvar("bot_ai_weapon_combo") && bestweapon == WEP_ROCKET_LAUNCHER )
 967                         self.bot_chooseweapontime += (distance  / cvar("g_balance_rocketlauncher_speed"));
 968         }
 969 };
 970
 971 .float nextaim;
 972 void havocbot_aim()
 973 {
 974         local vector selfvel, enemyvel;
 975 //      if(self.flags & FL_INWATER)
 976 //              return;
 977         if (time < self.nextaim)
 978                 return;
 979         self.nextaim = time + 0.1;
 980         selfvel = self.velocity;
 981         if (!self.waterlevel)
 982                 selfvel_z = 0;
 983         if (self.enemy)
 984         {
 985                 enemyvel = self.enemy.velocity;
 986                 if (!self.enemy.waterlevel)
 987                         enemyvel_z = 0;
 988                 lag_additem(time + self.ping, 0, 0, self.enemy, self.origin, selfvel, self.enemy.origin, enemyvel);
 989         }
 990         else
 991                 lag_additem(time + self.ping, 0, 0, world, self.origin, selfvel, self.goalcurrent.origin, '0 0 0');
 992 };
 993
 994 void havocbot_ai()
 995 {
 996     if(bot_execute_commands())
 997         return;
 998
 999         if (bot_strategytoken == self)
1000         if (!bot_strategytoken_taken)
1001         {
1002                 if(self.havocbot_blockhead)
1003                 {
1004                         self.havocbot_blockhead = FALSE;
1005                 }
1006                 else
1007                 {
1008                         self.havocbot_role();
1009                 }
1010
1011                 // TODO: tracewalk() should take care of this job (better path finding under water)
1012                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
1013                 if(self.goalcurrent==world)
1014                 if(self.waterlevel==WATERLEVEL_SWIMMING || self.aistatus & AI_STATUS_OUT_WATER)
1015                 {
1016                         // Look for the closest waypoint out of water
1017                         local entity newgoal, head;
1018                         local float bestdistance, distance;
1019
1020                         newgoal = world;
1021                         bestdistance = 10000;
1022                         for (head = findchain(classname, "waypoint"); head; head = head.chain)
1023                         {
1024                                 distance = vlen(head.origin - self.origin);
1025                                 if(distance>10000)
1026                                         continue;
1027
1028                                 if(head.origin_z < self.origin_z)
1029                                         continue;
1030
1031                                 if(head.origin_z - self.origin_z - self.view_ofs_z > 100)
1032                                         continue;
1033
1034                                 if (pointcontents(head.origin + head.maxs + '0 0 1') != CONTENT_EMPTY)
1035                                         continue;
1036
1037                                 traceline(self.origin + self.view_ofs , head.origin, TRUE, head);
1038
1039                                 if(trace_fraction<1)
1040                                         continue;
1041
1042                                 if(distance<bestdistance)
1043                                 {
1044                                         newgoal = head;
1045                                         bestdistance = distance;
1046                                 }
1047                         }
1048
1049                         if(newgoal)
1050                         {
1051                         //      te_wizspike(newgoal.origin);
1052                                 navigation_pushroute(newgoal);
1053                         }
1054                 }
1055
1056                 // token has been used this frame
1057                 bot_strategytoken_taken = TRUE;
1058         }
1059         havocbot_chooseenemy();
1060         if (self.bot_chooseweapontime < time )
1061         {
1062                 self.bot_chooseweapontime = time + cvar("bot_ai_chooseweaponinterval");
1063                 havocbot_chooseweapon();
1064         }
1065         havocbot_aim();
1066         lag_update();
1067         if (self.bot_aimtarg)
1068         {
1069                 self.aistatus |= AI_STATUS_ATTACKING;
1070                 self.aistatus &~= AI_STATUS_ROAMING;
1071
1072                 weapon_action(self.weapon, WR_AIM);
1073                 if (cvar("bot_nofire") || IS_INDEPENDENT_PLAYER(self))
1074                 {
1075                         self.BUTTON_ATCK = FALSE;
1076                         self.BUTTON_ATCK2 = FALSE;
1077                 }
1078                 else
1079                 {
1080                         if(self.BUTTON_ATCK||self.BUTTON_ATCK2)
1081                                 self.lastfiredweapon = self.weapon;
1082                 }
1083         }
1084         else if (self.goalcurrent)
1085         {
1086                 self.aistatus |= AI_STATUS_ROAMING;
1087                 self.aistatus &~= AI_STATUS_ATTACKING;
1088
1089                 local vector now,v,next;//,heading;
1090                 local float aimdistance,skillblend,distanceblend,blend;
1091                 next = now = self.goalcurrent.origin - (self.origin + self.view_ofs);
1092                 aimdistance = vlen(now);
1093                 //heading = self.velocity;
1094                 //dprint(self.goalstack01.classname,etos(self.goalstack01),"\n");
1095                 if(
1096                         self.goalstack01 != self && self.goalstack01 != world && self.aistatus & AI_STATUS_RUNNING == 0 &&
1097                         !(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1098                 )
1099                         next = self.goalstack01.origin - (self.origin + self.view_ofs);
1100
1101                 skillblend=bound(0,(skill-2.5)*0.5,1); //lower skill player can't preturn
1102                 distanceblend=bound(0,aimdistance/cvar("bot_ai_keyboard_distance"),1);
1103                 blend = skillblend * (1-distanceblend);
1104                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
1105                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
1106                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
1107                 v = now + blend * (next - now);
1108                 //dprint(etos(self), " ");
1109                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
1110                 //v = now * (distanceblend) + next * (1-distanceblend);
1111                 if (self.waterlevel < WATERLEVEL_SWIMMING)
1112                         v_z = 0;
1113                 //dprint("walk at:", vtos(v), "\n");
1114                 //te_lightning2(world, self.origin, self.goalcurrent.origin);
1115                 bot_aimdir(v, -1);
1116         }
1117         havocbot_movetogoal();
1118 };
1119
1120 void havocbot_setupbot()
1121 {
1122         self.bot_ai = havocbot_ai;
1123         // will be updated by think code
1124         //Generate some random skill levels
1125         self.havocbot_keyboardskill=random()-0.5;
1126         havocbot_chooserole();
1127 }
1128
1129
1130 #ifdef DEBUG_BOT_GOALSTACK
1131
1132 .float goalcounter;
1133 .vector lastposition;
1134
1135 // Debug the goal stack visually
1136 void debuggoalstack()
1137 {
1138         local entity target;
1139         local vector org;
1140
1141         if(self.goalcounter==0)target=self.goalcurrent;
1142         else if(self.goalcounter==1)target=self.goalstack01;
1143         else if(self.goalcounter==2)target=self.goalstack02;
1144         else if(self.goalcounter==3)target=self.goalstack03;
1145         else if(self.goalcounter==4)target=self.goalstack04;
1146         else if(self.goalcounter==5)target=self.goalstack05;
1147         else if(self.goalcounter==6)target=self.goalstack06;
1148         else if(self.goalcounter==7)target=self.goalstack07;
1149         else if(self.goalcounter==8)target=self.goalstack08;
1150         else if(self.goalcounter==9)target=self.goalstack09;
1151         else if(self.goalcounter==10)target=self.goalstack10;
1152         else if(self.goalcounter==11)target=self.goalstack11;
1153         else if(self.goalcounter==12)target=self.goalstack12;
1154         else if(self.goalcounter==13)target=self.goalstack13;
1155         else if(self.goalcounter==14)target=self.goalstack14;
1156         else if(self.goalcounter==15)target=self.goalstack15;
1157         else if(self.goalcounter==16)target=self.goalstack16;
1158         else if(self.goalcounter==17)target=self.goalstack17;
1159         else if(self.goalcounter==18)target=self.goalstack18;
1160         else if(self.goalcounter==19)target=self.goalstack19;
1161         else if(self.goalcounter==20)target=self.goalstack20;
1162         else if(self.goalcounter==21)target=self.goalstack21;
1163         else if(self.goalcounter==22)target=self.goalstack22;
1164         else if(self.goalcounter==23)target=self.goalstack23;
1165         else if(self.goalcounter==24)target=self.goalstack24;
1166         else if(self.goalcounter==25)target=self.goalstack25;
1167         else if(self.goalcounter==26)target=self.goalstack26;
1168         else if(self.goalcounter==27)target=self.goalstack27;
1169         else if(self.goalcounter==28)target=self.goalstack28;
1170         else if(self.goalcounter==29)target=self.goalstack29;
1171         else if(self.goalcounter==30)target=self.goalstack30;
1172         else if(self.goalcounter==31)target=self.goalstack31;
1173
1174         if(target==world)
1175         {
1176                 self.goalcounter = 0;
1177                 self.lastposition='0 0 0';
1178                 return;
1179         }
1180
1181         if(self.lastposition=='0 0 0')
1182                 org = self.origin;
1183         else
1184                 org = self.lastposition;
1185
1186
1187         te_lightning2(world, org, target.origin);
1188         self.lastposition = target.origin;
1189
1190         self.goalcounter++;
1191 }
1192
1193 #endif