data/qcsrc/server/gamecommand.qc

   1 string GotoMap(string m);
   2
   3 float FullTraceFraction(vector a, vector mi, vector ma, vector b)
   4 {
   5         vector c;
   6         float white, black;
   7         if(a_z > b_z)
   8                 return 0;
   9
  10         white = 0;
  11         black = 0;
  12
  13         c = a;
  14
  15         while(vlen(c - b) > 1)
  16         {
  17                 tracebox(c, mi, ma, b, MOVE_WORLDONLY, world);
  18                 if(!trace_startsolid)
  19                 {
  20                         black += trace_endpos_z - c_z;
  21                         c = trace_endpos;
  22                 }
  23                 tracebox_inverted(c, mi, ma, b, MOVE_WORLDONLY, world);
  24                 white += trace_endpos_z - c_z;
  25                 c = trace_endpos;
  26         }
  27
  28         return white / (black + white);
  29 }
  30
  31 float RadarMapAtPoint_Trace(float x, float y, float w, float h, float zmin, float zsize)
  32 {
  33         vector a, b, mi, ma;
  34         mi = '0 0 0';
  35         ma = '1 0 0' * w + '0 1 0' * h;
  36         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  37         b = '1 0 0' * x + '0 1 0' * y + '0 0 1' * (zsize - zmin);
  38         return FullTraceFraction(a, mi, ma, b);
  39 }
  40 float RadarMapAtPoint_Block(float x, float y, float w, float h, float zmin, float zsize, float q)
  41 {
  42         vector o, mi, ma;
  43         float i, r;
  44         vector dz;
  45         mi = '0 0 0';
  46         dz = (zsize / q) * '0 0 1';
  47         ma = '1 0 0' * w + '0 1 0' * h + dz;
  48         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  49
  50         if(x < world.absmin_x - w)
  51                 return 0;
  52         if(y < world.absmin_y - h)
  53                 return 0;
  54         if(x > world.absmax_x)
  55                 return 0;
  56         if(y > world.absmax_y)
  57                 return 0;
  58
  59         r = 0;
  60         for(i = 0; i < q; ++i)
  61         {
  62                 tracebox(o + dz * i, mi, ma, o + dz * i, MOVE_WORLDONLY, world);
  63                 if(trace_startsolid)
  64                         ++r;
  65         }
  66         return r / q; // 0 .. 1
  67 }
  68
  69 string doublehex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F404142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F606162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F808182838485868788898A8B8C8D8E8F909192939495969798999A9B9C9D9E9FA0A1A2A3A4A5A6A7A8A9AAABACADAEAFB0B1B2B3B4B5B6B7B8B9BABBBCBDBEBFC0C1C2C3C4C5C6C7C8C9CACBCCCDCECFD0D1D2D3D4D5D6D7D8D9DADBDCDDDEDFE0E1E2E3E4E5E6E7E8E9EAEBECEDEEEFF0F1F2F3F4F5F6F7F8F9FAFBFCFDFEFF";
  70
  71 float RADAR_WIDTH_MAX = 2048;
  72 float RADAR_HEIGHT_MAX = 2048;
  73 float sharpen_buffer[RADAR_WIDTH_MAX * 3];
  74
  75 void sharpen_set(float x, float v)
  76 {
  77         sharpen_buffer[x + 2 * RADAR_WIDTH_MAX] = v;
  78 }
  79
  80 float sharpen_getpixel(float x, float y)
  81 {
  82         if(x < 0)
  83                 return 0;
  84         if(x >= RADAR_WIDTH_MAX)
  85                 return 0;
  86         if(y < 0)
  87                 return 0;
  88         if(y > 2)
  89                 return 0;
  90         return sharpen_buffer[x + y * RADAR_WIDTH_MAX];
  91 }
  92
  93 float sharpen_get(float x, float a)
  94 {
  95         float sum;
  96         sum = sharpen_getpixel(x, 1);
  97         if(a == 0)
  98                 return sum;
  99         sum *= (8 + 1/a);
 100         sum -= sharpen_getpixel(x - 1, 0);
 101         sum -= sharpen_getpixel(x - 1, 1);
 102         sum -= sharpen_getpixel(x - 1, 2);
 103         sum -= sharpen_getpixel(x + 1, 0);
 104         sum -= sharpen_getpixel(x + 1, 1);
 105         sum -= sharpen_getpixel(x + 1, 2);
 106         sum -= sharpen_getpixel(x, 0);
 107         sum -= sharpen_getpixel(x, 2);
 108         return bound(0, sum * a, 1);
 109 }
 110
 111 void sharpen_shift(float w)
 112 {
 113         float i;
 114         for(i = 0; i < w; ++i)
 115         {
 116                 sharpen_buffer[i] = sharpen_buffer[i + RADAR_WIDTH_MAX];
 117                 sharpen_buffer[i + RADAR_WIDTH_MAX] = sharpen_buffer[i + 2 * RADAR_WIDTH_MAX];
 118                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
 119         }
 120 }
 121
 122 void sharpen_init(float w)
 123 {
 124         float i;
 125         for(i = 0; i < w; ++i)
 126         {
 127                 sharpen_buffer[i] = 0;
 128                 sharpen_buffer[i + RADAR_WIDTH_MAX] = 0;
 129                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
 130         }
 131 }
 132
 133 entity radarmapper;
 134 // rough map entity
 135 //   cnt: current line
 136 //   size: pixel width/height
 137 //   maxs: cell width/height
 138 //   frame: counter
 139 void RadarMap_Think()
 140 {
 141         float i, x, l;
 142         string si;
 143
 144         if(self.frame == 0)
 145         {
 146                 // initialize
 147                 get_mi_min_max_texcoords(1);
 148                 self.mins = mi_picmin;
 149                 self.maxs_x = (mi_picmax_x - mi_picmin_x) / self.size_x;
 150                 self.maxs_y = (mi_picmax_y - mi_picmin_y) / self.size_y;
 151                 self.maxs_z = mi_max_z - mi_min_z;
 152                 print("Picture mins/maxs: ", ftos(self.maxs_x), " and ", ftos(self.maxs_y), " should match\n");
 153                 self.netname = strzone(strcat("gfx/", mi_shortname, "_radar.xpm"));
 154                 if(!(self.count & 1))
 155                 {
 156                         self.cnt = fopen(self.netname, FILE_READ);
 157                         if(self.cnt >= 0)
 158                         {
 159                                 print(self.netname, " already exists, aborting (you may want to specify --force)\n");
 160                                 if(self.count & 4)
 161                                 {
 162                                         localcmd("quit\n");
 163                                 }
 164                                 else if(self.count & 2)
 165                                 {
 166                                         localcmd(strcat("defer 1 \"sv_cmd radarmap --flags ", ftos(self.count), strcat(" --res ", ftos(self.size_x), " ", ftos(self.size_y), " --sharpen ", ftos(self.ltime)), "\"\n"));
 167                                         GotoNextMap();
 168                                 }
 169                                 remove(self);
 170                                 radarmapper = world;
 171                                 return;
 172                         }
 173                 }
 174                 self.cnt = fopen(self.netname, FILE_WRITE);
 175                 if(self.cnt < 0)
 176                 {
 177                         print("Error writing ", self.netname, "\n");
 178                         remove(self);
 179                         radarmapper = world;
 180                         return;
 181                 }
 182                 print("Writing to ", self.netname, "...\n");
 183                 fputs(self.cnt, "/* XPM */\n");
 184                 fputs(self.cnt, "static char *RadarMap[] = {\n");
 185                 fputs(self.cnt, "/* columns rows colors chars-per-pixel */\n");
 186                 fputs(self.cnt, strcat("\"", ftos(self.size_x), " ", ftos(self.size_y), " 256 2\",\n"));
 187                 for(i = 0; i < 256; ++i)
 188                 {
 189                         si = substring(doublehex, i*2, 2);
 190                         fputs(self.cnt, strcat("\"", si, " c #", si, si, si, "\",\n"));
 191                 }
 192                 self.frame += 1;
 193                 self.nextthink = time;
 194                 sharpen_init(self.size_x);
 195         }
 196         else if(self.frame <= self.size_y)
 197         {
 198                 // fill the sharpen buffer with this line
 199                 sharpen_shift(self.size_x);
 200                 if(self.count & 8)
 201                 {
 202                         for(x = 0; x < self.size_x; ++x)
 203                         {
 204                                 l = RadarMapAtPoint_Trace(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z);
 205                                 sharpen_set(x, l);
 206                         }
 207                 }
 208                 else if(self.count & 16)
 209                 {
 210                         for(x = 0; x < self.size_x; ++x)
 211                         {
 212                                 l = RadarMapAtPoint_Block(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, 1023);
 213                                 sharpen_set(x, l);
 214                         }
 215                 }
 216                 else
 217                 {
 218                         for(x = 0; x < self.size_x; ++x)
 219                         {
 220                                 l = RadarMapAtPoint_Block(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, 255);
 221                                 sharpen_set(x, l);
 222                         }
 223                 }
 224
 225                 // do we have enough lines?
 226                 if(self.frame >= 2)
 227                 {
 228                         // write a pixel line
 229                         fputs(self.cnt, "\"");
 230                         for(x = 0; x < self.size_x; ++x)
 231                         {
 232                                 l = sharpen_get(x, self.ltime);
 233                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 255.0 + 0.5), 2));
 234                         }
 235                         if(self.frame == self.size_y)
 236                                 fputs(self.cnt, "\"\n");
 237                         else
 238                         {
 239                                 fputs(self.cnt, "\",\n");
 240                                 print(ftos(self.size_y - self.frame), " lines left\n");
 241                         }
 242                 }
 243
 244                 // is this the last line? then write back the missing line
 245                 if(self.frame == self.size_y)
 246                 {
 247                         sharpen_shift(self.size_x);
 248                         // write a pixel line
 249                         fputs(self.cnt, "\"");
 250                         for(x = 0; x < self.size_x; ++x)
 251                         {
 252                                 l = sharpen_get(x, self.ltime);
 253                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 255.0 + 0.5), 2));
 254                         }
 255                         if(self.frame == self.size_y)
 256                                 fputs(self.cnt, "\"\n");
 257                         else
 258                         {
 259                                 fputs(self.cnt, "\",\n");
 260                                 print(ftos(self.size_y - self.frame), " lines left\n");
 261                         }
 262                 }
 263
 264                 self.frame += 1;
 265                 self.nextthink = time;
 266         }
 267         else
 268         {
 269                 // close the file
 270                 fputs(self.cnt, "};\n");
 271                 fclose(self.cnt);
 272                 print("Finished. Please edit data/", self.netname, " with an image editing application and place it in the TGA format in the gfx folder.\n");
 273                 if(self.count & 4)
 274                 {
 275                         localcmd("quit\n");
 276                 }
 277                 else if(self.count & 2)
 278                 {
 279                         localcmd(strcat("defer 1 \"sv_cmd radarmap --flags ", ftos(self.count), strcat(" --res ", ftos(self.size_x), " ", ftos(self.size_y), " --sharpen ", ftos(self.ltime)), "\"\n"));
 280                         GotoNextMap();
 281                 }
 282                 remove(self);
 283                 radarmapper = world;
 284         }
 285 }
 286
 287 void RadarMap(float argc)
 288 {
 289         if(radarmapper)
 290                 return;
 291         float i;
 292         radarmapper = spawn();
 293         radarmapper.classname = "radarmapper";
 294         radarmapper.think = RadarMap_Think;
 295         radarmapper.nextthink = time;
 296         radarmapper.count = 0;
 297         radarmapper.ltime = 1;
 298         radarmapper.size_x = 512;
 299         radarmapper.size_y = 512;
 300
 301         for(i = 1; i < argc; ++i)
 302         {
 303                 if(argv(i) == "--force")
 304                         radarmapper.count |= 1;
 305                 else if(argv(i) == "--loop")
 306                         radarmapper.count |= 2;
 307                 else if(argv(i) == "--quit")
 308                         radarmapper.count |= 4;
 309                 else if(argv(i) == "--block")
 310                 {
 311                         radarmapper.count &~= 24;
 312                 }
 313                 else if(argv(i) == "--trace")
 314                 {
 315                         radarmapper.count &~= 24;
 316                         radarmapper.count |= 8;
 317                 }
 318                 else if(argv(i) == "--hqblock")
 319                 {
 320                         radarmapper.count &~= 24;
 321                         radarmapper.count |= 16;
 322                 }
 323                 else if(argv(i) == "--flags") // for the recursive call
 324                 {
 325                         ++i;
 326                         radarmapper.count = stof(argv(i));
 327                 }
 328                 else if(argv(i) == "--sharpen") // for the recursive call
 329                 {
 330                         ++i;
 331                         radarmapper.ltime = stof(argv(i));
 332                 }
 333                 else if(argv(i) == "--res") // resolution
 334                 {
 335                         ++i;
 336                         radarmapper.size_x = stof(argv(i));
 337                         ++i;
 338                         radarmapper.size_y = stof(argv(i));
 339                 }
 340                 else
 341                 {
 342                         remove(radarmapper);
 343                         print("Usage: sv_cmd radarmap [--force] [--loop] [--quit] [--trace | --block | --hqblock] [--sharpen N] [--res W H]\n");
 344                         return;
 345                 }
 346         }
 347 }
 348
 349 void BBox()
 350 {
 351         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 352         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 353         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 354         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 355         print("Solid bounding box size:");
 356
 357         tracebox('1 0 0' * world.absmin_x,
 358                  '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 359                  '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 360                  '1 0 0' * world.absmax_x,
 361                          MOVE_WORLDONLY,
 362                          world);
 363         if(trace_startsolid)
 364                 print(" ", ftos(world.absmin_x));
 365         else
 366                 print(" ", ftos(trace_endpos_x));
 367
 368         tracebox('0 1 0' * world.absmin_y,
 369                  '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 370                  '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 371                  '0 1 0' * world.absmax_y,
 372                          MOVE_WORLDONLY,
 373                          world);
 374         if(trace_startsolid)
 375                 print(" ", ftos(world.absmin_y));
 376         else
 377                 print(" ", ftos(trace_endpos_y));
 378
 379         tracebox('0 0 1' * world.absmin_z,
 380                  '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 381                  '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 382                  '0 0 1' * world.absmax_z,
 383                          MOVE_WORLDONLY,
 384                          world);
 385         if(trace_startsolid)
 386                 print(" ", ftos(world.absmin_z));
 387         else
 388                 print(" ", ftos(trace_endpos_z));
 389
 390         tracebox('1 0 0' * world.absmax_x,
 391                  '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 392                  '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 393                  '1 0 0' * world.absmin_x,
 394                          MOVE_WORLDONLY,
 395                          world);
 396         if(trace_startsolid)
 397                 print(" ", ftos(world.absmax_x));
 398         else
 399                 print(" ", ftos(trace_endpos_x));
 400
 401         tracebox('0 1 0' * world.absmax_y,
 402                  '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 403                  '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 404                  '0 1 0' * world.absmin_y,
 405                          MOVE_WORLDONLY,
 406                          world);
 407         if(trace_startsolid)
 408                 print(" ", ftos(world.absmax_y));
 409         else
 410                 print(" ", ftos(trace_endpos_y));
 411
 412         tracebox('0 0 1' * world.absmax_z,
 413                  '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 414                  '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 415                  '0 0 1' * world.absmin_z,
 416                          MOVE_WORLDONLY,
 417                          world);
 418         if(trace_startsolid)
 419                 print(" ", ftos(world.absmax_z));
 420         else
 421                 print(" ", ftos(trace_endpos_z));
 422
 423         print("\n");
 424 }
 425
 426 void EffectIndexDump()
 427 {
 428         float d;
 429         float fh;
 430         string s;
 431
 432         d = db_create();
 433
 434         print("begin of effects list\n");
 435         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 436         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 437         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 438         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 439         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 440         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 441         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 442         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 443         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 444         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 445         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 446         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 447         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 448         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 449         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 450         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 451         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 452         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 453         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 454         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 455         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 456         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 457         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 458         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 459         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 460         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 461         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 462         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 463         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 464         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 465         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 466         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 467         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 468         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 469         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 470
 471         fh = fopen("effectinfo.txt", FILE_READ);
 472         while((s = fgets(fh)))
 473         {
 474                 tokenize_insane(s); // tokenize_sane would hit the loop counter :(
 475                 if(argv(0) == "effect")
 476                 {
 477                         if(db_get(d, argv(1)) != "1")
 478                         {
 479                                 if(particleeffectnum(argv(1)) >= 0)
 480                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 481                                 db_put(d, argv(1), "1");
 482                         }
 483                 }
 484         }
 485         print("end of effects list\n");
 486
 487         db_close(d);
 488 }
 489
 490 void make_mapinfo_Think()
 491 {
 492         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 493         {
 494                 print("Done rebuiling mapinfos.\n");
 495                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 496                 remove(self);
 497         }
 498         else
 499         {
 500                 self.think = make_mapinfo_Think;
 501                 self.nextthink = time;
 502         }
 503 }
 504
 505 void GameCommand(string command)
 506 {
 507         float argc;
 508         entity client;
 509         float entno;
 510         argc = tokenize_sane(command);
 511
 512         if(argv(0) == "help" || argc == 0)
 513         {
 514                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");
 515                 print("  adminmsg clientnumber \"message\"\n");
 516                 print("  teamstatus\n");
 517                 print("  printstats\n");
 518                 print("  make_mapinfo\n");
 519                 print("  gametype dm|ctf|...\n");
 520                 print("  savedb filename\n");
 521                 print("  dumpdb filename\n");
 522                 print("  loaddb filename\n");
 523                 print("  allready\n");
 524                 print("  effectindexdump\n");
 525                 print("  radarmap [--force] [--quit | --loop] [sharpness]\n");
 526                 print("  bbox\n");
 527                 print("  cvar_changes\n");
 528                 print("  find classname\n");
 529                 GameCommand_Vote("help", world);
 530                 GameCommand_Ban("help");
 531                 GameCommand_Generic("help");
 532                 return;
 533         }
 534
 535         if(GameCommand_Vote(command, world))
 536                 return;
 537
 538         if(GameCommand_Ban(command))
 539                 return;
 540
 541         if(GameCommand_Generic(command))
 542                 return;
 543
 544         if(argv(0) == "printstats")
 545         {
 546                 DumpStats(FALSE);
 547                 return;
 548         }
 549
 550         if(argv(0) == "make_mapinfo")
 551         {
 552                 entity e;
 553                 e = spawn();
 554                 e.classname = "make_mapinfo";
 555                 e.think = make_mapinfo_Think;
 556                 e.nextthink = time;
 557                 MapInfo_Enumerate();
 558                 return;
 559         }
 560
 561         if(argv(0) == "warp") if(argc == 2) if(cvar("g_campaign"))
 562         {
 563                 CampaignLevelWarp(stof(argv(1)));
 564                 return;
 565         }
 566
 567         if(argv(0) == "gotomap") if(argc == 2)
 568         {
 569                 print(GotoMap(argv(1)), "\n");
 570                 return;
 571         }
 572
 573         if(argv(0) == "gametype") if(argc == 2)
 574         {
 575                 float t, tsave;
 576                 string s;
 577                 s = argv(1);
 578                 t = MapInfo_Type_FromString(s);
 579                 tsave = MapInfo_CurrentGametype();
 580                 if(t)
 581                 {
 582                         MapInfo_SwitchGameType(t);
 583                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, MAPINFO_FLAG_HIDDEN, 0);
 584                         if(MapInfo_count > 0)
 585                         {
 586                                 bprint("Game type successfully switched to ", s, "\n");
 587                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 588                         }
 589                         else
 590                         {
 591                                 bprint("Cannot use this game type: no map for it found\n");
 592                                 MapInfo_SwitchGameType(tsave);
 593                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 594                         }
 595                 }
 596                 else
 597                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 598                 return;
 599         }
 600
 601         if(argv(0) == "adminmsg") if(argc == 3)
 602         {
 603                 entno = stof(argv(1));
 604                 client = world;
 605                 if(entno <= maxclients)
 606                         client = edict_num(entno);
 607                 if(client.flags & FL_CLIENT)
 608                 {
 609                         centerprint_atprio(client, CENTERPRIO_ADMIN, strcat("^3SERVER ADMIN:\n\n^7", argv(2)));
 610                         sprint(client, strcat("\{1}\{13}^3SERVER ADMIN^7: ", argv(2), "\n"));
 611                         print("Message sent to ", client.netname, "\n");
 612                 }
 613                 else
 614                         print("Client not found\n");
 615                 return;
 616         }
 617
 618         if(argv(0) == "savedb") if(argc == 2)
 619         {
 620                 db_save(ServerProgsDB, argv(1));
 621                 print("DB saved.\n");
 622                 return;
 623         }
 624
 625         if(argv(0) == "dumpdb") if(argc == 2)
 626         {
 627                 db_dump(ServerProgsDB, argv(1));
 628                 print("DB dumped.\n");
 629                 return;
 630         }
 631
 632         if(argv(0) == "loaddb") if(argc == 2)
 633         {
 634                 db_close(ServerProgsDB);
 635                 ServerProgsDB = db_load(argv(1));
 636                 print("DB loaded.\n");
 637                 return;
 638         }
 639         if (argv(0) == "nospectators")
 640         {
 641                 blockSpectators = 1;
 642                 local entity plr;
 643                 FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
 644                 {
 645                         if(plr.classname == "spectator" || plr.classname == "observer")
 646                         {
 647                                 plr.spectatortime = time;
 648                                 sprint(plr, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 649                         }
 650                 }
 651                 bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds!\n"));
 652                 return;
 653         }
 654         if (argv(0) == "lockteams")
 655         {
 656                 if(teamplay)
 657                 {
 658                         lockteams = 1;
 659                         bprint("^1The teams are now locked.\n");
 660                 }
 661                 else
 662                         bprint("That command can only be used in a team-based gamemode.\n");
 663                 return;
 664         }
 665         if (argv(0) == "unlockteams")
 666         {
 667                 if(teamplay)
 668                 {
 669                         lockteams = 0;
 670                         bprint("^1The teams are now unlocked.\n");
 671                 }
 672                 else
 673                         bprint("That command can only be used in a team-based gamemode.\n");
 674                 return;
 675         }
 676         if (argv(0) == "movetoteam") if(argc == 3)
 677         {
 678                 entno = stof(argv(1));
 679                 client = world;
 680                 if(entno <= maxclients)
 681                         client = edict_num(entno);
 682                 if(client.flags & FL_CLIENT)
 683                 {
 684                         float lt;
 685                         lt = lockteams;
 686                         lockteams = 0;
 687
 688                         self = client;
 689                         SV_ParseClientCommand(strcat("selectteam ", argv(2)));
 690
 691                         lockteams = lt;
 692                 }
 693                 else
 694                         print("Client not found\n");
 695                 return;
 696         }
 697         if (argv(0) == "teamstatus")
 698         {
 699                 Score_NicePrint(world);
 700                 return;
 701         }
 702         if (argv(0) == "allready")
 703         {
 704                 ReadyRestart();
 705                 return;
 706         }
 707         if (argv(0) == "effectindexdump")
 708         {
 709                 EffectIndexDump();
 710                 return;
 711         }
 712         if (argv(0) == "radarmap")
 713         {
 714                 RadarMap(argc);
 715                 return;
 716         }
 717         if (argv(0) == "bbox")
 718         {
 719                 BBox();
 720                 return;
 721         }
 722         if (argv(0) == "cvar_changes")
 723         {
 724                 print(cvar_changes);
 725                 return;
 726         }
 727         if (argv(0) == "find") if(argc == 2)
 728         {
 729                 for(client = world; (client = find(client, classname, argv(1))); )
 730                         print(etos(client), "\n");
 731                 return;
 732         }
 733         if (argv(0) == "records")
 734         {
 735                 strunzone(records_reply);
 736                 records_reply = strzone(getrecords());
 737                 print(records_reply);
 738                 return;
 739         }
 740
 741         print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
 742 }
 743