data/qcsrc/server/gamec/w_rocketlauncher.c

   1 void() rlauncher_ready_01;
   2 void() rlauncher_fire1_01;
   3 void() rlauncher_deselect_01;
   4 void() rlauncher_select_01;
   5 .float rl_sound;
   6
   7 float() rlauncher_check =
   8 {
   9         if ((self.attack_finished > time && self.weapon == WEP_ROCKET_LAUNCHER)  // don't switch while guiding a missile
  10                 || self.ammo_rockets >= cvar("g_balance_rocketlauncher_ammo"))
  11                 return TRUE;
  12         return FALSE;
  13 };
  14
  15 void(float req) w_rlauncher =
  16 {
  17         if (req == WR_IDLE)
  18                 rlauncher_ready_01();
  19         else if (req == WR_AIM)
  20         {
  21                 // aim and decide to fire if appropriate
  22                 self.button0 = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
  23                 // decide whether to detonate rockets
  24                 local entity missile, targetlist, targ;
  25                 local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
  26                 local float selfdamage, teamdamage, enemydamage;
  27                 edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
  28                 coredamage = cvar("g_balance_rocketlauncher_damage");
  29                 edgeradius = cvar("g_balance_rocketlauncher_radius");
  30                 recipricoledgeradius = 1 / edgeradius;
  31                 selfdamage = 0;
  32                 teamdamage = 0;
  33                 enemydamage = 0;
  34                 targetlist = findchainfloat(bot_attack, TRUE);
  35                 missile = find(world, classname, "missile");
  36                 while (missile)
  37                 {
  38                         targ = targetlist;
  39                         while (targ)
  40                         {
  41                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
  42                                 d = edgedamage + (coredamage - edgedamage) * (1 - d * recipricoledgeradius);
  43                                 // count potential damage according to type of target
  44                                 if (targ == self)
  45                                         selfdamage = selfdamage + d;
  46                                 else if (targ.team == self.team && teamplay)
  47                                         teamdamage = teamdamage + d;
  48                                 else if (bot_shouldattack(targ))
  49                                         enemydamage = enemydamage + d;
  50                                 targ = targ.chain;
  51                         }
  52                         missile = find(missile, classname, "missile");
  53                 }
  54                 local float desirabledamage;
  55                 desirabledamage = enemydamage;
  56                 if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
  57                         desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
  58                 if (self.team && teamplay == 2)
  59                         desirabledamage = desirabledamage - teamdamage;
  60                 // if we would be doing at least half of the core damage, detonate it
  61                 // but don't fire a new shot at the same time!
  62                 if (desirabledamage >= 0.5 * coredamage)
  63                 {
  64                         self.button3 = TRUE;
  65                         self.button0 = FALSE;
  66                 }
  67         }
  68         else if (req == WR_FIRE1)
  69                 weapon_prepareattack(rlauncher_check, rlauncher_check, rlauncher_fire1_01, cvar("g_balance_rocketlauncher_refire"));
  70         else if (req == WR_FIRE2)
  71         {
  72                 if(time > self.rl_sound)
  73                 {
  74                         self.rl_sound = time + 1;
  75                         sound (self, CHAN_BODY, "weapons/rocket_det.ogg", 0.5, ATTN_NORM);
  76                 }
  77                 if(cvar("g_laserguided_missile"))
  78                 if(self.exteriorweaponentity.attack_finished < time)
  79                 {
  80                         self.exteriorweaponentity.attack_finished = time + 0.4;
  81                         self.laser_on = !self.laser_on;
  82                         sound (self, CHAN_AUTO, "weapons/tink1.ogg", 1, ATTN_NORM);
  83                 }
  84         }
  85         else if (req == WR_RAISE)
  86                 rlauncher_select_01();
  87         else if (req == WR_UPDATECOUNTS)
  88                 self.currentammo = self.ammo_rockets;
  89         else if (req == WR_DROP)
  90                 rlauncher_deselect_01();
  91         else if (req == WR_SETUP)
  92                 weapon_setup(WEP_ROCKET_LAUNCHER, "w_rl.zym", IT_ROCKETS);
  93         else if (req == WR_CHECKAMMO)
  94                 weapon_hasammo = rlauncher_check();
  95 };
  96
  97
  98 void W_Rocket_Explode (void)
  99 {
 100         vector  org2;
 101         sound (self, CHAN_BODY, "weapons/rocket_impact.ogg", 1, ATTN_NORM);
 102         org2 = findbetterlocation (self.origin, 16);
 103
 104         //te_explosion (org2);
 105         // LordHavoc: TE_TEI_BIGEXPLOSION
 106         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
 107         WriteByte (MSG_BROADCAST, 78);
 108         WriteCoord (MSG_BROADCAST, org2_x);
 109         WriteCoord (MSG_BROADCAST, org2_y);
 110         WriteCoord (MSG_BROADCAST, org2_z);
 111
 112         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
 113         self.event_damage = SUB_Null;
 114         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), IT_ROCKET_LAUNCHER);
 115
 116         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 117         {
 118                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 119                 {
 120                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
 121                         self.owner.attack_finished = time;
 122                         self.owner.switchweapon = w_getbestweapon(self.owner);
 123                 }
 124                 if(cvar("g_laserguided_missile"))
 125                                   self.owner.attack_finished = time + cvar("g_balance_rocketlauncher_refire");
 126         }
 127         remove (self);
 128 }
 129
 130 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
 131 {
 132         entity head, selected;
 133         vector dir;
 134         float dist, maxdist,// bestdist,
 135                 dot,// bestdot,
 136                 points, bestpoints;
 137         //bestdist = 9999;
 138         //bestdot = -2;
 139         bestpoints = 0;
 140         maxdist = 800;
 141         selected = world;
 142
 143         makevectors(e.angles);
 144
 145         head = find(world, classname, "laser_target");
 146         while(head)
 147         {
 148                 points = 0;
 149                 dir = normalize(head.origin - self.origin);
 150                 dot = dir * v_forward;
 151                 dist = vlen(head.origin - self.origin);
 152                 if(dist > maxdist)
 153                         dist = maxdist;
 154
 155                 // gain points for being in front
 156                 points = points + ((dot+1)*0.5) * 500
 157                         * (1 + crandom()*dot_variance);
 158                 // gain points for being close away
 159                 points = points + (1 - dist/maxdist) * 1000
 160                         * (1 + crandom()*dot_variance);
 161
 162                 traceline(e.origin, head.origin, TRUE, self);
 163                 if(trace_fraction < 1)
 164                 {
 165                         points = 0;
 166                 }
 167
 168                 if(points > bestpoints)//random() > 0.5)//
 169                 {
 170                         bestpoints = points;
 171                         selected = head;
 172                 }
 173
 174
 175                 /*
 176                 dot = dir * v_forward;
 177                 if(dot > bestdot * (1 + crandom()*dot_variance))
 178                 {
 179                         dist = vlen(head.origin - self.origin);
 180                         if(dist < bestdist * (1 + crandom()*dist_variance))
 181                         {
 182                                 traceline(e.origin, head.origin, TRUE, self);
 183                                 if(trace_fraction >= 1)
 184                                 {
 185                                 }
 186                         }
 187                 }
 188                 */
 189                 head = find(head, classname, "laser_target");
 190         }
 191
 192         //bprint(selected.owner.netname);
 193         //bprint("\n");
 194         return selected;
 195 }
 196
 197 void W_Rocket_Think (void)
 198 {
 199         entity e;
 200         vector desireddir, olddir, newdir;
 201         float turnrate;
 202         self.nextthink = time;
 203         if (time > self.cnt)
 204         {
 205                 W_Rocket_Explode ();
 206                 return;
 207         }
 208         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 209         {
 210                 if(cvar("g_laserguided_missile"))
 211                 {
 212                         if(!self.owner.button0)
 213                                 self.ltime = -1; // indicate that the player has let go of the button
 214
 215
 216                         if (self.owner.button0 && self.ltime < 0) // if the player let go of the button and then pushed it again
 217                         {
 218                                   W_Rocket_Explode ();
 219                                   return;
 220                         }
 221
 222                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 223                         {
 224                                 if(self.owner.laser_on)
 225                                 {
 226                                         if(self.attack_finished < time)
 227                                         {
 228                                                 self.attack_finished = time + 0.2 + random()*0.3;
 229                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 230                                         }
 231
 232                                         if(!self.enemy)
 233                                                 self.enemy = self.owner.weaponentity.lasertarget;
 234                                 }
 235                                 else self.enemy = world;
 236                         }
 237                         else // don't allow stealing: always target my owner's laser (if it exists)
 238                                 self.enemy = self.owner.weaponentity.lasertarget;
 239
 240                         if(self.enemy != world)
 241                         {
 242                                 //bprint(strcat("Targeting ", self.enemy.owner.netname, "'s laser\n"));
 243                                 if(!self.speed)
 244                                         self.speed = vlen(self.velocity);
 245                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 246                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 247                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 248                                 olddir = normalize(self.velocity);                              // get my current direction
 249                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 250                                 self.velocity = newdir * self.speed;                    // make me fly in the new direction at my flight speed
 251                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 252
 253                                 self.owner.attack_finished = time + 0.2;
 254                         }
 255                 }
 256                 else
 257                 {
 258                         if (self.owner.button3)
 259                                   W_Rocket_Explode ();
 260                 }
 261         }
 262 }
 263
 264 void W_Rocket_Touch (void)
 265 {
 266         if(self.owner && self.owner.lastrocket == self)
 267                 self.owner.lastrocket = world;
 268         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 269         {
 270                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
 271                 remove(self);
 272                 return;
 273         }
 274         W_Rocket_Explode ();
 275 }
 276
 277 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 278 {
 279         self.health = self.health - damage;
 280         if (self.health <= 0)
 281         {
 282                 self.owner = attacker;
 283                 W_Rocket_Explode();
 284         }
 285 }
 286
 287 void W_Rocket_Attack (void)
 288 {
 289         local entity missile;
 290         local entity flash;
 291         local vector org;
 292
 293         local vector trueaim;
 294         trueaim = W_TrueAim();
 295
 296         sound (self, CHAN_WEAPON, "weapons/rocket_fire.ogg", 1, ATTN_NORM);
 297         if (self.items & IT_STRENGTH)
 298                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 299
 300         if (cvar("g_use_ammunition") && !cvar("g_rocketarena"))
 301                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 302         self.punchangle_x = -4;
 303
 304         org = W_MuzzleOrigin (self, '15 3 -11');
 305         te_smallflash(org);
 306
 307         missile = spawn ();
 308         missile.owner = self;
 309         self.lastrocket = missile;
 310         missile.classname = "missile";
 311         missile.bot_dodge = TRUE;
 312         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 313
 314         missile.takedamage = DAMAGE_YES;
 315         missile.damageforcescale = 4;
 316         missile.health = 30;
 317         missile.event_damage = W_Rocket_Damage;
 318
 319         missile.movetype = MOVETYPE_FLY;
 320         missile.solid = SOLID_BBOX;
 321         setmodel (missile, "models/rocket.md3");
 322         setsize (missile, '0 0 0', '0 0 0');
 323
 324         setorigin (missile, org);
 325         if(cvar("g_laserguided_missile") && self.laser_on)
 326                 missile.velocity = normalize(trueaim - org) * cvar("g_balance_rocketlauncher_laserguided_speed");
 327         else
 328                 missile.velocity = normalize(trueaim - org) * cvar("g_balance_rocketlauncher_speed");
 329         missile.angles = vectoangles (missile.velocity);
 330
 331         missile.touch = W_Rocket_Touch;
 332         missile.think = W_Rocket_Think;
 333         missile.nextthink = time;
 334         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 335         missile.effects = EF_NOSHADOW;
 336         sound (missile, CHAN_BODY, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);
 337         missile.flags = FL_PROJECTILE;
 338
 339         flash = spawn ();
 340         setorigin (flash, org);
 341         setmodel (flash, "models/flash.md3");
 342         flash.velocity = v_forward * 20;
 343         flash.angles = vectoangles (flash.velocity);
 344         SUB_SetFade (flash, time, 0.4);
 345         flash.effects = flash.effects | EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 346 }
 347
 348 // weapon frames
 349
 350 void()  rlauncher_ready_01 =    {weapon_thinkf(WFRAME_IDLE, 0.1, rlauncher_ready_01); self.weaponentity.state = WS_READY;};
 351 void()  rlauncher_select_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0'); self.laser_on = 1;};
 352 void()  rlauncher_deselect_01 = {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);  self.laser_on = 0;};
 353 void()  rlauncher_fire1_01 =
 354 {
 355         weapon_doattack(rlauncher_check, rlauncher_check, W_Rocket_Attack);
 356         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), rlauncher_ready_01);
 357 };