data/qcsrc/server/gamec/w_rocketlauncher.c

   1 void() rlauncher_ready_01;
   2 void() rlauncher_fire1_01;
   3 void() rlauncher_deselect_01;
   4 void() rlauncher_select_01;
   5 .float rl_sound;
   6
   7 float() rlauncher_check =
   8 {
   9         if ((self.attack_finished > time && self.weapon == WEP_ROCKET_LAUNCHER)  // don't switch while guiding a missile
  10                 || self.ammo_rockets >= cvar("g_balance_rocketlauncher_ammo"))
  11                 return TRUE;
  12         return FALSE;
  13 };
  14
  15 void(float req) w_rlauncher =
  16 {
  17         if (req == WR_IDLE)
  18                 rlauncher_ready_01();
  19         else if (req == WR_FIRE1)
  20                 weapon_prepareattack(rlauncher_check, rlauncher_check, rlauncher_fire1_01, cvar("g_balance_rocketlauncher_refire"));
  21         else if (req == WR_FIRE2)
  22         {
  23                 if(time > self.rl_sound)
  24                 {
  25                         self.rl_sound = time + 1;
  26                         sound (self, CHAN_BODY, "weapons/rocket_det.ogg", 0.5, ATTN_NORM);
  27                 }
  28                 if(cvar("g_laserguided_missile"))
  29                 if(self.exteriorweaponentity.attack_finished < time)
  30                 {
  31                         self.exteriorweaponentity.attack_finished = time + 0.4;
  32                         self.laser_on = !self.laser_on;
  33                         sound (self, CHAN_AUTO, "weapons/tink1.ogg", 1, ATTN_NORM);
  34                 }
  35         }
  36         else if (req == WR_RAISE)
  37                 rlauncher_select_01();
  38         else if (req == WR_UPDATECOUNTS)
  39                 self.currentammo = self.ammo_rockets;
  40         else if (req == WR_DROP)
  41                 rlauncher_deselect_01();
  42         else if (req == WR_SETUP)
  43                 weapon_setup(WEP_ROCKET_LAUNCHER, "w_rl.zym", IT_ROCKETS);
  44         else if (req == WR_CHECKAMMO)
  45                 weapon_hasammo = rlauncher_check();
  46 };
  47
  48
  49 void W_Rocket_Explode (void)
  50 {
  51         vector  org2;
  52         sound (self, CHAN_BODY, "weapons/rocket_impact.ogg", 1, ATTN_NORM);
  53         org2 = findbetterlocation (self.origin, 16);
  54
  55         //te_explosion (org2);
  56         // LordHavoc: TE_TEI_BIGEXPLOSION
  57         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  58         WriteByte (MSG_BROADCAST, 78);
  59         WriteCoord (MSG_BROADCAST, org2_x);
  60         WriteCoord (MSG_BROADCAST, org2_y);
  61         WriteCoord (MSG_BROADCAST, org2_z);
  62
  63         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  64         self.event_damage = SUB_Null;
  65         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), IT_ROCKET_LAUNCHER);
  66
  67         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  68         {
  69                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  70                 {
  71                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  72                         self.owner.attack_finished = time;
  73                         self.owner.switchweapon = w_getbestweapon(self.owner);
  74                 }
  75                 if(cvar("g_laserguided_missile"))
  76                                   self.owner.attack_finished = time + cvar("g_balance_rocketlauncher_refire");
  77         }
  78         remove (self);
  79 }
  80
  81 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  82 {
  83         entity head, selected;
  84         vector dir;
  85         float dist, maxdist,// bestdist,
  86                 dot,// bestdot,
  87                 points, bestpoints;
  88         //bestdist = 9999;
  89         //bestdot = -2;
  90         bestpoints = 0;
  91         maxdist = 800;
  92         selected = world;
  93
  94         makevectors(e.angles);
  95
  96         head = find(world, classname, "laser_target");
  97         while(head)
  98         {
  99                 points = 0;
 100                 dir = normalize(head.origin - self.origin);
 101                 dot = dir * v_forward;
 102                 dist = vlen(head.origin - self.origin);
 103                 if(dist > maxdist)
 104                         dist = maxdist;
 105
 106                 // gain points for being in front
 107                 points = points + ((dot+1)*0.5) * 500
 108                         * (1 + crandom()*dot_variance);
 109                 // gain points for being close away
 110                 points = points + (1 - dist/maxdist) * 1000
 111                         * (1 + crandom()*dot_variance);
 112
 113                 traceline(e.origin, head.origin, TRUE, self);
 114                 if(trace_fraction < 1)
 115                 {
 116                         points = 0;
 117                 }
 118
 119                 if(points > bestpoints)//random() > 0.5)//
 120                 {
 121                         bestpoints = points;
 122                         selected = head;
 123                 }
 124
 125
 126                 /*
 127                 dot = dir * v_forward;
 128                 if(dot > bestdot * (1 + crandom()*dot_variance))
 129                 {
 130                         dist = vlen(head.origin - self.origin);
 131                         if(dist < bestdist * (1 + crandom()*dist_variance))
 132                         {
 133                                 traceline(e.origin, head.origin, TRUE, self);
 134                                 if(trace_fraction >= 1)
 135                                 {
 136                                 }
 137                         }
 138                 }
 139                 */
 140                 head = find(head, classname, "laser_target");
 141         }
 142
 143         //bprint(selected.owner.netname);
 144         //bprint("\n");
 145         return selected;
 146 }
 147
 148 void W_Rocket_Think (void)
 149 {
 150         entity e;
 151         vector desireddir, olddir, newdir;
 152         float turnrate;
 153         self.nextthink = time;
 154         if (time > self.cnt)
 155         {
 156                 W_Rocket_Explode ();
 157                 return;
 158         }
 159         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 160         {
 161                 if(cvar("g_laserguided_missile"))
 162                 {
 163                         if(!self.owner.button0)
 164                                 self.ltime = -1; // indicate that the player has let go of the button
 165
 166
 167                         if (self.owner.button0 && self.ltime < 0) // if the player let go of the button and then pushed it again
 168                         {
 169                                   W_Rocket_Explode ();
 170                                   return;
 171                         }
 172
 173                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 174                         {
 175                                 if(self.owner.laser_on)
 176                                 {
 177                                         if(self.attack_finished < time)
 178                                         {
 179                                                 self.attack_finished = time + 0.2 + random()*0.3;
 180                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 181                                         }
 182
 183                                         if(!self.enemy)
 184                                                 self.enemy = self.owner.weaponentity.lasertarget;
 185                                 }
 186                                 else self.enemy = world;
 187                         }
 188                         else // don't allow stealing: always target my owner's laser (if it exists)
 189                                 self.enemy = self.owner.weaponentity.lasertarget;
 190
 191                         if(self.enemy != world)
 192                         {
 193                                 //bprint(strcat("Targeting ", self.enemy.owner.netname, "'s laser\n"));
 194                                 if(!self.speed)
 195                                         self.speed = vlen(self.velocity);
 196                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 197                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 198                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 199                                 olddir = normalize(self.velocity);                              // get my current direction
 200                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 201                                 self.velocity = newdir * self.speed;                    // make me fly in the new direction at my flight speed
 202                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 203
 204                                 self.owner.attack_finished = time + 0.2;
 205                         }
 206                 }
 207                 else
 208                 {
 209                         if (self.owner.button3)
 210                                   W_Rocket_Explode ();
 211                 }
 212         }
 213 }
 214
 215 void W_Rocket_Touch (void)
 216 {
 217         if(self.owner && self.owner.lastrocket == self)
 218                 self.owner.lastrocket = world;
 219         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 220         {
 221                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
 222                 remove(self);
 223                 return;
 224         }
 225         W_Rocket_Explode ();
 226 }
 227
 228 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 229 {
 230         self.health = self.health - damage;
 231         if (self.health <= 0)
 232         {
 233                 self.owner = attacker;
 234                 W_Rocket_Explode();
 235         }
 236 }
 237
 238 void W_Rocket_Attack (void)
 239 {
 240         local entity missile;
 241         local entity flash;
 242         local vector org;
 243
 244         local vector trueaim;
 245         trueaim = W_TrueAim();
 246
 247         sound (self, CHAN_WEAPON, "weapons/rocket_fire.ogg", 1, ATTN_NORM);
 248         if (self.items & IT_STRENGTH)
 249                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 250
 251         if (cvar("g_use_ammunition") && !cvar("g_rocketarena"))
 252                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 253         self.punchangle_x = -4;
 254
 255         org = W_MuzzleOrigin (self, '15 3 -11');
 256         te_smallflash(org);
 257
 258         missile = spawn ();
 259         missile.owner = self;
 260         self.lastrocket = missile;
 261         missile.classname = "missile";
 262
 263         missile.takedamage = DAMAGE_YES;
 264         missile.damageforcescale = 4;
 265         missile.health = 30;
 266         missile.event_damage = W_Rocket_Damage;
 267
 268         missile.movetype = MOVETYPE_FLY;
 269         missile.solid = SOLID_BBOX;
 270         setmodel (missile, "models/rocket.md3");
 271         setsize (missile, '0 0 0', '0 0 0');
 272
 273         setorigin (missile, org);
 274         if(cvar("g_laserguided_missile") && self.laser_on)
 275                 missile.velocity = normalize(trueaim - org) * cvar("g_balance_rocketlauncher_laserguided_speed");
 276         else
 277                 missile.velocity = normalize(trueaim - org) * cvar("g_balance_rocketlauncher_speed");
 278         missile.angles = vectoangles (missile.velocity);
 279
 280         missile.touch = W_Rocket_Touch;
 281         missile.think = W_Rocket_Think;
 282         missile.nextthink = time;
 283         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 284         missile.effects = EF_NOSHADOW;
 285         sound (missile, CHAN_BODY, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);
 286         missile.flags = FL_PROJECTILE;
 287
 288         flash = spawn ();
 289         setorigin (flash, org);
 290         setmodel (flash, "models/flash.md3");
 291         flash.velocity = v_forward * 20;
 292         flash.angles = vectoangles (flash.velocity);
 293         SUB_SetFade (flash, time, 0.4);
 294         flash.effects = flash.effects | EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 295 }
 296
 297 // weapon frames
 298
 299 void()  rlauncher_ready_01 =    {weapon_thinkf(WFRAME_IDLE, 0.1, rlauncher_ready_01); self.weaponentity.state = WS_READY;};
 300 void()  rlauncher_select_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0'); self.laser_on = 1;};
 301 void()  rlauncher_deselect_01 = {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);  self.laser_on = 0;};
 302 void()  rlauncher_fire1_01 =
 303 {
 304         weapon_doattack(rlauncher_check, rlauncher_check, W_Rocket_Attack);
 305         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), rlauncher_ready_01);
 306 };