data/qcsrc/server/gamec/w_electro.c

   1 void() electro_ready_01;
   2 void() electro_fire1_01;
   3 void() electro_fire2_01;
   4 void() electro_deselect_01;
   5 void() electro_select_01;
   6
   7 float() electro_check =
   8 {
   9         if (self.ammo_cells >= cvar("g_balance_electro_primary_ammo"))
  10                 return TRUE;
  11         return FALSE;
  12 };
  13
  14 float() electro_check2 =
  15 {
  16         if (self.ammo_cells >= cvar("g_balance_electro_secondary_ammo") * 3)
  17                 return TRUE;
  18         return FALSE;
  19 };
  20
  21 void(float req) w_electro =
  22 {
  23         if (req == WR_IDLE)
  24                 electro_ready_01();
  25         else if (req == WR_FIRE1)
  26                 weapon_prepareattack(electro_check, electro_check, electro_fire1_01, cvar("g_balance_electro_primary_refire"));
  27         else if (req == WR_FIRE2)
  28                 weapon_prepareattack(electro_check, electro_check, electro_fire2_01, cvar("g_balance_electro_secondary_refire"));
  29         else if (req == WR_RAISE)
  30                 electro_select_01();
  31         else if (req == WR_UPDATECOUNTS)
  32                 self.currentammo = self.ammo_cells;
  33         else if (req == WR_DROP)
  34                 electro_deselect_01();
  35         else if (req == WR_SETUP)
  36                 weapon_setup(WEP_ELECTRO, "w_electro.zym", IT_CELLS);
  37         else if (req == WR_CHECKAMMO)
  38                 weapon_hasammo = electro_check() + electro_check2();
  39 };
  40
  41 void W_Plasma_Explode (void)
  42 {
  43         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  44         WriteByte (MSG_BROADCAST, 79);
  45         WriteCoord (MSG_BROADCAST, self.origin_x);
  46         WriteCoord (MSG_BROADCAST, self.origin_y);
  47         WriteCoord (MSG_BROADCAST, self.origin_z);
  48         WriteCoord (MSG_BROADCAST, 0);          // SeienAbunae: groan... Useless clutter
  49         WriteCoord (MSG_BROADCAST, 0);
  50         WriteCoord (MSG_BROADCAST, 0);
  51         WriteByte (MSG_BROADCAST, 155);
  52
  53         self.event_damage = SUB_Null;
  54         if (self.movetype == MOVETYPE_BOUNCE)
  55                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), IT_ELECTRO);
  56         else
  57                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), IT_ELECTRO);
  58         sound (self, CHAN_BODY, "weapons/electro_impact.ogg", 1, ATTN_NORM);
  59
  60         remove (self);
  61 }
  62
  63 void W_Plasma_Explode_Combo (void) {
  64         vector org2;
  65
  66         org2 = findbetterlocation (self.origin);
  67         effect (org2, "models/sprites/electrocombo.spr32", 0, 30, 35);
  68         sound (self, CHAN_BODY, "weapons/electro_impact_combo.ogg", 1, ATTN_NORM);
  69
  70         self.event_damage = SUB_Null;
  71         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), IT_ELECTRO);
  72         //te_customflash(org2, 150, 5, '0.5 0.5 1');
  73         te_explosionrgb(org2, '0.5 0.5 1');
  74         remove (self);
  75 }
  76
  77 void W_Plasma_Touch (void)
  78 {
  79         if (other.takedamage == DAMAGE_AIM) {
  80                 W_Plasma_Explode ();
  81         } else {
  82                 sound (self, CHAN_IMPACT, "weapons/electro_bounce.ogg", 1, ATTN_NORM);
  83         }
  84 }
  85
  86 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  87 {
  88         self.health = self.health - damage;
  89         if (self.health <= 0)
  90         {
  91                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  92                 {
  93                         self.classname = "plasma_chain";
  94                         W_Plasma_Explode_Combo ();
  95                 }
  96                 else
  97                         W_Plasma_Explode ();
  98         }
  99 }
 100
 101 void() W_Electro_Attack
 102 {
 103         local entity proj;
 104         local vector org;
 105         local float postion;
 106
 107         local vector trueaim;
 108         trueaim = W_TrueAim();
 109
 110         postion = self.electrocount;
 111         sound (self, CHAN_WEAPON, "weapons/electro_fire.ogg", 1, ATTN_NORM);
 112         if (self.items & IT_STRENGTH) {
 113                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 114         }
 115
 116         self.punchangle_x = -2;
 117
 118         if (self.electrocount == 0)
 119         {
 120                 self.electrocount = 1;
 121                 org = self.origin + self.view_ofs + v_forward * 15 + v_right * 5 + v_up * -14;
 122         }
 123         else if (self.electrocount == 1)
 124         {
 125                 self.electrocount = 2;
 126                 org = self.origin + self.view_ofs + v_forward * 15 + v_right * 10 + v_up * -12;
 127         }
 128         else
 129         {
 130                 self.electrocount = 0;
 131                 org = self.origin + self.view_ofs + v_forward * 15 + v_right * 15 + v_up * -14;
 132         }
 133
 134         proj = spawn ();
 135         proj.classname = "plasma_prim";
 136         proj.owner = self;
 137         proj.think = W_Plasma_Explode;
 138         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 139         proj.solid = SOLID_BBOX;
 140         setorigin(proj, org);
 141
 142         if (cvar("g_use_ammunition"))
 143                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 144         proj.effects = EF_BRIGHTFIELD | EF_FULLBRIGHT | EF_NOSHADOW;
 145         proj.movetype = MOVETYPE_FLY;
 146         proj.velocity = normalize(trueaim - org) * cvar("g_balance_electro_primary_speed");
 147         proj.angles = vectoangles(proj.velocity);
 148         proj.touch = W_Plasma_Explode;
 149         setmodel(proj, "models/elaser.mdl");
 150         setsize(proj, '0 0 0', '0 0 0');
 151
 152         sound (proj, CHAN_BODY, "weapons/electro_fly.wav", 1, ATTN_NORM);
 153 }
 154
 155 void() W_Electro_Attack2
 156 {
 157         local entity proj;
 158         local vector org;
 159         local float postion;
 160
 161         postion = self.electrocount;
 162         sound (self, CHAN_WEAPON, "weapons/electro_fire2.ogg", 1, ATTN_NORM);
 163         if (self.items & IT_STRENGTH) {
 164                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 165         }
 166
 167         self.punchangle_x = -2;
 168
 169         if (self.electrocount == 0)
 170         {
 171                 self.electrocount = 1;
 172                 org = self.origin + self.view_ofs + v_forward * 15 + v_right * 5 + v_up * -14;
 173         }
 174         else if (self.electrocount == 1)
 175         {
 176                 self.electrocount = 2;
 177                 org = self.origin + self.view_ofs + v_forward * 15 + v_right * 10 + v_up * -12;
 178         }
 179         else
 180         {
 181                 self.electrocount = 0;
 182                 org = self.origin + self.view_ofs + v_forward * 15 + v_right * 15 + v_up * -14;
 183         }
 184
 185         proj = spawn ();
 186         proj.classname = "plasma";
 187         proj.owner = self;
 188         proj.think = W_Plasma_Explode;
 189         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 190         proj.solid = SOLID_BBOX;
 191         setorigin(proj, org);
 192
 193         if (cvar("g_use_ammunition"))
 194                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 195         proj.effects = EF_ADDITIVE | EF_NOSHADOW;
 196         proj.glow_size = 50;
 197         proj.glow_color = 45;
 198         proj.movetype = MOVETYPE_BOUNCE;
 199         proj.velocity = v_forward * cvar("g_balance_electro_secondary_speed") + v_up * cvar("g_balance_electro_secondary_speed_up");
 200         proj.touch = W_Plasma_Touch;
 201         setmodel(proj, "models/ebomb.mdl");
 202         setsize(proj, '-6 -6 -3', '6 6 3');
 203         proj.takedamage = DAMAGE_YES;
 204         proj.damageforcescale = 4;
 205         proj.health = 5;
 206         proj.event_damage = W_Plasma_Damage;
 207
 208         sound (proj, CHAN_BODY, "weapons/electro_fly.wav", 1, ATTN_NORM);
 209 }
 210
 211 // weapon frames
 212
 213 void()  electro_ready_01 =      {weapon_thinkf(WFRAME_IDLE, 0.1, electro_ready_01); self.weaponentity.state = WS_READY;};
 214 void()  electro_select_01 =     {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};
 215 void()  electro_deselect_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};
 216 /*
 217 void()  electro_fire1_01 =
 218 {
 219         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 220         weapon_thinkf(WFRAME_FIRE1, 0.3, electro_ready_01);
 221 };
 222 */
 223 /*
 224 void()  electro_fire1_03 =
 225 {
 226         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 227         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_refire3"), electro_ready_01);
 228 }
 229 void()  electro_fire1_02 =
 230 {
 231         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 232         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_refire3"), electro_fire1_03);
 233 }
 234 void()  electro_fire1_01 =
 235 {
 236         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 237         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_refire3"), electro_fire1_02);
 238 }
 239 */
 240 void()  electro_fire1_01 =
 241 {
 242         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 243         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), electro_ready_01);
 244 };
 245 void()  electro_fire2_03 =
 246 {
 247         weapon_doattack(electro_check2, electro_check2, W_Electro_Attack2);
 248         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), electro_ready_01);
 249 }
 250 void()  electro_fire2_02 =
 251 {
 252         weapon_doattack(electro_check2, electro_check2, W_Electro_Attack2);
 253         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), electro_fire2_03);
 254 }
 255 void()  electro_fire2_01 =
 256 {
 257         weapon_doattack(electro_check2, electro_check2, W_Electro_Attack2);
 258         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_rsecondary_animtime"), electro_fire2_02);
 259 }