data/qcsrc/server/gamec/w_electro.c

   1 void() electro_ready_01;
   2 void() electro_fire1_01;
   3 void() electro_fire2_01;
   4 void() electro_deselect_01;
   5 void() electro_select_01;
   6
   7 float() electro_check =
   8 {
   9         if (self.ammo_cells >= cvar("g_balance_electro_primary_ammo"))
  10                 return TRUE;
  11         return FALSE;
  12 };
  13
  14 float() electro_check2 =
  15 {
  16         if (self.ammo_cells >= cvar("g_balance_electro_secondary_ammo") * 3)
  17                 return TRUE;
  18         return FALSE;
  19 };
  20
  21 void(float req) w_electro =
  22 {
  23         if (req == WR_IDLE)
  24                 electro_ready_01();
  25         else if (req == WR_FIRE1)
  26                 weapon_prepareattack(electro_check, electro_check, electro_fire1_01, cvar("g_balance_electro_primary_refire"));
  27         else if (req == WR_FIRE2)
  28                 weapon_prepareattack(electro_check2, electro_check2, electro_fire2_01, cvar("g_balance_electro_secondary_refire"));
  29         else if (req == WR_RAISE)
  30                 electro_select_01();
  31         else if (req == WR_UPDATECOUNTS)
  32                 self.currentammo = self.ammo_cells;
  33         else if (req == WR_DROP)
  34                 electro_deselect_01();
  35         else if (req == WR_SETUP)
  36                 weapon_setup(WEP_ELECTRO, "w_electro.zym", IT_CELLS);
  37         else if (req == WR_CHECKAMMO)
  38                 weapon_hasammo = electro_check() + electro_check2();
  39 };
  40
  41 void W_Plasma_Explode (void)
  42 {
  43         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  44         WriteByte (MSG_BROADCAST, 79);
  45         WriteCoord (MSG_BROADCAST, self.origin_x);
  46         WriteCoord (MSG_BROADCAST, self.origin_y);
  47         WriteCoord (MSG_BROADCAST, self.origin_z);
  48         WriteCoord (MSG_BROADCAST, 0);          // SeienAbunae: groan... Useless clutter
  49         WriteCoord (MSG_BROADCAST, 0);
  50         WriteCoord (MSG_BROADCAST, 0);
  51         WriteByte (MSG_BROADCAST, 155);
  52
  53         self.event_damage = SUB_Null;
  54         if (self.movetype == MOVETYPE_BOUNCE)
  55                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), IT_ELECTRO);
  56         else
  57                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), IT_ELECTRO);
  58         sound (self, CHAN_BODY, "weapons/electro_impact.ogg", 1, ATTN_NORM);
  59
  60         remove (self);
  61 }
  62
  63 void W_Plasma_Explode_Combo (void) {
  64         vector org2;
  65
  66         org2 = findbetterlocation (self.origin);
  67         effect (org2, "models/sprites/electrocombo.spr32", 0, 30, 35);
  68         sound (self, CHAN_BODY, "weapons/electro_impact_combo.ogg", 1, ATTN_NORM);
  69
  70         self.event_damage = SUB_Null;
  71         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), IT_ELECTRO);
  72         //te_customflash(org2, 150, 5, '0.5 0.5 1');
  73         te_explosionrgb(org2, '0.5 0.5 1');
  74         remove (self);
  75 }
  76
  77 void W_Plasma_Touch (void)
  78 {
  79         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  80         {
  81                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
  82                 remove(self);
  83                 return;
  84         }
  85         if (other.takedamage == DAMAGE_AIM) {
  86                 W_Plasma_Explode ();
  87         } else {
  88                 sound (self, CHAN_IMPACT, "weapons/electro_bounce.ogg", 1, ATTN_NORM);
  89         }
  90 }
  91
  92 void W_Plasma_TouchExplode (void)
  93 {
  94         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  95         {
  96                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
  97                 remove(self);
  98                 return;
  99         }
 100         W_Plasma_Explode ();
 101 }
 102
 103 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 104 {
 105         self.health = self.health - damage;
 106         if (self.health <= 0)
 107         {
 108                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
 109                 {
 110                         self.classname = "plasma_chain";
 111                         W_Plasma_Explode_Combo ();
 112                 }
 113                 else
 114                         W_Plasma_Explode ();
 115         }
 116 }
 117
 118 void() W_Electro_Attack
 119 {
 120         local entity proj;
 121         local vector org;
 122
 123         local vector trueaim;
 124         trueaim = W_TrueAim();
 125
 126         sound (self, CHAN_WEAPON, "weapons/electro_fire.ogg", 1, ATTN_NORM);
 127         if (self.items & IT_STRENGTH)
 128                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 129
 130         self.punchangle_x = -2;
 131
 132         if (self.electrocount == 0)
 133         {
 134                 self.electrocount = 1;
 135                 org = W_MuzzleOrigin (self, '24 5.5 -11');
 136         }
 137         else if (self.electrocount == 1)
 138         {
 139                 self.electrocount = 2;
 140                 org = W_MuzzleOrigin (self, '24 8 -8.1');
 141         }
 142         else
 143         {
 144                 self.electrocount = 0;
 145                 org = W_MuzzleOrigin (self, '24 10.5 -11');
 146         }
 147
 148         proj = spawn ();
 149         proj.classname = "plasma_prim";
 150         proj.owner = self;
 151         proj.think = W_Plasma_Explode;
 152         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 153         proj.solid = SOLID_BBOX;
 154         setorigin(proj, org);
 155
 156         if (cvar("g_use_ammunition"))
 157                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 158         proj.effects = EF_BRIGHTFIELD | EF_FULLBRIGHT | EF_NOSHADOW;
 159         proj.movetype = MOVETYPE_FLY;
 160         proj.velocity = normalize(trueaim - org) * cvar("g_balance_electro_primary_speed");
 161         proj.angles = vectoangles(proj.velocity);
 162         proj.touch = W_Plasma_TouchExplode;
 163         setmodel(proj, "models/elaser.mdl");
 164         setsize(proj, '0 0 0', '0 0 0');
 165
 166         sound (proj, CHAN_BODY, "weapons/electro_fly.wav", 1, ATTN_NORM);
 167 }
 168
 169 void() W_Electro_Attack2
 170 {
 171         local entity proj;
 172         local vector org;
 173
 174         sound (self, CHAN_WEAPON, "weapons/electro_fire2.ogg", 1, ATTN_NORM);
 175         if (self.items & IT_STRENGTH)
 176                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 177
 178         self.punchangle_x = -2;
 179
 180         if (self.electrocount == 0)
 181         {
 182                 self.electrocount = 1;
 183                 org = W_MuzzleOrigin (self, '24 6 -12');
 184         }
 185         else if (self.electrocount == 1)
 186         {
 187                 self.electrocount = 2;
 188                 org = W_MuzzleOrigin (self, '24 8 -10');
 189         }
 190         else
 191         {
 192                 self.electrocount = 0;
 193                 org = W_MuzzleOrigin (self, '24 10 -12');
 194         }
 195
 196         proj = spawn ();
 197         proj.classname = "plasma";
 198         proj.owner = self;
 199         proj.think = W_Plasma_Explode;
 200         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 201         proj.solid = SOLID_BBOX;
 202         setorigin(proj, org);
 203
 204         if (cvar("g_use_ammunition"))
 205                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 206         proj.effects = EF_ADDITIVE | EF_NOSHADOW;
 207         proj.glow_size = 50;
 208         proj.glow_color = 45;
 209         proj.movetype = MOVETYPE_BOUNCE;
 210         proj.velocity = v_forward * cvar("g_balance_electro_secondary_speed") + v_up * cvar("g_balance_electro_secondary_speed_up");
 211         proj.touch = W_Plasma_Touch;
 212         setmodel(proj, "models/ebomb.mdl");
 213         setsize(proj, '0 0 -3', '0 0 -3');
 214         proj.takedamage = DAMAGE_YES;
 215         proj.damageforcescale = 4;
 216         proj.health = 5;
 217         proj.event_damage = W_Plasma_Damage;
 218
 219         sound (proj, CHAN_BODY, "weapons/electro_fly.wav", 1, ATTN_NORM);
 220 }
 221
 222 // weapon frames
 223
 224 void()  electro_ready_01 =      {weapon_thinkf(WFRAME_IDLE, 0.1, electro_ready_01); self.weaponentity.state = WS_READY;};
 225 void()  electro_select_01 =     {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};
 226 void()  electro_deselect_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};
 227 /*
 228 void()  electro_fire1_01 =
 229 {
 230         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 231         weapon_thinkf(WFRAME_FIRE1, 0.3, electro_ready_01);
 232 };
 233 */
 234 /*
 235 void()  electro_fire1_03 =
 236 {
 237         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 238         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_refire3"), electro_ready_01);
 239 }
 240 void()  electro_fire1_02 =
 241 {
 242         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 243         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_refire3"), electro_fire1_03);
 244 }
 245 void()  electro_fire1_01 =
 246 {
 247         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 248         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_refire3"), electro_fire1_02);
 249 }
 250 */
 251 void()  electro_fire1_01 =
 252 {
 253         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 254         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), electro_ready_01);
 255 };
 256 void()  electro_fire2_03 =
 257 {
 258         weapon_doattack(electro_check2, electro_check2, W_Electro_Attack2);
 259         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), electro_ready_01);
 260 }
 261 void()  electro_fire2_02 =
 262 {
 263         weapon_doattack(electro_check2, electro_check2, W_Electro_Attack2);
 264         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), electro_fire2_03);
 265 }
 266 void()  electro_fire2_01 =
 267 {
 268         weapon_doattack(electro_check2, electro_check2, W_Electro_Attack2);
 269         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), electro_fire2_02);
 270 }