data/qcsrc/server/gamec/w_electro.c

   1 void() electro_ready_01;
   2 void() electro_fire1_01;
   3 void() electro_fire2_01;
   4 void() electro_deselect_01;
   5 void() electro_select_01;
   6
   7 float() electro_check =
   8 {
   9         if (self.ammo_cells >= cvar("g_balance_electro_primary_ammo"))
  10                 return TRUE;
  11         return FALSE;
  12 };
  13
  14 float() electro_check2 =
  15 {
  16         if (self.ammo_cells >= cvar("g_balance_electro_secondary_ammo"))
  17                 return TRUE;
  18         return FALSE;
  19 };
  20
  21 void(float req) w_electro =
  22 {
  23         if (req == WR_IDLE)
  24                 electro_ready_01();
  25         else if (req == WR_AIM)
  26                 self.button0 = bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE);
  27         else if (req == WR_FIRE1)
  28                 weapon_prepareattack(electro_check, electro_check, electro_fire1_01, cvar("g_balance_electro_primary_refire"));
  29         else if (req == WR_FIRE2)
  30                 weapon_prepareattack(electro_check2, electro_check2, electro_fire2_01, cvar("g_balance_electro_secondary_refire"));
  31         else if (req == WR_RAISE)
  32                 electro_select_01();
  33         else if (req == WR_UPDATECOUNTS)
  34                 self.currentammo = self.ammo_cells;
  35         else if (req == WR_DROP)
  36                 electro_deselect_01();
  37         else if (req == WR_SETUP)
  38                 weapon_setup(WEP_ELECTRO, "w_electro.zym", IT_CELLS);
  39         else if (req == WR_CHECKAMMO)
  40                 weapon_hasammo = electro_check() + electro_check2();
  41 };
  42
  43 void W_Plasma_Explode (void)
  44 {
  45         vector org2;
  46         org2 = findbetterlocation (self.origin, 8);
  47         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  48         WriteByte (MSG_BROADCAST, 79);
  49         WriteCoord (MSG_BROADCAST, org2_x);
  50         WriteCoord (MSG_BROADCAST, org2_y);
  51         WriteCoord (MSG_BROADCAST, org2_z);
  52         WriteCoord (MSG_BROADCAST, 0);          // SeienAbunae: groan... Useless clutter
  53         WriteCoord (MSG_BROADCAST, 0);
  54         WriteCoord (MSG_BROADCAST, 0);
  55         WriteByte (MSG_BROADCAST, 155);
  56
  57         self.event_damage = SUB_Null;
  58         if (self.movetype == MOVETYPE_BOUNCE)
  59                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), IT_ELECTRO);
  60         else
  61                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), IT_ELECTRO);
  62         sound (self, CHAN_BODY, "weapons/electro_impact.ogg", 1, ATTN_NORM);
  63
  64         remove (self);
  65 }
  66
  67 void W_Plasma_Explode_Combo (void) {
  68         vector org2;
  69
  70         org2 = findbetterlocation (self.origin, 8);
  71         te_spikequad(self.origin);
  72         /*
  73         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  74         WriteByte (MSG_BROADCAST, 79);
  75         WriteCoord (MSG_BROADCAST, org2_x);
  76         WriteCoord (MSG_BROADCAST, org2_y);
  77         WriteCoord (MSG_BROADCAST, org2_z);
  78         WriteCoord (MSG_BROADCAST, 0);          // SeienAbunae: groan... Useless clutter
  79         WriteCoord (MSG_BROADCAST, 0);
  80         WriteCoord (MSG_BROADCAST, 0);
  81         WriteByte (MSG_BROADCAST, 155);
  82         */
  83         //effect (org2, "models/sprites/electrocombo.spr32", 0, 30, 35);
  84
  85         sound (self, CHAN_BODY, "weapons/electro_impact_combo.ogg", 1, ATTN_NORM);
  86
  87         self.event_damage = SUB_Null;
  88         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), IT_ELECTRO);
  89         //te_customflash(org2, 150, 5, '0.5 0.5 1');
  90         te_explosionrgb(org2, '0.5 0.5 1');
  91         remove (self);
  92 }
  93
  94 void W_Plasma_Touch (void)
  95 {
  96         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  97         {
  98                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
  99                 remove(self);
 100                 return;
 101         }
 102         if (other.takedamage == DAMAGE_AIM) {
 103                 W_Plasma_Explode ();
 104         } else {
 105                 sound (self, CHAN_IMPACT, "weapons/electro_bounce.ogg", 1, ATTN_NORM);
 106         }
 107 }
 108
 109 void W_Plasma_TouchExplode (void)
 110 {
 111         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 112         {
 113                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
 114                 remove(self);
 115                 return;
 116         }
 117         W_Plasma_Explode ();
 118 }
 119
 120 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 121 {
 122         self.health = self.health - damage;
 123         if (self.health <= 0)
 124         {
 125                 self.takedamage = DAMAGE_NO;
 126                 self.nextthink = time;
 127                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
 128                 {
 129                         // change owner to whoever caused the combo explosion
 130                         self.owner = inflictor.owner;
 131                         self.classname = "plasma_chain";
 132                         self.think = W_Plasma_Explode_Combo;
 133                 }
 134                 else
 135                         self.think = W_Plasma_Explode;
 136         }
 137 }
 138
 139 void() W_Electro_Attack
 140 {
 141         local entity proj;
 142         local vector org;
 143
 144         local vector trueaim;
 145         trueaim = W_TrueAim();
 146
 147         sound (self, CHAN_WEAPON, "weapons/electro_fire.ogg", 1, ATTN_NORM);
 148         if (self.items & IT_STRENGTH)
 149                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 150
 151         self.punchangle_x = -2;
 152
 153         if (self.electrocount == 0)
 154         {
 155                 self.electrocount = 1;
 156                 org = W_MuzzleOrigin (self, '24 5.5 -11');
 157         }
 158         else if (self.electrocount == 1)
 159         {
 160                 self.electrocount = 2;
 161                 org = W_MuzzleOrigin (self, '24 8 -8.1');
 162         }
 163         else
 164         {
 165                 self.electrocount = 0;
 166                 org = W_MuzzleOrigin (self, '24 10.5 -11');
 167         }
 168
 169         proj = spawn ();
 170         proj.classname = "plasma_prim";
 171         proj.owner = self;
 172         proj.bot_dodge = TRUE;
 173         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 174         proj.think = W_Plasma_Explode;
 175         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 176         proj.solid = SOLID_BBOX;
 177         setorigin(proj, org);
 178
 179         if (cvar("g_use_ammunition"))
 180                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 181         proj.effects = EF_BRIGHTFIELD | EF_FULLBRIGHT | EF_NOSHADOW;
 182         proj.movetype = MOVETYPE_FLY;
 183         proj.velocity = normalize(trueaim - org) * cvar("g_balance_electro_primary_speed");
 184         proj.angles = vectoangles(proj.velocity);
 185         proj.touch = W_Plasma_TouchExplode;
 186         proj.flags = FL_PROJECTILE;
 187         setmodel(proj, "models/elaser.mdl");
 188         setsize(proj, '0 0 0', '0 0 0');
 189
 190         sound (proj, CHAN_BODY, "weapons/electro_fly.wav", 1, ATTN_NORM);
 191 }
 192
 193 void() W_Electro_Attack2
 194 {
 195         local entity proj;
 196         local vector org;
 197
 198         sound (self, CHAN_WEAPON, "weapons/electro_fire2.ogg", 1, ATTN_NORM);
 199         if (self.items & IT_STRENGTH)
 200                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 201
 202         self.punchangle_x = -2;
 203
 204         if (self.electrocount == 0)
 205         {
 206                 self.electrocount = 1;
 207                 org = W_MuzzleOrigin (self, '24 6 -12');
 208         }
 209         else if (self.electrocount == 1)
 210         {
 211                 self.electrocount = 2;
 212                 org = W_MuzzleOrigin (self, '24 8 -10');
 213         }
 214         else
 215         {
 216                 self.electrocount = 0;
 217                 org = W_MuzzleOrigin (self, '24 10 -12');
 218         }
 219
 220         proj = spawn ();
 221         proj.classname = "plasma";
 222         proj.owner = self;
 223         proj.think = W_Plasma_Explode;
 224         proj.bot_dodge = TRUE;
 225         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 226         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 227         proj.solid = SOLID_BBOX;
 228         setorigin(proj, org);
 229
 230         if (cvar("g_use_ammunition"))
 231                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 232         proj.effects = EF_ADDITIVE | EF_NOSHADOW;
 233         proj.glow_size = 50;
 234         proj.glow_color = 45;
 235         proj.movetype = MOVETYPE_BOUNCE;
 236         proj.velocity = v_forward * cvar("g_balance_electro_secondary_speed") + v_up * cvar("g_balance_electro_secondary_speed_up");
 237         proj.touch = W_Plasma_Touch;
 238         setmodel(proj, "models/ebomb.mdl");
 239         setsize(proj, '0 0 -3', '0 0 -3');
 240         proj.takedamage = DAMAGE_YES;
 241         proj.damageforcescale = 4;
 242         proj.health = 5;
 243         proj.event_damage = W_Plasma_Damage;
 244         proj.flags = FL_PROJECTILE;
 245
 246         sound (proj, CHAN_BODY, "weapons/electro_fly.wav", 1, ATTN_NORM);
 247 }
 248
 249 // weapon frames
 250
 251 void()  electro_ready_01 =      {weapon_thinkf(WFRAME_IDLE, 0.1, electro_ready_01); self.weaponentity.state = WS_READY;};
 252 void()  electro_select_01 =     {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};
 253 void()  electro_deselect_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};
 254 /*
 255 void()  electro_fire1_01 =
 256 {
 257         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 258         weapon_thinkf(WFRAME_FIRE1, 0.3, electro_ready_01);
 259 };
 260 */
 261 /*
 262 void()  electro_fire1_03 =
 263 {
 264         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 265         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_refire3"), electro_ready_01);
 266 }
 267 void()  electro_fire1_02 =
 268 {
 269         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 270         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_refire3"), electro_fire1_03);
 271 }
 272 void()  electro_fire1_01 =
 273 {
 274         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 275         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_refire3"), electro_fire1_02);
 276 }
 277 */
 278 void()  electro_fire1_01 =
 279 {
 280         weapon_doattack(electro_check, electro_check, W_Electro_Attack);
 281         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), electro_ready_01);
 282 };
 283 /*
 284 void()  electro_fire2_03 =
 285 {
 286         weapon_doattack(electro_check2, electro_check2, W_Electro_Attack2);
 287         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), electro_ready_01);
 288 }
 289 void()  electro_fire2_02 =
 290 {
 291         weapon_doattack(electro_check2, electro_check2, W_Electro_Attack2);
 292         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), electro_fire2_03);
 293 }
 294 void()  electro_fire2_01 =
 295 {
 296         weapon_doattack(electro_check2, electro_check2, W_Electro_Attack2);
 297         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), electro_fire2_02);
 298 }
 299 */
 300 void()  electro_fire2_01 =
 301 {
 302         weapon_doattack(electro_check2, electro_check2, W_Electro_Attack2);
 303         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), electro_ready_01);
 304 }