data/qcsrc/server/gamec/t_items.c

   1 //void Item_ClearRespawnEffect (void) {
   2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
   3 //}
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
  13         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
  14         //// Savage: Add simple Respawn effect and make sure it gets removed
  15         //self.effects = self.effects | EF_STARDUST;
  16         //self.think = Item_ClearRespawnEffect;
  17         //self.nextthink = time + 0.1;
  18 }
  19
  20 void Item_Touch (void)
  21 {
  22         local entity oldself;
  23         local float _switchweapon;
  24
  25         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  26         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  27         {
  28                 remove(self);
  29                 return;
  30         }
  31         if (other.classname != "player")
  32                 return;
  33         if (other.deadflag)
  34                 return;
  35         if (self.solid != SOLID_TRIGGER)
  36                 return;
  37         if (self.health && other.health >= other.max_health)
  38                 return;
  39         if (self.owner == other)
  40                 return;
  41         // Savage: Remove the respawn effect if still present
  42         self.effects = self.effects - (self.effects & EF_STARDUST);
  43
  44         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  45
  46         // in case the player has autoswitch enabled do the following:
  47         // if the player is using their best weapon before items are given, they
  48         // probably want to switch to an even better weapon after items are given
  49         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  50
  51         if (cvar("g_minstagib"))
  52         {
  53                 if (self.ammo_cells)
  54                 {
  55                         // play some cool sounds ;)
  56                         centerprint(other, "\n");
  57                         if(other.health <= 5)
  58                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  59                         else if(other.health < 50)
  60                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  61                         // sound not available
  62                         // else if(self.items == IT_CELLS)
  63                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  64
  65                         if (self.items & IT_NEX)
  66                                 W_GiveWeapon (other, IT_NEX, "Nex");
  67                         if (self.ammo_cells)
  68                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  69                         other.health = 100;
  70                 }
  71
  72                 // extralife powerup
  73                 if (self.max_health)
  74                 {
  75                         // sound not available
  76                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  77                         other.extralives = other.extralives + cvar("g_minstagib_extralives");
  78                         other.armorvalue = other.extralives;
  79                         sprint(other, "^3You picked up some extra lives\n");
  80                 }
  81
  82                 // invis powerup
  83                 if (self.strength_finished)
  84                 {
  85                         // sound not available
  86                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  87                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  88                 }
  89
  90                 // speed powerup
  91                 if (self.invincible_finished)
  92                 {
  93                         // sound not available
  94                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  95                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  96                 }
  97         }
  98         else
  99         {
 100                 if (cvar("deathmatch") == 2 && self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
 101                         return;
 102
 103                 if (self.ammo_shells)
 104                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 105                 if (self.ammo_nails)
 106                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 107                 if (self.ammo_rockets)
 108                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 109                 if (self.ammo_cells)
 110                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 111
 112                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 113                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 114                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 115                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 116                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 117                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 118                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 119                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 120
 121                 if (self.strength_finished)
 122                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 123                 if (self.invincible_finished)
 124                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 125                 //if (self.speed_finished)
 126                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 127                 //if (self.slowmo_finished)
 128                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 129
 130                 if (self.max_health)
 131                 {
 132                         other.health = other.health + self.max_health;
 133                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 134                 }
 135                 if (self.health && other.health < other.max_health)
 136                         other.health = min(other.health + self.health, other.max_health);
 137                 if (self.armorvalue)
 138                 {
 139                         other.armorvalue = other.armorvalue + self.armorvalue;
 140                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 141                 }
 142         }
 143
 144         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 145
 146         oldself = self;
 147         self = other;
 148
 149         if (_switchweapon)
 150                 self.switchweapon = w_getbestweapon(self);
 151         if (self.switchweapon != self.weapon)
 152                 self.cnt = self.weapon;
 153
 154         //w_updateweapon ();
 155         //w_updateammo ();
 156         weapon_action(self.weapon, WR_UPDATECOUNTS);
 157
 158         self = oldself;
 159
 160         if (self.classname == "droppedweapon")
 161                 remove (self);
 162         else
 163         {
 164                 self.solid = SOLID_NOT;
 165                 self.model = string_null;
 166                 self.nextthink = time + self.respawntime;
 167                 self.think = Item_Respawn;
 168                 setorigin (self, self.origin);
 169         }
 170 }
 171
 172 // Savage: used for item garbage-collection
 173 // TODO: perhaps nice special effect?
 174 void RemoveItem(void) = {
 175         remove(self);
 176 }
 177
 178 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags)
 179 {
 180         vector org;
 181         org = self.origin;
 182
 183         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 184                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 185         {
 186                 remove (self);
 187                 return;
 188         }
 189
 190         if (cvar("g_minstagib"))
 191         {
 192                 // don't remove dropped items and powerups
 193                 if (self.classname != "droppedweapon" &&
 194                     self.classname != "minstagib")
 195                 {
 196                         remove (self);
 197                         return;
 198                 }
 199         }
 200
 201         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 202         {
 203                 remove(self);
 204                 return;
 205         }
 206
 207         if(cvar("g_instagib") || cvar("g_rocketarena"))
 208         {
 209                 remove(self);
 210                 return;
 211         }
 212
 213         if (self.classname == "droppedweapon")
 214         {
 215                 // don't drop if in a NODROP zone (such as lava)
 216                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 217                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 218                 {
 219                         remove(self);
 220                         return;
 221                 }
 222         }
 223
 224         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 225                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 226                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
 227         {
 228                 self.target = "###item###"; // for finding the nearest item using find()
 229         }
 230         self.mdl = itemmodel;
 231         //self.noise = pickupsound;
 232         self.item_pickupsound = pickupsound;
 233         // let mappers override respawntime
 234         if (!self.respawntime)
 235                 self.respawntime = defaultrespawntime;
 236         self.netname = itemname;
 237         self.items = itemid;
 238         self.flags = FL_ITEM | itemflags;
 239         setmodel (self, self.mdl);
 240         if (itemflags & FL_WEAPON)
 241         {
 242                 setorigin (self, self.origin + '0 0 23');
 243                 setsize (self, '-12 -12 -12', '12 12 12');
 244
 245                 // neutral team color for pickup weapons
 246                 self.colormap = 160 * 1024 + 160;
 247         }
 248         else
 249         {
 250                 setorigin (self, self.origin + '0 0 25');
 251         //      setsize (self, '-8 -8 -5', '8 8 8');
 252         }
 253         self.movetype = MOVETYPE_TOSS;
 254         self.solid = SOLID_TRIGGER;
 255         self.touch = Item_Touch;
 256
 257         // Savage: remove thrown items after a certain period of time ("garbage collection")
 258         if (self.classname == "droppedweapon")
 259         {
 260                 self.think = RemoveItem;
 261                 self.nextthink = time + 60;
 262         }
 263         else if (!self.noalign)
 264         {
 265                 vector z_offset;
 266
 267                 z_offset = '0 0 1';
 268
 269                 if (itemid == IT_SHELLS)
 270                         z_offset = '0 0 4';
 271                 else if (itemid == IT_ROCKETS)
 272                         z_offset = '0 0 4';
 273                 else if (itemid == IT_NAILS)
 274                         z_offset = '0 0 0';
 275                 else if (itemid == IT_25HP)
 276                         z_offset = '0 0 5';
 277                 else if (itemid == IT_ARMOR)
 278                         z_offset = '0 0 3';
 279
 280                 self.movetype = MOVETYPE_NONE;
 281                 setorigin(self, find_floor(org) + z_offset);
 282         }
 283         else
 284         {
 285                 self.movetype = MOVETYPE_NONE;
 286                 setorigin(self, org);
 287         }
 288
 289         if (cvar("g_fullbrightitems"))
 290                 self.effects = self.effects | EF_FULLBRIGHT;
 291
 292 }
 293
 294 /* replace items in minstagib
 295  * IT_STRENGTH   = invisibility
 296  * IT_NAILS      = extra lives
 297  * IT_INVINCIBLE = speed
 298  */
 299 void minstagib_items (float itemid)
 300 {
 301         // we don't want to replace dropped weapons ;)
 302         if (self.classname == "droppedweapon")
 303         {
 304                 self.ammo_cells = 25;
 305                 StartItem ("models/weapons/g_nex.md3",
 306                         "weapons/weaponpickup.ogg", 15,
 307                         "Nex Gun", IT_NEX, FL_WEAPON);
 308                 return;
 309         }
 310
 311         local float rnd;
 312         self.classname = "minstagib";
 313
 314         // replace rocket launchers and nex guns with ammo cells
 315         if (itemid == IT_CELLS)
 316         {
 317                 self.ammo_cells = 1;
 318                 StartItem ("models/items/a_cells.md3",
 319                         "misc/itempickup.ogg", 45,
 320                         "Nex Ammo", IT_CELLS, 0);
 321                 return;
 322         }
 323
 324         // randomize
 325         rnd = random() * 3;
 326         if (rnd <= 1)
 327                 itemid = IT_STRENGTH;
 328         else if (rnd <= 2)
 329                 itemid = IT_NAILS;
 330         else
 331                 itemid = IT_INVINCIBLE;
 332
 333         // replace with invis
 334         if (itemid == IT_STRENGTH)
 335         {
 336                 self.effects = EF_ADDITIVE;
 337                 self.strength_finished = 30;
 338                 StartItem ("models/items/g_strength.md3",
 339                         "misc/powerup.ogg", 120,
 340                         "Invisibility", IT_STRENGTH, FL_POWERUP);
 341         }
 342         // replace with extra lives
 343         if (itemid == IT_NAILS)
 344         {
 345                 self.max_health = 1;
 346                 StartItem ("models/items/g_h100.md3",
 347                         "misc/megahealth.ogg", 120,
 348                         "Extralife", IT_NAILS, FL_POWERUP);
 349
 350         }
 351         // replace with ammo
 352         if (itemid == IT_INVINCIBLE)
 353         {
 354                 self.effects = EF_ADDITIVE;
 355                 self.invincible_finished = 30;
 356                 StartItem ("models/items/g_invincible.md3",
 357                         "misc/powerup_shield.ogg", 120,
 358                         "Speed", IT_INVINCIBLE, FL_POWERUP);
 359         }
 360
 361 }
 362
 363 void weapon_uzi (void) {
 364         self.ammo_nails = 120;
 365         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON);
 366 }
 367
 368 void weapon_shotgun (void) {
 369         self.ammo_shells = 15;
 370         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON);
 371 }
 372
 373 void weapon_grenadelauncher (void) {
 374         self.ammo_rockets = 15;
 375         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON);
 376 }
 377
 378 void weapon_electro (void) {
 379         self.ammo_cells = 25;
 380         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON);
 381 }
 382
 383 void weapon_crylink (void) {
 384         self.ammo_cells = 25;
 385         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON);
 386 }
 387
 388 void weapon_nex (void) {
 389         if (cvar("g_minstagib")) {
 390                 minstagib_items(IT_CELLS);
 391         } else {
 392                 self.ammo_cells = 25;
 393                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_NEX), IT_NEX, FL_WEAPON);
 394         }
 395 }
 396
 397 void weapon_hagar (void) {
 398         self.ammo_rockets = 15;
 399         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON);
 400 }
 401
 402 void weapon_rocketlauncher (void) {
 403         if (cvar("g_minstagib")) {
 404                 minstagib_items(IT_CELLS);
 405         } else {
 406                 self.ammo_rockets = 15;
 407                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON);
 408         }
 409 }
 410
 411 void item_rockets (void) {
 412         self.ammo_rockets = 15;
 413         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0);
 414 }
 415
 416 void item_bullets (void) {
 417         self.ammo_nails = 120;
 418         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0);
 419 }
 420
 421 void item_cells (void) {
 422         self.ammo_cells = 25;
 423         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0);
 424 }
 425
 426 void item_shells (void) {
 427         self.ammo_shells = 15;
 428         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0);
 429 }
 430
 431 void item_armor1 (void) {
 432         self.armorvalue = 5;
 433         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0);
 434 }
 435
 436 void item_armor25 (void) {
 437         self.armorvalue = 100;
 438         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0);
 439 }
 440
 441 void item_health1 (void) {
 442         self.max_health = 5;
 443         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", IT_5HP, 0);
 444 }
 445
 446 void item_health25 (void) {
 447         self.max_health = 25;
 448         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", IT_25HP, 0);
 449 }
 450
 451 void item_health100 (void) {
 452         if(!cvar("g_powerup_superhealth"))
 453                 return;
 454
 455         if(cvar("g_minstagib")) {
 456                 minstagib_items(IT_NAILS);
 457         } else {
 458                 self.max_health = 100;
 459                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", IT_HEALTH, 0);
 460         }
 461 }
 462
 463 void item_strength (void) {
 464         if(!cvar("g_powerup_strength"))
 465                 return;
 466
 467         if(cvar("g_minstagib")) {
 468                 minstagib_items(IT_STRENGTH);
 469         } else {
 470                 self.strength_finished = 30;
 471                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP);
 472         }
 473 }
 474
 475 void item_invincible (void) {
 476         if(!cvar("g_powerup_shield"))
 477                 return;
 478
 479         if(cvar("g_minstagib")) {
 480                 minstagib_items(IT_INVINCIBLE);
 481         } else {
 482                 self.invincible_finished = 30;
 483                 self.effects = EF_ADDITIVE;
 484                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP);
 485         }
 486 }
 487 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP);}
 488 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP);}
 489
 490 void misc_models (void)
 491 {
 492         precache_model (self.model);
 493         setmodel (self, self.model);
 494         setsize (self, self.mins, self.maxs);
 495 }
 496
 497